arch/mn10300/kernel/entry.S

   1 ###############################################################################
   2 #
   3 # MN10300 Exception and interrupt entry points
   4 #
   5 # Copyright (C) 2007 Matsushita Electric Industrial Co., Ltd.
   6 # Copyright (C) 2007 Red Hat, Inc. All Rights Reserved.
   7 # Modified by David Howells (dhowells@redhat.com)
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public Licence
  11 # as published by the Free Software Foundation; either version
  12 # 2 of the Licence, or (at your option) any later version.
  13 #
  14 ###############################################################################
  15 #include <linux/sys.h>
  16 #include <linux/linkage.h>
  17 #include <asm/smp.h>
  18 #include <asm/irqflags.h>
  19 #include <asm/thread_info.h>
  20 #include <asm/intctl-regs.h>
  21 #include <asm/busctl-regs.h>
  22 #include <asm/timer-regs.h>
  23 #include <unit/leds.h>
  24 #include <asm/page.h>
  25 #include <asm/pgtable.h>
  26 #include <asm/errno.h>
  27 #include <asm/asm-offsets.h>
  28 #include <asm/frame.inc>
  29
  30 #if defined(CONFIG_SMP) && defined(CONFIG_GDBSTUB)
  31 #include <asm/gdb-stub.h>
  32 #endif /* CONFIG_SMP && CONFIG_GDBSTUB */
  33
  34 #ifdef CONFIG_PREEMPT
  35 #define preempt_stop            LOCAL_IRQ_DISABLE
  36 #else
  37 #define preempt_stop
  38 #define resume_kernel           restore_all
  39 #endif
  40
  41         .am33_2
  42
  43 ###############################################################################
  44 #
  45 # the return path for a forked child
  46 # - on entry, D0 holds the address of the previous task to run
  47 #
  48 ###############################################################################
  49 ENTRY(ret_from_fork)
  50         call    schedule_tail[],0
  51         GET_THREAD_INFO a2
  52
  53         # return 0 to indicate child process
  54         clr     d0
  55         mov     d0,(REG_D0,fp)
  56         jmp     syscall_exit
  57
  58 ENTRY(ret_from_kernel_thread)
  59         call    schedule_tail[],0
  60         mov     (REG_D0,fp),d0
  61         mov     (REG_A0,fp),a0
  62         calls   (a0)
  63         GET_THREAD_INFO a2              # A2 must be set on return from sys_exit()
  64         clr     d0
  65         mov     d0,(REG_D0,fp)
  66         jmp     syscall_exit
  67
  68 ###############################################################################
  69 #
  70 # system call handler
  71 #
  72 ###############################################################################
  73 ENTRY(system_call)
  74         add     -4,sp
  75         SAVE_ALL
  76         mov     d0,(REG_ORIG_D0,fp)
  77         GET_THREAD_INFO a2
  78         cmp     nr_syscalls,d0
  79         bcc     syscall_badsys
  80         btst    _TIF_SYSCALL_TRACE,(TI_flags,a2)
  81         bne     syscall_entry_trace
  82 syscall_call:
  83         add     d0,d0,a1
  84         add     a1,a1
  85         mov     (REG_A0,fp),d0
  86         mov     (sys_call_table,a1),a0
  87         calls   (a0)
  88         mov     d0,(REG_D0,fp)
  89 syscall_exit:
  90         # make sure we don't miss an interrupt setting need_resched or
  91         # sigpending between sampling and the rti
  92         LOCAL_IRQ_DISABLE
  93         mov     (TI_flags,a2),d2
  94         btst    _TIF_ALLWORK_MASK,d2
  95         bne     syscall_exit_work
  96 restore_all:
  97         RESTORE_ALL
  98
  99 ###############################################################################
 100 #
 101 # perform work that needs to be done immediately before resumption and syscall
 102 # tracing
 103 #
 104 ###############################################################################
 105         ALIGN
 106 syscall_exit_work:
 107         mov     (REG_EPSW,fp),d0
 108         and     EPSW_nSL,d0
 109         beq     resume_kernel           # returning to supervisor mode
 110
 111         LOCAL_IRQ_ENABLE                # could let syscall_trace_exit() call
 112                                         # schedule() instead
 113         btst    _TIF_SYSCALL_TRACE,d2
 114         beq     work_pending
 115         mov     fp,d0
 116         call    syscall_trace_exit[],0  # do_syscall_trace(regs)
 117         jmp     resume_userspace
 118
 119         ALIGN
 120 work_pending:
 121         btst    _TIF_NEED_RESCHED,d2
 122         beq     work_notifysig
 123
 124 work_resched:
 125         call    schedule[],0
 126
 127 resume_userspace:
 128         # make sure we don't miss an interrupt setting need_resched or
 129         # sigpending between sampling and the rti
 130         LOCAL_IRQ_DISABLE
 131
 132         # is there any work to be done other than syscall tracing?
 133         mov     (TI_flags,a2),d2
 134         btst    _TIF_WORK_MASK,d2
 135         beq     restore_all
 136
 137         LOCAL_IRQ_ENABLE
 138         btst    _TIF_NEED_RESCHED,d2
 139         bne     work_resched
 140
 141         # deal with pending signals and notify-resume requests
 142 work_notifysig:
 143         mov     fp,d0
 144         mov     d2,d1
 145         call    do_notify_resume[],0
 146         jmp     resume_userspace
 147
 148         # perform syscall entry tracing
 149 syscall_entry_trace:
 150         mov     -ENOSYS,d0
 151         mov     d0,(REG_D0,fp)
 152         mov     fp,d0
 153         call    syscall_trace_entry[],0 # returns the syscall number to actually use
 154         mov     (REG_D1,fp),d1
 155         cmp     nr_syscalls,d0
 156         bcs     syscall_call
 157         jmp     syscall_exit
 158
 159 syscall_badsys:
 160         mov     -ENOSYS,d0
 161         mov     d0,(REG_D0,fp)
 162         jmp     resume_userspace
 163
 164         # userspace resumption stub bypassing syscall exit tracing
 165         .globl  ret_from_exception, ret_from_intr
 166         ALIGN
 167 ret_from_exception:
 168         preempt_stop
 169 ret_from_intr:
 170         GET_THREAD_INFO a2
 171         mov     (REG_EPSW,fp),d0        # need to deliver signals before
 172                                         # returning to userspace
 173         and     EPSW_nSL,d0
 174         bne     resume_userspace        # returning to userspace
 175
 176 #ifdef CONFIG_PREEMPT
 177 resume_kernel:
 178         LOCAL_IRQ_DISABLE
 179         mov     (TI_preempt_count,a2),d0        # non-zero preempt_count ?
 180         cmp     0,d0
 181         bne     restore_all
 182
 183 need_resched:
 184         btst    _TIF_NEED_RESCHED,(TI_flags,a2)
 185         beq     restore_all
 186         mov     (REG_EPSW,fp),d0
 187         and     EPSW_IM,d0
 188         cmp     EPSW_IM_7,d0            # interrupts off (exception path) ?
 189         bne     restore_all
 190         call    preempt_schedule_irq[],0
 191         jmp     need_resched
 192 #else
 193         jmp     resume_kernel
 194 #endif
 195
 196
 197 ###############################################################################
 198 #
 199 # IRQ handler entry point
 200 # - intended to be entered at multiple priorities
 201 #
 202 ###############################################################################
 203 ENTRY(irq_handler)
 204         add     -4,sp
 205         SAVE_ALL
 206
 207         # it's not a syscall
 208         mov     0xffffffff,d0
 209         mov     d0,(REG_ORIG_D0,fp)
 210
 211         mov     fp,d0
 212         call    do_IRQ[],0                      # do_IRQ(regs)
 213
 214         jmp     ret_from_intr
 215
 216 ###############################################################################
 217 #
 218 # Double Fault handler entry point
 219 # - note that there will not be a stack, D0/A0 will hold EPSW/PC as were
 220 #
 221 ###############################################################################
 222         .section .bss
 223         .balign THREAD_SIZE
 224         .space  THREAD_SIZE
 225 __df_stack:
 226         .previous
 227
 228 ENTRY(double_fault)
 229         mov     a0,(__df_stack-4)       # PC as was
 230         mov     d0,(__df_stack-8)       # EPSW as was
 231         mn10300_set_dbfleds             # display 'db-f' on the LEDs
 232         mov     0xaa55aa55,d0
 233         mov     d0,(__df_stack-12)      # no ORIG_D0
 234         mov     sp,a0                   # save corrupted SP
 235         mov     __df_stack-12,sp        # emergency supervisor stack
 236         SAVE_ALL
 237         mov     a0,(REG_A0,fp)          # save corrupted SP as A0 (which got
 238                                         # clobbered by the CPU)
 239         mov     fp,d0
 240         calls   do_double_fault
 241 double_fault_loop:
 242         bra     double_fault_loop
 243
 244 ###############################################################################
 245 #
 246 # Bus Error handler entry point
 247 # - handle external (async) bus errors separately
 248 #
 249 ###############################################################################
 250 ENTRY(raw_bus_error)
 251         add     -4,sp
 252         mov     d0,(sp)
 253 #if defined(CONFIG_ERRATUM_NEED_TO_RELOAD_MMUCTR)
 254         mov     (MMUCTR),d0
 255         mov     d0,(MMUCTR)
 256 #endif
 257         mov     (BCBERR),d0             # what
 258         btst    BCBERR_BEMR_DMA,d0      # see if it was an external bus error
 259         beq     __common_exception_aux  # it wasn't
 260
 261         SAVE_ALL
 262         mov     (BCBEAR),d1             # destination of erroneous access
 263
 264         mov     (REG_ORIG_D0,fp),d2
 265         mov     d2,(REG_D0,fp)
 266         mov     -1,d2
 267         mov     d2,(REG_ORIG_D0,fp)
 268
 269         add     -4,sp
 270         mov     fp,(12,sp)              # frame pointer
 271         call    io_bus_error[],0
 272         jmp     restore_all
 273
 274 ###############################################################################
 275 #
 276 # NMI exception entry points
 277 #
 278 # This is used by ordinary interrupt channels that have the GxICR_NMI bit set
 279 # in addition to the main NMI and Watchdog channels.  SMP NMI IPIs use this
 280 # facility.
 281 #
 282 ###############################################################################
 283 ENTRY(nmi_handler)
 284         add     -4,sp
 285         mov     d0,(sp)
 286         mov     (TBR),d0
 287
 288 #ifdef CONFIG_SMP
 289         add     -4,sp
 290         mov     d0,(sp)                 # save d0(TBR)
 291         movhu   (NMIAGR),d0
 292         and     NMIAGR_GN,d0
 293         lsr     0x2,d0
 294         cmp     CALL_FUNCTION_NMI_IPI,d0
 295         bne     nmi_not_smp_callfunc    # if not call function, jump
 296
 297         # function call nmi ipi
 298         add     4,sp                    # no need to store TBR
 299         mov     GxICR_DETECT,d0         # clear NMI request
 300         movbu   d0,(GxICR(CALL_FUNCTION_NMI_IPI))
 301         movhu   (GxICR(CALL_FUNCTION_NMI_IPI)),d0
 302         and     ~EPSW_NMID,epsw         # enable NMI
 303
 304         mov     (sp),d0                 # restore d0
 305         SAVE_ALL
 306         call    smp_nmi_call_function_interrupt[],0
 307         RESTORE_ALL
 308
 309 nmi_not_smp_callfunc:
 310 #ifdef CONFIG_KERNEL_DEBUGGER
 311         cmp     DEBUGGER_NMI_IPI,d0
 312         bne     nmi_not_debugger        # if not kernel debugger NMI IPI, jump
 313
 314         # kernel debugger NMI IPI
 315         add     4,sp                    # no need to store TBR
 316         mov     GxICR_DETECT,d0         # clear NMI
 317         movbu   d0,(GxICR(DEBUGGER_NMI_IPI))
 318         movhu   (GxICR(DEBUGGER_NMI_IPI)),d0
 319         and     ~EPSW_NMID,epsw         # enable NMI
 320
 321         mov     (sp),d0
 322         SAVE_ALL
 323         mov     fp,d0                   # arg 0: stacked register file
 324         mov     a2,d1                   # arg 1: exception number
 325         call    debugger_nmi_interrupt[],0
 326         RESTORE_ALL
 327
 328 nmi_not_debugger:
 329 #endif /* CONFIG_KERNEL_DEBUGGER */
 330         mov     (sp),d0                 # restore TBR to d0
 331         add     4,sp
 332 #endif /* CONFIG_SMP */
 333
 334         bra     __common_exception_nonmi
 335
 336 ###############################################################################
 337 #
 338 # General exception entry point
 339 #
 340 ###############################################################################
 341 ENTRY(__common_exception)
 342         add     -4,sp
 343         mov     d0,(sp)
 344 #if defined(CONFIG_ERRATUM_NEED_TO_RELOAD_MMUCTR)
 345         mov     (MMUCTR),d0
 346         mov     d0,(MMUCTR)
 347 #endif
 348
 349 __common_exception_aux:
 350         mov     (TBR),d0
 351         and     ~EPSW_NMID,epsw         # turn NMIs back on if not NMI
 352         or      EPSW_IE,epsw
 353
 354 __common_exception_nonmi:
 355         and     0x0000FFFF,d0           # turn the exception code into a vector
 356                                         # table index
 357
 358         btst    0x00000007,d0
 359         bne     1f
 360         cmp     0x00000400,d0
 361         bge     1f
 362
 363         SAVE_ALL                        # build the stack frame
 364
 365         mov     (REG_D0,fp),a2          # get the exception number
 366         mov     (REG_ORIG_D0,fp),d0
 367         mov     d0,(REG_D0,fp)
 368         mov     -1,d0
 369         mov     d0,(REG_ORIG_D0,fp)
 370
 371 #ifdef CONFIG_GDBSTUB
 372 #ifdef CONFIG_SMP
 373         call    gdbstub_busy_check[],0
 374         and     d0,d0                   # check return value
 375         beq     2f
 376 #else  /* CONFIG_SMP */
 377         btst    0x01,(gdbstub_busy)
 378         beq     2f
 379 #endif /* CONFIG_SMP */
 380         and     ~EPSW_IE,epsw
 381         mov     fp,d0
 382         mov     a2,d1
 383         call    gdbstub_exception[],0   # gdbstub itself caused an exception
 384         bra     restore_all
 385 2:
 386 #endif /* CONFIG_GDBSTUB */
 387
 388         mov     fp,d0                   # arg 0: stacked register file
 389         mov     a2,d1                   # arg 1: exception number
 390         lsr     1,a2
 391
 392         mov     (exception_table,a2),a2
 393         calls   (a2)
 394         jmp     ret_from_exception
 395
 396 1:      pi                              # BUG() equivalent
 397
 398 ###############################################################################
 399 #
 400 # Exception handler functions table
 401 #
 402 ###############################################################################
 403         .data
 404 ENTRY(exception_table)
 405         .rept   0x400>>1
 406          .long  uninitialised_exception
 407         .endr
 408         .previous
 409
 410 ###############################################################################
 411 #
 412 # Change an entry in the exception table
 413 # - D0 exception code, D1 handler
 414 #
 415 ###############################################################################
 416 ENTRY(set_excp_vector)
 417         lsr     1,d0
 418         add     exception_table,d0
 419         mov     d1,(d0)
 420         mov     4,d1
 421         ret     [],0
 422
 423 ###############################################################################
 424 #
 425 # System call table
 426 #
 427 ###############################################################################
 428         .data
 429 ENTRY(sys_call_table)
 430         .long sys_restart_syscall       /* 0 */
 431         .long sys_exit
 432         .long sys_fork
 433         .long sys_read
 434         .long sys_write
 435         .long sys_open          /* 5 */
 436         .long sys_close
 437         .long sys_waitpid
 438         .long sys_creat
 439         .long sys_link
 440         .long sys_unlink        /* 10 */
 441         .long sys_execve
 442         .long sys_chdir
 443         .long sys_time
 444         .long sys_mknod
 445         .long sys_chmod         /* 15 */
 446         .long sys_lchown16
 447         .long sys_ni_syscall    /* old break syscall holder */
 448         .long sys_stat
 449         .long sys_lseek
 450         .long sys_getpid        /* 20 */
 451         .long sys_mount
 452         .long sys_oldumount
 453         .long sys_setuid16
 454         .long sys_getuid16
 455         .long sys_stime         /* 25 */
 456         .long sys_ptrace
 457         .long sys_alarm
 458         .long sys_fstat
 459         .long sys_pause
 460         .long sys_utime         /* 30 */
 461         .long sys_ni_syscall    /* old stty syscall holder */
 462         .long sys_ni_syscall    /* old gtty syscall holder */
 463         .long sys_access
 464         .long sys_nice
 465         .long sys_ni_syscall    /* 35 - old ftime syscall holder */
 466         .long sys_sync
 467         .long sys_kill
 468         .long sys_rename
 469         .long sys_mkdir
 470         .long sys_rmdir         /* 40 */
 471         .long sys_dup
 472         .long sys_pipe
 473         .long sys_times
 474         .long sys_ni_syscall    /* old prof syscall holder */
 475         .long sys_brk           /* 45 */
 476         .long sys_setgid16
 477         .long sys_getgid16
 478         .long sys_signal
 479         .long sys_geteuid16
 480         .long sys_getegid16     /* 50 */
 481         .long sys_acct
 482         .long sys_umount        /* recycled never used phys() */
 483         .long sys_ni_syscall    /* old lock syscall holder */
 484         .long sys_ioctl
 485         .long sys_fcntl         /* 55 */
 486         .long sys_ni_syscall    /* old mpx syscall holder */
 487         .long sys_setpgid
 488         .long sys_ni_syscall    /* old ulimit syscall holder */
 489         .long sys_ni_syscall    /* old sys_olduname */
 490         .long sys_umask         /* 60 */
 491         .long sys_chroot
 492         .long sys_ustat
 493         .long sys_dup2
 494         .long sys_getppid
 495         .long sys_getpgrp       /* 65 */
 496         .long sys_setsid
 497         .long sys_sigaction
 498         .long sys_sgetmask
 499         .long sys_ssetmask
 500         .long sys_setreuid16    /* 70 */
 501         .long sys_setregid16
 502         .long sys_sigsuspend
 503         .long sys_sigpending
 504         .long sys_sethostname
 505         .long sys_setrlimit     /* 75 */
 506         .long sys_old_getrlimit
 507         .long sys_getrusage
 508         .long sys_gettimeofday
 509         .long sys_settimeofday
 510         .long sys_getgroups16   /* 80 */
 511         .long sys_setgroups16
 512         .long sys_old_select
 513         .long sys_symlink
 514         .long sys_lstat
 515         .long sys_readlink      /* 85 */
 516         .long sys_uselib
 517         .long sys_swapon
 518         .long sys_reboot
 519         .long sys_old_readdir
 520         .long old_mmap          /* 90 */
 521         .long sys_munmap
 522         .long sys_truncate
 523         .long sys_ftruncate
 524         .long sys_fchmod
 525         .long sys_fchown16      /* 95 */
 526         .long sys_getpriority
 527         .long sys_setpriority
 528         .long sys_ni_syscall    /* old profil syscall holder */
 529         .long sys_statfs
 530         .long sys_fstatfs       /* 100 */
 531         .long sys_ni_syscall    /* ioperm */
 532         .long sys_socketcall
 533         .long sys_syslog
 534         .long sys_setitimer
 535         .long sys_getitimer     /* 105 */
 536         .long sys_newstat
 537         .long sys_newlstat
 538         .long sys_newfstat
 539         .long sys_ni_syscall    /* old sys_uname */
 540         .long sys_ni_syscall    /* 110 - iopl */
 541         .long sys_vhangup
 542         .long sys_ni_syscall    /* old "idle" system call */
 543         .long sys_ni_syscall    /* vm86old */
 544         .long sys_wait4
 545         .long sys_swapoff       /* 115 */
 546         .long sys_sysinfo
 547         .long sys_ipc
 548         .long sys_fsync
 549         .long sys_sigreturn
 550         .long sys_clone         /* 120 */
 551         .long sys_setdomainname
 552         .long sys_newuname
 553         .long sys_ni_syscall    /* modify_ldt */
 554         .long sys_adjtimex
 555         .long sys_mprotect      /* 125 */
 556         .long sys_sigprocmask
 557         .long sys_ni_syscall    /* old "create_module" */
 558         .long sys_init_module
 559         .long sys_delete_module
 560         .long sys_ni_syscall    /* 130: old "get_kernel_syms" */
 561         .long sys_quotactl
 562         .long sys_getpgid
 563         .long sys_fchdir
 564         .long sys_bdflush
 565         .long sys_sysfs         /* 135 */
 566         .long sys_personality
 567         .long sys_ni_syscall    /* reserved for afs_syscall */
 568         .long sys_setfsuid16
 569         .long sys_setfsgid16
 570         .long sys_llseek        /* 140 */
 571         .long sys_getdents
 572         .long sys_select
 573         .long sys_flock
 574         .long sys_msync
 575         .long sys_readv         /* 145 */
 576         .long sys_writev
 577         .long sys_getsid
 578         .long sys_fdatasync
 579         .long sys_sysctl
 580         .long sys_mlock         /* 150 */
 581         .long sys_munlock
 582         .long sys_mlockall
 583         .long sys_munlockall
 584         .long sys_sched_setparam
 585         .long sys_sched_getparam   /* 155 */
 586         .long sys_sched_setscheduler
 587         .long sys_sched_getscheduler
 588         .long sys_sched_yield
 589         .long sys_sched_get_priority_max
 590         .long sys_sched_get_priority_min  /* 160 */
 591         .long sys_sched_rr_get_interval
 592         .long sys_nanosleep
 593         .long sys_mremap
 594         .long sys_setresuid16
 595         .long sys_getresuid16   /* 165 */
 596         .long sys_ni_syscall    /* vm86 */
 597         .long sys_ni_syscall    /* Old sys_query_module */
 598         .long sys_poll
 599         .long sys_ni_syscall    /* was nfsservctl */
 600         .long sys_setresgid16   /* 170 */
 601         .long sys_getresgid16
 602         .long sys_prctl
 603         .long sys_rt_sigreturn
 604         .long sys_rt_sigaction
 605         .long sys_rt_sigprocmask        /* 175 */
 606         .long sys_rt_sigpending
 607         .long sys_rt_sigtimedwait
 608         .long sys_rt_sigqueueinfo
 609         .long sys_rt_sigsuspend
 610         .long sys_pread64       /* 180 */
 611         .long sys_pwrite64
 612         .long sys_chown16
 613         .long sys_getcwd
 614         .long sys_capget
 615         .long sys_capset        /* 185 */
 616         .long sys_sigaltstack
 617         .long sys_sendfile
 618         .long sys_ni_syscall    /* reserved for streams1 */
 619         .long sys_ni_syscall    /* reserved for streams2 */
 620         .long sys_vfork         /* 190 */
 621         .long sys_getrlimit
 622         .long sys_mmap_pgoff
 623         .long sys_truncate64
 624         .long sys_ftruncate64
 625         .long sys_stat64        /* 195 */
 626         .long sys_lstat64
 627         .long sys_fstat64
 628         .long sys_lchown
 629         .long sys_getuid
 630         .long sys_getgid        /* 200 */
 631         .long sys_geteuid
 632         .long sys_getegid
 633         .long sys_setreuid
 634         .long sys_setregid
 635         .long sys_getgroups     /* 205 */
 636         .long sys_setgroups
 637         .long sys_fchown
 638         .long sys_setresuid
 639         .long sys_getresuid
 640         .long sys_setresgid     /* 210 */
 641         .long sys_getresgid
 642         .long sys_chown
 643         .long sys_setuid
 644         .long sys_setgid
 645         .long sys_setfsuid      /* 215 */
 646         .long sys_setfsgid
 647         .long sys_pivot_root
 648         .long sys_mincore
 649         .long sys_madvise
 650         .long sys_getdents64    /* 220 */
 651         .long sys_fcntl64
 652         .long sys_ni_syscall    /* reserved for TUX */
 653         .long sys_ni_syscall
 654         .long sys_gettid
 655         .long sys_readahead     /* 225 */
 656         .long sys_setxattr
 657         .long sys_lsetxattr
 658         .long sys_fsetxattr
 659         .long sys_getxattr
 660         .long sys_lgetxattr     /* 230 */
 661         .long sys_fgetxattr
 662         .long sys_listxattr
 663         .long sys_llistxattr
 664         .long sys_flistxattr
 665         .long sys_removexattr   /* 235 */
 666         .long sys_lremovexattr
 667         .long sys_fremovexattr
 668         .long sys_tkill
 669         .long sys_sendfile64
 670         .long sys_futex         /* 240 */
 671         .long sys_sched_setaffinity
 672         .long sys_sched_getaffinity
 673         .long sys_ni_syscall    /* sys_set_thread_area */
 674         .long sys_ni_syscall    /* sys_get_thread_area */
 675         .long sys_io_setup      /* 245 */
 676         .long sys_io_destroy
 677         .long sys_io_getevents
 678         .long sys_io_submit
 679         .long sys_io_cancel
 680         .long sys_fadvise64     /* 250 */
 681         .long sys_ni_syscall
 682         .long sys_exit_group
 683         .long sys_lookup_dcookie
 684         .long sys_epoll_create
 685         .long sys_epoll_ctl     /* 255 */
 686         .long sys_epoll_wait
 687         .long sys_remap_file_pages
 688         .long sys_set_tid_address
 689         .long sys_timer_create
 690         .long sys_timer_settime         /* 260 */
 691         .long sys_timer_gettime
 692         .long sys_timer_getoverrun
 693         .long sys_timer_delete
 694         .long sys_clock_settime
 695         .long sys_clock_gettime         /* 265 */
 696         .long sys_clock_getres
 697         .long sys_clock_nanosleep
 698         .long sys_statfs64
 699         .long sys_fstatfs64
 700         .long sys_tgkill                /* 270 */
 701         .long sys_utimes
 702         .long sys_fadvise64_64
 703         .long sys_ni_syscall    /* sys_vserver */
 704         .long sys_mbind
 705         .long sys_get_mempolicy         /* 275 */
 706         .long sys_set_mempolicy
 707         .long sys_mq_open
 708         .long sys_mq_unlink
 709         .long sys_mq_timedsend
 710         .long sys_mq_timedreceive       /* 280 */
 711         .long sys_mq_notify
 712         .long sys_mq_getsetattr
 713         .long sys_kexec_load
 714         .long sys_waitid
 715         .long sys_ni_syscall            /* 285 */ /* available */
 716         .long sys_add_key
 717         .long sys_request_key
 718         .long sys_keyctl
 719         .long sys_cacheflush
 720         .long sys_ioprio_set            /* 290 */
 721         .long sys_ioprio_get
 722         .long sys_inotify_init
 723         .long sys_inotify_add_watch
 724         .long sys_inotify_rm_watch
 725         .long sys_migrate_pages         /* 295 */
 726         .long sys_openat
 727         .long sys_mkdirat
 728         .long sys_mknodat
 729         .long sys_fchownat
 730         .long sys_futimesat             /* 300 */
 731         .long sys_fstatat64
 732         .long sys_unlinkat
 733         .long sys_renameat
 734         .long sys_linkat
 735         .long sys_symlinkat             /* 305 */
 736         .long sys_readlinkat
 737         .long sys_fchmodat
 738         .long sys_faccessat
 739         .long sys_pselect6
 740         .long sys_ppoll                 /* 310 */
 741         .long sys_unshare
 742         .long sys_set_robust_list
 743         .long sys_get_robust_list
 744         .long sys_splice
 745         .long sys_sync_file_range       /* 315 */
 746         .long sys_tee
 747         .long sys_vmsplice
 748         .long sys_move_pages
 749         .long sys_getcpu
 750         .long sys_epoll_pwait           /* 320 */
 751         .long sys_utimensat
 752         .long sys_signalfd
 753         .long sys_timerfd_create
 754         .long sys_eventfd
 755         .long sys_fallocate             /* 325 */
 756         .long sys_timerfd_settime
 757         .long sys_timerfd_gettime
 758         .long sys_signalfd4
 759         .long sys_eventfd2
 760         .long sys_epoll_create1         /* 330 */
 761         .long sys_dup3
 762         .long sys_pipe2
 763         .long sys_inotify_init1
 764         .long sys_preadv
 765         .long sys_pwritev               /* 335 */
 766         .long sys_rt_tgsigqueueinfo
 767         .long sys_perf_event_open
 768         .long sys_recvmmsg
 769         .long sys_setns
 770
 771
 772 nr_syscalls=(.-sys_call_table)/4