| blob | edb3d46c16db3372a1ab3bc53fec17a8c31c2fea |
1 /*
2 *
3 * Copyright (C) 1991, 1992 Linus Torvalds
4 */
6 /*
7 * entry.S contains the system-call and fault low-level handling routines.
8 * This also contains the timer-interrupt handler, as well as all interrupts
9 * and faults that can result in a task-switch.
10 *
11 * NOTE: This code handles signal-recognition, which happens every time
12 * after a timer-interrupt and after each system call.
13 *
14 * I changed all the .align's to 4 (16 byte alignment), as that's faster
15 * on a 486.
16 *
17 * Stack layout in 'syscall_exit':
18 * ptrace needs to have all regs on the stack.
19 * if the order here is changed, it needs to be
20 * updated in fork.c:copy_process, signal.c:do_signal,
21 * ptrace.c and ptrace.h
22 *
23 * 0(%esp) - %ebx
24 * 4(%esp) - %ecx
25 * 8(%esp) - %edx
26 * C(%esp) - %esi
27 * 10(%esp) - %edi
28 * 14(%esp) - %ebp
29 * 18(%esp) - %eax
30 * 1C(%esp) - %ds
31 * 20(%esp) - %es
32 * 24(%esp) - %fs
33 * 28(%esp) - %gs saved iff !CONFIG_X86_32_LAZY_GS
34 * 2C(%esp) - orig_eax
35 * 30(%esp) - %eip
36 * 34(%esp) - %cs
37 * 38(%esp) - %eflags
38 * 3C(%esp) - %oldesp
39 * 40(%esp) - %oldss
40 *
41 * "current" is in register %ebx during any slow entries.
42 */
44 #include <linux/linkage.h>
45 #include <asm/thread_info.h>
46 #include <asm/irqflags.h>
47 #include <asm/errno.h>
48 #include <asm/segment.h>
49 #include <asm/smp.h>
50 #include <asm/page_types.h>
51 #include <asm/percpu.h>
52 #include <asm/dwarf2.h>
53 #include <asm/processor-flags.h>
54 #include <asm/ftrace.h>
55 #include <asm/irq_vectors.h>
56 #include <asm/cpufeature.h>
58 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this. */
59 #include <linux/elf-em.h>
60 #define AUDIT_ARCH_I386 (EM_386|__AUDIT_ARCH_LE)
61 #define __AUDIT_ARCH_LE 0x40000000
63 #ifndef CONFIG_AUDITSYSCALL
64 #define sysenter_audit syscall_trace_entry
65 #define sysexit_audit syscall_exit_work
66 #endif
68 .section .entry.text, "ax"
70 /*
71 * We use macros for low-level operations which need to be overridden
72 * for paravirtualization. The following will never clobber any registers:
73 * INTERRUPT_RETURN (aka. "iret")
74 * GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
75 * ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
76 *
77 * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
78 * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
79 * Allowing a register to be clobbered can shrink the paravirt replacement
80 * enough to patch inline, increasing performance.
81 */
83 #define nr_syscalls ((syscall_table_size)/4)
85 #ifdef CONFIG_PREEMPT
86 #define preempt_stop(clobbers) DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
87 #else
88 #define preempt_stop(clobbers)
89 #define resume_kernel restore_all
90 #endif
92 .macro TRACE_IRQS_IRET
93 #ifdef CONFIG_TRACE_IRQFLAGS
94 testl $X86_EFLAGS_IF,PT_EFLAGS(%esp) # interrupts off?
95 jz 1f
96 TRACE_IRQS_ON
97 1:
98 #endif
99 .endm
101 /*
102 * User gs save/restore
103 *
104 * %gs is used for userland TLS and kernel only uses it for stack
105 * canary which is required to be at %gs:20 by gcc. Read the comment
106 * at the top of stackprotector.h for more info.
107 *
108 * Local labels 98 and 99 are used.
109 */
110 #ifdef CONFIG_X86_32_LAZY_GS
112 /* unfortunately push/pop can't be no-op */
113 .macro PUSH_GS
114 pushl_cfi $0
115 .endm
116 .macro POP_GS pop=0
117 addl $(4 + \pop), %esp
118 CFI_ADJUST_CFA_OFFSET -(4 + \pop)
119 .endm
120 .macro POP_GS_EX
121 .endm
123 /* all the rest are no-op */
124 .macro PTGS_TO_GS
125 .endm
126 .macro PTGS_TO_GS_EX
127 .endm
128 .macro GS_TO_REG reg
129 .endm
130 .macro REG_TO_PTGS reg
131 .endm
132 .macro SET_KERNEL_GS reg
133 .endm
135 #else /* CONFIG_X86_32_LAZY_GS */
137 .macro PUSH_GS
138 pushl_cfi %gs
139 /*CFI_REL_OFFSET gs, 0*/
140 .endm
142 .macro POP_GS pop=0
143 98: popl_cfi %gs
144 /*CFI_RESTORE gs*/
145 .if \pop <> 0
146 add $\pop, %esp
147 CFI_ADJUST_CFA_OFFSET -\pop
148 .endif
149 .endm
150 .macro POP_GS_EX
151 .pushsection .fixup, "ax"
152 99: movl $0, (%esp)
153 jmp 98b
154 .section __ex_table, "a"
155 .align 4
156 .long 98b, 99b
157 .popsection
158 .endm
160 .macro PTGS_TO_GS
161 98: mov PT_GS(%esp), %gs
162 .endm
163 .macro PTGS_TO_GS_EX
164 .pushsection .fixup, "ax"
165 99: movl $0, PT_GS(%esp)
166 jmp 98b
167 .section __ex_table, "a"
168 .align 4
169 .long 98b, 99b
170 .popsection
171 .endm
173 .macro GS_TO_REG reg
174 movl %gs, \reg
175 /*CFI_REGISTER gs, \reg*/
176 .endm
177 .macro REG_TO_PTGS reg
178 movl \reg, PT_GS(%esp)
179 /*CFI_REL_OFFSET gs, PT_GS*/
180 .endm
181 .macro SET_KERNEL_GS reg
182 movl $(__KERNEL_STACK_CANARY), \reg
183 movl \reg, %gs
184 .endm
186 #endif /* CONFIG_X86_32_LAZY_GS */
188 .macro SAVE_ALL
189 cld
190 PUSH_GS
191 pushl_cfi %fs
192 /*CFI_REL_OFFSET fs, 0;*/
193 pushl_cfi %es
194 /*CFI_REL_OFFSET es, 0;*/
195 pushl_cfi %ds
196 /*CFI_REL_OFFSET ds, 0;*/
197 pushl_cfi %eax
198 CFI_REL_OFFSET eax, 0
199 pushl_cfi %ebp
200 CFI_REL_OFFSET ebp, 0
201 pushl_cfi %edi
202 CFI_REL_OFFSET edi, 0
203 pushl_cfi %esi
204 CFI_REL_OFFSET esi, 0
205 pushl_cfi %edx
206 CFI_REL_OFFSET edx, 0
207 pushl_cfi %ecx
208 CFI_REL_OFFSET ecx, 0
209 pushl_cfi %ebx
210 CFI_REL_OFFSET ebx, 0
211 movl $(__USER_DS), %edx
212 movl %edx, %ds
213 movl %edx, %es
214 movl $(__KERNEL_PERCPU), %edx
215 movl %edx, %fs
216 SET_KERNEL_GS %edx
217 .endm
219 .macro RESTORE_INT_REGS
220 popl_cfi %ebx
221 CFI_RESTORE ebx
222 popl_cfi %ecx
223 CFI_RESTORE ecx
224 popl_cfi %edx
225 CFI_RESTORE edx
226 popl_cfi %esi
227 CFI_RESTORE esi
228 popl_cfi %edi
229 CFI_RESTORE edi
230 popl_cfi %ebp
231 CFI_RESTORE ebp
232 popl_cfi %eax
233 CFI_RESTORE eax
234 .endm
236 .macro RESTORE_REGS pop=0
237 RESTORE_INT_REGS
238 1: popl_cfi %ds
239 /*CFI_RESTORE ds;*/
240 2: popl_cfi %es
241 /*CFI_RESTORE es;*/
242 3: popl_cfi %fs
243 /*CFI_RESTORE fs;*/
244 POP_GS \pop
245 .pushsection .fixup, "ax"
246 4: movl $0, (%esp)
247 jmp 1b
248 5: movl $0, (%esp)
249 jmp 2b
250 6: movl $0, (%esp)
251 jmp 3b
252 .section __ex_table, "a"
253 .align 4
254 .long 1b, 4b
255 .long 2b, 5b
256 .long 3b, 6b
257 .popsection
258 POP_GS_EX
259 .endm
261 .macro RING0_INT_FRAME
262 CFI_STARTPROC simple
263 CFI_SIGNAL_FRAME
264 CFI_DEF_CFA esp, 3*4
265 /*CFI_OFFSET cs, -2*4;*/
266 CFI_OFFSET eip, -3*4
267 .endm
269 .macro RING0_EC_FRAME
270 CFI_STARTPROC simple
271 CFI_SIGNAL_FRAME
272 CFI_DEF_CFA esp, 4*4
273 /*CFI_OFFSET cs, -2*4;*/
274 CFI_OFFSET eip, -3*4
275 .endm
277 .macro RING0_PTREGS_FRAME
278 CFI_STARTPROC simple
279 CFI_SIGNAL_FRAME
280 CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
281 /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
282 CFI_OFFSET eip, PT_EIP-PT_OLDESP
283 /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
284 /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
285 CFI_OFFSET eax, PT_EAX-PT_OLDESP
286 CFI_OFFSET ebp, PT_EBP-PT_OLDESP
287 CFI_OFFSET edi, PT_EDI-PT_OLDESP
288 CFI_OFFSET esi, PT_ESI-PT_OLDESP
289 CFI_OFFSET edx, PT_EDX-PT_OLDESP
290 CFI_OFFSET ecx, PT_ECX-PT_OLDESP
291 CFI_OFFSET ebx, PT_EBX-PT_OLDESP
292 .endm
294 ENTRY(ret_from_fork)
295 CFI_STARTPROC
296 pushl_cfi %eax
297 call schedule_tail
298 GET_THREAD_INFO(%ebp)
299 popl_cfi %eax
300 pushl_cfi $0x0202 # Reset kernel eflags
301 popfl_cfi
302 jmp syscall_exit
303 CFI_ENDPROC
304 END(ret_from_fork)
306 /*
307 * Interrupt exit functions should be protected against kprobes
308 */
309 .pushsection .kprobes.text, "ax"
310 /*
311 * Return to user mode is not as complex as all this looks,
312 * but we want the default path for a system call return to
313 * go as quickly as possible which is why some of this is
314 * less clear than it otherwise should be.
315 */
317 # userspace resumption stub bypassing syscall exit tracing
318 ALIGN
319 RING0_PTREGS_FRAME
320 ret_from_exception:
321 preempt_stop(CLBR_ANY)
322 ret_from_intr:
323 GET_THREAD_INFO(%ebp)
324 resume_userspace_sig:
325 #ifdef CONFIG_VM86
326 movl PT_EFLAGS(%esp), %eax # mix EFLAGS and CS
327 movb PT_CS(%esp), %al
328 andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
329 #else
330 /*
331 * We can be coming here from a syscall done in the kernel space,
332 * e.g. a failed kernel_execve().
333 */
334 movl PT_CS(%esp), %eax
335 andl $SEGMENT_RPL_MASK, %eax
336 #endif
337 cmpl $USER_RPL, %eax
338 jb resume_kernel # not returning to v8086 or userspace
340 ENTRY(resume_userspace)
341 LOCKDEP_SYS_EXIT
342 DISABLE_INTERRUPTS(CLBR_ANY) # make sure we don't miss an interrupt
343 # setting need_resched or sigpending
344 # between sampling and the iret
345 TRACE_IRQS_OFF
346 movl TI_flags(%ebp), %ecx
347 andl $_TIF_WORK_MASK, %ecx # is there any work to be done on
348 # int/exception return?
349 jne work_pending
350 jmp restore_all
351 END(ret_from_exception)
353 #ifdef CONFIG_PREEMPT
354 ENTRY(resume_kernel)
355 DISABLE_INTERRUPTS(CLBR_ANY)
356 cmpl $0,TI_preempt_count(%ebp) # non-zero preempt_count ?
357 jnz restore_all
358 need_resched:
359 movl TI_flags(%ebp), %ecx # need_resched set ?
360 testb $_TIF_NEED_RESCHED, %cl
361 jz restore_all
362 testl $X86_EFLAGS_IF,PT_EFLAGS(%esp) # interrupts off (exception path) ?
363 jz restore_all
364 call preempt_schedule_irq
365 jmp need_resched
366 END(resume_kernel)
367 #endif
368 CFI_ENDPROC
369 /*
370 * End of kprobes section
371 */
372 .popsection
374 /* SYSENTER_RETURN points to after the "sysenter" instruction in
375 the vsyscall page. See vsyscall-sysentry.S, which defines the symbol. */
377 # sysenter call handler stub
378 ENTRY(ia32_sysenter_target)
379 CFI_STARTPROC simple
380 CFI_SIGNAL_FRAME
381 CFI_DEF_CFA esp, 0
382 CFI_REGISTER esp, ebp
383 movl TSS_sysenter_sp0(%esp),%esp
384 sysenter_past_esp:
385 /*
386 * Interrupts are disabled here, but we can't trace it until
387 * enough kernel state to call TRACE_IRQS_OFF can be called - but
388 * we immediately enable interrupts at that point anyway.
389 */
390 pushl_cfi $__USER_DS
391 /*CFI_REL_OFFSET ss, 0*/
392 pushl_cfi %ebp
393 CFI_REL_OFFSET esp, 0
394 pushfl_cfi
395 orl $X86_EFLAGS_IF, (%esp)
396 pushl_cfi $__USER_CS
397 /*CFI_REL_OFFSET cs, 0*/
398 /*
399 * Push current_thread_info()->sysenter_return to the stack.
400 * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
401 * pushed above; +8 corresponds to copy_thread's esp0 setting.
402 */
403 pushl_cfi ((TI_sysenter_return)-THREAD_SIZE+8+4*4)(%esp)
404 CFI_REL_OFFSET eip, 0
406 pushl_cfi %eax
407 SAVE_ALL
408 ENABLE_INTERRUPTS(CLBR_NONE)
410 /*
411 * Load the potential sixth argument from user stack.
412 * Careful about security.
413 */
414 cmpl $__PAGE_OFFSET-3,%ebp
415 jae syscall_fault
416 1: movl (%ebp),%ebp
417 movl %ebp,PT_EBP(%esp)
418 .section __ex_table,"a"
419 .align 4
420 .long 1b,syscall_fault
421 .previous
423 GET_THREAD_INFO(%ebp)
425 testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
426 jnz sysenter_audit
427 sysenter_do_call:
428 cmpl $(nr_syscalls), %eax
429 jae syscall_badsys
430 call *sys_call_table(,%eax,4)
431 movl %eax,PT_EAX(%esp)
432 LOCKDEP_SYS_EXIT
433 DISABLE_INTERRUPTS(CLBR_ANY)
434 TRACE_IRQS_OFF
435 movl TI_flags(%ebp), %ecx
436 testl $_TIF_ALLWORK_MASK, %ecx
437 jne sysexit_audit
438 sysenter_exit:
439 /* if something modifies registers it must also disable sysexit */
440 movl PT_EIP(%esp), %edx
441 movl PT_OLDESP(%esp), %ecx
442 xorl %ebp,%ebp
443 TRACE_IRQS_ON
444 1: mov PT_FS(%esp), %fs
445 PTGS_TO_GS
446 ENABLE_INTERRUPTS_SYSEXIT
448 #ifdef CONFIG_AUDITSYSCALL
449 sysenter_audit:
450 testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
451 jnz syscall_trace_entry
452 addl $4,%esp
453 CFI_ADJUST_CFA_OFFSET -4
454 /* %esi already in 8(%esp) 6th arg: 4th syscall arg */
455 /* %edx already in 4(%esp) 5th arg: 3rd syscall arg */
456 /* %ecx already in 0(%esp) 4th arg: 2nd syscall arg */
457 movl %ebx,%ecx /* 3rd arg: 1st syscall arg */
458 movl %eax,%edx /* 2nd arg: syscall number */
459 movl $AUDIT_ARCH_I386,%eax /* 1st arg: audit arch */
460 call audit_syscall_entry
461 pushl_cfi %ebx
462 movl PT_EAX(%esp),%eax /* reload syscall number */
463 jmp sysenter_do_call
465 sysexit_audit:
466 testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
467 jne syscall_exit_work
468 TRACE_IRQS_ON
469 ENABLE_INTERRUPTS(CLBR_ANY)
470 movl %eax,%edx /* second arg, syscall return value */
471 cmpl $0,%eax /* is it < 0? */
472 setl %al /* 1 if so, 0 if not */
473 movzbl %al,%eax /* zero-extend that */
474 inc %eax /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
475 call audit_syscall_exit
476 DISABLE_INTERRUPTS(CLBR_ANY)
477 TRACE_IRQS_OFF
478 movl TI_flags(%ebp), %ecx
479 testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
480 jne syscall_exit_work
481 movl PT_EAX(%esp),%eax /* reload syscall return value */
482 jmp sysenter_exit
483 #endif
485 CFI_ENDPROC
486 .pushsection .fixup,"ax"
487 2: movl $0,PT_FS(%esp)
488 jmp 1b
489 .section __ex_table,"a"
490 .align 4
491 .long 1b,2b
492 .popsection
493 PTGS_TO_GS_EX
494 ENDPROC(ia32_sysenter_target)
496 /*
497 * syscall stub including irq exit should be protected against kprobes
498 */
499 .pushsection .kprobes.text, "ax"
500 # system call handler stub
501 ENTRY(system_call)
502 RING0_INT_FRAME # can't unwind into user space anyway
503 pushl_cfi %eax # save orig_eax
504 SAVE_ALL
505 GET_THREAD_INFO(%ebp)
506 # system call tracing in operation / emulation
507 testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
508 jnz syscall_trace_entry
509 cmpl $(nr_syscalls), %eax
510 jae syscall_badsys
511 syscall_call:
512 call *sys_call_table(,%eax,4)
513 movl %eax,PT_EAX(%esp) # store the return value
514 syscall_exit:
515 LOCKDEP_SYS_EXIT
516 DISABLE_INTERRUPTS(CLBR_ANY) # make sure we don't miss an interrupt
517 # setting need_resched or sigpending
518 # between sampling and the iret
519 TRACE_IRQS_OFF
520 movl TI_flags(%ebp), %ecx
521 testl $_TIF_ALLWORK_MASK, %ecx # current->work
522 jne syscall_exit_work
524 restore_all:
525 TRACE_IRQS_IRET
526 restore_all_notrace:
527 movl PT_EFLAGS(%esp), %eax # mix EFLAGS, SS and CS
528 # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
529 # are returning to the kernel.
530 # See comments in process.c:copy_thread() for details.
531 movb PT_OLDSS(%esp), %ah
532 movb PT_CS(%esp), %al
533 andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
534 cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
535 CFI_REMEMBER_STATE
536 je ldt_ss # returning to user-space with LDT SS
537 restore_nocheck:
538 RESTORE_REGS 4 # skip orig_eax/error_code
539 irq_return:
540 INTERRUPT_RETURN
541 .section .fixup,"ax"
542 ENTRY(iret_exc)
543 pushl $0 # no error code
544 pushl $do_iret_error
545 jmp error_code
546 .previous
547 .section __ex_table,"a"
548 .align 4
549 .long irq_return,iret_exc
550 .previous
552 CFI_RESTORE_STATE
553 ldt_ss:
554 larl PT_OLDSS(%esp), %eax
555 jnz restore_nocheck
556 testl $0x00400000, %eax # returning to 32bit stack?
557 jnz restore_nocheck # allright, normal return
559 #ifdef CONFIG_PARAVIRT
560 /*
561 * The kernel can't run on a non-flat stack if paravirt mode
562 * is active. Rather than try to fixup the high bits of
563 * ESP, bypass this code entirely. This may break DOSemu
564 * and/or Wine support in a paravirt VM, although the option
565 * is still available to implement the setting of the high
566 * 16-bits in the INTERRUPT_RETURN paravirt-op.
567 */
568 cmpl $0, pv_info+PARAVIRT_enabled
569 jne restore_nocheck
570 #endif
572 /*
573 * Setup and switch to ESPFIX stack
574 *
575 * We're returning to userspace with a 16 bit stack. The CPU will not
576 * restore the high word of ESP for us on executing iret... This is an
577 * "official" bug of all the x86-compatible CPUs, which we can work
578 * around to make dosemu and wine happy. We do this by preloading the
579 * high word of ESP with the high word of the userspace ESP while
580 * compensating for the offset by changing to the ESPFIX segment with
581 * a base address that matches for the difference.
582 */
583 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
584 mov %esp, %edx /* load kernel esp */
585 mov PT_OLDESP(%esp), %eax /* load userspace esp */
586 mov %dx, %ax /* eax: new kernel esp */
587 sub %eax, %edx /* offset (low word is 0) */
588 shr $16, %edx
589 mov %dl, GDT_ESPFIX_SS + 4 /* bits 16..23 */
590 mov %dh, GDT_ESPFIX_SS + 7 /* bits 24..31 */
591 pushl_cfi $__ESPFIX_SS
592 pushl_cfi %eax /* new kernel esp */
593 /* Disable interrupts, but do not irqtrace this section: we
594 * will soon execute iret and the tracer was already set to
595 * the irqstate after the iret */
596 DISABLE_INTERRUPTS(CLBR_EAX)
597 lss (%esp), %esp /* switch to espfix segment */
598 CFI_ADJUST_CFA_OFFSET -8
599 jmp restore_nocheck
600 CFI_ENDPROC
601 ENDPROC(system_call)
603 # perform work that needs to be done immediately before resumption
604 ALIGN
605 RING0_PTREGS_FRAME # can't unwind into user space anyway
606 work_pending:
607 testb $_TIF_NEED_RESCHED, %cl
608 jz work_notifysig
609 work_resched:
610 call schedule
611 LOCKDEP_SYS_EXIT
612 DISABLE_INTERRUPTS(CLBR_ANY) # make sure we don't miss an interrupt
613 # setting need_resched or sigpending
614 # between sampling and the iret
615 TRACE_IRQS_OFF
616 movl TI_flags(%ebp), %ecx
617 andl $_TIF_WORK_MASK, %ecx # is there any work to be done other
618 # than syscall tracing?
619 jz restore_all
620 testb $_TIF_NEED_RESCHED, %cl
621 jnz work_resched
623 work_notifysig: # deal with pending signals and
624 # notify-resume requests
625 #ifdef CONFIG_VM86
626 testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
627 movl %esp, %eax
628 jne work_notifysig_v86 # returning to kernel-space or
629 # vm86-space
630 xorl %edx, %edx
631 call do_notify_resume
632 jmp resume_userspace_sig
634 ALIGN
635 work_notifysig_v86:
636 pushl_cfi %ecx # save ti_flags for do_notify_resume
637 call save_v86_state # %eax contains pt_regs pointer
638 popl_cfi %ecx
639 movl %eax, %esp
640 #else
641 movl %esp, %eax
642 #endif
643 xorl %edx, %edx
644 call do_notify_resume
645 jmp resume_userspace_sig
646 END(work_pending)
648 # perform syscall exit tracing
649 ALIGN
650 syscall_trace_entry:
651 movl $-ENOSYS,PT_EAX(%esp)
652 movl %esp, %eax
653 call syscall_trace_enter
654 /* What it returned is what we'll actually use. */
655 cmpl $(nr_syscalls), %eax
656 jnae syscall_call
657 jmp syscall_exit
658 END(syscall_trace_entry)
660 # perform syscall exit tracing
661 ALIGN
662 syscall_exit_work:
663 testl $_TIF_WORK_SYSCALL_EXIT, %ecx
664 jz work_pending
665 TRACE_IRQS_ON
666 ENABLE_INTERRUPTS(CLBR_ANY) # could let syscall_trace_leave() call
667 # schedule() instead
668 movl %esp, %eax
669 call syscall_trace_leave
670 jmp resume_userspace
671 END(syscall_exit_work)
672 CFI_ENDPROC
674 RING0_INT_FRAME # can't unwind into user space anyway
675 syscall_fault:
676 GET_THREAD_INFO(%ebp)
677 movl $-EFAULT,PT_EAX(%esp)
678 jmp resume_userspace
679 END(syscall_fault)
681 syscall_badsys:
682 movl $-ENOSYS,PT_EAX(%esp)
683 jmp resume_userspace
684 END(syscall_badsys)
685 CFI_ENDPROC
686 /*
687 * End of kprobes section
688 */
689 .popsection
691 /*
692 * System calls that need a pt_regs pointer.
693 */
694 #define PTREGSCALL0(name) \
695 ALIGN; \
696 ptregs_##name: \
697 leal 4(%esp),%eax; \
698 jmp sys_##name;
700 #define PTREGSCALL1(name) \
701 ALIGN; \
702 ptregs_##name: \
703 leal 4(%esp),%edx; \
704 movl (PT_EBX+4)(%esp),%eax; \
705 jmp sys_##name;
707 #define PTREGSCALL2(name) \
708 ALIGN; \
709 ptregs_##name: \
710 leal 4(%esp),%ecx; \
711 movl (PT_ECX+4)(%esp),%edx; \
712 movl (PT_EBX+4)(%esp),%eax; \
713 jmp sys_##name;
715 #define PTREGSCALL3(name) \
716 ALIGN; \
717 ptregs_##name: \
718 CFI_STARTPROC; \
719 leal 4(%esp),%eax; \
720 pushl_cfi %eax; \
721 movl PT_EDX(%eax),%ecx; \
722 movl PT_ECX(%eax),%edx; \
723 movl PT_EBX(%eax),%eax; \
724 call sys_##name; \
725 addl $4,%esp; \
726 CFI_ADJUST_CFA_OFFSET -4; \
727 ret; \
728 CFI_ENDPROC; \
729 ENDPROC(ptregs_##name)
731 PTREGSCALL1(iopl)
732 PTREGSCALL0(fork)
733 PTREGSCALL0(vfork)
734 PTREGSCALL3(execve)
735 PTREGSCALL2(sigaltstack)
736 PTREGSCALL0(sigreturn)
737 PTREGSCALL0(rt_sigreturn)
738 PTREGSCALL2(vm86)
739 PTREGSCALL1(vm86old)
741 /* Clone is an oddball. The 4th arg is in %edi */
742 ALIGN;
743 ptregs_clone:
744 CFI_STARTPROC
745 leal 4(%esp),%eax
746 pushl_cfi %eax
747 pushl_cfi PT_EDI(%eax)
748 movl PT_EDX(%eax),%ecx
749 movl PT_ECX(%eax),%edx
750 movl PT_EBX(%eax),%eax
751 call sys_clone
752 addl $8,%esp
753 CFI_ADJUST_CFA_OFFSET -8
754 ret
755 CFI_ENDPROC
756 ENDPROC(ptregs_clone)
758 .macro FIXUP_ESPFIX_STACK
759 /*
760 * Switch back for ESPFIX stack to the normal zerobased stack
761 *
762 * We can't call C functions using the ESPFIX stack. This code reads
763 * the high word of the segment base from the GDT and swiches to the
764 * normal stack and adjusts ESP with the matching offset.
765 */
766 /* fixup the stack */
767 mov GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
768 mov GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
769 shl $16, %eax
770 addl %esp, %eax /* the adjusted stack pointer */
771 pushl_cfi $__KERNEL_DS
772 pushl_cfi %eax
773 lss (%esp), %esp /* switch to the normal stack segment */
774 CFI_ADJUST_CFA_OFFSET -8
775 .endm
776 .macro UNWIND_ESPFIX_STACK
777 movl %ss, %eax
778 /* see if on espfix stack */
779 cmpw $__ESPFIX_SS, %ax
780 jne 27f
781 movl $__KERNEL_DS, %eax
782 movl %eax, %ds
783 movl %eax, %es
784 /* switch to normal stack */
785 FIXUP_ESPFIX_STACK
786 27:
787 .endm
789 /*
790 * Build the entry stubs and pointer table with some assembler magic.
791 * We pack 7 stubs into a single 32-byte chunk, which will fit in a
792 * single cache line on all modern x86 implementations.
793 */
794 .section .init.rodata,"a"
795 ENTRY(interrupt)
796 .section .entry.text, "ax"
797 .p2align 5
798 .p2align CONFIG_X86_L1_CACHE_SHIFT
799 ENTRY(irq_entries_start)
800 RING0_INT_FRAME
801 vector=FIRST_EXTERNAL_VECTOR
802 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
803 .balign 32
804 .rept 7
805 .if vector < NR_VECTORS
806 .if vector <> FIRST_EXTERNAL_VECTOR
807 CFI_ADJUST_CFA_OFFSET -4
808 .endif
809 1: pushl_cfi $(~vector+0x80) /* Note: always in signed byte range */
810 .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
811 jmp 2f
812 .endif
813 .previous
814 .long 1b
815 .section .entry.text, "ax"
816 vector=vector+1
817 .endif
818 .endr
819 2: jmp common_interrupt
820 .endr
821 END(irq_entries_start)
823 .previous
824 END(interrupt)
825 .previous
827 /*
828 * the CPU automatically disables interrupts when executing an IRQ vector,
829 * so IRQ-flags tracing has to follow that:
830 */
831 .p2align CONFIG_X86_L1_CACHE_SHIFT
832 common_interrupt:
833 addl $-0x80,(%esp) /* Adjust vector into the [-256,-1] range */
834 SAVE_ALL
835 TRACE_IRQS_OFF
836 movl %esp,%eax
837 call do_IRQ
838 jmp ret_from_intr
839 ENDPROC(common_interrupt)
840 CFI_ENDPROC
842 /*
843 * Irq entries should be protected against kprobes
844 */
845 .pushsection .kprobes.text, "ax"
846 #define BUILD_INTERRUPT3(name, nr, fn) \
847 ENTRY(name) \
848 RING0_INT_FRAME; \
849 pushl_cfi $~(nr); \
850 SAVE_ALL; \
851 TRACE_IRQS_OFF \
852 movl %esp,%eax; \
853 call fn; \
854 jmp ret_from_intr; \
855 CFI_ENDPROC; \
856 ENDPROC(name)
858 #define BUILD_INTERRUPT(name, nr) BUILD_INTERRUPT3(name, nr, smp_##name)
860 /* The include is where all of the SMP etc. interrupts come from */
861 #include <asm/entry_arch.h>
863 ENTRY(coprocessor_error)
864 RING0_INT_FRAME
865 pushl_cfi $0
866 pushl_cfi $do_coprocessor_error
867 jmp error_code
868 CFI_ENDPROC
869 END(coprocessor_error)
871 ENTRY(simd_coprocessor_error)
872 RING0_INT_FRAME
873 pushl_cfi $0
874 #ifdef CONFIG_X86_INVD_BUG
875 /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
876 661: pushl_cfi $do_general_protection
877 662:
878 .section .altinstructions,"a"
879 .balign 4
880 .long 661b
881 .long 663f
882 .word X86_FEATURE_XMM
883 .byte 662b-661b
884 .byte 664f-663f
885 .previous
886 .section .altinstr_replacement,"ax"
887 663: pushl $do_simd_coprocessor_error
888 664:
889 .previous
890 #else
891 pushl_cfi $do_simd_coprocessor_error
892 #endif
893 jmp error_code
894 CFI_ENDPROC
895 END(simd_coprocessor_error)
897 ENTRY(device_not_available)
898 RING0_INT_FRAME
899 pushl_cfi $-1 # mark this as an int
900 pushl_cfi $do_device_not_available
901 jmp error_code
902 CFI_ENDPROC
903 END(device_not_available)
905 #ifdef CONFIG_PARAVIRT
906 ENTRY(native_iret)
907 iret
908 .section __ex_table,"a"
909 .align 4
910 .long native_iret, iret_exc
911 .previous
912 END(native_iret)
914 ENTRY(native_irq_enable_sysexit)
915 sti
916 sysexit
917 END(native_irq_enable_sysexit)
918 #endif
920 ENTRY(overflow)
921 RING0_INT_FRAME
922 pushl_cfi $0
923 pushl_cfi $do_overflow
924 jmp error_code
925 CFI_ENDPROC
926 END(overflow)
928 ENTRY(bounds)
929 RING0_INT_FRAME
930 pushl_cfi $0
931 pushl_cfi $do_bounds
932 jmp error_code
933 CFI_ENDPROC
934 END(bounds)
936 ENTRY(invalid_op)
937 RING0_INT_FRAME
938 pushl_cfi $0
939 pushl_cfi $do_invalid_op
940 jmp error_code
941 CFI_ENDPROC
942 END(invalid_op)
944 ENTRY(coprocessor_segment_overrun)
945 RING0_INT_FRAME
946 pushl_cfi $0
947 pushl_cfi $do_coprocessor_segment_overrun
948 jmp error_code
949 CFI_ENDPROC
950 END(coprocessor_segment_overrun)
952 ENTRY(invalid_TSS)
953 RING0_EC_FRAME
954 pushl_cfi $do_invalid_TSS
955 jmp error_code
956 CFI_ENDPROC
957 END(invalid_TSS)
959 ENTRY(segment_not_present)
960 RING0_EC_FRAME
961 pushl_cfi $do_segment_not_present
962 jmp error_code
963 CFI_ENDPROC
964 END(segment_not_present)
966 ENTRY(stack_segment)
967 RING0_EC_FRAME
968 pushl_cfi $do_stack_segment
969 jmp error_code
970 CFI_ENDPROC
971 END(stack_segment)
973 ENTRY(alignment_check)
974 RING0_EC_FRAME
975 pushl_cfi $do_alignment_check
976 jmp error_code
977 CFI_ENDPROC
978 END(alignment_check)
980 ENTRY(divide_error)
981 RING0_INT_FRAME
982 pushl_cfi $0 # no error code
983 pushl_cfi $do_divide_error
984 jmp error_code
985 CFI_ENDPROC
986 END(divide_error)
988 #ifdef CONFIG_X86_MCE
989 ENTRY(machine_check)
990 RING0_INT_FRAME
991 pushl_cfi $0
992 pushl_cfi machine_check_vector
993 jmp error_code
994 CFI_ENDPROC
995 END(machine_check)
996 #endif
998 ENTRY(spurious_interrupt_bug)
999 RING0_INT_FRAME
1000 pushl_cfi $0
1001 pushl_cfi $do_spurious_interrupt_bug
1002 jmp error_code
1003 CFI_ENDPROC
1004 END(spurious_interrupt_bug)
1005 /*
1006 * End of kprobes section
1007 */
1008 .popsection
1010 ENTRY(kernel_thread_helper)
1011 pushl $0 # fake return address for unwinder
1012 CFI_STARTPROC
1013 movl %edi,%eax
1014 call *%esi
1015 call do_exit
1016 ud2 # padding for call trace
1017 CFI_ENDPROC
1018 ENDPROC(kernel_thread_helper)
1020 #ifdef CONFIG_XEN
1021 /* Xen doesn't set %esp to be precisely what the normal sysenter
1022 entrypoint expects, so fix it up before using the normal path. */
1023 ENTRY(xen_sysenter_target)
1024 RING0_INT_FRAME
1025 addl $5*4, %esp /* remove xen-provided frame */
1026 CFI_ADJUST_CFA_OFFSET -5*4
1027 jmp sysenter_past_esp
1028 CFI_ENDPROC
1030 ENTRY(xen_hypervisor_callback)
1031 CFI_STARTPROC
1032 pushl_cfi $0
1033 SAVE_ALL
1034 TRACE_IRQS_OFF
1036 /* Check to see if we got the event in the critical
1037 region in xen_iret_direct, after we've reenabled
1038 events and checked for pending events. This simulates
1039 iret instruction's behaviour where it delivers a
1040 pending interrupt when enabling interrupts. */
1041 movl PT_EIP(%esp),%eax
1042 cmpl $xen_iret_start_crit,%eax
1043 jb 1f
1044 cmpl $xen_iret_end_crit,%eax
1045 jae 1f
1047 jmp xen_iret_crit_fixup
1049 ENTRY(xen_do_upcall)
1050 1: mov %esp, %eax
1051 call xen_evtchn_do_upcall
1052 jmp ret_from_intr
1053 CFI_ENDPROC
1054 ENDPROC(xen_hypervisor_callback)
1056 # Hypervisor uses this for application faults while it executes.
1057 # We get here for two reasons:
1058 # 1. Fault while reloading DS, ES, FS or GS
1059 # 2. Fault while executing IRET
1060 # Category 1 we fix up by reattempting the load, and zeroing the segment
1061 # register if the load fails.
1062 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
1063 # normal Linux return path in this case because if we use the IRET hypercall
1064 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1065 # We distinguish between categories by maintaining a status value in EAX.
1066 ENTRY(xen_failsafe_callback)
1067 CFI_STARTPROC
1068 pushl_cfi %eax
1069 movl $1,%eax
1070 1: mov 4(%esp),%ds
1071 2: mov 8(%esp),%es
1072 3: mov 12(%esp),%fs
1073 4: mov 16(%esp),%gs
1074 testl %eax,%eax
1075 popl_cfi %eax
1076 lea 16(%esp),%esp
1077 CFI_ADJUST_CFA_OFFSET -16
1078 jz 5f
1079 addl $16,%esp
1080 jmp iret_exc # EAX != 0 => Category 2 (Bad IRET)
1081 5: pushl_cfi $0 # EAX == 0 => Category 1 (Bad segment)
1082 SAVE_ALL
1083 jmp ret_from_exception
1084 CFI_ENDPROC
1086 .section .fixup,"ax"
1087 6: xorl %eax,%eax
1088 movl %eax,4(%esp)
1089 jmp 1b
1090 7: xorl %eax,%eax
1091 movl %eax,8(%esp)
1092 jmp 2b
1093 8: xorl %eax,%eax
1094 movl %eax,12(%esp)
1095 jmp 3b
1096 9: xorl %eax,%eax
1097 movl %eax,16(%esp)
1098 jmp 4b
1099 .previous
1100 .section __ex_table,"a"
1101 .align 4
1102 .long 1b,6b
1103 .long 2b,7b
1104 .long 3b,8b
1105 .long 4b,9b
1106 .previous
1107 ENDPROC(xen_failsafe_callback)
1109 BUILD_INTERRUPT3(xen_hvm_callback_vector, XEN_HVM_EVTCHN_CALLBACK,
1110 xen_evtchn_do_upcall)
1112 #endif /* CONFIG_XEN */
1114 #ifdef CONFIG_FUNCTION_TRACER
1115 #ifdef CONFIG_DYNAMIC_FTRACE
1117 ENTRY(mcount)
1118 ret
1119 END(mcount)
1121 ENTRY(ftrace_caller)
1122 cmpl $0, function_trace_stop
1123 jne ftrace_stub
1125 pushl %eax
1126 pushl %ecx
1127 pushl %edx
1128 movl 0xc(%esp), %eax
1129 movl 0x4(%ebp), %edx
1130 subl $MCOUNT_INSN_SIZE, %eax
1132 .globl ftrace_call
1133 ftrace_call:
1134 call ftrace_stub
1136 popl %edx
1137 popl %ecx
1138 popl %eax
1139 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1140 .globl ftrace_graph_call
1141 ftrace_graph_call:
1142 jmp ftrace_stub
1143 #endif
1145 .globl ftrace_stub
1146 ftrace_stub:
1147 ret
1148 END(ftrace_caller)
1150 #else /* ! CONFIG_DYNAMIC_FTRACE */
1152 ENTRY(mcount)
1153 cmpl $0, function_trace_stop
1154 jne ftrace_stub
1156 cmpl $ftrace_stub, ftrace_trace_function
1157 jnz trace
1158 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1159 cmpl $ftrace_stub, ftrace_graph_return
1160 jnz ftrace_graph_caller
1162 cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1163 jnz ftrace_graph_caller
1164 #endif
1165 .globl ftrace_stub
1166 ftrace_stub:
1167 ret
1169 /* taken from glibc */
1170 trace:
1171 pushl %eax
1172 pushl %ecx
1173 pushl %edx
1174 movl 0xc(%esp), %eax
1175 movl 0x4(%ebp), %edx
1176 subl $MCOUNT_INSN_SIZE, %eax
1178 call *ftrace_trace_function
1180 popl %edx
1181 popl %ecx
1182 popl %eax
1183 jmp ftrace_stub
1184 END(mcount)
1185 #endif /* CONFIG_DYNAMIC_FTRACE */
1186 #endif /* CONFIG_FUNCTION_TRACER */
1188 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1189 ENTRY(ftrace_graph_caller)
1190 cmpl $0, function_trace_stop
1191 jne ftrace_stub
1193 pushl %eax
1194 pushl %ecx
1195 pushl %edx
1196 movl 0xc(%esp), %edx
1197 lea 0x4(%ebp), %eax
1198 movl (%ebp), %ecx
1199 subl $MCOUNT_INSN_SIZE, %edx
1200 call prepare_ftrace_return
1201 popl %edx
1202 popl %ecx
1203 popl %eax
1204 ret
1205 END(ftrace_graph_caller)
1207 .globl return_to_handler
1208 return_to_handler:
1209 pushl %eax
1210 pushl %edx
1211 movl %ebp, %eax
1212 call ftrace_return_to_handler
1213 movl %eax, %ecx
1214 popl %edx
1215 popl %eax
1216 jmp *%ecx
1217 #endif
1219 .section .rodata,"a"
1220 #include "syscall_table_32.S"
1222 syscall_table_size=(.-sys_call_table)
1224 /*
1225 * Some functions should be protected against kprobes
1226 */
1227 .pushsection .kprobes.text, "ax"
1229 ENTRY(page_fault)
1230 RING0_EC_FRAME
1231 pushl_cfi $do_page_fault
1232 ALIGN
1233 error_code:
1234 /* the function address is in %gs's slot on the stack */
1235 pushl_cfi %fs
1236 /*CFI_REL_OFFSET fs, 0*/
1237 pushl_cfi %es
1238 /*CFI_REL_OFFSET es, 0*/
1239 pushl_cfi %ds
1240 /*CFI_REL_OFFSET ds, 0*/
1241 pushl_cfi %eax
1242 CFI_REL_OFFSET eax, 0
1243 pushl_cfi %ebp
1244 CFI_REL_OFFSET ebp, 0
1245 pushl_cfi %edi
1246 CFI_REL_OFFSET edi, 0
1247 pushl_cfi %esi
1248 CFI_REL_OFFSET esi, 0
1249 pushl_cfi %edx
1250 CFI_REL_OFFSET edx, 0
1251 pushl_cfi %ecx
1252 CFI_REL_OFFSET ecx, 0
1253 pushl_cfi %ebx
1254 CFI_REL_OFFSET ebx, 0
1255 cld
1256 movl $(__KERNEL_PERCPU), %ecx
1257 movl %ecx, %fs
1258 UNWIND_ESPFIX_STACK
1259 GS_TO_REG %ecx
1260 movl PT_GS(%esp), %edi # get the function address
1261 movl PT_ORIG_EAX(%esp), %edx # get the error code
1262 movl $-1, PT_ORIG_EAX(%esp) # no syscall to restart
1263 REG_TO_PTGS %ecx
1264 SET_KERNEL_GS %ecx
1265 movl $(__USER_DS), %ecx
1266 movl %ecx, %ds
1267 movl %ecx, %es
1268 TRACE_IRQS_OFF
1269 movl %esp,%eax # pt_regs pointer
1270 call *%edi
1271 jmp ret_from_exception
1272 CFI_ENDPROC
1273 END(page_fault)
1275 /*
1276 * Debug traps and NMI can happen at the one SYSENTER instruction
1277 * that sets up the real kernel stack. Check here, since we can't
1278 * allow the wrong stack to be used.
1279 *
1280 * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1281 * already pushed 3 words if it hits on the sysenter instruction:
1282 * eflags, cs and eip.
1283 *
1284 * We just load the right stack, and push the three (known) values
1285 * by hand onto the new stack - while updating the return eip past
1286 * the instruction that would have done it for sysenter.
1287 */
1288 .macro FIX_STACK offset ok label
1289 cmpw $__KERNEL_CS, 4(%esp)
1290 jne \ok
1291 \label:
1292 movl TSS_sysenter_sp0 + \offset(%esp), %esp
1293 CFI_DEF_CFA esp, 0
1294 CFI_UNDEFINED eip
1295 pushfl_cfi
1296 pushl_cfi $__KERNEL_CS
1297 pushl_cfi $sysenter_past_esp
1298 CFI_REL_OFFSET eip, 0
1299 .endm
1301 ENTRY(debug)
1302 RING0_INT_FRAME
1303 cmpl $ia32_sysenter_target,(%esp)
1304 jne debug_stack_correct
1305 FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1306 debug_stack_correct:
1307 pushl_cfi $-1 # mark this as an int
1308 SAVE_ALL
1309 TRACE_IRQS_OFF
1310 xorl %edx,%edx # error code 0
1311 movl %esp,%eax # pt_regs pointer
1312 call do_debug
1313 jmp ret_from_exception
1314 CFI_ENDPROC
1315 END(debug)
1317 /*
1318 * NMI is doubly nasty. It can happen _while_ we're handling
1319 * a debug fault, and the debug fault hasn't yet been able to
1320 * clear up the stack. So we first check whether we got an
1321 * NMI on the sysenter entry path, but after that we need to
1322 * check whether we got an NMI on the debug path where the debug
1323 * fault happened on the sysenter path.
1324 */
1325 ENTRY(nmi)
1326 RING0_INT_FRAME
1327 pushl_cfi %eax
1328 movl %ss, %eax
1329 cmpw $__ESPFIX_SS, %ax
1330 popl_cfi %eax
1331 je nmi_espfix_stack
1332 cmpl $ia32_sysenter_target,(%esp)
1333 je nmi_stack_fixup
1334 pushl_cfi %eax
1335 movl %esp,%eax
1336 /* Do not access memory above the end of our stack page,
1337 * it might not exist.
1338 */
1339 andl $(THREAD_SIZE-1),%eax
1340 cmpl $(THREAD_SIZE-20),%eax
1341 popl_cfi %eax
1342 jae nmi_stack_correct
1343 cmpl $ia32_sysenter_target,12(%esp)
1344 je nmi_debug_stack_check
1345 nmi_stack_correct:
1346 /* We have a RING0_INT_FRAME here */
1347 pushl_cfi %eax
1348 SAVE_ALL
1349 xorl %edx,%edx # zero error code
1350 movl %esp,%eax # pt_regs pointer
1351 call do_nmi
1352 jmp restore_all_notrace
1353 CFI_ENDPROC
1355 nmi_stack_fixup:
1356 RING0_INT_FRAME
1357 FIX_STACK 12, nmi_stack_correct, 1
1358 jmp nmi_stack_correct
1360 nmi_debug_stack_check:
1361 /* We have a RING0_INT_FRAME here */
1362 cmpw $__KERNEL_CS,16(%esp)
1363 jne nmi_stack_correct
1364 cmpl $debug,(%esp)
1365 jb nmi_stack_correct
1366 cmpl $debug_esp_fix_insn,(%esp)
1367 ja nmi_stack_correct
1368 FIX_STACK 24, nmi_stack_correct, 1
1369 jmp nmi_stack_correct
1371 nmi_espfix_stack:
1372 /* We have a RING0_INT_FRAME here.
1373 *
1374 * create the pointer to lss back
1375 */
1376 pushl_cfi %ss
1377 pushl_cfi %esp
1378 addl $4, (%esp)
1379 /* copy the iret frame of 12 bytes */
1380 .rept 3
1381 pushl_cfi 16(%esp)
1382 .endr
1383 pushl_cfi %eax
1384 SAVE_ALL
1385 FIXUP_ESPFIX_STACK # %eax == %esp
1386 xorl %edx,%edx # zero error code
1387 call do_nmi
1388 RESTORE_REGS
1389 lss 12+4(%esp), %esp # back to espfix stack
1390 CFI_ADJUST_CFA_OFFSET -24
1391 jmp irq_return
1392 CFI_ENDPROC
1393 END(nmi)
1395 ENTRY(int3)
1396 RING0_INT_FRAME
1397 pushl_cfi $-1 # mark this as an int
1398 SAVE_ALL
1399 TRACE_IRQS_OFF
1400 xorl %edx,%edx # zero error code
1401 movl %esp,%eax # pt_regs pointer
1402 call do_int3
1403 jmp ret_from_exception
1404 CFI_ENDPROC
1405 END(int3)
1407 ENTRY(general_protection)
1408 RING0_EC_FRAME
1409 pushl_cfi $do_general_protection
1410 jmp error_code
1411 CFI_ENDPROC
1412 END(general_protection)
1414 #ifdef CONFIG_KVM_GUEST
1415 ENTRY(async_page_fault)
1416 RING0_EC_FRAME
1417 pushl_cfi $do_async_page_fault
1418 jmp error_code
1419 CFI_ENDPROC
1420 END(async_page_fault)
1421 #endif
1423 /*
1424 * End of kprobes section
1425 */
1426 .popsection