scripts/documentation-file-ref-check

   1 #!/usr/bin/env perl
   2 # SPDX-License-Identifier: GPL-2.0
   3 #
   4 # Treewide grep for references to files under Documentation, and report
   5 # non-existing files in stderr.
   6
   7 use warnings;
   8 use strict;
   9 use Getopt::Long qw(:config no_auto_abbrev);
  10
  11 # NOTE: only add things here when the file was gone, but the text wants
  12 # to mention a past documentation file, for example, to give credits for
  13 # the original work.
  14 my %false_positives = (
  15         "Documentation/scsi/scsi_mid_low_api.rst" => "Documentation/Configure.help",
  16         "drivers/vhost/vhost.c" => "Documentation/virtual/lguest/lguest.c",
  17 );
  18
  19 my $scriptname = $0;
  20 $scriptname =~ s,.*/([^/]+/),$1,;
  21
  22 # Parse arguments
  23 my $help = 0;
  24 my $fix = 0;
  25 my $warn = 0;
  26
  27 if (! -d ".git") {
  28         printf "Warning: can't check if file exists, as this is not a git tree\n";
  29         exit 0;
  30 }
  31
  32 GetOptions(
  33         'fix' => \$fix,
  34         'warn' => \$warn,
  35         'h|help|usage' => \$help,
  36 );
  37
  38 if ($help != 0) {
  39     print "$scriptname [--help] [--fix]\n";
  40     exit -1;
  41 }
  42
  43 # Step 1: find broken references
  44 print "Finding broken references. This may take a while...  " if ($fix);
  45
  46 my %broken_ref;
  47
  48 my $doc_fix = 0;
  49
  50 open IN, "git grep ':doc:\`' Documentation/|"
  51      or die "Failed to run git grep";
  52 while (<IN>) {
  53         next if (!m,^([^:]+):.*\:doc\:\`([^\`]+)\`,);
  54         next if (m,sphinx/,);
  55
  56         my $file = $1;
  57         my $d = $1;
  58         my $doc_ref = $2;
  59
  60         my $f = $doc_ref;
  61
  62         $d =~ s,(.*/).*,$1,;
  63         $f =~ s,.*\<([^\>]+)\>,$1,;
  64
  65         if ($f =~ m,^/,) {
  66                 $f = "$f.rst";
  67                 $f =~ s,^/,Documentation/,;
  68         } else {
  69                 $f = "$d$f.rst";
  70         }
  71
  72         next if (grep -e, glob("$f"));
  73
  74         if ($fix && !$doc_fix) {
  75                 print STDERR "\nWARNING: Currently, can't fix broken :doc:`` fields\n";
  76         }
  77         $doc_fix++;
  78
  79         print STDERR "$file: :doc:`$doc_ref`\n";
  80 }
  81 close IN;
  82
  83 open IN, "git grep 'Documentation/'|"
  84      or die "Failed to run git grep";
  85 while (<IN>) {
  86         next if (!m/^([^:]+):(.*)/);
  87
  88         my $f = $1;
  89         my $ln = $2;
  90
  91         # On linux-next, discard the Next/ directory
  92         next if ($f =~ m,^Next/,);
  93
  94         # Makefiles and scripts contain nasty expressions to parse docs
  95         next if ($f =~ m/Makefile/ || $f =~ m/\.sh$/);
  96
  97         # Skip this script
  98         next if ($f eq $scriptname);
  99
 100         # Ignore the dir where documentation will be built
 101         next if ($ln =~ m,\b(\S*)Documentation/output,);
 102
 103         if ($ln =~ m,\b(\S*)(Documentation/[A-Za-z0-9\_\.\,\~/\*\[\]\?+-]*)(.*),) {
 104                 my $prefix = $1;
 105                 my $ref = $2;
 106                 my $base = $2;
 107                 my $extra = $3;
 108
 109                 # some file references are like:
 110                 # /usr/src/linux/Documentation/DMA-{API,mapping}.txt
 111                 # For now, ignore them
 112                 next if ($extra =~ m/^{/);
 113
 114                 # Remove footnotes at the end like:
 115                 # Documentation/devicetree/dt-object-internal.txt[1]
 116                 $ref =~ s/(txt|rst)\[\d+]$/$1/;
 117
 118                 # Remove ending ']' without any '['
 119                 $ref =~ s/\].*// if (!($ref =~ m/\[/));
 120
 121                 # Remove puntuation marks at the end
 122                 $ref =~ s/[\,\.]+$//;
 123
 124                 my $fulref = "$prefix$ref";
 125
 126                 $fulref =~ s/^(\<file|ref)://;
 127                 $fulref =~ s/^[\'\`]+//;
 128                 $fulref =~ s,^\$\(.*\)/,,;
 129                 $base =~ s,.*/,,;
 130
 131                 # Remove URL false-positives
 132                 next if ($fulref =~ m/^http/);
 133
 134                 # Remove sched-pelt false-positive
 135                 next if ($fulref =~ m,^Documentation/scheduler/sched-pelt$,);
 136
 137                 # Discard some build examples from Documentation/target/tcm_mod_builder.rst
 138                 next if ($fulref =~ m,mnt/sdb/lio-core-2.6.git/Documentation/target,);
 139
 140                 # Check if exists, evaluating wildcards
 141                 next if (grep -e, glob("$ref $fulref"));
 142
 143                 # Accept relative Documentation patches for tools/
 144                 if ($f =~ m/tools/) {
 145                         my $path = $f;
 146                         $path =~ s,(.*)/.*,$1,;
 147                         next if (grep -e, glob("$path/$ref $path/../$ref $path/$fulref"));
 148                 }
 149
 150                 # Discard known false-positives
 151                 if (defined($false_positives{$f})) {
 152                         next if ($false_positives{$f} eq $fulref);
 153                 }
 154
 155                 if ($fix) {
 156                         if (!($ref =~ m/(scripts|Kconfig|Kbuild)/)) {
 157                                 $broken_ref{$ref}++;
 158                         }
 159                 } elsif ($warn) {
 160                         print STDERR "Warning: $f references a file that doesn't exist: $fulref\n";
 161                 } else {
 162                         print STDERR "$f: $fulref\n";
 163                 }
 164         }
 165 }
 166 close IN;
 167
 168 exit 0 if (!$fix);
 169
 170 # Step 2: Seek for file name alternatives
 171 print "Auto-fixing broken references. Please double-check the results\n";
 172
 173 foreach my $ref (keys %broken_ref) {
 174         my $new =$ref;
 175
 176         my $basedir = ".";
 177         # On translations, only seek inside the translations directory
 178         $basedir  = $1 if ($ref =~ m,(Documentation/translations/[^/]+),);
 179
 180         # get just the basename
 181         $new =~ s,.*/,,;
 182
 183         my $f="";
 184
 185         # usual reason for breakage: DT file moved around
 186         if ($ref =~ /devicetree/) {
 187                 # usual reason for breakage: DT file renamed to .yaml
 188                 if (!$f) {
 189                         my $new_ref = $ref;
 190                         $new_ref =~ s/\.txt$/.yaml/;
 191                         $f=$new_ref if (-f $new_ref);
 192                 }
 193
 194                 if (!$f) {
 195                         my $search = $new;
 196                         $search =~ s,^.*/,,;
 197                         $f = qx(find Documentation/devicetree/ -iname "*$search*") if ($search);
 198                         if (!$f) {
 199                                 # Manufacturer name may have changed
 200                                 $search =~ s/^.*,//;
 201                                 $f = qx(find Documentation/devicetree/ -iname "*$search*") if ($search);
 202                         }
 203                 }
 204         }
 205
 206         # usual reason for breakage: file renamed to .rst
 207         if (!$f) {
 208                 $new =~ s/\.txt$/.rst/;
 209                 $f=qx(find $basedir -iname $new) if ($new);
 210         }
 211
 212         # usual reason for breakage: use dash or underline
 213         if (!$f) {
 214                 $new =~ s/[-_]/[-_]/g;
 215                 $f=qx(find $basedir -iname $new) if ($new);
 216         }
 217
 218         # Wild guess: seek for the same name on another place
 219         if (!$f) {
 220                 $f = qx(find $basedir -iname $new) if ($new);
 221         }
 222
 223         my @find = split /\s+/, $f;
 224
 225         if (!$f) {
 226                 print STDERR "ERROR: Didn't find a replacement for $ref\n";
 227         } elsif (scalar(@find) > 1) {
 228                 print STDERR "WARNING: Won't auto-replace, as found multiple files close to $ref:\n";
 229                 foreach my $j (@find) {
 230                         $j =~ s,^./,,;
 231                         print STDERR "    $j\n";
 232                 }
 233         } else {
 234                 $f = $find[0];
 235                 $f =~ s,^./,,;
 236                 print "INFO: Replacing $ref to $f\n";
 237                 foreach my $j (qx(git grep -l $ref)) {
 238                         qx(sed "s\@$ref\@$f\@g" -i $j);
 239                 }
 240         }
 241 }