| blob | f0b4b516304f48cb1863b1ebda7fafa80a0e5ab7 |
1 /*
2 * head.S: The initial boot code for the Sparc port of Linux.
3 *
4 * Copyright (C) 1995 David S. Miller (davem@caip.rutgers.edu)
5 * Copyright (C) 1995,1999 Pete Zaitcev (zaitcev@yahoo.com)
6 * Copyright (C) 1996 Miguel de Icaza (miguel@nuclecu.unam.mx)
7 * Copyright (C) 1997 Jakub Jelinek (jj@sunsite.mff.cuni.cz)
8 * Copyright (C) 1997 Michael A. Griffith (grif@acm.org)
9 *
10 * CompactPCI platform by Eric Brower, 1999.
11 */
13 #include <linux/version.h>
14 #include <linux/init.h>
16 #include <asm/head.h>
17 #include <asm/asi.h>
18 #include <asm/contregs.h>
19 #include <asm/ptrace.h>
20 #include <asm/psr.h>
21 #include <asm/page.h>
22 #include <asm/kdebug.h>
23 #include <asm/winmacro.h>
24 #include <asm/thread_info.h> /* TI_UWINMASK */
25 #include <asm/errno.h>
26 #include <asm/pgtsrmmu.h> /* SRMMU_PGDIR_SHIFT */
28 .data
29 /*
30 * The following are used with the prom_vector node-ops to figure out
31 * the cpu-type
32 */
34 .align 4
35 cputyp:
36 .word 1
38 .align 4
39 .globl cputypval
40 cputypval:
41 .asciz "sun4c"
42 .ascii " "
44 cputypvalend:
45 cputypvallen = cputypvar - cputypval
47 .align 4
48 /*
49 * Sun people can't spell worth damn. "compatability" indeed.
50 * At least we *know* we can't spell, and use a spell-checker.
51 */
53 /* Uh, actually Linus it is I who cannot spell. Too much murky
54 * Sparc assembly will do this to ya.
55 */
56 cputypvar:
57 .asciz "compatability"
59 /* Tested on SS-5, SS-10. Probably someone at Sun applied a spell-checker. */
60 .align 4
61 cputypvar_sun4m:
62 .asciz "compatible"
64 .align 4
66 sun4_notsup:
67 .asciz "Sparc-Linux sun4 support does no longer exist.\n\n"
68 .align 4
70 sun4e_notsup:
71 .asciz "Sparc-Linux sun4e support does not exist\n\n"
72 .align 4
74 /* The Sparc trap table, bootloader gives us control at _start. */
75 .section .text.head,"ax"
76 .globl start, _stext, _start, __stext
77 .globl trapbase
78 _start: /* danger danger */
79 __stext:
80 _stext:
81 start:
82 trapbase:
83 #ifdef CONFIG_SMP
84 trapbase_cpu0:
85 #endif
86 /* We get control passed to us here at t_zero. */
87 t_zero: b gokernel; nop; nop; nop;
88 t_tflt: SPARC_TFAULT /* Inst. Access Exception */
89 t_bins: TRAP_ENTRY(0x2, bad_instruction) /* Illegal Instruction */
90 t_pins: TRAP_ENTRY(0x3, priv_instruction) /* Privileged Instruction */
91 t_fpd: TRAP_ENTRY(0x4, fpd_trap_handler) /* Floating Point Disabled */
92 t_wovf: WINDOW_SPILL /* Window Overflow */
93 t_wunf: WINDOW_FILL /* Window Underflow */
94 t_mna: TRAP_ENTRY(0x7, mna_handler) /* Memory Address Not Aligned */
95 t_fpe: TRAP_ENTRY(0x8, fpe_trap_handler) /* Floating Point Exception */
96 t_dflt: SPARC_DFAULT /* Data Miss Exception */
97 t_tio: TRAP_ENTRY(0xa, do_tag_overflow) /* Tagged Instruction Ovrflw */
98 t_wpt: TRAP_ENTRY(0xb, do_watchpoint) /* Watchpoint Detected */
99 t_badc: BAD_TRAP(0xc) BAD_TRAP(0xd) BAD_TRAP(0xe) BAD_TRAP(0xf) BAD_TRAP(0x10)
100 t_irq1: TRAP_ENTRY_INTERRUPT(1) /* IRQ Software/SBUS Level 1 */
101 t_irq2: TRAP_ENTRY_INTERRUPT(2) /* IRQ SBUS Level 2 */
102 t_irq3: TRAP_ENTRY_INTERRUPT(3) /* IRQ SCSI/DMA/SBUS Level 3 */
103 t_irq4: TRAP_ENTRY_INTERRUPT(4) /* IRQ Software Level 4 */
104 t_irq5: TRAP_ENTRY_INTERRUPT(5) /* IRQ SBUS/Ethernet Level 5 */
105 t_irq6: TRAP_ENTRY_INTERRUPT(6) /* IRQ Software Level 6 */
106 t_irq7: TRAP_ENTRY_INTERRUPT(7) /* IRQ Video/SBUS Level 5 */
107 t_irq8: TRAP_ENTRY_INTERRUPT(8) /* IRQ SBUS Level 6 */
108 t_irq9: TRAP_ENTRY_INTERRUPT(9) /* IRQ SBUS Level 7 */
109 t_irq10:TRAP_ENTRY_INTERRUPT(10) /* IRQ Timer #1 (one we use) */
110 t_irq11:TRAP_ENTRY_INTERRUPT(11) /* IRQ Floppy Intr. */
111 t_irq12:TRAP_ENTRY_INTERRUPT(12) /* IRQ Zilog serial chip */
112 t_irq13:TRAP_ENTRY_INTERRUPT(13) /* IRQ Audio Intr. */
113 t_irq14:TRAP_ENTRY_INTERRUPT(14) /* IRQ Timer #2 */
114 .globl t_nmi
115 #ifndef CONFIG_SMP
116 t_nmi: NMI_TRAP /* Level 15 (NMI) */
117 #else
118 t_nmi: TRAP_ENTRY(0x1f, linux_trap_ipi15_sun4m)
119 #endif
120 t_racc: TRAP_ENTRY(0x20, do_reg_access) /* General Register Access Error */
121 t_iacce:BAD_TRAP(0x21) /* Instr Access Error */
122 t_bad22:BAD_TRAP(0x22) BAD_TRAP(0x23)
123 t_cpdis:TRAP_ENTRY(0x24, do_cp_disabled) /* Co-Processor Disabled */
124 t_uflsh:SKIP_TRAP(0x25, unimp_flush) /* Unimplemented FLUSH inst. */
125 t_bad26:BAD_TRAP(0x26) BAD_TRAP(0x27)
126 t_cpexc:TRAP_ENTRY(0x28, do_cp_exception) /* Co-Processor Exception */
127 t_dacce:SPARC_DFAULT /* Data Access Error */
128 t_hwdz: TRAP_ENTRY(0x2a, do_hw_divzero) /* Division by zero, you lose... */
129 t_dserr:BAD_TRAP(0x2b) /* Data Store Error */
130 t_daccm:BAD_TRAP(0x2c) /* Data Access MMU-Miss */
131 t_bad2d:BAD_TRAP(0x2d) BAD_TRAP(0x2e) BAD_TRAP(0x2f) BAD_TRAP(0x30) BAD_TRAP(0x31)
132 t_bad32:BAD_TRAP(0x32) BAD_TRAP(0x33) BAD_TRAP(0x34) BAD_TRAP(0x35) BAD_TRAP(0x36)
133 t_bad37:BAD_TRAP(0x37) BAD_TRAP(0x38) BAD_TRAP(0x39) BAD_TRAP(0x3a) BAD_TRAP(0x3b)
134 t_iaccm:BAD_TRAP(0x3c) /* Instr Access MMU-Miss */
135 t_bad3d:BAD_TRAP(0x3d) BAD_TRAP(0x3e) BAD_TRAP(0x3f) BAD_TRAP(0x40) BAD_TRAP(0x41)
136 t_bad42:BAD_TRAP(0x42) BAD_TRAP(0x43) BAD_TRAP(0x44) BAD_TRAP(0x45) BAD_TRAP(0x46)
137 t_bad47:BAD_TRAP(0x47) BAD_TRAP(0x48) BAD_TRAP(0x49) BAD_TRAP(0x4a) BAD_TRAP(0x4b)
138 t_bad4c:BAD_TRAP(0x4c) BAD_TRAP(0x4d) BAD_TRAP(0x4e) BAD_TRAP(0x4f) BAD_TRAP(0x50)
139 t_bad51:BAD_TRAP(0x51) BAD_TRAP(0x52) BAD_TRAP(0x53) BAD_TRAP(0x54) BAD_TRAP(0x55)
140 t_bad56:BAD_TRAP(0x56) BAD_TRAP(0x57) BAD_TRAP(0x58) BAD_TRAP(0x59) BAD_TRAP(0x5a)
141 t_bad5b:BAD_TRAP(0x5b) BAD_TRAP(0x5c) BAD_TRAP(0x5d) BAD_TRAP(0x5e) BAD_TRAP(0x5f)
142 t_bad60:BAD_TRAP(0x60) BAD_TRAP(0x61) BAD_TRAP(0x62) BAD_TRAP(0x63) BAD_TRAP(0x64)
143 t_bad65:BAD_TRAP(0x65) BAD_TRAP(0x66) BAD_TRAP(0x67) BAD_TRAP(0x68) BAD_TRAP(0x69)
144 t_bad6a:BAD_TRAP(0x6a) BAD_TRAP(0x6b) BAD_TRAP(0x6c) BAD_TRAP(0x6d) BAD_TRAP(0x6e)
145 t_bad6f:BAD_TRAP(0x6f) BAD_TRAP(0x70) BAD_TRAP(0x71) BAD_TRAP(0x72) BAD_TRAP(0x73)
146 t_bad74:BAD_TRAP(0x74) BAD_TRAP(0x75) BAD_TRAP(0x76) BAD_TRAP(0x77) BAD_TRAP(0x78)
147 t_bad79:BAD_TRAP(0x79) BAD_TRAP(0x7a) BAD_TRAP(0x7b) BAD_TRAP(0x7c) BAD_TRAP(0x7d)
148 t_bad7e:BAD_TRAP(0x7e) BAD_TRAP(0x7f)
149 t_bad80:BAD_TRAP(0x80) /* SunOS System Call */
150 t_sbkpt:BREAKPOINT_TRAP /* Software Breakpoint/KGDB */
151 t_divz: TRAP_ENTRY(0x82, do_hw_divzero) /* Divide by zero trap */
152 t_flwin:TRAP_ENTRY(0x83, do_flush_windows) /* Flush Windows Trap */
153 t_clwin:BAD_TRAP(0x84) /* Clean Windows Trap */
154 t_rchk: BAD_TRAP(0x85) /* Range Check */
155 t_funal:BAD_TRAP(0x86) /* Fix Unaligned Access Trap */
156 t_iovf: BAD_TRAP(0x87) /* Integer Overflow Trap */
157 t_bad88:BAD_TRAP(0x88) /* Slowaris System Call */
158 t_bad89:BAD_TRAP(0x89) /* Net-B.S. System Call */
159 t_bad8a:BAD_TRAP(0x8a) BAD_TRAP(0x8b) BAD_TRAP(0x8c) BAD_TRAP(0x8d) BAD_TRAP(0x8e)
160 t_bad8f:BAD_TRAP(0x8f)
161 t_linux:LINUX_SYSCALL_TRAP /* Linux System Call */
162 t_bad91:BAD_TRAP(0x91) BAD_TRAP(0x92) BAD_TRAP(0x93) BAD_TRAP(0x94) BAD_TRAP(0x95)
163 t_bad96:BAD_TRAP(0x96) BAD_TRAP(0x97) BAD_TRAP(0x98) BAD_TRAP(0x99) BAD_TRAP(0x9a)
164 t_bad9b:BAD_TRAP(0x9b) BAD_TRAP(0x9c) BAD_TRAP(0x9d) BAD_TRAP(0x9e) BAD_TRAP(0x9f)
165 t_getcc:GETCC_TRAP /* Get Condition Codes */
166 t_setcc:SETCC_TRAP /* Set Condition Codes */
167 t_getpsr:GETPSR_TRAP /* Get PSR Register */
168 t_bada3:BAD_TRAP(0xa3) BAD_TRAP(0xa4) BAD_TRAP(0xa5) BAD_TRAP(0xa6)
169 t_bada7:BAD_TRAP(0xa7)
170 t_bada8:BAD_TRAP(0xa8) BAD_TRAP(0xa9) BAD_TRAP(0xaa) BAD_TRAP(0xab)
171 t_badac:BAD_TRAP(0xac) BAD_TRAP(0xad) BAD_TRAP(0xae) BAD_TRAP(0xaf) BAD_TRAP(0xb0)
172 t_badb1:BAD_TRAP(0xb1) BAD_TRAP(0xb2) BAD_TRAP(0xb3) BAD_TRAP(0xb4) BAD_TRAP(0xb5)
173 t_badb6:BAD_TRAP(0xb6) BAD_TRAP(0xb7) BAD_TRAP(0xb8) BAD_TRAP(0xb9) BAD_TRAP(0xba)
174 t_badbb:BAD_TRAP(0xbb) BAD_TRAP(0xbc) BAD_TRAP(0xbd) BAD_TRAP(0xbe) BAD_TRAP(0xbf)
175 t_badc0:BAD_TRAP(0xc0) BAD_TRAP(0xc1) BAD_TRAP(0xc2) BAD_TRAP(0xc3) BAD_TRAP(0xc4)
176 t_badc5:BAD_TRAP(0xc5) BAD_TRAP(0xc6) BAD_TRAP(0xc7) BAD_TRAP(0xc8) BAD_TRAP(0xc9)
177 t_badca:BAD_TRAP(0xca) BAD_TRAP(0xcb) BAD_TRAP(0xcc) BAD_TRAP(0xcd) BAD_TRAP(0xce)
178 t_badcf:BAD_TRAP(0xcf) BAD_TRAP(0xd0) BAD_TRAP(0xd1) BAD_TRAP(0xd2) BAD_TRAP(0xd3)
179 t_badd4:BAD_TRAP(0xd4) BAD_TRAP(0xd5) BAD_TRAP(0xd6) BAD_TRAP(0xd7) BAD_TRAP(0xd8)
180 t_badd9:BAD_TRAP(0xd9) BAD_TRAP(0xda) BAD_TRAP(0xdb) BAD_TRAP(0xdc) BAD_TRAP(0xdd)
181 t_badde:BAD_TRAP(0xde) BAD_TRAP(0xdf) BAD_TRAP(0xe0) BAD_TRAP(0xe1) BAD_TRAP(0xe2)
182 t_bade3:BAD_TRAP(0xe3) BAD_TRAP(0xe4) BAD_TRAP(0xe5) BAD_TRAP(0xe6) BAD_TRAP(0xe7)
183 t_bade8:BAD_TRAP(0xe8) BAD_TRAP(0xe9) BAD_TRAP(0xea) BAD_TRAP(0xeb) BAD_TRAP(0xec)
184 t_baded:BAD_TRAP(0xed) BAD_TRAP(0xee) BAD_TRAP(0xef) BAD_TRAP(0xf0) BAD_TRAP(0xf1)
185 t_badf2:BAD_TRAP(0xf2) BAD_TRAP(0xf3) BAD_TRAP(0xf4) BAD_TRAP(0xf5) BAD_TRAP(0xf6)
186 t_badf7:BAD_TRAP(0xf7) BAD_TRAP(0xf8) BAD_TRAP(0xf9) BAD_TRAP(0xfa) BAD_TRAP(0xfb)
187 t_badfc:BAD_TRAP(0xfc)
188 t_kgdb: KGDB_TRAP(0xfd)
189 dbtrap: BAD_TRAP(0xfe) /* Debugger/PROM breakpoint #1 */
190 dbtrap2:BAD_TRAP(0xff) /* Debugger/PROM breakpoint #2 */
192 .globl end_traptable
193 end_traptable:
195 #ifdef CONFIG_SMP
196 /* Trap tables for the other cpus. */
197 .globl trapbase_cpu1, trapbase_cpu2, trapbase_cpu3
198 trapbase_cpu1:
199 BAD_TRAP(0x0) SRMMU_TFAULT TRAP_ENTRY(0x2, bad_instruction)
200 TRAP_ENTRY(0x3, priv_instruction) TRAP_ENTRY(0x4, fpd_trap_handler)
201 WINDOW_SPILL WINDOW_FILL TRAP_ENTRY(0x7, mna_handler)
202 TRAP_ENTRY(0x8, fpe_trap_handler) SRMMU_DFAULT
203 TRAP_ENTRY(0xa, do_tag_overflow) TRAP_ENTRY(0xb, do_watchpoint)
204 BAD_TRAP(0xc) BAD_TRAP(0xd) BAD_TRAP(0xe) BAD_TRAP(0xf) BAD_TRAP(0x10)
205 TRAP_ENTRY_INTERRUPT(1) TRAP_ENTRY_INTERRUPT(2)
206 TRAP_ENTRY_INTERRUPT(3) TRAP_ENTRY_INTERRUPT(4)
207 TRAP_ENTRY_INTERRUPT(5) TRAP_ENTRY_INTERRUPT(6)
208 TRAP_ENTRY_INTERRUPT(7) TRAP_ENTRY_INTERRUPT(8)
209 TRAP_ENTRY_INTERRUPT(9) TRAP_ENTRY_INTERRUPT(10)
210 TRAP_ENTRY_INTERRUPT(11) TRAP_ENTRY_INTERRUPT(12)
211 TRAP_ENTRY_INTERRUPT(13) TRAP_ENTRY_INTERRUPT(14)
212 TRAP_ENTRY(0x1f, linux_trap_ipi15_sun4m)
213 TRAP_ENTRY(0x20, do_reg_access) BAD_TRAP(0x21) BAD_TRAP(0x22)
214 BAD_TRAP(0x23) TRAP_ENTRY(0x24, do_cp_disabled) SKIP_TRAP(0x25, unimp_flush)
215 BAD_TRAP(0x26) BAD_TRAP(0x27) TRAP_ENTRY(0x28, do_cp_exception)
216 SRMMU_DFAULT TRAP_ENTRY(0x2a, do_hw_divzero) BAD_TRAP(0x2b) BAD_TRAP(0x2c)
217 BAD_TRAP(0x2d) BAD_TRAP(0x2e) BAD_TRAP(0x2f) BAD_TRAP(0x30) BAD_TRAP(0x31)
218 BAD_TRAP(0x32) BAD_TRAP(0x33) BAD_TRAP(0x34) BAD_TRAP(0x35) BAD_TRAP(0x36)
219 BAD_TRAP(0x37) BAD_TRAP(0x38) BAD_TRAP(0x39) BAD_TRAP(0x3a) BAD_TRAP(0x3b)
220 BAD_TRAP(0x3c) BAD_TRAP(0x3d) BAD_TRAP(0x3e) BAD_TRAP(0x3f) BAD_TRAP(0x40)
221 BAD_TRAP(0x41) BAD_TRAP(0x42) BAD_TRAP(0x43) BAD_TRAP(0x44) BAD_TRAP(0x45)
222 BAD_TRAP(0x46) BAD_TRAP(0x47) BAD_TRAP(0x48) BAD_TRAP(0x49) BAD_TRAP(0x4a)
223 BAD_TRAP(0x4b) BAD_TRAP(0x4c) BAD_TRAP(0x4d) BAD_TRAP(0x4e) BAD_TRAP(0x4f)
224 BAD_TRAP(0x50)
225 BAD_TRAP(0x51) BAD_TRAP(0x52) BAD_TRAP(0x53) BAD_TRAP(0x54) BAD_TRAP(0x55)
226 BAD_TRAP(0x56) BAD_TRAP(0x57) BAD_TRAP(0x58) BAD_TRAP(0x59) BAD_TRAP(0x5a)
227 BAD_TRAP(0x5b) BAD_TRAP(0x5c) BAD_TRAP(0x5d) BAD_TRAP(0x5e) BAD_TRAP(0x5f)
228 BAD_TRAP(0x60) BAD_TRAP(0x61) BAD_TRAP(0x62) BAD_TRAP(0x63) BAD_TRAP(0x64)
229 BAD_TRAP(0x65) BAD_TRAP(0x66) BAD_TRAP(0x67) BAD_TRAP(0x68) BAD_TRAP(0x69)
230 BAD_TRAP(0x6a) BAD_TRAP(0x6b) BAD_TRAP(0x6c) BAD_TRAP(0x6d) BAD_TRAP(0x6e)
231 BAD_TRAP(0x6f) BAD_TRAP(0x70) BAD_TRAP(0x71) BAD_TRAP(0x72) BAD_TRAP(0x73)
232 BAD_TRAP(0x74) BAD_TRAP(0x75) BAD_TRAP(0x76) BAD_TRAP(0x77) BAD_TRAP(0x78)
233 BAD_TRAP(0x79) BAD_TRAP(0x7a) BAD_TRAP(0x7b) BAD_TRAP(0x7c) BAD_TRAP(0x7d)
234 BAD_TRAP(0x7e) BAD_TRAP(0x7f)
235 BAD_TRAP(0x80)
236 BREAKPOINT_TRAP
237 TRAP_ENTRY(0x82, do_hw_divzero)
238 TRAP_ENTRY(0x83, do_flush_windows) BAD_TRAP(0x84) BAD_TRAP(0x85)
239 BAD_TRAP(0x86) BAD_TRAP(0x87) BAD_TRAP(0x88)
240 BAD_TRAP(0x89) BAD_TRAP(0x8a) BAD_TRAP(0x8b) BAD_TRAP(0x8c)
241 BAD_TRAP(0x8d) BAD_TRAP(0x8e) BAD_TRAP(0x8f)
242 LINUX_SYSCALL_TRAP BAD_TRAP(0x91) BAD_TRAP(0x92) BAD_TRAP(0x93) BAD_TRAP(0x94)
243 BAD_TRAP(0x95) BAD_TRAP(0x96) BAD_TRAP(0x97) BAD_TRAP(0x98) BAD_TRAP(0x99)
244 BAD_TRAP(0x9a) BAD_TRAP(0x9b) BAD_TRAP(0x9c) BAD_TRAP(0x9d) BAD_TRAP(0x9e)
245 BAD_TRAP(0x9f) GETCC_TRAP SETCC_TRAP GETPSR_TRAP
246 BAD_TRAP(0xa3) BAD_TRAP(0xa4) BAD_TRAP(0xa5) BAD_TRAP(0xa6)
247 BAD_TRAP(0xa7) BAD_TRAP(0xa8) BAD_TRAP(0xa9) BAD_TRAP(0xaa) BAD_TRAP(0xab)
248 BAD_TRAP(0xac) BAD_TRAP(0xad) BAD_TRAP(0xae) BAD_TRAP(0xaf) BAD_TRAP(0xb0)
249 BAD_TRAP(0xb1) BAD_TRAP(0xb2) BAD_TRAP(0xb3) BAD_TRAP(0xb4) BAD_TRAP(0xb5)
250 BAD_TRAP(0xb6) BAD_TRAP(0xb7) BAD_TRAP(0xb8) BAD_TRAP(0xb9) BAD_TRAP(0xba)
251 BAD_TRAP(0xbb) BAD_TRAP(0xbc) BAD_TRAP(0xbd) BAD_TRAP(0xbe) BAD_TRAP(0xbf)
252 BAD_TRAP(0xc0) BAD_TRAP(0xc1) BAD_TRAP(0xc2) BAD_TRAP(0xc3) BAD_TRAP(0xc4)
253 BAD_TRAP(0xc5) BAD_TRAP(0xc6) BAD_TRAP(0xc7) BAD_TRAP(0xc8) BAD_TRAP(0xc9)
254 BAD_TRAP(0xca) BAD_TRAP(0xcb) BAD_TRAP(0xcc) BAD_TRAP(0xcd) BAD_TRAP(0xce)
255 BAD_TRAP(0xcf) BAD_TRAP(0xd0) BAD_TRAP(0xd1) BAD_TRAP(0xd2) BAD_TRAP(0xd3)
256 BAD_TRAP(0xd4) BAD_TRAP(0xd5) BAD_TRAP(0xd6) BAD_TRAP(0xd7) BAD_TRAP(0xd8)
257 BAD_TRAP(0xd9) BAD_TRAP(0xda) BAD_TRAP(0xdb) BAD_TRAP(0xdc) BAD_TRAP(0xdd)
258 BAD_TRAP(0xde) BAD_TRAP(0xdf) BAD_TRAP(0xe0) BAD_TRAP(0xe1) BAD_TRAP(0xe2)
259 BAD_TRAP(0xe3) BAD_TRAP(0xe4) BAD_TRAP(0xe5) BAD_TRAP(0xe6) BAD_TRAP(0xe7)
260 BAD_TRAP(0xe8) BAD_TRAP(0xe9) BAD_TRAP(0xea) BAD_TRAP(0xeb) BAD_TRAP(0xec)
261 BAD_TRAP(0xed) BAD_TRAP(0xee) BAD_TRAP(0xef) BAD_TRAP(0xf0) BAD_TRAP(0xf1)
262 BAD_TRAP(0xf2) BAD_TRAP(0xf3) BAD_TRAP(0xf4) BAD_TRAP(0xf5) BAD_TRAP(0xf6)
263 BAD_TRAP(0xf7) BAD_TRAP(0xf8) BAD_TRAP(0xf9) BAD_TRAP(0xfa) BAD_TRAP(0xfb)
264 BAD_TRAP(0xfc) KGDB_TRAP(0xfd) BAD_TRAP(0xfe) BAD_TRAP(0xff)
266 trapbase_cpu2:
267 BAD_TRAP(0x0) SRMMU_TFAULT TRAP_ENTRY(0x2, bad_instruction)
268 TRAP_ENTRY(0x3, priv_instruction) TRAP_ENTRY(0x4, fpd_trap_handler)
269 WINDOW_SPILL WINDOW_FILL TRAP_ENTRY(0x7, mna_handler)
270 TRAP_ENTRY(0x8, fpe_trap_handler) SRMMU_DFAULT
271 TRAP_ENTRY(0xa, do_tag_overflow) TRAP_ENTRY(0xb, do_watchpoint)
272 BAD_TRAP(0xc) BAD_TRAP(0xd) BAD_TRAP(0xe) BAD_TRAP(0xf) BAD_TRAP(0x10)
273 TRAP_ENTRY_INTERRUPT(1) TRAP_ENTRY_INTERRUPT(2)
274 TRAP_ENTRY_INTERRUPT(3) TRAP_ENTRY_INTERRUPT(4)
275 TRAP_ENTRY_INTERRUPT(5) TRAP_ENTRY_INTERRUPT(6)
276 TRAP_ENTRY_INTERRUPT(7) TRAP_ENTRY_INTERRUPT(8)
277 TRAP_ENTRY_INTERRUPT(9) TRAP_ENTRY_INTERRUPT(10)
278 TRAP_ENTRY_INTERRUPT(11) TRAP_ENTRY_INTERRUPT(12)
279 TRAP_ENTRY_INTERRUPT(13) TRAP_ENTRY_INTERRUPT(14)
280 TRAP_ENTRY(0x1f, linux_trap_ipi15_sun4m)
281 TRAP_ENTRY(0x20, do_reg_access) BAD_TRAP(0x21) BAD_TRAP(0x22)
282 BAD_TRAP(0x23) TRAP_ENTRY(0x24, do_cp_disabled) SKIP_TRAP(0x25, unimp_flush)
283 BAD_TRAP(0x26) BAD_TRAP(0x27) TRAP_ENTRY(0x28, do_cp_exception)
284 SRMMU_DFAULT TRAP_ENTRY(0x2a, do_hw_divzero) BAD_TRAP(0x2b) BAD_TRAP(0x2c)
285 BAD_TRAP(0x2d) BAD_TRAP(0x2e) BAD_TRAP(0x2f) BAD_TRAP(0x30) BAD_TRAP(0x31)
286 BAD_TRAP(0x32) BAD_TRAP(0x33) BAD_TRAP(0x34) BAD_TRAP(0x35) BAD_TRAP(0x36)
287 BAD_TRAP(0x37) BAD_TRAP(0x38) BAD_TRAP(0x39) BAD_TRAP(0x3a) BAD_TRAP(0x3b)
288 BAD_TRAP(0x3c) BAD_TRAP(0x3d) BAD_TRAP(0x3e) BAD_TRAP(0x3f) BAD_TRAP(0x40)
289 BAD_TRAP(0x41) BAD_TRAP(0x42) BAD_TRAP(0x43) BAD_TRAP(0x44) BAD_TRAP(0x45)
290 BAD_TRAP(0x46) BAD_TRAP(0x47) BAD_TRAP(0x48) BAD_TRAP(0x49) BAD_TRAP(0x4a)
291 BAD_TRAP(0x4b) BAD_TRAP(0x4c) BAD_TRAP(0x4d) BAD_TRAP(0x4e) BAD_TRAP(0x4f)
292 BAD_TRAP(0x50)
293 BAD_TRAP(0x51) BAD_TRAP(0x52) BAD_TRAP(0x53) BAD_TRAP(0x54) BAD_TRAP(0x55)
294 BAD_TRAP(0x56) BAD_TRAP(0x57) BAD_TRAP(0x58) BAD_TRAP(0x59) BAD_TRAP(0x5a)
295 BAD_TRAP(0x5b) BAD_TRAP(0x5c) BAD_TRAP(0x5d) BAD_TRAP(0x5e) BAD_TRAP(0x5f)
296 BAD_TRAP(0x60) BAD_TRAP(0x61) BAD_TRAP(0x62) BAD_TRAP(0x63) BAD_TRAP(0x64)
297 BAD_TRAP(0x65) BAD_TRAP(0x66) BAD_TRAP(0x67) BAD_TRAP(0x68) BAD_TRAP(0x69)
298 BAD_TRAP(0x6a) BAD_TRAP(0x6b) BAD_TRAP(0x6c) BAD_TRAP(0x6d) BAD_TRAP(0x6e)
299 BAD_TRAP(0x6f) BAD_TRAP(0x70) BAD_TRAP(0x71) BAD_TRAP(0x72) BAD_TRAP(0x73)
300 BAD_TRAP(0x74) BAD_TRAP(0x75) BAD_TRAP(0x76) BAD_TRAP(0x77) BAD_TRAP(0x78)
301 BAD_TRAP(0x79) BAD_TRAP(0x7a) BAD_TRAP(0x7b) BAD_TRAP(0x7c) BAD_TRAP(0x7d)
302 BAD_TRAP(0x7e) BAD_TRAP(0x7f)
303 BAD_TRAP(0x80)
304 BREAKPOINT_TRAP
305 TRAP_ENTRY(0x82, do_hw_divzero)
306 TRAP_ENTRY(0x83, do_flush_windows) BAD_TRAP(0x84) BAD_TRAP(0x85)
307 BAD_TRAP(0x86) BAD_TRAP(0x87) BAD_TRAP(0x88)
308 BAD_TRAP(0x89) BAD_TRAP(0x8a) BAD_TRAP(0x8b) BAD_TRAP(0x8c)
309 BAD_TRAP(0x8d) BAD_TRAP(0x8e) BAD_TRAP(0x8f)
310 LINUX_SYSCALL_TRAP BAD_TRAP(0x91) BAD_TRAP(0x92) BAD_TRAP(0x93) BAD_TRAP(0x94)
311 BAD_TRAP(0x95) BAD_TRAP(0x96) BAD_TRAP(0x97) BAD_TRAP(0x98) BAD_TRAP(0x99)
312 BAD_TRAP(0x9a) BAD_TRAP(0x9b) BAD_TRAP(0x9c) BAD_TRAP(0x9d) BAD_TRAP(0x9e)
313 BAD_TRAP(0x9f) GETCC_TRAP SETCC_TRAP GETPSR_TRAP
314 BAD_TRAP(0xa3) BAD_TRAP(0xa4) BAD_TRAP(0xa5) BAD_TRAP(0xa6)
315 BAD_TRAP(0xa7) BAD_TRAP(0xa8) BAD_TRAP(0xa9) BAD_TRAP(0xaa) BAD_TRAP(0xab)
316 BAD_TRAP(0xac) BAD_TRAP(0xad) BAD_TRAP(0xae) BAD_TRAP(0xaf) BAD_TRAP(0xb0)
317 BAD_TRAP(0xb1) BAD_TRAP(0xb2) BAD_TRAP(0xb3) BAD_TRAP(0xb4) BAD_TRAP(0xb5)
318 BAD_TRAP(0xb6) BAD_TRAP(0xb7) BAD_TRAP(0xb8) BAD_TRAP(0xb9) BAD_TRAP(0xba)
319 BAD_TRAP(0xbb) BAD_TRAP(0xbc) BAD_TRAP(0xbd) BAD_TRAP(0xbe) BAD_TRAP(0xbf)
320 BAD_TRAP(0xc0) BAD_TRAP(0xc1) BAD_TRAP(0xc2) BAD_TRAP(0xc3) BAD_TRAP(0xc4)
321 BAD_TRAP(0xc5) BAD_TRAP(0xc6) BAD_TRAP(0xc7) BAD_TRAP(0xc8) BAD_TRAP(0xc9)
322 BAD_TRAP(0xca) BAD_TRAP(0xcb) BAD_TRAP(0xcc) BAD_TRAP(0xcd) BAD_TRAP(0xce)
323 BAD_TRAP(0xcf) BAD_TRAP(0xd0) BAD_TRAP(0xd1) BAD_TRAP(0xd2) BAD_TRAP(0xd3)
324 BAD_TRAP(0xd4) BAD_TRAP(0xd5) BAD_TRAP(0xd6) BAD_TRAP(0xd7) BAD_TRAP(0xd8)
325 BAD_TRAP(0xd9) BAD_TRAP(0xda) BAD_TRAP(0xdb) BAD_TRAP(0xdc) BAD_TRAP(0xdd)
326 BAD_TRAP(0xde) BAD_TRAP(0xdf) BAD_TRAP(0xe0) BAD_TRAP(0xe1) BAD_TRAP(0xe2)
327 BAD_TRAP(0xe3) BAD_TRAP(0xe4) BAD_TRAP(0xe5) BAD_TRAP(0xe6) BAD_TRAP(0xe7)
328 BAD_TRAP(0xe8) BAD_TRAP(0xe9) BAD_TRAP(0xea) BAD_TRAP(0xeb) BAD_TRAP(0xec)
329 BAD_TRAP(0xed) BAD_TRAP(0xee) BAD_TRAP(0xef) BAD_TRAP(0xf0) BAD_TRAP(0xf1)
330 BAD_TRAP(0xf2) BAD_TRAP(0xf3) BAD_TRAP(0xf4) BAD_TRAP(0xf5) BAD_TRAP(0xf6)
331 BAD_TRAP(0xf7) BAD_TRAP(0xf8) BAD_TRAP(0xf9) BAD_TRAP(0xfa) BAD_TRAP(0xfb)
332 BAD_TRAP(0xfc) KGDB_TRAP(0xfd) BAD_TRAP(0xfe) BAD_TRAP(0xff)
334 trapbase_cpu3:
335 BAD_TRAP(0x0) SRMMU_TFAULT TRAP_ENTRY(0x2, bad_instruction)
336 TRAP_ENTRY(0x3, priv_instruction) TRAP_ENTRY(0x4, fpd_trap_handler)
337 WINDOW_SPILL WINDOW_FILL TRAP_ENTRY(0x7, mna_handler)
338 TRAP_ENTRY(0x8, fpe_trap_handler) SRMMU_DFAULT
339 TRAP_ENTRY(0xa, do_tag_overflow) TRAP_ENTRY(0xb, do_watchpoint)
340 BAD_TRAP(0xc) BAD_TRAP(0xd) BAD_TRAP(0xe) BAD_TRAP(0xf) BAD_TRAP(0x10)
341 TRAP_ENTRY_INTERRUPT(1) TRAP_ENTRY_INTERRUPT(2)
342 TRAP_ENTRY_INTERRUPT(3) TRAP_ENTRY_INTERRUPT(4)
343 TRAP_ENTRY_INTERRUPT(5) TRAP_ENTRY_INTERRUPT(6)
344 TRAP_ENTRY_INTERRUPT(7) TRAP_ENTRY_INTERRUPT(8)
345 TRAP_ENTRY_INTERRUPT(9) TRAP_ENTRY_INTERRUPT(10)
346 TRAP_ENTRY_INTERRUPT(11) TRAP_ENTRY_INTERRUPT(12)
347 TRAP_ENTRY_INTERRUPT(13) TRAP_ENTRY_INTERRUPT(14)
348 TRAP_ENTRY(0x1f, linux_trap_ipi15_sun4m)
349 TRAP_ENTRY(0x20, do_reg_access) BAD_TRAP(0x21) BAD_TRAP(0x22)
350 BAD_TRAP(0x23) TRAP_ENTRY(0x24, do_cp_disabled) SKIP_TRAP(0x25, unimp_flush)
351 BAD_TRAP(0x26) BAD_TRAP(0x27) TRAP_ENTRY(0x28, do_cp_exception)
352 SRMMU_DFAULT TRAP_ENTRY(0x2a, do_hw_divzero) BAD_TRAP(0x2b) BAD_TRAP(0x2c)
353 BAD_TRAP(0x2d) BAD_TRAP(0x2e) BAD_TRAP(0x2f) BAD_TRAP(0x30) BAD_TRAP(0x31)
354 BAD_TRAP(0x32) BAD_TRAP(0x33) BAD_TRAP(0x34) BAD_TRAP(0x35) BAD_TRAP(0x36)
355 BAD_TRAP(0x37) BAD_TRAP(0x38) BAD_TRAP(0x39) BAD_TRAP(0x3a) BAD_TRAP(0x3b)
356 BAD_TRAP(0x3c) BAD_TRAP(0x3d) BAD_TRAP(0x3e) BAD_TRAP(0x3f) BAD_TRAP(0x40)
357 BAD_TRAP(0x41) BAD_TRAP(0x42) BAD_TRAP(0x43) BAD_TRAP(0x44) BAD_TRAP(0x45)
358 BAD_TRAP(0x46) BAD_TRAP(0x47) BAD_TRAP(0x48) BAD_TRAP(0x49) BAD_TRAP(0x4a)
359 BAD_TRAP(0x4b) BAD_TRAP(0x4c) BAD_TRAP(0x4d) BAD_TRAP(0x4e) BAD_TRAP(0x4f)
360 BAD_TRAP(0x50)
361 BAD_TRAP(0x51) BAD_TRAP(0x52) BAD_TRAP(0x53) BAD_TRAP(0x54) BAD_TRAP(0x55)
362 BAD_TRAP(0x56) BAD_TRAP(0x57) BAD_TRAP(0x58) BAD_TRAP(0x59) BAD_TRAP(0x5a)
363 BAD_TRAP(0x5b) BAD_TRAP(0x5c) BAD_TRAP(0x5d) BAD_TRAP(0x5e) BAD_TRAP(0x5f)
364 BAD_TRAP(0x60) BAD_TRAP(0x61) BAD_TRAP(0x62) BAD_TRAP(0x63) BAD_TRAP(0x64)
365 BAD_TRAP(0x65) BAD_TRAP(0x66) BAD_TRAP(0x67) BAD_TRAP(0x68) BAD_TRAP(0x69)
366 BAD_TRAP(0x6a) BAD_TRAP(0x6b) BAD_TRAP(0x6c) BAD_TRAP(0x6d) BAD_TRAP(0x6e)
367 BAD_TRAP(0x6f) BAD_TRAP(0x70) BAD_TRAP(0x71) BAD_TRAP(0x72) BAD_TRAP(0x73)
368 BAD_TRAP(0x74) BAD_TRAP(0x75) BAD_TRAP(0x76) BAD_TRAP(0x77) BAD_TRAP(0x78)
369 BAD_TRAP(0x79) BAD_TRAP(0x7a) BAD_TRAP(0x7b) BAD_TRAP(0x7c) BAD_TRAP(0x7d)
370 BAD_TRAP(0x7e) BAD_TRAP(0x7f)
371 BAD_TRAP(0x80)
372 BREAKPOINT_TRAP
373 TRAP_ENTRY(0x82, do_hw_divzero)
374 TRAP_ENTRY(0x83, do_flush_windows) BAD_TRAP(0x84) BAD_TRAP(0x85)
375 BAD_TRAP(0x86) BAD_TRAP(0x87) BAD_TRAP(0x88)
376 BAD_TRAP(0x89) BAD_TRAP(0x8a) BAD_TRAP(0x8b) BAD_TRAP(0x8c)
377 BAD_TRAP(0x8d) BAD_TRAP(0x8e) BAD_TRAP(0x8f)
378 LINUX_SYSCALL_TRAP BAD_TRAP(0x91) BAD_TRAP(0x92) BAD_TRAP(0x93) BAD_TRAP(0x94)
379 BAD_TRAP(0x95) BAD_TRAP(0x96) BAD_TRAP(0x97) BAD_TRAP(0x98) BAD_TRAP(0x99)
380 BAD_TRAP(0x9a) BAD_TRAP(0x9b) BAD_TRAP(0x9c) BAD_TRAP(0x9d) BAD_TRAP(0x9e)
381 BAD_TRAP(0x9f) GETCC_TRAP SETCC_TRAP GETPSR_TRAP
382 BAD_TRAP(0xa3) BAD_TRAP(0xa4) BAD_TRAP(0xa5) BAD_TRAP(0xa6)
383 BAD_TRAP(0xa7) BAD_TRAP(0xa8) BAD_TRAP(0xa9) BAD_TRAP(0xaa) BAD_TRAP(0xab)
384 BAD_TRAP(0xac) BAD_TRAP(0xad) BAD_TRAP(0xae) BAD_TRAP(0xaf) BAD_TRAP(0xb0)
385 BAD_TRAP(0xb1) BAD_TRAP(0xb2) BAD_TRAP(0xb3) BAD_TRAP(0xb4) BAD_TRAP(0xb5)
386 BAD_TRAP(0xb6) BAD_TRAP(0xb7) BAD_TRAP(0xb8) BAD_TRAP(0xb9) BAD_TRAP(0xba)
387 BAD_TRAP(0xbb) BAD_TRAP(0xbc) BAD_TRAP(0xbd) BAD_TRAP(0xbe) BAD_TRAP(0xbf)
388 BAD_TRAP(0xc0) BAD_TRAP(0xc1) BAD_TRAP(0xc2) BAD_TRAP(0xc3) BAD_TRAP(0xc4)
389 BAD_TRAP(0xc5) BAD_TRAP(0xc6) BAD_TRAP(0xc7) BAD_TRAP(0xc8) BAD_TRAP(0xc9)
390 BAD_TRAP(0xca) BAD_TRAP(0xcb) BAD_TRAP(0xcc) BAD_TRAP(0xcd) BAD_TRAP(0xce)
391 BAD_TRAP(0xcf) BAD_TRAP(0xd0) BAD_TRAP(0xd1) BAD_TRAP(0xd2) BAD_TRAP(0xd3)
392 BAD_TRAP(0xd4) BAD_TRAP(0xd5) BAD_TRAP(0xd6) BAD_TRAP(0xd7) BAD_TRAP(0xd8)
393 BAD_TRAP(0xd9) BAD_TRAP(0xda) BAD_TRAP(0xdb) BAD_TRAP(0xdc) BAD_TRAP(0xdd)
394 BAD_TRAP(0xde) BAD_TRAP(0xdf) BAD_TRAP(0xe0) BAD_TRAP(0xe1) BAD_TRAP(0xe2)
395 BAD_TRAP(0xe3) BAD_TRAP(0xe4) BAD_TRAP(0xe5) BAD_TRAP(0xe6) BAD_TRAP(0xe7)
396 BAD_TRAP(0xe8) BAD_TRAP(0xe9) BAD_TRAP(0xea) BAD_TRAP(0xeb) BAD_TRAP(0xec)
397 BAD_TRAP(0xed) BAD_TRAP(0xee) BAD_TRAP(0xef) BAD_TRAP(0xf0) BAD_TRAP(0xf1)
398 BAD_TRAP(0xf2) BAD_TRAP(0xf3) BAD_TRAP(0xf4) BAD_TRAP(0xf5) BAD_TRAP(0xf6)
399 BAD_TRAP(0xf7) BAD_TRAP(0xf8) BAD_TRAP(0xf9) BAD_TRAP(0xfa) BAD_TRAP(0xfb)
400 BAD_TRAP(0xfc) KGDB_TRAP(0xfd) BAD_TRAP(0xfe) BAD_TRAP(0xff)
402 #endif
403 .align PAGE_SIZE
405 /* This was the only reasonable way I could think of to properly align
406 * these page-table data structures.
407 */
408 .globl pg0, pg1, pg2, pg3
409 .globl empty_bad_page
410 .globl empty_bad_page_table
411 .globl empty_zero_page
412 .globl swapper_pg_dir
413 swapper_pg_dir: .skip PAGE_SIZE
414 pg0: .skip PAGE_SIZE
415 pg1: .skip PAGE_SIZE
416 pg2: .skip PAGE_SIZE
417 pg3: .skip PAGE_SIZE
418 empty_bad_page: .skip PAGE_SIZE
419 empty_bad_page_table: .skip PAGE_SIZE
420 empty_zero_page: .skip PAGE_SIZE
422 .global root_flags
423 .global ram_flags
424 .global root_dev
425 .global sparc_ramdisk_image
426 .global sparc_ramdisk_size
428 /* This stuff has to be in sync with SILO and other potential boot loaders
429 * Fields should be kept upward compatible and whenever any change is made,
430 * HdrS version should be incremented.
431 */
432 .ascii "HdrS"
433 .word LINUX_VERSION_CODE
434 .half 0x0203 /* HdrS version */
435 root_flags:
436 .half 1
437 root_dev:
438 .half 0
439 ram_flags:
440 .half 0
441 sparc_ramdisk_image:
442 .word 0
443 sparc_ramdisk_size:
444 .word 0
445 .word reboot_command
446 .word 0, 0, 0
447 .word _end
449 /* Cool, here we go. Pick up the romvec pointer in %o0 and stash it in
450 * %g7 and at prom_vector_p. And also quickly check whether we are on
451 * a v0, v2, or v3 prom.
452 */
453 gokernel:
454 /* Ok, it's nice to know, as early as possible, if we
455 * are already mapped where we expect to be in virtual
456 * memory. The Solaris /boot elf format bootloader
457 * will peek into our elf header and load us where
458 * we want to be, otherwise we have to re-map.
459 *
460 * Some boot loaders don't place the jmp'rs address
461 * in %o7, so we do a pc-relative call to a local
462 * label, then see what %o7 has.
463 */
465 mov %o7, %g4 ! Save %o7
467 /* Jump to it, and pray... */
468 current_pc:
469 call 1f
470 nop
472 1:
473 mov %o7, %g3
475 tst %o0
476 be no_sun4u_here
477 mov %g4, %o7 /* Previous %o7. */
479 mov %o0, %l0 ! stash away romvec
480 mov %o0, %g7 ! put it here too
481 mov %o1, %l1 ! stash away debug_vec too
483 /* Ok, let's check out our run time program counter. */
484 set current_pc, %g5
485 cmp %g3, %g5
486 be already_mapped
487 nop
489 /* %l6 will hold the offset we have to subtract
490 * from absolute symbols in order to access areas
491 * in our own image. If already mapped this is
492 * just plain zero, else it is KERNBASE.
493 */
494 set KERNBASE, %l6
495 b copy_prom_lvl14
496 nop
498 already_mapped:
499 mov 0, %l6
501 /* Copy over the Prom's level 14 clock handler. */
502 copy_prom_lvl14:
503 #if 1
504 /* DJHR
505 * preserve our linked/calculated instructions
506 */
507 set lvl14_save, %g1
508 set t_irq14, %g3
509 sub %g1, %l6, %g1 ! translate to physical
510 sub %g3, %l6, %g3 ! translate to physical
511 ldd [%g3], %g4
512 std %g4, [%g1]
513 ldd [%g3+8], %g4
514 std %g4, [%g1+8]
515 #endif
516 rd %tbr, %g1
517 andn %g1, 0xfff, %g1 ! proms trap table base
518 or %g0, (0x1e<<4), %g2 ! offset to lvl14 intr
519 or %g1, %g2, %g2
520 set t_irq14, %g3
521 sub %g3, %l6, %g3
522 ldd [%g2], %g4
523 std %g4, [%g3]
524 ldd [%g2 + 0x8], %g4
525 std %g4, [%g3 + 0x8] ! Copy proms handler
527 /* Must determine whether we are on a sun4c MMU, SRMMU, or SUN4/400 MUTANT
528 * MMU so we can remap ourselves properly. DON'T TOUCH %l0 thru %l5 in these
529 * remapping routines, we need their values afterwards!
530 */
531 /* Now check whether we are already mapped, if we
532 * are we can skip all this garbage coming up.
533 */
534 copy_prom_done:
535 cmp %l6, 0
536 be go_to_highmem ! this will be a nop then
537 nop
539 set LOAD_ADDR, %g6
540 cmp %g7, %g6
541 bne remap_not_a_sun4 ! This is not a Sun4
542 nop
544 or %g0, 0x1, %g1
545 lduba [%g1] ASI_CONTROL, %g1 ! Only safe to try on Sun4.
546 subcc %g1, 0x24, %g0 ! Is this a mutant Sun4/400???
547 be sun4_mutant_remap ! Ugh, it is...
548 nop
550 b sun4_normal_remap ! regular sun4, 2 level mmu
551 nop
553 remap_not_a_sun4:
554 lda [%g0] ASI_M_MMUREGS, %g1 ! same as ASI_PTE on sun4c
555 and %g1, 0x1, %g1 ! Test SRMMU Enable bit ;-)
556 cmp %g1, 0x0
557 be sun4c_remap ! A sun4c MMU or normal Sun4
558 nop
559 srmmu_remap:
560 /* First, check for a viking (TI) module. */
561 set 0x40000000, %g2
562 rd %psr, %g3
563 and %g2, %g3, %g3
564 subcc %g3, 0x0, %g0
565 bz srmmu_nviking
566 nop
568 /* Figure out what kind of viking we are on.
569 * We need to know if we have to play with the
570 * AC bit and disable traps or not.
571 */
573 /* I've only seen MicroSparc's on SparcClassics with this
574 * bit set.
575 */
576 set 0x800, %g2
577 lda [%g0] ASI_M_MMUREGS, %g3 ! peek in the control reg
578 and %g2, %g3, %g3
579 subcc %g3, 0x0, %g0
580 bnz srmmu_nviking ! is in mbus mode
581 nop
583 rd %psr, %g3 ! DO NOT TOUCH %g3
584 andn %g3, PSR_ET, %g2
585 wr %g2, 0x0, %psr
586 WRITE_PAUSE
588 /* Get context table pointer, then convert to
589 * a physical address, which is 36 bits.
590 */
591 set AC_M_CTPR, %g4
592 lda [%g4] ASI_M_MMUREGS, %g4
593 sll %g4, 0x4, %g4 ! We use this below
594 ! DO NOT TOUCH %g4
596 /* Set the AC bit in the Viking's MMU control reg. */
597 lda [%g0] ASI_M_MMUREGS, %g5 ! DO NOT TOUCH %g5
598 set 0x8000, %g6 ! AC bit mask
599 or %g5, %g6, %g6 ! Or it in...
600 sta %g6, [%g0] ASI_M_MMUREGS ! Close your eyes...
602 /* Grrr, why does it seem like every other load/store
603 * on the sun4m is in some ASI space...
604 * Fine with me, let's get the pointer to the level 1
605 * page table directory and fetch its entry.
606 */
607 lda [%g4] ASI_M_BYPASS, %o1 ! This is a level 1 ptr
608 srl %o1, 0x4, %o1 ! Clear low 4 bits
609 sll %o1, 0x8, %o1 ! Make physical
611 /* Ok, pull in the PTD. */
612 lda [%o1] ASI_M_BYPASS, %o2 ! This is the 0x0 16MB pgd
614 /* Calculate to KERNBASE entry. */
615 add %o1, KERNBASE >> (SRMMU_PGDIR_SHIFT - 2), %o3
617 /* Poke the entry into the calculated address. */
618 sta %o2, [%o3] ASI_M_BYPASS
620 /* I don't get it Sun, if you engineered all these
621 * boot loaders and the PROM (thank you for the debugging
622 * features btw) why did you not have them load kernel
623 * images up in high address space, since this is necessary
624 * for ABI compliance anyways? Does this low-mapping provide
625 * enhanced interoperability?
626 *
627 * "The PROM is the computer."
628 */
630 /* Ok, restore the MMU control register we saved in %g5 */
631 sta %g5, [%g0] ASI_M_MMUREGS ! POW... ouch
633 /* Turn traps back on. We saved it in %g3 earlier. */
634 wr %g3, 0x0, %psr ! tick tock, tick tock
636 /* Now we burn precious CPU cycles due to bad engineering. */
637 WRITE_PAUSE
639 /* Wow, all that just to move a 32-bit value from one
640 * place to another... Jump to high memory.
641 */
642 b go_to_highmem
643 nop
645 /* This works on viking's in Mbus mode and all
646 * other MBUS modules. It is virtually the same as
647 * the above madness sans turning traps off and flipping
648 * the AC bit.
649 */
650 srmmu_nviking:
651 set AC_M_CTPR, %g1
652 lda [%g1] ASI_M_MMUREGS, %g1 ! get ctx table ptr
653 sll %g1, 0x4, %g1 ! make physical addr
654 lda [%g1] ASI_M_BYPASS, %g1 ! ptr to level 1 pg_table
655 srl %g1, 0x4, %g1
656 sll %g1, 0x8, %g1 ! make phys addr for l1 tbl
658 lda [%g1] ASI_M_BYPASS, %g2 ! get level1 entry for 0x0
659 add %g1, KERNBASE >> (SRMMU_PGDIR_SHIFT - 2), %g3
660 sta %g2, [%g3] ASI_M_BYPASS ! place at KERNBASE entry
661 b go_to_highmem
662 nop ! wheee....
664 /* This remaps the kernel on Sun4/4xx machines
665 * that have the Sun Mutant Three Level MMU.
666 * It's like a platypus, Sun didn't have the
667 * SRMMU in conception so they kludged the three
668 * level logic in the regular Sun4 MMU probably.
669 *
670 * Basically, you take each entry in the top level
671 * directory that maps the low 3MB starting at
672 * address zero and put the mapping in the KERNBASE
673 * slots. These top level pgd's are called regmaps.
674 */
675 sun4_mutant_remap:
676 or %g0, %g0, %g3 ! source base
677 sethi %hi(KERNBASE), %g4 ! destination base
678 or %g4, %lo(KERNBASE), %g4
679 sethi %hi(0x300000), %g5
680 or %g5, %lo(0x300000), %g5 ! upper bound 3MB
681 or %g0, 0x1, %l6
682 sll %l6, 24, %l6 ! Regmap mapping size
683 add %g3, 0x2, %g3 ! Base magic
684 add %g4, 0x2, %g4 ! Base magic
686 /* Main remapping loop on Sun4-Mutant-MMU.
687 * "I am not an animal..." -Famous Mutant Person
688 */
689 sun4_mutant_loop:
690 lduha [%g3] ASI_REGMAP, %g2 ! Get lower entry
691 stha %g2, [%g4] ASI_REGMAP ! Store in high entry
692 add %g4, %l6, %g4 ! Move up high memory ptr
693 subcc %g3, %g5, %g0 ! Reached our limit?
694 blu sun4_mutant_loop ! Nope, loop again
695 add %g3, %l6, %g3 ! delay, Move up low ptr
696 b go_to_highmem ! Jump to high memory.
697 nop
699 /* The following is for non-4/4xx sun4 MMU's. */
700 sun4_normal_remap:
701 mov 0, %g3 ! source base
702 set KERNBASE, %g4 ! destination base
703 set 0x300000, %g5 ! upper bound 3MB
704 mov 1, %l6
705 sll %l6, 18, %l6 ! sun4 mmu segmap size
706 sun4_normal_loop:
707 lduha [%g3] ASI_SEGMAP, %g6 ! load phys_seg
708 stha %g6, [%g4] ASI_SEGMAP ! stort new virt mapping
709 add %g3, %l6, %g3 ! increment source pointer
710 subcc %g3, %g5, %g0 ! reached limit?
711 blu sun4_normal_loop ! nope, loop again
712 add %g4, %l6, %g4 ! delay, increment dest ptr
713 b go_to_highmem
714 nop
716 /* The following works for Sun4c MMU's */
717 sun4c_remap:
718 mov 0, %g3 ! source base
719 set KERNBASE, %g4 ! destination base
720 set 0x300000, %g5 ! upper bound 3MB
721 mov 1, %l6
722 sll %l6, 18, %l6 ! sun4c mmu segmap size
723 sun4c_remap_loop:
724 lda [%g3] ASI_SEGMAP, %g6 ! load phys_seg
725 sta %g6, [%g4] ASI_SEGMAP ! store new virt mapping
726 add %g3, %l6, %g3 ! Increment source ptr
727 subcc %g3, %g5, %g0 ! Reached limit?
728 bl sun4c_remap_loop ! Nope, loop again
729 add %g4, %l6, %g4 ! delay, Increment dest ptr
731 /* Now do a non-relative jump so that PC is in high-memory */
732 go_to_highmem:
733 set execute_in_high_mem, %g1
734 jmpl %g1, %g0
735 nop
737 /* The code above should be at beginning and we have to take care about
738 * short jumps, as branching to .text.init section from .text is usually
739 * impossible */
740 __INIT
741 /* Acquire boot time privileged register values, this will help debugging.
742 * I figure out and store nwindows and nwindowsm1 later on.
743 */
744 execute_in_high_mem:
745 mov %l0, %o0 ! put back romvec
746 mov %l1, %o1 ! and debug_vec
748 sethi %hi(prom_vector_p), %g1
749 st %o0, [%g1 + %lo(prom_vector_p)]
751 sethi %hi(linux_dbvec), %g1
752 st %o1, [%g1 + %lo(linux_dbvec)]
754 ld [%o0 + 0x4], %o3
755 and %o3, 0x3, %o5 ! get the version
757 cmp %o3, 0x2 ! a v2 prom?
758 be found_version
759 nop
761 /* paul@sfe.com.au */
762 cmp %o3, 0x3 ! a v3 prom?
763 be found_version
764 nop
766 /* Old sun4's pass our load address into %o0 instead of the prom
767 * pointer. On sun4's you have to hard code the romvec pointer into
768 * your code. Sun probably still does that because they don't even
769 * trust their own "OpenBoot" specifications.
770 */
771 set LOAD_ADDR, %g6
772 cmp %o0, %g6 ! an old sun4?
773 be sun4_init
774 nop
776 found_version:
777 /* Get the machine type via the mysterious romvec node operations. */
779 add %g7, 0x1c, %l1
780 ld [%l1], %l0
781 ld [%l0], %l0
782 call %l0
783 or %g0, %g0, %o0 ! next_node(0) = first_node
784 or %o0, %g0, %g6
786 sethi %hi(cputypvar), %o1 ! First node has cpu-arch
787 or %o1, %lo(cputypvar), %o1
788 sethi %hi(cputypval), %o2 ! information, the string
789 or %o2, %lo(cputypval), %o2
790 ld [%l1], %l0 ! 'compatibility' tells
791 ld [%l0 + 0xc], %l0 ! that we want 'sun4x' where
792 call %l0 ! x is one of '', 'c', 'm',
793 nop ! 'd' or 'e'. %o2 holds pointer
794 ! to a buf where above string
795 ! will get stored by the prom.
797 subcc %o0, %g0, %g0
798 bpos got_prop ! Got the property
799 nop
801 or %g6, %g0, %o0
802 sethi %hi(cputypvar_sun4m), %o1
803 or %o1, %lo(cputypvar_sun4m), %o1
804 sethi %hi(cputypval), %o2
805 or %o2, %lo(cputypval), %o2
806 ld [%l1], %l0
807 ld [%l0 + 0xc], %l0
808 call %l0
809 nop
811 got_prop:
812 set cputypval, %o2
813 ldub [%o2 + 0x4], %l1
815 cmp %l1, ' '
816 be 1f
817 cmp %l1, 'c'
818 be 1f
819 cmp %l1, 'm'
820 be 1f
821 cmp %l1, 's'
822 be 1f
823 cmp %l1, 'd'
824 be 1f
825 cmp %l1, 'e'
826 be no_sun4e_here ! Could be a sun4e.
827 nop
828 b no_sun4u_here ! AIEEE, a V9 sun4u... Get our BIG BROTHER kernel :))
829 nop
831 1: set cputypval, %l1
832 ldub [%l1 + 0x4], %l1
833 cmp %l1, 'm' ! Test for sun4d, sun4e ?
834 be sun4m_init
835 cmp %l1, 's' ! Treat sun4s as sun4m
836 be sun4m_init
837 cmp %l1, 'd' ! Let us see how the beast will die
838 be sun4d_init
839 nop
841 /* Jump into mmu context zero. */
842 set AC_CONTEXT, %g1
843 stba %g0, [%g1] ASI_CONTROL
845 b sun4c_continue_boot
846 nop
848 /* CPUID in bootbus can be found at PA 0xff0140000 */
849 #define SUN4D_BOOTBUS_CPUID 0xf0140000
851 sun4d_init:
852 /* Need to patch call to handler_irq */
853 set patch_handler_irq, %g4
854 set sun4d_handler_irq, %g5
855 sethi %hi(0x40000000), %g3 ! call
856 sub %g5, %g4, %g5
857 srl %g5, 2, %g5
858 or %g5, %g3, %g5
859 st %g5, [%g4]
861 #ifdef CONFIG_SMP
862 /* Get our CPU id out of bootbus */
863 set SUN4D_BOOTBUS_CPUID, %g3
864 lduba [%g3] ASI_M_CTL, %g3
865 and %g3, 0xf8, %g3
866 srl %g3, 3, %g4
867 sta %g4, [%g0] ASI_M_VIKING_TMP1
868 sethi %hi(boot_cpu_id), %g5
869 stb %g4, [%g5 + %lo(boot_cpu_id)]
870 sll %g4, 2, %g4
871 sethi %hi(boot_cpu_id4), %g5
872 stb %g4, [%g5 + %lo(boot_cpu_id4)]
873 #endif
875 /* Fall through to sun4m_init */
877 sun4m_init:
878 /* XXX Fucking Cypress... */
879 lda [%g0] ASI_M_MMUREGS, %g5
880 srl %g5, 28, %g4
882 cmp %g4, 1
883 bne 1f
884 srl %g5, 24, %g4
886 and %g4, 0xf, %g4
887 cmp %g4, 7 /* This would be a HyperSparc. */
889 bne 2f
890 nop
892 1:
894 #define PATCH_IT(dst, src) \
895 set (dst), %g5; \
896 set (src), %g4; \
897 ld [%g4], %g3; \
898 st %g3, [%g5]; \
899 ld [%g4+0x4], %g3; \
900 st %g3, [%g5+0x4];
902 /* Signed multiply. */
903 PATCH_IT(.mul, .mul_patch)
904 PATCH_IT(.mul+0x08, .mul_patch+0x08)
906 /* Signed remainder. */
907 PATCH_IT(.rem, .rem_patch)
908 PATCH_IT(.rem+0x08, .rem_patch+0x08)
909 PATCH_IT(.rem+0x10, .rem_patch+0x10)
910 PATCH_IT(.rem+0x18, .rem_patch+0x18)
911 PATCH_IT(.rem+0x20, .rem_patch+0x20)
912 PATCH_IT(.rem+0x28, .rem_patch+0x28)
914 /* Signed division. */
915 PATCH_IT(.div, .div_patch)
916 PATCH_IT(.div+0x08, .div_patch+0x08)
917 PATCH_IT(.div+0x10, .div_patch+0x10)
918 PATCH_IT(.div+0x18, .div_patch+0x18)
919 PATCH_IT(.div+0x20, .div_patch+0x20)
921 /* Unsigned multiply. */
922 PATCH_IT(.umul, .umul_patch)
923 PATCH_IT(.umul+0x08, .umul_patch+0x08)
925 /* Unsigned remainder. */
926 PATCH_IT(.urem, .urem_patch)
927 PATCH_IT(.urem+0x08, .urem_patch+0x08)
928 PATCH_IT(.urem+0x10, .urem_patch+0x10)
929 PATCH_IT(.urem+0x18, .urem_patch+0x18)
931 /* Unsigned division. */
932 PATCH_IT(.udiv, .udiv_patch)
933 PATCH_IT(.udiv+0x08, .udiv_patch+0x08)
934 PATCH_IT(.udiv+0x10, .udiv_patch+0x10)
936 #undef PATCH_IT
938 /* Ok, the PROM could have done funny things and apple cider could still
939 * be sitting in the fault status/address registers. Read them all to
940 * clear them so we don't get magic faults later on.
941 */
942 /* This sucks, apparently this makes Vikings call prom panic, will fix later */
943 2:
944 rd %psr, %o1
945 srl %o1, 28, %o1 ! Get a type of the CPU
947 subcc %o1, 4, %g0 ! TI: Viking or MicroSPARC
948 be sun4c_continue_boot
949 nop
951 set AC_M_SFSR, %o0
952 lda [%o0] ASI_M_MMUREGS, %g0
953 set AC_M_SFAR, %o0
954 lda [%o0] ASI_M_MMUREGS, %g0
956 /* Fujitsu MicroSPARC-II has no asynchronous flavors of FARs */
957 subcc %o1, 0, %g0
958 be sun4c_continue_boot
959 nop
961 set AC_M_AFSR, %o0
962 lda [%o0] ASI_M_MMUREGS, %g0
963 set AC_M_AFAR, %o0
964 lda [%o0] ASI_M_MMUREGS, %g0
965 nop
968 sun4c_continue_boot:
971 /* Aieee, now set PC and nPC, enable traps, give ourselves a stack and it's
972 * show-time!
973 */
975 sethi %hi(cputyp), %o0
976 st %g4, [%o0 + %lo(cputyp)]
978 /* Turn on Supervisor, EnableFloating, and all the PIL bits.
979 * Also puts us in register window zero with traps off.
980 */
981 set (PSR_PS | PSR_S | PSR_PIL | PSR_EF), %g2
982 wr %g2, 0x0, %psr
983 WRITE_PAUSE
985 /* I want a kernel stack NOW! */
986 set init_thread_union, %g1
987 set (THREAD_SIZE - STACKFRAME_SZ), %g2
988 add %g1, %g2, %sp
989 mov 0, %fp /* And for good luck */
991 /* Zero out our BSS section. */
992 set __bss_start , %o0 ! First address of BSS
993 set _end , %o1 ! Last address of BSS
994 add %o0, 0x1, %o0
995 1:
996 stb %g0, [%o0]
997 subcc %o0, %o1, %g0
998 bl 1b
999 add %o0, 0x1, %o0
1001 /* Initialize the uwinmask value for init task just in case.
1002 * But first make current_set[boot_cpu_id] point to something useful.
1003 */
1004 set init_thread_union, %g6
1005 set current_set, %g2
1006 #ifdef CONFIG_SMP
1007 sethi %hi(boot_cpu_id4), %g3
1008 ldub [%g3 + %lo(boot_cpu_id4)], %g3
1009 st %g6, [%g2]
1010 add %g2, %g3, %g2
1011 #endif
1012 st %g6, [%g2]
1014 st %g0, [%g6 + TI_UWINMASK]
1016 /* Compute NWINDOWS and stash it away. Now uses %wim trick explained
1017 * in the V8 manual. Ok, this method seems to work, Sparc is cool...
1018 * No, it doesn't work, have to play the save/readCWP/restore trick.
1019 */
1021 wr %g0, 0x0, %wim ! so we do not get a trap
1022 WRITE_PAUSE
1024 save
1026 rd %psr, %g3
1028 restore
1030 and %g3, 0x1f, %g3
1031 add %g3, 0x1, %g3
1033 mov 2, %g1
1034 wr %g1, 0x0, %wim ! make window 1 invalid
1035 WRITE_PAUSE
1037 cmp %g3, 0x7
1038 bne 2f
1039 nop
1041 /* Adjust our window handling routines to
1042 * do things correctly on 7 window Sparcs.
1043 */
1045 #define PATCH_INSN(src, dest) \
1046 set src, %g5; \
1047 set dest, %g2; \
1048 ld [%g5], %g4; \
1049 st %g4, [%g2];
1051 /* Patch for window spills... */
1052 PATCH_INSN(spnwin_patch1_7win, spnwin_patch1)
1053 PATCH_INSN(spnwin_patch2_7win, spnwin_patch2)
1054 PATCH_INSN(spnwin_patch3_7win, spnwin_patch3)
1056 /* Patch for window fills... */
1057 PATCH_INSN(fnwin_patch1_7win, fnwin_patch1)
1058 PATCH_INSN(fnwin_patch2_7win, fnwin_patch2)
1060 /* Patch for trap entry setup... */
1061 PATCH_INSN(tsetup_7win_patch1, tsetup_patch1)
1062 PATCH_INSN(tsetup_7win_patch2, tsetup_patch2)
1063 PATCH_INSN(tsetup_7win_patch3, tsetup_patch3)
1064 PATCH_INSN(tsetup_7win_patch4, tsetup_patch4)
1065 PATCH_INSN(tsetup_7win_patch5, tsetup_patch5)
1066 PATCH_INSN(tsetup_7win_patch6, tsetup_patch6)
1068 /* Patch for returning from traps... */
1069 PATCH_INSN(rtrap_7win_patch1, rtrap_patch1)
1070 PATCH_INSN(rtrap_7win_patch2, rtrap_patch2)
1071 PATCH_INSN(rtrap_7win_patch3, rtrap_patch3)
1072 PATCH_INSN(rtrap_7win_patch4, rtrap_patch4)
1073 PATCH_INSN(rtrap_7win_patch5, rtrap_patch5)
1075 /* Patch for killing user windows from the register file. */
1076 PATCH_INSN(kuw_patch1_7win, kuw_patch1)
1078 /* Now patch the kernel window flush sequences.
1079 * This saves 2 traps on every switch and fork.
1080 */
1081 set 0x01000000, %g4
1082 set flush_patch_one, %g5
1083 st %g4, [%g5 + 0x18]
1084 st %g4, [%g5 + 0x1c]
1085 set flush_patch_two, %g5
1086 st %g4, [%g5 + 0x18]
1087 st %g4, [%g5 + 0x1c]
1088 set flush_patch_three, %g5
1089 st %g4, [%g5 + 0x18]
1090 st %g4, [%g5 + 0x1c]
1091 set flush_patch_four, %g5
1092 st %g4, [%g5 + 0x18]
1093 st %g4, [%g5 + 0x1c]
1094 set flush_patch_exception, %g5
1095 st %g4, [%g5 + 0x18]
1096 st %g4, [%g5 + 0x1c]
1097 set flush_patch_switch, %g5
1098 st %g4, [%g5 + 0x18]
1099 st %g4, [%g5 + 0x1c]
1101 2:
1102 sethi %hi(nwindows), %g4
1103 st %g3, [%g4 + %lo(nwindows)] ! store final value
1104 sub %g3, 0x1, %g3
1105 sethi %hi(nwindowsm1), %g4
1106 st %g3, [%g4 + %lo(nwindowsm1)]
1108 /* Here we go, start using Linux's trap table... */
1109 set trapbase, %g3
1110 wr %g3, 0x0, %tbr
1111 WRITE_PAUSE
1113 /* Finally, turn on traps so that we can call c-code. */
1114 rd %psr, %g3
1115 wr %g3, 0x0, %psr
1116 WRITE_PAUSE
1118 wr %g3, PSR_ET, %psr
1119 WRITE_PAUSE
1121 /* First we call prom_init() to set up PROMLIB, then
1122 * off to start_kernel().
1123 */
1125 sethi %hi(prom_vector_p), %g5
1126 ld [%g5 + %lo(prom_vector_p)], %o0
1127 call prom_init
1128 nop
1130 call start_kernel
1131 nop
1133 /* We should not get here. */
1134 call halt_me
1135 nop
1137 sun4_init:
1138 sethi %hi(SUN4_PROM_VECTOR+0x84), %o1
1139 ld [%o1 + %lo(SUN4_PROM_VECTOR+0x84)], %o1
1140 set sun4_notsup, %o0
1141 call %o1 /* printf */
1142 nop
1143 sethi %hi(SUN4_PROM_VECTOR+0xc4), %o1
1144 ld [%o1 + %lo(SUN4_PROM_VECTOR+0xc4)], %o1
1145 call %o1 /* exittomon */
1146 nop
1147 1: ba 1b ! Cannot exit into KMON
1148 nop
1150 no_sun4e_here:
1151 ld [%g7 + 0x68], %o1
1152 set sun4e_notsup, %o0
1153 call %o1
1154 nop
1155 b halt_me
1156 nop
1158 __INITDATA
1160 sun4u_1:
1161 .asciz "finddevice"
1162 .align 4
1163 sun4u_2:
1164 .asciz "/chosen"
1165 .align 4
1166 sun4u_3:
1167 .asciz "getprop"
1168 .align 4
1169 sun4u_4:
1170 .asciz "stdout"
1171 .align 4
1172 sun4u_5:
1173 .asciz "write"
1174 .align 4
1175 sun4u_6:
1176 .asciz "\n\rOn sun4u you have to use UltraLinux (64bit) kernel\n\rand not a 32bit sun4[cdem] version\n\r\n\r"
1177 sun4u_6e:
1178 .align 4
1179 sun4u_7:
1180 .asciz "exit"
1181 .align 8
1182 sun4u_a1:
1183 .word 0, sun4u_1, 0, 1, 0, 1, 0, sun4u_2, 0
1184 sun4u_r1:
1185 .word 0
1186 sun4u_a2:
1187 .word 0, sun4u_3, 0, 4, 0, 1, 0
1188 sun4u_i2:
1189 .word 0, 0, sun4u_4, 0, sun4u_1, 0, 8, 0
1190 sun4u_r2:
1191 .word 0
1192 sun4u_a3:
1193 .word 0, sun4u_5, 0, 3, 0, 1, 0
1194 sun4u_i3:
1195 .word 0, 0, sun4u_6, 0, sun4u_6e - sun4u_6 - 1, 0
1196 sun4u_r3:
1197 .word 0
1198 sun4u_a4:
1199 .word 0, sun4u_7, 0, 0, 0, 0
1200 sun4u_r4:
1202 __INIT
1203 no_sun4u_here:
1204 set sun4u_a1, %o0
1205 set current_pc, %l2
1206 cmp %l2, %g3
1207 be 1f
1208 mov %o4, %l0
1209 sub %g3, %l2, %l6
1210 add %o0, %l6, %o0
1211 mov %o0, %l4
1212 mov sun4u_r4 - sun4u_a1, %l3
1213 ld [%l4], %l5
1214 2:
1215 add %l4, 4, %l4
1216 cmp %l5, %l2
1217 add %l5, %l6, %l5
1218 bgeu,a 3f
1219 st %l5, [%l4 - 4]
1220 3:
1221 subcc %l3, 4, %l3
1222 bne 2b
1223 ld [%l4], %l5
1224 1:
1225 call %l0
1226 mov %o0, %l1
1228 ld [%l1 + (sun4u_r1 - sun4u_a1)], %o1
1229 add %l1, (sun4u_a2 - sun4u_a1), %o0
1230 call %l0
1231 st %o1, [%o0 + (sun4u_i2 - sun4u_a2)]
1233 ld [%l1 + (sun4u_1 - sun4u_a1)], %o1
1234 add %l1, (sun4u_a3 - sun4u_a1), %o0
1235 call %l0
1236 st %o1, [%o0 + (sun4u_i3 - sun4u_a3)]
1238 call %l0
1239 add %l1, (sun4u_a4 - sun4u_a1), %o0
1241 /* Not reached */
1242 halt_me:
1243 ld [%g7 + 0x74], %o0
1244 call %o0 ! Get us out of here...
1245 nop ! Apparently Solaris is better.
1247 /* Ok, now we continue in the .data/.text sections */
1249 .data
1250 .align 4
1252 /*
1253 * Fill up the prom vector, note in particular the kind first element,
1254 * no joke. I don't need all of them in here as the entire prom vector
1255 * gets initialized in c-code so all routines can use it.
1256 */
1258 prom_vector_p:
1259 .word 0
1261 /* We calculate the following at boot time, window fills/spills and trap entry
1262 * code uses these to keep track of the register windows.
1263 */
1265 .align 4
1266 .globl nwindows
1267 .globl nwindowsm1
1268 nwindows:
1269 .word 8
1270 nwindowsm1:
1271 .word 7
1273 /* Boot time debugger vector value. We need this later on. */
1275 .align 4
1276 .globl linux_dbvec
1277 linux_dbvec:
1278 .word 0
1279 .word 0
1281 .align 8
1283 .globl lvl14_save
1284 lvl14_save:
1285 .word 0
1286 .word 0
1287 .word 0
1288 .word 0
1289 .word t_irq14
1291 .section ".fixup",#alloc,#execinstr
1292 .globl __ret_efault
1293 __ret_efault:
1294 ret
1295 restore %g0, -EFAULT, %o0