arch/s390/kernel/vmlinux.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /* ld script to make s390 Linux kernel
   3  * Written by Martin Schwidefsky (schwidefsky@de.ibm.com)
   4  */
   5
   6 #include <asm/thread_info.h>
   7 #include <asm/page.h>
   8
   9 /*
  10  * Put .bss..swapper_pg_dir as the first thing in .bss. This will
  11  * make sure it has 16k alignment.
  12  */
  13 #define BSS_FIRST_SECTIONS *(.bss..swapper_pg_dir)
  14
  15 /* Handle ro_after_init data on our own. */
  16 #define RO_AFTER_INIT_DATA
  17
  18 #include <asm-generic/vmlinux.lds.h>
  19 #include <asm/vmlinux.lds.h>
  20
  21 OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
  22 OUTPUT_ARCH(s390:64-bit)
  23 ENTRY(startup_continue)
  24 jiffies = jiffies_64;
  25
  26 PHDRS {
  27         text PT_LOAD FLAGS(5);  /* R_E */
  28         data PT_LOAD FLAGS(7);  /* RWE */
  29         note PT_NOTE FLAGS(0);  /* ___ */
  30 }
  31
  32 SECTIONS
  33 {
  34         . = 0x100000;
  35         _stext = .;             /* Start of text section */
  36         .text : {
  37                 /* Text and read-only data */
  38                 _text = .;
  39                 HEAD_TEXT
  40                 TEXT_TEXT
  41                 SCHED_TEXT
  42                 CPUIDLE_TEXT
  43                 LOCK_TEXT
  44                 KPROBES_TEXT
  45                 IRQENTRY_TEXT
  46                 SOFTIRQENTRY_TEXT
  47                 *(.text.*_indirect_*)
  48                 *(.fixup)
  49                 *(.gnu.warning)
  50         } :text = 0x0700
  51
  52         . = ALIGN(PAGE_SIZE);
  53         _etext = .;             /* End of text section */
  54
  55         NOTES :text :note
  56
  57         .dummy : { *(.dummy) } :data
  58
  59         RO_DATA_SECTION(PAGE_SIZE)
  60
  61         . = ALIGN(PAGE_SIZE);
  62         _sdata = .;             /* Start of data section */
  63
  64         . = ALIGN(PAGE_SIZE);
  65         __start_ro_after_init = .;
  66         .data..ro_after_init : {
  67                  *(.data..ro_after_init)
  68                 JUMP_TABLE_DATA
  69         }
  70         EXCEPTION_TABLE(16)
  71         . = ALIGN(PAGE_SIZE);
  72         __end_ro_after_init = .;
  73
  74         RW_DATA_SECTION(0x100, PAGE_SIZE, THREAD_SIZE)
  75
  76         _edata = .;             /* End of data section */
  77
  78         /* will be freed after init */
  79         . = ALIGN(PAGE_SIZE);   /* Init code and data */
  80         __init_begin = .;
  81
  82         . = ALIGN(PAGE_SIZE);
  83         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
  84                 _sinittext = .;
  85                 INIT_TEXT
  86                 . = ALIGN(PAGE_SIZE);
  87                 _einittext = .;
  88         }
  89
  90         /*
  91          * .exit.text is discarded at runtime, not link time,
  92          * to deal with references from __bug_table
  93         */
  94         .exit.text : {
  95                 EXIT_TEXT
  96         }
  97
  98         .exit.data : {
  99                 EXIT_DATA
 100         }
 101
 102         /*
 103          * struct alt_inst entries. From the header (alternative.h):
 104          * "Alternative instructions for different CPU types or capabilities"
 105          * Think locking instructions on spinlocks.
 106          * Note, that it is a part of __init region.
 107          */
 108         . = ALIGN(8);
 109         .altinstructions : {
 110                 __alt_instructions = .;
 111                 *(.altinstructions)
 112                 __alt_instructions_end = .;
 113         }
 114
 115         /*
 116          * And here are the replacement instructions. The linker sticks
 117          * them as binary blobs. The .altinstructions has enough data to
 118          * get the address and the length of them to patch the kernel safely.
 119          * Note, that it is a part of __init region.
 120          */
 121         .altinstr_replacement : {
 122                 *(.altinstr_replacement)
 123         }
 124
 125         /*
 126          * Table with the patch locations to undo expolines
 127         */
 128         .nospec_call_table : {
 129                 __nospec_call_start = . ;
 130                 *(.s390_indirect*)
 131                 __nospec_call_end = . ;
 132         }
 133         .nospec_return_table : {
 134                 __nospec_return_start = . ;
 135                 *(.s390_return*)
 136                 __nospec_return_end = . ;
 137         }
 138
 139         BOOT_DATA
 140
 141         /* early.c uses stsi, which requires page aligned data. */
 142         . = ALIGN(PAGE_SIZE);
 143         INIT_DATA_SECTION(0x100)
 144
 145         PERCPU_SECTION(0x100)
 146         . = ALIGN(PAGE_SIZE);
 147         __init_end = .;         /* freed after init ends here */
 148
 149         BSS_SECTION(PAGE_SIZE, 4 * PAGE_SIZE, PAGE_SIZE)
 150
 151         _end = . ;
 152
 153         /*
 154          * uncompressed image info used by the decompressor
 155          * it should match struct vmlinux_info
 156          */
 157         .vmlinux.info 0 (INFO) : {
 158                 QUAD(_stext)                                    /* default_lma */
 159                 QUAD(startup_continue)                          /* entry */
 160                 QUAD(__bss_start - _stext)                      /* image_size */
 161                 QUAD(__bss_stop - __bss_start)                  /* bss_size */
 162                 QUAD(__boot_data_start)                         /* bootdata_off */
 163                 QUAD(__boot_data_end - __boot_data_start)       /* bootdata_size */
 164         } :NONE
 165
 166         /* Debugging sections.  */
 167         STABS_DEBUG
 168         DWARF_DEBUG
 169
 170         /* Sections to be discarded */
 171         DISCARDS
 172         /DISCARD/ : {
 173                 *(.eh_frame)
 174         }
 175 }