utils/gn/secondary/llvm/lib/Target/RISCV/MCTargetDesc/BUILD.gn

   1 import("//llvm/utils/TableGen/tablegen.gni")
   2
   3 tablegen("RISCVGenAsmWriter") {
   4   visibility = [ ":MCTargetDesc" ]
   5   args = [ "-gen-asm-writer" ]
   6   td_file = "../RISCV.td"
   7 }
   8
   9 tablegen("RISCVGenInstrInfo") {
  10   visibility = [ ":tablegen" ]
  11   args = [ "-gen-instr-info" ]
  12   td_file = "../RISCV.td"
  13 }
  14
  15 tablegen("RISCVGenMCCodeEmitter") {
  16   visibility = [ ":MCTargetDesc" ]
  17   args = [ "-gen-emitter" ]
  18   td_file = "../RISCV.td"
  19 }
  20
  21 tablegen("RISCVGenRegisterInfo") {
  22   visibility = [ ":tablegen" ]
  23   args = [ "-gen-register-info" ]
  24   td_file = "../RISCV.td"
  25 }
  26
  27 tablegen("RISCVGenSubtargetInfo") {
  28   visibility = [ ":tablegen" ]
  29   args = [ "-gen-subtarget" ]
  30   td_file = "../RISCV.td"
  31 }
  32
  33 # This should contain tablegen targets generating .inc files included
  34 # by other targets. .inc files only used by .cpp files in this directory
  35 # should be in deps on the static_library instead.
  36 group("tablegen") {
  37   visibility = [
  38     ":MCTargetDesc",
  39     "../Utils",
  40   ]
  41   public_deps = [
  42     ":RISCVGenInstrInfo",
  43     ":RISCVGenRegisterInfo",
  44     ":RISCVGenSubtargetInfo",
  45   ]
  46 }
  47
  48 static_library("MCTargetDesc") {
  49   output_name = "LLVMRISCVDesc"
  50   public_deps = [
  51     ":tablegen",
  52   ]
  53   deps = [
  54     ":RISCVGenAsmWriter",
  55     ":RISCVGenMCCodeEmitter",
  56     "//llvm/lib/MC",
  57     "//llvm/lib/Support",
  58     "//llvm/lib/Target/RISCV:RISCVGenCompressInstEmitter",
  59     "//llvm/lib/Target/RISCV/Utils",
  60   ]
  61   include_dirs = [ ".." ]
  62   sources = [
  63     "RISCVAsmBackend.cpp",
  64     "RISCVELFObjectWriter.cpp",
  65     "RISCVELFStreamer.cpp",
  66     "RISCVInstPrinter.cpp",
  67     "RISCVMCAsmInfo.cpp",
  68     "RISCVMCCodeEmitter.cpp",
  69     "RISCVMCExpr.cpp",
  70     "RISCVMCTargetDesc.cpp",
  71     "RISCVTargetStreamer.cpp",
  72   ]
  73 }