arch/sparc64/kernel/vmlinux.lds.S

   1 /* ld script to make UltraLinux kernel */
   2
   3 #include <asm-generic/vmlinux.lds.h>
   4
   5 OUTPUT_FORMAT("elf64-sparc", "elf64-sparc", "elf64-sparc")
   6 OUTPUT_ARCH(sparc:v9a)
   7 ENTRY(_start)
   8
   9 jiffies = jiffies_64;
  10 SECTIONS
  11 {
  12   swapper_low_pmd_dir = 0x0000000000402000;
  13   . = 0x4000;
  14   .text 0x0000000000404000 :
  15   {
  16     *(.text)
  17     SCHED_TEXT
  18     LOCK_TEXT
  19     KPROBES_TEXT
  20     *(.gnu.warning)
  21   } =0
  22   _etext = .;
  23   PROVIDE (etext = .);
  24
  25   RODATA
  26
  27   .data    :
  28   {
  29     *(.data)
  30     CONSTRUCTORS
  31   }
  32   .data1   : { *(.data1) }
  33   . = ALIGN(64);
  34   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  35   . = ALIGN(64);
  36   .data.read_mostly : { *(.data.read_mostly) }
  37   _edata  =  .;
  38   PROVIDE (edata = .);
  39   .fixup   : { *(.fixup) }
  40
  41   . = ALIGN(16);
  42   __start___ex_table = .;
  43   __ex_table : { *(__ex_table) }
  44   __stop___ex_table = .;
  45
  46   . = ALIGN(8192);
  47   __init_begin = .;
  48   .init.text : {
  49         _sinittext = .;
  50         *(.init.text)
  51         _einittext = .;
  52   }
  53   .init.data : { *(.init.data) }
  54   . = ALIGN(16);
  55   __setup_start = .;
  56   .init.setup : { *(.init.setup) }
  57   __setup_end = .;
  58   __initcall_start = .;
  59   .initcall.init : {
  60         INITCALLS
  61   }
  62   __initcall_end = .;
  63   __con_initcall_start = .;
  64   .con_initcall.init : { *(.con_initcall.init) }
  65   __con_initcall_end = .;
  66   SECURITY_INIT
  67   . = ALIGN(4);
  68   __tsb_ldquad_phys_patch = .;
  69   .tsb_ldquad_phys_patch : { *(.tsb_ldquad_phys_patch) }
  70   __tsb_ldquad_phys_patch_end = .;
  71   __tsb_phys_patch = .;
  72   .tsb_phys_patch : { *(.tsb_phys_patch) }
  73   __tsb_phys_patch_end = .;
  74   __cpuid_patch = .;
  75   .cpuid_patch : { *(.cpuid_patch) }
  76   __cpuid_patch_end = .;
  77   __sun4v_1insn_patch = .;
  78   .sun4v_1insn_patch : { *(.sun4v_1insn_patch) }
  79   __sun4v_1insn_patch_end = .;
  80   __sun4v_2insn_patch = .;
  81   .sun4v_2insn_patch : { *(.sun4v_2insn_patch) }
  82   __sun4v_2insn_patch_end = .;
  83   . = ALIGN(8192);
  84   __initramfs_start = .;
  85   .init.ramfs : { *(.init.ramfs) }
  86   __initramfs_end = .;
  87   . = ALIGN(8192);
  88   __per_cpu_start = .;
  89   .data.percpu  : { *(.data.percpu) }
  90   __per_cpu_end = .;
  91   . = ALIGN(8192);
  92   __init_end = .;
  93   __bss_start = .;
  94   .sbss      : { *(.sbss) *(.scommon) }
  95   .bss       :
  96   {
  97    *(.dynbss)
  98    *(.bss)
  99    *(COMMON)
 100   }
 101   _end = . ;
 102   PROVIDE (end = .);
 103   /DISCARD/ : { *(.exit.text) *(.exit.data) *(.exitcall.exit) }
 104
 105   STABS_DEBUG
 106
 107   DWARF_DEBUG
 108 }