scripts/checkstack.pl

   1 #!/usr/bin/env perl
   2 # SPDX-License-Identifier: GPL-2.0
   3
   4 #       Check the stack usage of functions
   5 #
   6 #       Copyright Joern Engel <joern@lazybastard.org>
   7 #       Inspired by Linus Torvalds
   8 #       Original idea maybe from Keith Owens
   9 #       s390 port and big speedup by Arnd Bergmann <arnd@bergmann-dalldorf.de>
  10 #       Mips port by Juan Quintela <quintela@mandrakesoft.com>
  11 #       IA64 port via Andreas Dilger
  12 #       Arm port by Holger Schurig
  13 #       sh64 port by Paul Mundt
  14 #       Random bits by Matt Mackall <mpm@selenic.com>
  15 #       M68k port by Geert Uytterhoeven and Andreas Schwab
  16 #       AArch64, PARISC ports by Kyle McMartin
  17 #       sparc port by Martin Habets <errandir_news@mph.eclipse.co.uk>
  18 #       ppc64le port by Breno Leitao <leitao@debian.org>
  19 #
  20 #       Usage:
  21 #       objdump -d vmlinux | scripts/checkstack.pl [arch]
  22 #
  23 #       TODO :  Port to all architectures (one regex per arch)
  24
  25 use strict;
  26
  27 # check for arch
  28 #
  29 # $re is used for two matches:
  30 # $& (whole re) matches the complete objdump line with the stack growth
  31 # $1 (first bracket) matches the size of the stack growth
  32 #
  33 # $dre is similar, but for dynamic stack redutions:
  34 # $& (whole re) matches the complete objdump line with the stack growth
  35 # $1 (first bracket) matches the dynamic amount of the stack growth
  36 #
  37 # use anything else and feel the pain ;)
  38 my (@stack, $re, $dre, $x, $xs, $funcre);
  39 {
  40         my $arch = shift;
  41         if ($arch eq "") {
  42                 $arch = `uname -m`;
  43                 chomp($arch);
  44         }
  45
  46         $x      = "[0-9a-f]";   # hex character
  47         $xs     = "[0-9a-f ]";  # hex character or space
  48         $funcre = qr/^$x* <(.*)>:$/;
  49         if ($arch eq 'aarch64') {
  50                 #ffffffc0006325cc:       a9bb7bfd        stp     x29, x30, [sp, #-80]!
  51                 $re = qr/^.*stp.*sp, \#-([0-9]{1,8})\]\!/o;
  52         } elsif ($arch eq 'arm') {
  53                 #c0008ffc:      e24dd064        sub     sp, sp, #100    ; 0x64
  54                 $re = qr/.*sub.*sp, sp, #(([0-9]{2}|[3-9])[0-9]{2})/o;
  55         } elsif ($arch =~ /^x86(_64)?$/ || $arch =~ /^i[3456]86$/) {
  56                 #c0105234:       81 ec ac 05 00 00       sub    $0x5ac,%esp
  57                 # or
  58                 #    2f60:    48 81 ec e8 05 00 00       sub    $0x5e8,%rsp
  59                 $re = qr/^.*[as][du][db]    \$(0x$x{1,8}),\%(e|r)sp$/o;
  60                 $dre = qr/^.*[as][du][db]    (%.*),\%(e|r)sp$/o;
  61         } elsif ($arch eq 'ia64') {
  62                 #e0000000044011fc:       01 0f fc 8c     adds r12=-384,r12
  63                 $re = qr/.*adds.*r12=-(([0-9]{2}|[3-9])[0-9]{2}),r12/o;
  64         } elsif ($arch eq 'm68k') {
  65                 #    2b6c:       4e56 fb70       linkw %fp,#-1168
  66                 #  1df770:       defc ffe4       addaw #-28,%sp
  67                 $re = qr/.*(?:linkw %fp,|addaw )#-([0-9]{1,4})(?:,%sp)?$/o;
  68         } elsif ($arch eq 'mips64') {
  69                 #8800402c:       67bdfff0        daddiu  sp,sp,-16
  70                 $re = qr/.*daddiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  71         } elsif ($arch eq 'mips') {
  72                 #88003254:       27bdffe0        addiu   sp,sp,-32
  73                 $re = qr/.*addiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  74         } elsif ($arch eq 'nios2') {
  75                 #25a8:  defffb04        addi    sp,sp,-20
  76                 $re = qr/.*addi.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  77         } elsif ($arch eq 'openrisc') {
  78                 # c000043c:       9c 21 fe f0     l.addi r1,r1,-272
  79                 $re = qr/.*l\.addi.*r1,r1,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  80         } elsif ($arch eq 'parisc' || $arch eq 'parisc64') {
  81                 $re = qr/.*ldo ($x{1,8})\(sp\),sp/o;
  82         } elsif ($arch eq 'powerpc' || $arch =~ /^ppc(64)?(le)?$/ ) {
  83                 # powerpc    : 94 21 ff 30     stwu    r1,-208(r1)
  84                 # ppc64(le)  : 81 ff 21 f8     stdu    r1,-128(r1)
  85                 $re = qr/.*st[dw]u.*r1,-($x{1,8})\(r1\)/o;
  86         } elsif ($arch =~ /^s390x?$/) {
  87                 #   11160:       a7 fb ff 60             aghi   %r15,-160
  88                 # or
  89                 #  100092:       e3 f0 ff c8 ff 71       lay     %r15,-56(%r15)
  90                 $re = qr/.*(?:lay|ag?hi).*\%r15,-(([0-9]{2}|[3-9])[0-9]{2})
  91                       (?:\(\%r15\))?$/ox;
  92         } elsif ($arch =~ /^sh64$/) {
  93                 #XXX: we only check for the immediate case presently,
  94                 #     though we will want to check for the movi/sub
  95                 #     pair for larger users. -- PFM.
  96                 #a00048e0:       d4fc40f0        addi.l  r15,-240,r15
  97                 $re = qr/.*addi\.l.*r15,-(([0-9]{2}|[3-9])[0-9]{2}),r15/o;
  98         } elsif ($arch eq 'sparc' || $arch eq 'sparc64') {
  99                 # f0019d10:       9d e3 bf 90     save  %sp, -112, %sp
 100                 $re = qr/.*save.*%sp, -(([0-9]{2}|[3-9])[0-9]{2}), %sp/o;
 101         } else {
 102                 print("wrong or unknown architecture \"$arch\"\n");
 103                 exit
 104         }
 105 }
 106
 107 #
 108 # main()
 109 #
 110 my ($func, $file, $lastslash);
 111
 112 while (my $line = <STDIN>) {
 113         if ($line =~ m/$funcre/) {
 114                 $func = $1;
 115         }
 116         elsif ($line =~ m/(.*):\s*file format/) {
 117                 $file = $1;
 118                 $file =~ s/\.ko//;
 119                 $lastslash = rindex($file, "/");
 120                 if ($lastslash != -1) {
 121                         $file = substr($file, $lastslash + 1);
 122                 }
 123         }
 124         elsif ($line =~ m/$re/) {
 125                 my $size = $1;
 126                 $size = hex($size) if ($size =~ /^0x/);
 127
 128                 if ($size > 0xf0000000) {
 129                         $size = - $size;
 130                         $size += 0x80000000;
 131                         $size += 0x80000000;
 132                 }
 133                 next if ($size > 0x10000000);
 134
 135                 next if $line !~ m/^($xs*)/;
 136                 my $addr = $1;
 137                 $addr =~ s/ /0/g;
 138                 $addr = "0x$addr";
 139
 140                 my $intro = "$addr $func [$file]:";
 141                 my $padlen = 56 - length($intro);
 142                 while ($padlen > 0) {
 143                         $intro .= '     ';
 144                         $padlen -= 8;
 145                 }
 146                 next if ($size < 100);
 147                 push @stack, "$intro$size\n";
 148         }
 149         elsif (defined $dre && $line =~ m/$dre/) {
 150                 my $size = "Dynamic ($1)";
 151
 152                 next if $line !~ m/^($xs*)/;
 153                 my $addr = $1;
 154                 $addr =~ s/ /0/g;
 155                 $addr = "0x$addr";
 156
 157                 my $intro = "$addr $func [$file]:";
 158                 my $padlen = 56 - length($intro);
 159                 while ($padlen > 0) {
 160                         $intro .= '     ';
 161                         $padlen -= 8;
 162                 }
 163                 push @stack, "$intro$size\n";
 164         }
 165 }
 166
 167 # Sort output by size (last field)
 168 print sort { ($b =~ /:\t*(\d+)$/)[0] <=> ($a =~ /:\t*(\d+)$/)[0] } @stack;