ground/gcs/src/libs/osgearth/osgearth.pro

   1 TEMPLATE = lib
   2 TARGET = GCSOsgEarth
   3 DEFINES += OSGEARTH_LIBRARY
   4
   5 #CONFIG += mys2
   6
   7 osg:DEFINES += USE_OSG
   8 osgQt:DEFINES += USE_OSG_QT
   9
  10 osgearth:DEFINES += USE_OSGEARTH
  11 osgearthQt:DEFINES += USE_OSGEARTH_QT
  12
  13 #DEFINES += OSG_USE_QT_PRIVATE
  14
  15 QT += widgets opengl qml quick
  16 contains(DEFINES, OSG_USE_QT_PRIVATE) {
  17     QT += core-private gui-private
  18 }
  19
  20 include(../../library.pri)
  21 include(../utils/utils.pri)
  22
  23 include(osgearth_dependencies.pri)
  24
  25 linux {
  26     QMAKE_RPATHDIR = $$shell_quote(\$$ORIGIN/$$relative_path($$GCS_LIBRARY_PATH/osg, $$GCS_LIBRARY_PATH))
  27     include(../../rpath.pri)
  28 }
  29
  30 # disable all warnings on mac to avoid build failures
  31 macx:CONFIG += warn_off
  32
  33 # osg and osgearth emit a lot of unused parameter warnings...
  34 QMAKE_CXXFLAGS += -Wno-unused-parameter
  35
  36 HEADERS += \
  37     osgearth_global.h \
  38     utility.h \
  39     shapeutils.h \
  40     qtwindowingsystem.h \
  41     osgearth.h
  42
  43 SOURCES += \
  44     utility.cpp \
  45     shapeutils.cpp \
  46     qtwindowingsystem.cpp \
  47     osgearth.cpp
  48
  49 HEADERS += \
  50     osgQtQuick/Export.hpp \
  51     osgQtQuick/OSGNode.hpp \
  52     osgQtQuick/OSGGroup.hpp \
  53     osgQtQuick/OSGTransformNode.hpp \
  54     osgQtQuick/OSGShapeNode.hpp \
  55     osgQtQuick/OSGTextNode.hpp \
  56     osgQtQuick/OSGFileNode.hpp \
  57     osgQtQuick/OSGBackgroundNode.hpp \
  58     osgQtQuick/OSGCamera.hpp \
  59     osgQtQuick/OSGViewport.hpp
  60
  61 SOURCES += \
  62     osgQtQuick/OSGNode.cpp \
  63     osgQtQuick/OSGGroup.cpp \
  64     osgQtQuick/OSGTransformNode.cpp \
  65     osgQtQuick/OSGShapeNode.cpp \
  66     osgQtQuick/OSGTextNode.cpp \
  67     osgQtQuick/OSGFileNode.cpp \
  68     osgQtQuick/OSGBackgroundNode.cpp \
  69     osgQtQuick/OSGCamera.cpp \
  70     osgQtQuick/OSGViewport.cpp
  71
  72 osgearth:HEADERS += \
  73     osgQtQuick/OSGModelNode.hpp \
  74     osgQtQuick/OSGSkyNode.hpp
  75
  76 osgearth:SOURCES += \
  77     osgQtQuick/OSGModelNode.cpp \
  78     osgQtQuick/OSGSkyNode.cpp
  79
  80 copy_osg:include(copydata.pro)