ground/gcs/gcs.pro

   1 #
   2 # Qmake project for the LibrePilot GCS.
   3 # Copyright (c) 2009-2013, The OpenPilot Team, http://www.openpilot.org
   4 # Copyright (c) 2015-2016, The LibrePilot Team, http://www.librepilot.org
   5 #
   6
   7 cache()
   8
   9 # check Qt version
  10 QT_VERSION = $$[QT_VERSION]
  11 QT_VERSION = $$split(QT_VERSION, ".")
  12 QT_VER_MAJ = $$member(QT_VERSION, 0)
  13 QT_VER_MIN = $$member(QT_VERSION, 1)
  14
  15 lessThan(QT_VER_MAJ, 5) | lessThan(QT_VER_MIN, 2) {
  16    error(OpenPilot GCS requires Qt 5.2.0 or newer but Qt $$[QT_VERSION] was detected.)
  17 }
  18
  19 macx {
  20     # This ensures that code is compiled with the /usr/bin version of gcc instead
  21     # of the gcc in XCode.app/Context/Development
  22     QMAKE_CC = /usr/bin/gcc
  23     QMAKE_CXX = /usr/bin/g++
  24     QMAKE_LINK = /usr/bin/g++
  25     QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.6
  26 }
  27
  28 include(gcs.pri)
  29
  30 TEMPLATE  = subdirs
  31 CONFIG   += ordered
  32
  33 DEFINES += USE_PATHPLANNER
  34
  35 SUBDIRS = src
  36
  37 equals(copyqt, 1) {
  38     SUBDIRS += copydata
  39     copydata.file = copydata.pro
  40     win32 {
  41         SUBDIRS += opengl
  42         opengl.file = opengl.pro
  43     }
  44 }