arch/x86/entry/vdso/vdso-layout.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 #include <asm/vdso.h>
   3
   4 /*
   5  * Linker script for vDSO.  This is an ELF shared object prelinked to
   6  * its virtual address, and with only one read-only segment.
   7  * This script controls its layout.
   8  */
   9
  10 #if defined(BUILD_VDSO64)
  11 # define SHDR_SIZE 64
  12 #elif defined(BUILD_VDSO32) || defined(BUILD_VDSOX32)
  13 # define SHDR_SIZE 40
  14 #else
  15 # error unknown VDSO target
  16 #endif
  17
  18 #define NUM_FAKE_SHDRS 13
  19
  20 SECTIONS
  21 {
  22         /*
  23          * User/kernel shared data is before the vDSO.  This may be a little
  24          * uglier than putting it after the vDSO, but it avoids issues with
  25          * non-allocatable things that dangle past the end of the PT_LOAD
  26          * segment.
  27          */
  28
  29         vvar_start = . - 3 * PAGE_SIZE;
  30         vvar_page = vvar_start;
  31
  32         /* Place all vvars at the offsets in asm/vvar.h. */
  33 #define EMIT_VVAR(name, offset) vvar_ ## name = vvar_page + offset;
  34 #define __VVAR_KERNEL_LDS
  35 #include <asm/vvar.h>
  36 #undef __VVAR_KERNEL_LDS
  37 #undef EMIT_VVAR
  38
  39         pvclock_page = vvar_start + PAGE_SIZE;
  40         hvclock_page = vvar_start + 2 * PAGE_SIZE;
  41
  42         . = SIZEOF_HEADERS;
  43
  44         .hash           : { *(.hash) }                  :text
  45         .gnu.hash       : { *(.gnu.hash) }
  46         .dynsym         : { *(.dynsym) }
  47         .dynstr         : { *(.dynstr) }
  48         .gnu.version    : { *(.gnu.version) }
  49         .gnu.version_d  : { *(.gnu.version_d) }
  50         .gnu.version_r  : { *(.gnu.version_r) }
  51
  52         .dynamic        : { *(.dynamic) }               :text   :dynamic
  53
  54         .rodata         : {
  55                 *(.rodata*)
  56                 *(.data*)
  57                 *(.sdata*)
  58                 *(.got.plt) *(.got)
  59                 *(.gnu.linkonce.d.*)
  60                 *(.bss*)
  61                 *(.dynbss*)
  62                 *(.gnu.linkonce.b.*)
  63
  64                 /*
  65                  * Ideally this would live in a C file, but that won't
  66                  * work cleanly for x32 until we start building the x32
  67                  * C code using an x32 toolchain.
  68                  */
  69                 VDSO_FAKE_SECTION_TABLE_START = .;
  70                 . = . + NUM_FAKE_SHDRS * SHDR_SIZE;
  71                 VDSO_FAKE_SECTION_TABLE_END = .;
  72         }                                               :text
  73
  74         .fake_shstrtab  : { *(.fake_shstrtab) }         :text
  75
  76
  77         .note           : { *(.note.*) }                :text   :note
  78
  79         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  80         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  81
  82
  83         /*
  84          * Text is well-separated from actual data: there's plenty of
  85          * stuff that isn't used at runtime in between.
  86          */
  87
  88         .text           : { *(.text*) }                 :text   =0x90909090,
  89
  90         /*
  91          * At the end so that eu-elflint stays happy when vdso2c strips
  92          * these.  A better implementation would avoid allocating space
  93          * for these.
  94          */
  95         .altinstructions        : { *(.altinstructions) }       :text
  96         .altinstr_replacement   : { *(.altinstr_replacement) }  :text
  97
  98         /DISCARD/ : {
  99                 *(.discard)
 100                 *(.discard.*)
 101                 *(__bug_table)
 102         }
 103 }
 104
 105 /*
 106  * Very old versions of ld do not recognize this name token; use the constant.
 107  */
 108 #define PT_GNU_EH_FRAME 0x6474e550
 109
 110 /*
 111  * We must supply the ELF program headers explicitly to get just one
 112  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
 113  */
 114 PHDRS
 115 {
 116         text            PT_LOAD         FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
 117         dynamic         PT_DYNAMIC      FLAGS(4);               /* PF_R */
 118         note            PT_NOTE         FLAGS(4);               /* PF_R */
 119         eh_frame_hdr    PT_GNU_EH_FRAME;
 120 }