arch/x86/kernel/vmlinux.lds.S

   1 /*
   2  * ld script for the x86 kernel
   3  *
   4  * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  *
   6  * Modernisation, unification and other changes and fixes:
   7  *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
   8  *
   9  *
  10  * Don't define absolute symbols until and unless you know that symbol
  11  * value is should remain constant even if kernel image is relocated
  12  * at run time. Absolute symbols are not relocated. If symbol value should
  13  * change if kernel is relocated, make the symbol section relative and
  14  * put it inside the section definition.
  15  */
  16
  17 #ifdef CONFIG_X86_32
  18 #define LOAD_OFFSET __PAGE_OFFSET
  19 #else
  20 #define LOAD_OFFSET __START_KERNEL_map
  21 #endif
  22
  23 #include <asm-generic/vmlinux.lds.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/thread_info.h>
  26 #include <asm/page_types.h>
  27 #include <asm/cache.h>
  28 #include <asm/boot.h>
  29
  30 #undef i386     /* in case the preprocessor is a 32bit one */
  31
  32 OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
  33
  34 #ifdef CONFIG_X86_32
  35 OUTPUT_ARCH(i386)
  36 ENTRY(phys_startup_32)
  37 jiffies = jiffies_64;
  38 #else
  39 OUTPUT_ARCH(i386:x86-64)
  40 ENTRY(phys_startup_64)
  41 jiffies_64 = jiffies;
  42 #endif
  43
  44 #if defined(CONFIG_X86_64) && defined(CONFIG_DEBUG_RODATA)
  45 /*
  46  * On 64-bit, align RODATA to 2MB so that even with CONFIG_DEBUG_RODATA
  47  * we retain large page mappings for boundaries spanning kernel text, rodata
  48  * and data sections.
  49  *
  50  * However, kernel identity mappings will have different RWX permissions
  51  * to the pages mapping to text and to the pages padding (which are freed) the
  52  * text section. Hence kernel identity mappings will be broken to smaller
  53  * pages. For 64-bit, kernel text and kernel identity mappings are different,
  54  * so we can enable protection checks that come with CONFIG_DEBUG_RODATA,
  55  * as well as retain 2MB large page mappings for kernel text.
  56  */
  57 #define X64_ALIGN_DEBUG_RODATA_BEGIN    . = ALIGN(HPAGE_SIZE);
  58
  59 #define X64_ALIGN_DEBUG_RODATA_END                              \
  60                 . = ALIGN(HPAGE_SIZE);                          \
  61                 __end_rodata_hpage_align = .;
  62
  63 #else
  64
  65 #define X64_ALIGN_DEBUG_RODATA_BEGIN
  66 #define X64_ALIGN_DEBUG_RODATA_END
  67
  68 #endif
  69
  70 PHDRS {
  71         text PT_LOAD FLAGS(5);          /* R_E */
  72         data PT_LOAD FLAGS(6);          /* RW_ */
  73 #ifdef CONFIG_X86_64
  74         user PT_LOAD FLAGS(5);          /* R_E */
  75 #ifdef CONFIG_SMP
  76         percpu PT_LOAD FLAGS(6);        /* RW_ */
  77 #endif
  78         init PT_LOAD FLAGS(7);          /* RWE */
  79 #endif
  80         note PT_NOTE FLAGS(0);          /* ___ */
  81 }
  82
  83 SECTIONS
  84 {
  85 #ifdef CONFIG_X86_32
  86         . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  87         phys_startup_32 = startup_32 - LOAD_OFFSET;
  88 #else
  89         . = __START_KERNEL;
  90         phys_startup_64 = startup_64 - LOAD_OFFSET;
  91 #endif
  92
  93         /* Text and read-only data */
  94         .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  95                 _text = .;
  96                 /* bootstrapping code */
  97                 HEAD_TEXT
  98 #ifdef CONFIG_X86_32
  99                 . = ALIGN(PAGE_SIZE);
 100                 *(.text..page_aligned)
 101 #endif
 102                 . = ALIGN(8);
 103                 _stext = .;
 104                 TEXT_TEXT
 105                 SCHED_TEXT
 106                 LOCK_TEXT
 107                 KPROBES_TEXT
 108                 ENTRY_TEXT
 109                 IRQENTRY_TEXT
 110                 *(.fixup)
 111                 *(.gnu.warning)
 112                 /* End of text section */
 113                 _etext = .;
 114         } :text = 0x9090
 115
 116         NOTES :text :note
 117
 118         EXCEPTION_TABLE(16) :text = 0x9090
 119
 120 #if defined(CONFIG_DEBUG_RODATA)
 121         /* .text should occupy whole number of pages */
 122         . = ALIGN(PAGE_SIZE);
 123 #endif
 124         X64_ALIGN_DEBUG_RODATA_BEGIN
 125         RO_DATA(PAGE_SIZE)
 126         X64_ALIGN_DEBUG_RODATA_END
 127
 128         /* Data */
 129         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 130                 /* Start of data section */
 131                 _sdata = .;
 132
 133                 /* init_task */
 134                 INIT_TASK_DATA(THREAD_SIZE)
 135
 136 #ifdef CONFIG_X86_32
 137                 /* 32 bit has nosave before _edata */
 138                 NOSAVE_DATA
 139 #endif
 140
 141                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 142
 143                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 144
 145                 DATA_DATA
 146                 CONSTRUCTORS
 147
 148                 /* rarely changed data like cpu maps */
 149                 READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES)
 150
 151                 /* End of data section */
 152                 _edata = .;
 153         } :data
 154
 155 #ifdef CONFIG_X86_64
 156
 157 #define VSYSCALL_ADDR (-10*1024*1024)
 158
 159 #define VLOAD_OFFSET (VSYSCALL_ADDR - __vsyscall_0 + LOAD_OFFSET)
 160 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
 161
 162 #define VVIRT_OFFSET (VSYSCALL_ADDR - __vsyscall_0)
 163 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
 164 #define EMIT_VVAR(x, offset) .vsyscall_var_ ## x        \
 165         ADDR(.vsyscall_0) + offset                      \
 166         : AT(VLOAD(.vsyscall_var_ ## x)) {              \
 167                 *(.vsyscall_var_ ## x)                  \
 168         }                                               \
 169         x = VVIRT(.vsyscall_var_ ## x);
 170
 171         . = ALIGN(4096);
 172         __vsyscall_0 = .;
 173
 174         . = VSYSCALL_ADDR;
 175         .vsyscall_0 : AT(VLOAD(.vsyscall_0)) {
 176                 *(.vsyscall_0)
 177         } :user
 178
 179         . = ALIGN(L1_CACHE_BYTES);
 180         .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) {
 181                 *(.vsyscall_fn)
 182         }
 183
 184         .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) {
 185                 *(.vsyscall_1)
 186         }
 187         .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) {
 188                 *(.vsyscall_2)
 189         }
 190
 191         .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) {
 192                 *(.vsyscall_3)
 193         }
 194
 195 #define __VVAR_KERNEL_LDS
 196 #include <asm/vvar.h>
 197 #undef __VVAR_KERNEL_LDS
 198
 199         . = __vsyscall_0 + PAGE_SIZE;
 200
 201 #undef VSYSCALL_ADDR
 202 #undef VLOAD_OFFSET
 203 #undef VLOAD
 204 #undef VVIRT_OFFSET
 205 #undef VVIRT
 206 #undef EMIT_VVAR
 207
 208 #endif /* CONFIG_X86_64 */
 209
 210         /* Init code and data - will be freed after init */
 211         . = ALIGN(PAGE_SIZE);
 212         .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
 213                 __init_begin = .; /* paired with __init_end */
 214         }
 215
 216 #if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
 217         /*
 218          * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
 219          * output PHDR, so the next output section - .init.text - should
 220          * start another segment - init.
 221          */
 222         PERCPU_VADDR(INTERNODE_CACHE_BYTES, 0, :percpu)
 223 #endif
 224
 225         INIT_TEXT_SECTION(PAGE_SIZE)
 226 #ifdef CONFIG_X86_64
 227         :init
 228 #endif
 229
 230         INIT_DATA_SECTION(16)
 231
 232         /*
 233          * Code and data for a variety of lowlevel trampolines, to be
 234          * copied into base memory (< 1 MiB) during initialization.
 235          * Since it is copied early, the main copy can be discarded
 236          * afterwards.
 237          */
 238          .x86_trampoline : AT(ADDR(.x86_trampoline) - LOAD_OFFSET) {
 239                 x86_trampoline_start = .;
 240                 *(.x86_trampoline)
 241                 x86_trampoline_end = .;
 242         }
 243
 244         .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
 245                 __x86_cpu_dev_start = .;
 246                 *(.x86_cpu_dev.init)
 247                 __x86_cpu_dev_end = .;
 248         }
 249
 250         /*
 251          * start address and size of operations which during runtime
 252          * can be patched with virtualization friendly instructions or
 253          * baremetal native ones. Think page table operations.
 254          * Details in paravirt_types.h
 255          */
 256         . = ALIGN(8);
 257         .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 258                 __parainstructions = .;
 259                 *(.parainstructions)
 260                 __parainstructions_end = .;
 261         }
 262
 263         /*
 264          * struct alt_inst entries. From the header (alternative.h):
 265          * "Alternative instructions for different CPU types or capabilities"
 266          * Think locking instructions on spinlocks.
 267          */
 268         . = ALIGN(8);
 269         .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 270                 __alt_instructions = .;
 271                 *(.altinstructions)
 272                 __alt_instructions_end = .;
 273         }
 274
 275         /*
 276          * And here are the replacement instructions. The linker sticks
 277          * them as binary blobs. The .altinstructions has enough data to
 278          * get the address and the length of them to patch the kernel safely.
 279          */
 280         .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 281                 *(.altinstr_replacement)
 282         }
 283
 284         /*
 285          * struct iommu_table_entry entries are injected in this section.
 286          * It is an array of IOMMUs which during run time gets sorted depending
 287          * on its dependency order. After rootfs_initcall is complete
 288          * this section can be safely removed.
 289          */
 290         .iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) {
 291                 __iommu_table = .;
 292                 *(.iommu_table)
 293                 __iommu_table_end = .;
 294         }
 295
 296         . = ALIGN(8);
 297         .apicdrivers : AT(ADDR(.apicdrivers) - LOAD_OFFSET) {
 298                 __apicdrivers = .;
 299                 *(.apicdrivers);
 300                 __apicdrivers_end = .;
 301         }
 302
 303         . = ALIGN(8);
 304         /*
 305          * .exit.text is discard at runtime, not link time, to deal with
 306          *  references from .altinstructions and .eh_frame
 307          */
 308         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 309                 EXIT_TEXT
 310         }
 311
 312         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 313                 EXIT_DATA
 314         }
 315
 316 #if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
 317         PERCPU_SECTION(INTERNODE_CACHE_BYTES)
 318 #endif
 319
 320         . = ALIGN(PAGE_SIZE);
 321
 322         /* freed after init ends here */
 323         .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
 324                 __init_end = .;
 325         }
 326
 327         /*
 328          * smp_locks might be freed after init
 329          * start/end must be page aligned
 330          */
 331         . = ALIGN(PAGE_SIZE);
 332         .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 333                 __smp_locks = .;
 334                 *(.smp_locks)
 335                 . = ALIGN(PAGE_SIZE);
 336                 __smp_locks_end = .;
 337         }
 338
 339 #ifdef CONFIG_X86_64
 340         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 341                 NOSAVE_DATA
 342         }
 343 #endif
 344
 345         /* BSS */
 346         . = ALIGN(PAGE_SIZE);
 347         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 348                 __bss_start = .;
 349                 *(.bss..page_aligned)
 350                 *(.bss)
 351                 . = ALIGN(PAGE_SIZE);
 352                 __bss_stop = .;
 353         }
 354
 355         . = ALIGN(PAGE_SIZE);
 356         .brk : AT(ADDR(.brk) - LOAD_OFFSET) {
 357                 __brk_base = .;
 358                 . += 64 * 1024;         /* 64k alignment slop space */
 359                 *(.brk_reservation)     /* areas brk users have reserved */
 360                 __brk_limit = .;
 361         }
 362
 363         _end = .;
 364
 365         STABS_DEBUG
 366         DWARF_DEBUG
 367
 368         /* Sections to be discarded */
 369         DISCARDS
 370         /DISCARD/ : { *(.eh_frame) }
 371 }
 372
 373
 374 #ifdef CONFIG_X86_32
 375 /*
 376  * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
 377  */
 378 . = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
 379            "kernel image bigger than KERNEL_IMAGE_SIZE");
 380 #else
 381 /*
 382  * Per-cpu symbols which need to be offset from __per_cpu_load
 383  * for the boot processor.
 384  */
 385 #define INIT_PER_CPU(x) init_per_cpu__##x = x + __per_cpu_load
 386 INIT_PER_CPU(gdt_page);
 387 INIT_PER_CPU(irq_stack_union);
 388
 389 /*
 390  * Build-time check on the image size:
 391  */
 392 . = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 393            "kernel image bigger than KERNEL_IMAGE_SIZE");
 394
 395 #ifdef CONFIG_SMP
 396 . = ASSERT((irq_stack_union == 0),
 397            "irq_stack_union is not at start of per-cpu area");
 398 #endif
 399
 400 #endif /* CONFIG_X86_32 */
 401
 402 #ifdef CONFIG_KEXEC
 403 #include <asm/kexec.h>
 404
 405 . = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
 406            "kexec control code size is too big");
 407 #endif
 408