arch/mn10300/kernel/entry.S

   1 ###############################################################################
   2 #
   3 # MN10300 Exception and interrupt entry points
   4 #
   5 # Copyright (C) 2007 Matsushita Electric Industrial Co., Ltd.
   6 # Copyright (C) 2007 Red Hat, Inc. All Rights Reserved.
   7 # Modified by David Howells (dhowells@redhat.com)
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public Licence
  11 # as published by the Free Software Foundation; either version
  12 # 2 of the Licence, or (at your option) any later version.
  13 #
  14 ###############################################################################
  15 #include <linux/sys.h>
  16 #include <linux/linkage.h>
  17 #include <asm/smp.h>
  18 #include <asm/irqflags.h>
  19 #include <asm/thread_info.h>
  20 #include <asm/intctl-regs.h>
  21 #include <asm/busctl-regs.h>
  22 #include <asm/timer-regs.h>
  23 #include <unit/leds.h>
  24 #include <asm/page.h>
  25 #include <asm/pgtable.h>
  26 #include <asm/errno.h>
  27 #include <asm/asm-offsets.h>
  28 #include <asm/frame.inc>
  29
  30 #if defined(CONFIG_SMP) && defined(CONFIG_GDBSTUB)
  31 #include <asm/gdb-stub.h>
  32 #endif /* CONFIG_SMP && CONFIG_GDBSTUB */
  33
  34 #ifdef CONFIG_PREEMPT
  35 #define preempt_stop            LOCAL_IRQ_DISABLE
  36 #else
  37 #define preempt_stop
  38 #define resume_kernel           restore_all
  39 #endif
  40
  41         .am33_2
  42
  43 ###############################################################################
  44 #
  45 # the return path for a forked child
  46 # - on entry, D0 holds the address of the previous task to run
  47 #
  48 ###############################################################################
  49 ENTRY(ret_from_fork)
  50         call    schedule_tail[],0
  51         GET_THREAD_INFO a2
  52
  53         # return 0 to indicate child process
  54         clr     d0
  55         mov     d0,(REG_D0,fp)
  56         jmp     syscall_exit
  57
  58 ###############################################################################
  59 #
  60 # system call handler
  61 #
  62 ###############################################################################
  63 ENTRY(system_call)
  64         add     -4,sp
  65         SAVE_ALL
  66         mov     d0,(REG_ORIG_D0,fp)
  67         GET_THREAD_INFO a2
  68         cmp     nr_syscalls,d0
  69         bcc     syscall_badsys
  70         btst    _TIF_SYSCALL_TRACE,(TI_flags,a2)
  71         bne     syscall_entry_trace
  72 syscall_call:
  73         add     d0,d0,a1
  74         add     a1,a1
  75         mov     (REG_A0,fp),d0
  76         mov     (sys_call_table,a1),a0
  77         calls   (a0)
  78         mov     d0,(REG_D0,fp)
  79 syscall_exit:
  80         # make sure we don't miss an interrupt setting need_resched or
  81         # sigpending between sampling and the rti
  82         LOCAL_IRQ_DISABLE
  83         mov     (TI_flags,a2),d2
  84         btst    _TIF_ALLWORK_MASK,d2
  85         bne     syscall_exit_work
  86 restore_all:
  87         RESTORE_ALL
  88
  89 ###############################################################################
  90 #
  91 # perform work that needs to be done immediately before resumption and syscall
  92 # tracing
  93 #
  94 ###############################################################################
  95         ALIGN
  96 syscall_exit_work:
  97         btst    _TIF_SYSCALL_TRACE,d2
  98         beq     work_pending
  99         LOCAL_IRQ_ENABLE                # could let syscall_trace_exit() call
 100                                         # schedule() instead
 101         mov     fp,d0
 102         call    syscall_trace_exit[],0  # do_syscall_trace(regs)
 103         jmp     resume_userspace
 104
 105         ALIGN
 106 work_pending:
 107         btst    _TIF_NEED_RESCHED,d2
 108         beq     work_notifysig
 109
 110 work_resched:
 111         call    schedule[],0
 112
 113         # make sure we don't miss an interrupt setting need_resched or
 114         # sigpending between sampling and the rti
 115         LOCAL_IRQ_DISABLE
 116
 117         # is there any work to be done other than syscall tracing?
 118         mov     (TI_flags,a2),d2
 119         btst    _TIF_WORK_MASK,d2
 120         beq     restore_all
 121         btst    _TIF_NEED_RESCHED,d2
 122         bne     work_resched
 123
 124         # deal with pending signals and notify-resume requests
 125 work_notifysig:
 126         mov     fp,d0
 127         mov     d2,d1
 128         call    do_notify_resume[],0
 129         jmp     resume_userspace
 130
 131         # perform syscall entry tracing
 132 syscall_entry_trace:
 133         mov     -ENOSYS,d0
 134         mov     d0,(REG_D0,fp)
 135         mov     fp,d0
 136         call    syscall_trace_entry[],0 # returns the syscall number to actually use
 137         mov     (REG_D1,fp),d1
 138         cmp     nr_syscalls,d0
 139         bcs     syscall_call
 140         jmp     syscall_exit
 141
 142 syscall_badsys:
 143         mov     -ENOSYS,d0
 144         mov     d0,(REG_D0,fp)
 145         jmp     resume_userspace
 146
 147         # userspace resumption stub bypassing syscall exit tracing
 148         .globl  ret_from_exception, ret_from_intr
 149         ALIGN
 150 ret_from_exception:
 151         preempt_stop
 152 ret_from_intr:
 153         GET_THREAD_INFO a2
 154         mov     (REG_EPSW,fp),d0        # need to deliver signals before
 155                                         # returning to userspace
 156         and     EPSW_nSL,d0
 157         beq     resume_kernel           # returning to supervisor mode
 158
 159 ENTRY(resume_userspace)
 160         # make sure we don't miss an interrupt setting need_resched or
 161         # sigpending between sampling and the rti
 162         LOCAL_IRQ_DISABLE
 163
 164         # is there any work to be done on int/exception return?
 165         mov     (TI_flags,a2),d2
 166         btst    _TIF_WORK_MASK,d2
 167         bne     work_pending
 168         jmp     restore_all
 169
 170 #ifdef CONFIG_PREEMPT
 171 ENTRY(resume_kernel)
 172         LOCAL_IRQ_DISABLE
 173         mov     (TI_preempt_count,a2),d0        # non-zero preempt_count ?
 174         cmp     0,d0
 175         bne     restore_all
 176
 177 need_resched:
 178         btst    _TIF_NEED_RESCHED,(TI_flags,a2)
 179         beq     restore_all
 180         mov     (REG_EPSW,fp),d0
 181         and     EPSW_IM,d0
 182         cmp     EPSW_IM_7,d0            # interrupts off (exception path) ?
 183         bne     restore_all
 184         call    preempt_schedule_irq[],0
 185         jmp     need_resched
 186 #endif
 187
 188
 189 ###############################################################################
 190 #
 191 # IRQ handler entry point
 192 # - intended to be entered at multiple priorities
 193 #
 194 ###############################################################################
 195 ENTRY(irq_handler)
 196         add     -4,sp
 197         SAVE_ALL
 198
 199         # it's not a syscall
 200         mov     0xffffffff,d0
 201         mov     d0,(REG_ORIG_D0,fp)
 202
 203         mov     fp,d0
 204         call    do_IRQ[],0                      # do_IRQ(regs)
 205
 206         jmp     ret_from_intr
 207
 208 ###############################################################################
 209 #
 210 # Double Fault handler entry point
 211 # - note that there will not be a stack, D0/A0 will hold EPSW/PC as were
 212 #
 213 ###############################################################################
 214         .section .bss
 215         .balign THREAD_SIZE
 216         .space  THREAD_SIZE
 217 __df_stack:
 218         .previous
 219
 220 ENTRY(double_fault)
 221         mov     a0,(__df_stack-4)       # PC as was
 222         mov     d0,(__df_stack-8)       # EPSW as was
 223         mn10300_set_dbfleds             # display 'db-f' on the LEDs
 224         mov     0xaa55aa55,d0
 225         mov     d0,(__df_stack-12)      # no ORIG_D0
 226         mov     sp,a0                   # save corrupted SP
 227         mov     __df_stack-12,sp        # emergency supervisor stack
 228         SAVE_ALL
 229         mov     a0,(REG_A0,fp)          # save corrupted SP as A0 (which got
 230                                         # clobbered by the CPU)
 231         mov     fp,d0
 232         calls   do_double_fault
 233 double_fault_loop:
 234         bra     double_fault_loop
 235
 236 ###############################################################################
 237 #
 238 # Bus Error handler entry point
 239 # - handle external (async) bus errors separately
 240 #
 241 ###############################################################################
 242 ENTRY(raw_bus_error)
 243         add     -4,sp
 244         mov     d0,(sp)
 245 #if defined(CONFIG_ERRATUM_NEED_TO_RELOAD_MMUCTR)
 246         mov     (MMUCTR),d0
 247         mov     d0,(MMUCTR)
 248 #endif
 249         mov     (BCBERR),d0             # what
 250         btst    BCBERR_BEMR_DMA,d0      # see if it was an external bus error
 251         beq     __common_exception_aux  # it wasn't
 252
 253         SAVE_ALL
 254         mov     (BCBEAR),d1             # destination of erroneous access
 255
 256         mov     (REG_ORIG_D0,fp),d2
 257         mov     d2,(REG_D0,fp)
 258         mov     -1,d2
 259         mov     d2,(REG_ORIG_D0,fp)
 260
 261         add     -4,sp
 262         mov     fp,(12,sp)              # frame pointer
 263         call    io_bus_error[],0
 264         jmp     restore_all
 265
 266 ###############################################################################
 267 #
 268 # NMI exception entry points
 269 #
 270 # This is used by ordinary interrupt channels that have the GxICR_NMI bit set
 271 # in addition to the main NMI and Watchdog channels.  SMP NMI IPIs use this
 272 # facility.
 273 #
 274 ###############################################################################
 275 ENTRY(nmi_handler)
 276         add     -4,sp
 277         mov     d0,(sp)
 278         mov     (TBR),d0
 279
 280 #ifdef CONFIG_SMP
 281         add     -4,sp
 282         mov     d0,(sp)                 # save d0(TBR)
 283         movhu   (NMIAGR),d0
 284         and     NMIAGR_GN,d0
 285         lsr     0x2,d0
 286         cmp     CALL_FUNCTION_NMI_IPI,d0
 287         bne     nmi_not_smp_callfunc    # if not call function, jump
 288
 289         # function call nmi ipi
 290         add     4,sp                    # no need to store TBR
 291         mov     GxICR_DETECT,d0         # clear NMI request
 292         movbu   d0,(GxICR(CALL_FUNCTION_NMI_IPI))
 293         movhu   (GxICR(CALL_FUNCTION_NMI_IPI)),d0
 294         and     ~EPSW_NMID,epsw         # enable NMI
 295
 296         mov     (sp),d0                 # restore d0
 297         SAVE_ALL
 298         call    smp_nmi_call_function_interrupt[],0
 299         RESTORE_ALL
 300
 301 nmi_not_smp_callfunc:
 302 #ifdef CONFIG_KERNEL_DEBUGGER
 303         cmp     DEBUGGER_NMI_IPI,d0
 304         bne     nmi_not_debugger        # if not kernel debugger NMI IPI, jump
 305
 306         # kernel debugger NMI IPI
 307         add     4,sp                    # no need to store TBR
 308         mov     GxICR_DETECT,d0         # clear NMI
 309         movbu   d0,(GxICR(DEBUGGER_NMI_IPI))
 310         movhu   (GxICR(DEBUGGER_NMI_IPI)),d0
 311         and     ~EPSW_NMID,epsw         # enable NMI
 312
 313         mov     (sp),d0
 314         SAVE_ALL
 315         mov     fp,d0                   # arg 0: stacked register file
 316         mov     a2,d1                   # arg 1: exception number
 317         call    debugger_nmi_interrupt[],0
 318         RESTORE_ALL
 319
 320 nmi_not_debugger:
 321 #endif /* CONFIG_KERNEL_DEBUGGER */
 322         mov     (sp),d0                 # restore TBR to d0
 323         add     4,sp
 324 #endif /* CONFIG_SMP */
 325
 326         bra     __common_exception_nonmi
 327
 328 ###############################################################################
 329 #
 330 # General exception entry point
 331 #
 332 ###############################################################################
 333 ENTRY(__common_exception)
 334         add     -4,sp
 335         mov     d0,(sp)
 336 #if defined(CONFIG_ERRATUM_NEED_TO_RELOAD_MMUCTR)
 337         mov     (MMUCTR),d0
 338         mov     d0,(MMUCTR)
 339 #endif
 340
 341 __common_exception_aux:
 342         mov     (TBR),d0
 343         and     ~EPSW_NMID,epsw         # turn NMIs back on if not NMI
 344         or      EPSW_IE,epsw
 345
 346 __common_exception_nonmi:
 347         and     0x0000FFFF,d0           # turn the exception code into a vector
 348                                         # table index
 349
 350         btst    0x00000007,d0
 351         bne     1f
 352         cmp     0x00000400,d0
 353         bge     1f
 354
 355         SAVE_ALL                        # build the stack frame
 356
 357         mov     (REG_D0,fp),a2          # get the exception number
 358         mov     (REG_ORIG_D0,fp),d0
 359         mov     d0,(REG_D0,fp)
 360         mov     -1,d0
 361         mov     d0,(REG_ORIG_D0,fp)
 362
 363 #ifdef CONFIG_GDBSTUB
 364 #ifdef CONFIG_SMP
 365         call    gdbstub_busy_check[],0
 366         and     d0,d0                   # check return value
 367         beq     2f
 368 #else  /* CONFIG_SMP */
 369         btst    0x01,(gdbstub_busy)
 370         beq     2f
 371 #endif /* CONFIG_SMP */
 372         and     ~EPSW_IE,epsw
 373         mov     fp,d0
 374         mov     a2,d1
 375         call    gdbstub_exception[],0   # gdbstub itself caused an exception
 376         bra     restore_all
 377 2:
 378 #endif /* CONFIG_GDBSTUB */
 379
 380         mov     fp,d0                   # arg 0: stacked register file
 381         mov     a2,d1                   # arg 1: exception number
 382         lsr     1,a2
 383
 384         mov     (exception_table,a2),a2
 385         calls   (a2)
 386         jmp     ret_from_exception
 387
 388 1:      pi                              # BUG() equivalent
 389
 390 ###############################################################################
 391 #
 392 # Exception handler functions table
 393 #
 394 ###############################################################################
 395         .data
 396 ENTRY(exception_table)
 397         .rept   0x400>>1
 398          .long  uninitialised_exception
 399         .endr
 400         .previous
 401
 402 ###############################################################################
 403 #
 404 # Change an entry in the exception table
 405 # - D0 exception code, D1 handler
 406 #
 407 ###############################################################################
 408 ENTRY(set_excp_vector)
 409         lsr     1,d0
 410         add     exception_table,d0
 411         mov     d1,(d0)
 412         mov     4,d1
 413         ret     [],0
 414
 415 ###############################################################################
 416 #
 417 # System call table
 418 #
 419 ###############################################################################
 420         .data
 421 ENTRY(sys_call_table)
 422         .long sys_restart_syscall       /* 0 */
 423         .long sys_exit
 424         .long sys_fork
 425         .long sys_read
 426         .long sys_write
 427         .long sys_open          /* 5 */
 428         .long sys_close
 429         .long sys_waitpid
 430         .long sys_creat
 431         .long sys_link
 432         .long sys_unlink        /* 10 */
 433         .long sys_execve
 434         .long sys_chdir
 435         .long sys_time
 436         .long sys_mknod
 437         .long sys_chmod         /* 15 */
 438         .long sys_lchown16
 439         .long sys_ni_syscall    /* old break syscall holder */
 440         .long sys_stat
 441         .long sys_lseek
 442         .long sys_getpid        /* 20 */
 443         .long sys_mount
 444         .long sys_oldumount
 445         .long sys_setuid16
 446         .long sys_getuid16
 447         .long sys_stime         /* 25 */
 448         .long sys_ptrace
 449         .long sys_alarm
 450         .long sys_fstat
 451         .long sys_pause
 452         .long sys_utime         /* 30 */
 453         .long sys_ni_syscall    /* old stty syscall holder */
 454         .long sys_ni_syscall    /* old gtty syscall holder */
 455         .long sys_access
 456         .long sys_nice
 457         .long sys_ni_syscall    /* 35 - old ftime syscall holder */
 458         .long sys_sync
 459         .long sys_kill
 460         .long sys_rename
 461         .long sys_mkdir
 462         .long sys_rmdir         /* 40 */
 463         .long sys_dup
 464         .long sys_pipe
 465         .long sys_times
 466         .long sys_ni_syscall    /* old prof syscall holder */
 467         .long sys_brk           /* 45 */
 468         .long sys_setgid16
 469         .long sys_getgid16
 470         .long sys_signal
 471         .long sys_geteuid16
 472         .long sys_getegid16     /* 50 */
 473         .long sys_acct
 474         .long sys_umount        /* recycled never used phys() */
 475         .long sys_ni_syscall    /* old lock syscall holder */
 476         .long sys_ioctl
 477         .long sys_fcntl         /* 55 */
 478         .long sys_ni_syscall    /* old mpx syscall holder */
 479         .long sys_setpgid
 480         .long sys_ni_syscall    /* old ulimit syscall holder */
 481         .long sys_ni_syscall    /* old sys_olduname */
 482         .long sys_umask         /* 60 */
 483         .long sys_chroot
 484         .long sys_ustat
 485         .long sys_dup2
 486         .long sys_getppid
 487         .long sys_getpgrp       /* 65 */
 488         .long sys_setsid
 489         .long sys_sigaction
 490         .long sys_sgetmask
 491         .long sys_ssetmask
 492         .long sys_setreuid16    /* 70 */
 493         .long sys_setregid16
 494         .long sys_sigsuspend
 495         .long sys_sigpending
 496         .long sys_sethostname
 497         .long sys_setrlimit     /* 75 */
 498         .long sys_old_getrlimit
 499         .long sys_getrusage
 500         .long sys_gettimeofday
 501         .long sys_settimeofday
 502         .long sys_getgroups16   /* 80 */
 503         .long sys_setgroups16
 504         .long sys_old_select
 505         .long sys_symlink
 506         .long sys_lstat
 507         .long sys_readlink      /* 85 */
 508         .long sys_uselib
 509         .long sys_swapon
 510         .long sys_reboot
 511         .long sys_old_readdir
 512         .long old_mmap          /* 90 */
 513         .long sys_munmap
 514         .long sys_truncate
 515         .long sys_ftruncate
 516         .long sys_fchmod
 517         .long sys_fchown16      /* 95 */
 518         .long sys_getpriority
 519         .long sys_setpriority
 520         .long sys_ni_syscall    /* old profil syscall holder */
 521         .long sys_statfs
 522         .long sys_fstatfs       /* 100 */
 523         .long sys_ni_syscall    /* ioperm */
 524         .long sys_socketcall
 525         .long sys_syslog
 526         .long sys_setitimer
 527         .long sys_getitimer     /* 105 */
 528         .long sys_newstat
 529         .long sys_newlstat
 530         .long sys_newfstat
 531         .long sys_ni_syscall    /* old sys_uname */
 532         .long sys_ni_syscall    /* 110 - iopl */
 533         .long sys_vhangup
 534         .long sys_ni_syscall    /* old "idle" system call */
 535         .long sys_ni_syscall    /* vm86old */
 536         .long sys_wait4
 537         .long sys_swapoff       /* 115 */
 538         .long sys_sysinfo
 539         .long sys_ipc
 540         .long sys_fsync
 541         .long sys_sigreturn
 542         .long sys_clone         /* 120 */
 543         .long sys_setdomainname
 544         .long sys_newuname
 545         .long sys_ni_syscall    /* modify_ldt */
 546         .long sys_adjtimex
 547         .long sys_mprotect      /* 125 */
 548         .long sys_sigprocmask
 549         .long sys_ni_syscall    /* old "create_module" */
 550         .long sys_init_module
 551         .long sys_delete_module
 552         .long sys_ni_syscall    /* 130: old "get_kernel_syms" */
 553         .long sys_quotactl
 554         .long sys_getpgid
 555         .long sys_fchdir
 556         .long sys_bdflush
 557         .long sys_sysfs         /* 135 */
 558         .long sys_personality
 559         .long sys_ni_syscall    /* reserved for afs_syscall */
 560         .long sys_setfsuid16
 561         .long sys_setfsgid16
 562         .long sys_llseek        /* 140 */
 563         .long sys_getdents
 564         .long sys_select
 565         .long sys_flock
 566         .long sys_msync
 567         .long sys_readv         /* 145 */
 568         .long sys_writev
 569         .long sys_getsid
 570         .long sys_fdatasync
 571         .long sys_sysctl
 572         .long sys_mlock         /* 150 */
 573         .long sys_munlock
 574         .long sys_mlockall
 575         .long sys_munlockall
 576         .long sys_sched_setparam
 577         .long sys_sched_getparam   /* 155 */
 578         .long sys_sched_setscheduler
 579         .long sys_sched_getscheduler
 580         .long sys_sched_yield
 581         .long sys_sched_get_priority_max
 582         .long sys_sched_get_priority_min  /* 160 */
 583         .long sys_sched_rr_get_interval
 584         .long sys_nanosleep
 585         .long sys_mremap
 586         .long sys_setresuid16
 587         .long sys_getresuid16   /* 165 */
 588         .long sys_ni_syscall    /* vm86 */
 589         .long sys_ni_syscall    /* Old sys_query_module */
 590         .long sys_poll
 591         .long sys_ni_syscall    /* was nfsservctl */
 592         .long sys_setresgid16   /* 170 */
 593         .long sys_getresgid16
 594         .long sys_prctl
 595         .long sys_rt_sigreturn
 596         .long sys_rt_sigaction
 597         .long sys_rt_sigprocmask        /* 175 */
 598         .long sys_rt_sigpending
 599         .long sys_rt_sigtimedwait
 600         .long sys_rt_sigqueueinfo
 601         .long sys_rt_sigsuspend
 602         .long sys_pread64       /* 180 */
 603         .long sys_pwrite64
 604         .long sys_chown16
 605         .long sys_getcwd
 606         .long sys_capget
 607         .long sys_capset        /* 185 */
 608         .long sys_sigaltstack
 609         .long sys_sendfile
 610         .long sys_ni_syscall    /* reserved for streams1 */
 611         .long sys_ni_syscall    /* reserved for streams2 */
 612         .long sys_vfork         /* 190 */
 613         .long sys_getrlimit
 614         .long sys_mmap_pgoff
 615         .long sys_truncate64
 616         .long sys_ftruncate64
 617         .long sys_stat64        /* 195 */
 618         .long sys_lstat64
 619         .long sys_fstat64
 620         .long sys_lchown
 621         .long sys_getuid
 622         .long sys_getgid        /* 200 */
 623         .long sys_geteuid
 624         .long sys_getegid
 625         .long sys_setreuid
 626         .long sys_setregid
 627         .long sys_getgroups     /* 205 */
 628         .long sys_setgroups
 629         .long sys_fchown
 630         .long sys_setresuid
 631         .long sys_getresuid
 632         .long sys_setresgid     /* 210 */
 633         .long sys_getresgid
 634         .long sys_chown
 635         .long sys_setuid
 636         .long sys_setgid
 637         .long sys_setfsuid      /* 215 */
 638         .long sys_setfsgid
 639         .long sys_pivot_root
 640         .long sys_mincore
 641         .long sys_madvise
 642         .long sys_getdents64    /* 220 */
 643         .long sys_fcntl64
 644         .long sys_ni_syscall    /* reserved for TUX */
 645         .long sys_ni_syscall
 646         .long sys_gettid
 647         .long sys_readahead     /* 225 */
 648         .long sys_setxattr
 649         .long sys_lsetxattr
 650         .long sys_fsetxattr
 651         .long sys_getxattr
 652         .long sys_lgetxattr     /* 230 */
 653         .long sys_fgetxattr
 654         .long sys_listxattr
 655         .long sys_llistxattr
 656         .long sys_flistxattr
 657         .long sys_removexattr   /* 235 */
 658         .long sys_lremovexattr
 659         .long sys_fremovexattr
 660         .long sys_tkill
 661         .long sys_sendfile64
 662         .long sys_futex         /* 240 */
 663         .long sys_sched_setaffinity
 664         .long sys_sched_getaffinity
 665         .long sys_ni_syscall    /* sys_set_thread_area */
 666         .long sys_ni_syscall    /* sys_get_thread_area */
 667         .long sys_io_setup      /* 245 */
 668         .long sys_io_destroy
 669         .long sys_io_getevents
 670         .long sys_io_submit
 671         .long sys_io_cancel
 672         .long sys_fadvise64     /* 250 */
 673         .long sys_ni_syscall
 674         .long sys_exit_group
 675         .long sys_lookup_dcookie
 676         .long sys_epoll_create
 677         .long sys_epoll_ctl     /* 255 */
 678         .long sys_epoll_wait
 679         .long sys_remap_file_pages
 680         .long sys_set_tid_address
 681         .long sys_timer_create
 682         .long sys_timer_settime         /* 260 */
 683         .long sys_timer_gettime
 684         .long sys_timer_getoverrun
 685         .long sys_timer_delete
 686         .long sys_clock_settime
 687         .long sys_clock_gettime         /* 265 */
 688         .long sys_clock_getres
 689         .long sys_clock_nanosleep
 690         .long sys_statfs64
 691         .long sys_fstatfs64
 692         .long sys_tgkill                /* 270 */
 693         .long sys_utimes
 694         .long sys_fadvise64_64
 695         .long sys_ni_syscall    /* sys_vserver */
 696         .long sys_mbind
 697         .long sys_get_mempolicy         /* 275 */
 698         .long sys_set_mempolicy
 699         .long sys_mq_open
 700         .long sys_mq_unlink
 701         .long sys_mq_timedsend
 702         .long sys_mq_timedreceive       /* 280 */
 703         .long sys_mq_notify
 704         .long sys_mq_getsetattr
 705         .long sys_kexec_load
 706         .long sys_waitid
 707         .long sys_ni_syscall            /* 285 */ /* available */
 708         .long sys_add_key
 709         .long sys_request_key
 710         .long sys_keyctl
 711         .long sys_cacheflush
 712         .long sys_ioprio_set            /* 290 */
 713         .long sys_ioprio_get
 714         .long sys_inotify_init
 715         .long sys_inotify_add_watch
 716         .long sys_inotify_rm_watch
 717         .long sys_migrate_pages         /* 295 */
 718         .long sys_openat
 719         .long sys_mkdirat
 720         .long sys_mknodat
 721         .long sys_fchownat
 722         .long sys_futimesat             /* 300 */
 723         .long sys_fstatat64
 724         .long sys_unlinkat
 725         .long sys_renameat
 726         .long sys_linkat
 727         .long sys_symlinkat             /* 305 */
 728         .long sys_readlinkat
 729         .long sys_fchmodat
 730         .long sys_faccessat
 731         .long sys_pselect6
 732         .long sys_ppoll                 /* 310 */
 733         .long sys_unshare
 734         .long sys_set_robust_list
 735         .long sys_get_robust_list
 736         .long sys_splice
 737         .long sys_sync_file_range       /* 315 */
 738         .long sys_tee
 739         .long sys_vmsplice
 740         .long sys_move_pages
 741         .long sys_getcpu
 742         .long sys_epoll_pwait           /* 320 */
 743         .long sys_utimensat
 744         .long sys_signalfd
 745         .long sys_timerfd_create
 746         .long sys_eventfd
 747         .long sys_fallocate             /* 325 */
 748         .long sys_timerfd_settime
 749         .long sys_timerfd_gettime
 750         .long sys_signalfd4
 751         .long sys_eventfd2
 752         .long sys_epoll_create1         /* 330 */
 753         .long sys_dup3
 754         .long sys_pipe2
 755         .long sys_inotify_init1
 756         .long sys_preadv
 757         .long sys_pwritev               /* 335 */
 758         .long sys_rt_tgsigqueueinfo
 759         .long sys_perf_event_open
 760         .long sys_recvmmsg
 761         .long sys_setns
 762
 763
 764 nr_syscalls=(.-sys_call_table)/4