cgi-bin/LJ/Knob.pm

   1 package LJ::Knob;
   2 use strict;
   3 use String::CRC32 ();
   4
   5 my %singleton;
   6
   7 # fields:
   8 #   name
   9 #   value -- if defined, loaded.  value in range [0,100] (inclusive)
  10
  11 sub instance {
  12     my ($class, $knobname) = @_;
  13     return $singleton{$knobname} ||= LJ::Knob->new($knobname);
  14 }
  15
  16 sub new {
  17     my ($class, $knobname) = @_;
  18     my $self = {
  19         name => $knobname,
  20     };
  21     return bless $self, $class;
  22 }
  23
  24 sub memkey {
  25     my $self = shift;
  26     return "knob:$self->{name}";
  27 }
  28
  29 sub set_value {
  30     my ($self, $val) = @_;
  31     $val += 0;
  32
  33     my $memkey = $self->memkey;
  34     LJ::MemCache::set($memkey, $val);
  35     my $dbh = LJ::get_db_writer();
  36     $dbh->do("REPLACE INTO knob (knobname, val) VALUES (?, ?)", undef,
  37              $self->{name}, $val);
  38
  39     # broadcast to other apache nodes to change
  40     $self->{value} = $val;
  41
  42     return 1;
  43 }
  44
  45 sub value {
  46     my $self = shift;
  47     return $self->{value} if defined $self->{value};
  48     my $name = $self->{name};
  49
  50     my $memkey = $self->memkey;
  51     my $rv = LJ::MemCache::get($memkey);
  52     if (defined $rv) {
  53         return $self->{value} = $rv;
  54     }
  55
  56     my $dbh = LJ::get_db_writer();
  57     $rv = $dbh->selectrow_array("SELECT val FROM knob WHERE knobname=?", undef, $name) + 0;
  58     LJ::MemCache::add($memkey, $rv);
  59     return $self->{value} = $rv;
  60 }
  61
  62 sub check {
  63     my ($self, $checkon) = @_;
  64     my $rand = (127 & int(String::CRC32::crc32($checkon))); # [0 .. 127]
  65     my $val  = int(127 * $self->value / 100);               # [0 .. 127]
  66     return $rand <= $val;
  67 }
  68
  69 1;