build/make/ads2gas_apple.pl

   1 #!/usr/bin/env perl
   2 ##
   3 ##  Copyright (c) 2010 The WebM project authors. All Rights Reserved.
   4 ##
   5 ##  Use of this source code is governed by a BSD-style license
   6 ##  that can be found in the LICENSE file in the root of the source
   7 ##  tree. An additional intellectual property rights grant can be found
   8 ##  in the file PATENTS.  All contributing project authors may
   9 ##  be found in the AUTHORS file in the root of the source tree.
  10 ##
  11
  12
  13 # ads2gas.pl
  14 # Author: Eric Fung (efung (at) acm.org)
  15 #
  16 # Convert ARM Developer Suite 1.0.1 syntax assembly source to GNU as format
  17 #
  18 # Usage: cat inputfile | perl ads2gas.pl > outputfile
  19 #
  20 print "@ This file was created from a .asm file\n";
  21 print "@  using the ads2gas_apple.pl script.\n\n";
  22 print "\t.set WIDE_REFERENCE, 0\n";
  23 print "\t.set ARCHITECTURE, 5\n";
  24 print "\t.set DO1STROUNDING, 0\n";
  25
  26 my %register_aliases;
  27 my %macro_aliases;
  28
  29 my @mapping_list = ("\$0", "\$1", "\$2", "\$3", "\$4", "\$5", "\$6", "\$7", "\$8", "\$9");
  30
  31 my @incoming_array;
  32
  33 # Perl trim function to remove whitespace from the start and end of the string
  34 sub trim($)
  35 {
  36     my $string = shift;
  37     $string =~ s/^\s+//;
  38     $string =~ s/\s+$//;
  39     return $string;
  40 }
  41
  42 while (<STDIN>)
  43 {
  44     # Load and store alignment
  45     s/@/,:/g;
  46
  47     # Comment character
  48     s/;/@/g;
  49
  50     # Hexadecimal constants prefaced by 0x
  51     s/#&/#0x/g;
  52
  53     # Convert :OR: to |
  54     s/:OR:/ | /g;
  55
  56     # Convert :AND: to &
  57     s/:AND:/ & /g;
  58
  59     # Convert :NOT: to ~
  60     s/:NOT:/ ~ /g;
  61
  62     # Convert :SHL: to <<
  63     s/:SHL:/ << /g;
  64
  65     # Convert :SHR: to >>
  66     s/:SHR:/ >> /g;
  67
  68     # Convert ELSE to .else
  69     s/ELSE/.else/g;
  70
  71     # Convert ENDIF to .endif
  72     s/ENDIF/.endif/g;
  73
  74     # Convert ELSEIF to .elseif
  75     s/ELSEIF/.elseif/g;
  76
  77     # Convert LTORG to .ltorg
  78     s/LTORG/.ltorg/g;
  79
  80     # Convert IF :DEF:to .if
  81     # gcc doesn't have the ability to do a conditional
  82     # if defined variable that is set by IF :DEF: on
  83     # armasm, so convert it to a normal .if and then
  84     # make sure to define a value elesewhere
  85     if (s/\bIF :DEF:\b/.if /g)
  86     {
  87         s/=/==/g;
  88     }
  89
  90     # Convert IF to .if
  91     if (s/\bIF\b/.if/g)
  92     {
  93         s/=/==/g;
  94     }
  95
  96     # Convert INCLUDE to .INCLUDE "file"
  97     s/INCLUDE(\s*)(.*)$/.include $1\"$2\"/;
  98
  99     # Code directive (ARM vs Thumb)
 100     s/CODE([0-9][0-9])/.code $1/;
 101
 102     # No AREA required
 103     # But ALIGNs in AREA must be obeyed
 104     s/^\s*AREA.*ALIGN=([0-9])$/.text\n.p2align $1/;
 105     # If no ALIGN, strip the AREA and align to 4 bytes
 106     s/^\s*AREA.*$/.text\n.p2align 2/;
 107
 108     # DCD to .word
 109     # This one is for incoming symbols
 110     s/DCD\s+\|(\w*)\|/.long $1/;
 111
 112     # DCW to .short
 113     s/DCW\s+\|(\w*)\|/.short $1/;
 114     s/DCW(.*)/.short $1/;
 115
 116     # Constants defined in scope
 117     s/DCD(.*)/.long $1/;
 118     s/DCB(.*)/.byte $1/;
 119
 120     # Build a hash of all the register - alias pairs.
 121     if (s/(.*)RN(.*)/$1 .req $2/g)
 122     {
 123         $register_aliases{trim($1)} = trim($2);
 124         next;
 125     }
 126
 127     while (($key, $value) = each(%register_aliases))
 128     {
 129         s/\b$key\b/$value/g;
 130     }
 131
 132     # Make function visible to linker, and make additional symbol with
 133     # prepended underscore
 134     s/EXPORT\s+\|([\$\w]*)\|/.globl _$1\n\t.globl $1/;
 135     s/IMPORT\s+\|([\$\w]*)\|/.globl $1/;
 136
 137     # No vertical bars required; make additional symbol with prepended
 138     # underscore
 139     s/^\|(\$?\w+)\|/_$1\n\t$1:/g;
 140
 141     # Labels need trailing colon
 142 #   s/^(\w+)/$1:/ if !/EQU/;
 143     # put the colon at the end of the line in the macro
 144     s/^([a-zA-Z_0-9\$]+)/$1:/ if !/EQU/;
 145
 146     # ALIGN directive
 147     s/ALIGN/.balign/g;
 148
 149     # Strip ARM
 150     s/\sARM/@ ARM/g;
 151
 152     # Strip REQUIRE8
 153     #s/\sREQUIRE8/@ REQUIRE8/g;
 154     s/\sREQUIRE8/@ /g;
 155
 156     # Strip PRESERVE8
 157     s/\sPRESERVE8/@ PRESERVE8/g;
 158
 159     # Strip PROC and ENDPROC
 160     s/PROC/@/g;
 161     s/ENDP/@/g;
 162
 163     # EQU directive
 164     s/(.*)EQU(.*)/.set $1, $2/;
 165
 166     # Begin macro definition
 167     if (/MACRO/)
 168     {
 169         # Process next line down, which will be the macro definition
 170         $_ = <STDIN>;
 171
 172         $trimmed = trim($_);
 173
 174         # remove commas that are separating list
 175         $trimmed =~ s/,//g;
 176
 177         # string to array
 178         @incoming_array = split(/ /, $trimmed);
 179
 180         print ".macro @incoming_array[0]\n";
 181
 182         # remove the first element, as that is the name of the macro
 183         shift (@incoming_array);
 184
 185         @macro_aliases{@incoming_array} = @mapping_list;
 186
 187         next;
 188     }
 189
 190     while (($key, $value) = each(%macro_aliases))
 191     {
 192         $key =~ s/\$/\\\$/;
 193         s/$key\b/$value/g;
 194     }
 195
 196     # For macros, use \ to reference formal params
 197 #   s/\$/\\/g;                  # End macro definition
 198     s/MEND/.endm/;              # No need to tell it where to stop assembling
 199     next if /^\s*END\s*$/;
 200     print;
 201 }