test/CodeGen/AArch64/aarch64-gep-opt.ll

   1 ; RUN: llc -O3 -aarch64-enable-gep-opt=true -verify-machineinstrs %s -o - | FileCheck %s
   2 ; RUN: llc -O3 -aarch64-enable-gep-opt=true -mattr=-use-aa -print-after=codegenprepare < %s >%t 2>&1 && FileCheck --check-prefix=CHECK-NoAA <%t %s
   3 ; RUN: llc -O3 -aarch64-enable-gep-opt=true -mattr=+use-aa -print-after=codegenprepare < %s >%t 2>&1 && FileCheck --check-prefix=CHECK-UseAA <%t %s
   4 ; RUN: llc -O3 -aarch64-enable-gep-opt=true -print-after=codegenprepare -mcpu=cyclone < %s >%t 2>&1 && FileCheck --check-prefix=CHECK-NoAA <%t %s
   5 ; RUN: llc -O3 -aarch64-enable-gep-opt=true -print-after=codegenprepare -mcpu=cortex-a53 < %s >%t 2>&1 && FileCheck --check-prefix=CHECK-UseAA <%t %s
   6
   7 target datalayout = "e-m:e-i64:64-i128:128-n32:64-S128"
   8 target triple = "aarch64-linux-gnueabi"
   9
  10 ; Following test cases test enabling SeparateConstOffsetFromGEP pass in AArch64
  11 ; backend. If useAA() returns true, it will lower a GEP with multiple indices
  12 ; into GEPs with a single index, otherwise it will lower it into a
  13 ; "ptrtoint+arithmetics+inttoptr" form.
  14
  15 %struct = type { i32, i32, i32, i32, [20 x i32] }
  16
  17 ; Check that when two complex GEPs are used in two basic blocks, LLVM can
  18 ; elimilate the common subexpression for the second use.
  19 define void @test_GEP_CSE([240 x %struct]* %string, i32* %adj, i32 %lib, i64 %idxprom) {
  20   %liberties = getelementptr [240 x %struct], [240 x %struct]* %string, i64 1, i64 %idxprom, i32 3
  21   %1 = load i32, i32* %liberties, align 4
  22   %cmp = icmp eq i32 %1, %lib
  23   br i1 %cmp, label %if.then, label %if.end
  24
  25 if.then:                                          ; preds = %entry
  26   %origin = getelementptr [240 x %struct], [240 x %struct]* %string, i64 1, i64 %idxprom, i32 2
  27   %2 = load i32, i32* %origin, align 4
  28   store i32 %2, i32* %adj, align 4
  29   br label %if.end
  30
  31 if.end:                                           ; preds = %if.then, %entry
  32   ret void
  33 }
  34
  35 ; CHECK-LABEL: test_GEP_CSE:
  36 ; CHECK: madd
  37 ; CHECK: ldr
  38 ; CHECK-NOT: madd
  39 ; CHECK:ldr
  40
  41 ; CHECK-NoAA-LABEL: @test_GEP_CSE(
  42 ; CHECK-NoAA: [[PTR0:%[a-zA-Z0-9]+]] = ptrtoint [240 x %struct]* %string to i64
  43 ; CHECK-NoAA: [[PTR1:%[a-zA-Z0-9]+]] = mul i64 %idxprom, 96
  44 ; CHECK-NoAA: [[PTR2:%[a-zA-Z0-9]+]] = add i64 [[PTR0]], [[PTR1]]
  45 ; CHECK-NoAA: add i64 [[PTR2]], 23052
  46 ; CHECK-NoAA: inttoptr
  47 ; CHECK-NoAA: if.then:
  48 ; CHECK-NoAA-NOT: ptrtoint
  49 ; CHECK-NoAA-NOT: mul
  50 ; CHECK-NoAA: add i64 [[PTR2]], 23048
  51 ; CHECK-NoAA: inttoptr
  52
  53 ; CHECK-UseAA-LABEL: @test_GEP_CSE(
  54 ; CHECK-UseAA: [[PTR0:%[a-zA-Z0-9]+]] = bitcast [240 x %struct]* %string to i8*
  55 ; CHECK-UseAA: [[IDX:%[a-zA-Z0-9]+]] = mul i64 %idxprom, 96
  56 ; CHECK-UseAA: [[PTR1:%[a-zA-Z0-9]+]] = getelementptr i8, i8* [[PTR0]], i64 [[IDX]]
  57 ; CHECK-UseAA: getelementptr i8, i8* [[PTR1]], i64 23052
  58 ; CHECK-UseAA: bitcast
  59 ; CHECK-UseAA: if.then:
  60 ; CHECK-UseAA: getelementptr i8, i8* [[PTR1]], i64 23048
  61 ; CHECK-UseAA: bitcast
  62
  63 %class.my = type { i32, [128 x i32], i32, [256 x %struct.pt]}
  64 %struct.pt = type { %struct.point*, i32, i32 }
  65 %struct.point = type { i32, i32 }
  66
  67 ; Check when a GEP is used across two basic block, LLVM can sink the address
  68 ; calculation and code gen can generate a better addressing mode for the second
  69 ; use.
  70 define void @test_GEP_across_BB(%class.my* %this, i64 %idx) {
  71   %1 = getelementptr %class.my, %class.my* %this, i64 0, i32 3, i64 %idx, i32 1
  72   %2 = load i32, i32* %1, align 4
  73   %3 = getelementptr %class.my, %class.my* %this, i64 0, i32 3, i64 %idx, i32 2
  74   %4 = load i32, i32* %3, align 4
  75   %5 = icmp eq i32 %2, %4
  76   br i1 %5, label %if.true, label %exit
  77
  78 if.true:
  79   %6 = shl i32 %4, 1
  80   store i32 %6, i32* %3, align 4
  81   br label %exit
  82
  83 exit:
  84   %7 = add nsw i32 %4, 1
  85   store i32 %7, i32* %1, align 4
  86   ret void
  87 }
  88 ; CHECK-LABEL: test_GEP_across_BB:
  89 ; CHECK: ldr {{w[0-9]+}}, [{{x[0-9]+}}, #528]
  90 ; CHECK: ldr {{w[0-9]+}}, [{{x[0-9]+}}, #532]
  91 ; CHECK-NOT: add
  92 ; CHECK: str {{w[0-9]+}}, [{{x[0-9]+}}, #532]
  93 ; CHECK: str {{w[0-9]+}}, [{{x[0-9]+}}, #528]
  94
  95 ; CHECK-NoAA-LABEL: test_GEP_across_BB(
  96 ; CHECK-NoAA: add i64 [[TMP:%[a-zA-Z0-9]+]], 528
  97 ; CHECK-NoAA: add i64 [[TMP]], 532
  98 ; CHECK-NoAA: if.true:
  99 ; CHECK-NoAA: inttoptr
 100 ; CHECK-NoAA: bitcast
 101 ; CHECK-NoAA: {{%sunk[a-zA-Z0-9]+}} = getelementptr i8, {{.*}}, i64 532
 102 ; CHECK-NoAA: exit:
 103 ; CHECK-NoAA: inttoptr
 104 ; CHECK-NoAA: bitcast
 105 ; CHECK-NoAA: {{%sunk[a-zA-Z0-9]+}} = getelementptr i8, {{.*}}, i64 528
 106
 107 ; CHECK-UseAA-LABEL: test_GEP_across_BB(
 108 ; CHECK-UseAA: [[PTR0:%[a-zA-Z0-9]+]] = getelementptr
 109 ; CHECK-UseAA: getelementptr i8, i8* [[PTR0]], i64 528
 110 ; CHECK-UseAA: getelementptr i8, i8* [[PTR0]], i64 532
 111 ; CHECK-UseAA: if.true:
 112 ; CHECK-UseAA: {{%sunk[a-zA-Z0-9]+}} = getelementptr i8, i8* [[PTR0]], i64 532
 113 ; CHECK-UseAA: exit:
 114 ; CHECK-UseAA: {{%sunk[a-zA-Z0-9]+}} = getelementptr i8, i8* [[PTR0]], i64 528
 115
 116 %struct.S = type { float, double }
 117 @struct_array = global [1024 x %struct.S] zeroinitializer, align 16
 118
 119 ; The following two test cases check we can extract constant from indices of
 120 ; struct type.
 121 ; The constant offsets are from indices "i64 %idxprom" and "i32 1". As the
 122 ; alloca size of %struct.S is 16, and "i32 1" is the 2rd element whose field
 123 ; offset is 8, the total constant offset is (5 * 16 + 8) = 88.
 124 define double* @test-struct_1(i32 %i) {
 125 entry:
 126   %add = add nsw i32 %i, 5
 127   %idxprom = sext i32 %add to i64
 128   %p = getelementptr [1024 x %struct.S], [1024 x %struct.S]* @struct_array, i64 0, i64 %idxprom, i32 1
 129   ret double* %p
 130 }
 131 ; CHECK-NoAA-LABEL: @test-struct_1(
 132 ; CHECK-NoAA-NOT: getelementptr
 133 ; CHECK-NoAA: add i64 %{{[a-zA-Z0-9]+}}, 88
 134
 135 ; CHECK-UseAA-LABEL: @test-struct_1(
 136 ; CHECK-UseAA: getelementptr i8, i8* %{{[a-zA-Z0-9]+}}, i64 88
 137
 138 %struct3 = type { i64, i32 }
 139 %struct2 = type { %struct3, i32 }
 140 %struct1 = type { i64, %struct2 }
 141 %struct0 = type { i32, i32, i64*, [100 x %struct1] }
 142
 143 ; The constant offsets are from indices "i32 3", "i64 %arrayidx" and "i32 1".
 144 ; "i32 3" is the 4th element whose field offset is 16. The alloca size of
 145 ; %struct1 is 32. "i32 1" is the 2rd element whose field offset is 8. So the
 146 ; total constant offset is 16 + (-2 * 32) + 8 = -40
 147 define %struct2* @test-struct_2(%struct0* %ptr, i64 %idx) {
 148 entry:
 149   %arrayidx = add nsw i64 %idx, -2
 150   %ptr2 = getelementptr %struct0, %struct0* %ptr, i64 0, i32 3, i64 %arrayidx, i32 1
 151   ret %struct2* %ptr2
 152 }
 153 ; CHECK-NoAA-LABEL: @test-struct_2(
 154 ; CHECK-NoAA-NOT: = getelementptr
 155 ; CHECK-NoAA: add i64 %{{[a-zA-Z0-9]+}}, -40
 156
 157 ; CHECK-UseAA-LABEL: @test-struct_2(
 158 ; CHECK-UseAA: getelementptr i8, i8* %{{[a-zA-Z0-9]+}}, i64 -40
 159
 160 ; Test that when a index is added from two constant, SeparateConstOffsetFromGEP
 161 ; pass does not generate incorrect result.
 162 define void @test_const_add([3 x i32]* %in) {
 163   %inc = add nsw i32 2, 1
 164   %idxprom = sext i32 %inc to i64
 165   %arrayidx = getelementptr [3 x i32], [3 x i32]* %in, i64 %idxprom, i64 2
 166   store i32 0, i32* %arrayidx, align 4
 167   ret void
 168 }
 169 ; CHECK-LABEL: test_const_add:
 170 ; CHECK: str wzr, [x0, #44]