CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0068)
   6   cmake_policy(SET CMP0068 NEW)
   7   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
   8 endif()
   9
  10 if(POLICY CMP0075)
  11   cmake_policy(SET CMP0075 NEW)
  12 endif()
  13
  14 if(POLICY CMP0077)
  15   cmake_policy(SET CMP0077 NEW)
  16 endif()
  17
  18 if(NOT DEFINED LLVM_VERSION_MAJOR)
  19   set(LLVM_VERSION_MAJOR 10)
  20 endif()
  21 if(NOT DEFINED LLVM_VERSION_MINOR)
  22   set(LLVM_VERSION_MINOR 0)
  23 endif()
  24 if(NOT DEFINED LLVM_VERSION_PATCH)
  25   set(LLVM_VERSION_PATCH 0)
  26 endif()
  27 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  28   set(LLVM_VERSION_SUFFIX svn)
  29 endif()
  30
  31 if (NOT PACKAGE_VERSION)
  32   set(PACKAGE_VERSION
  33     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  34 endif()
  35
  36 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  37   message(WARNING "Visual Studio generators use the x86 host compiler by "
  38                   "default, even for 64-bit targets. This can result in linker "
  39                   "instability and out of memory errors. To use the 64-bit "
  40                   "host compiler, pass -Thost=x64 on the CMake command line.")
  41 endif()
  42
  43 if (CMAKE_GENERATOR STREQUAL "Xcode" AND NOT CMAKE_OSX_ARCHITECTURES)
  44   # Some CMake features like object libraries get confused if you don't
  45   # explicitly specify an architecture setting with the Xcode generator.
  46   set(CMAKE_OSX_ARCHITECTURES "x86_64")
  47 endif()
  48
  49 project(LLVM
  50   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  51   LANGUAGES C CXX ASM)
  52
  53 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  54   message(STATUS "No build type selected, default to Debug")
  55   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  56 endif()
  57
  58 # Side-by-side subprojects layout: automatically set the
  59 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
  60 # This allows an easy way of setting up a build directory for llvm and another
  61 # one for llvm+clang+... using the same sources.
  62 set(LLVM_ALL_PROJECTS "clang;clang-tools-extra;compiler-rt;debuginfo-tests;libclc;libcxx;libcxxabi;libunwind;lld;lldb;llgo;openmp;parallel-libs;polly;pstl")
  63 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
  64         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
  65 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
  66   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
  67 endif()
  68
  69 # LLVM_ENABLE_PROJECTS_USED is `ON` if the user has ever used the
  70 # `LLVM_ENABLE_PROJECTS` CMake cache variable.  This exists for
  71 # several reasons:
  72 #
  73 # * As an indicator that the `LLVM_ENABLE_PROJECTS` list is now the single
  74 # source of truth for which projects to build. This means we will ignore user
  75 # supplied `LLVM_TOOL_<project>_BUILD` CMake cache variables and overwrite
  76 # them.
  77 #
  78 # * The case where the user previously had `LLVM_ENABLE_PROJECTS` set to a
  79 # non-empty list but now the user wishes to disable building all other projects
  80 # by setting `LLVM_ENABLE_PROJECTS` to an empty string. In that case we still
  81 # need to set the `LLVM_TOOL_${upper_proj}_BUILD` variables so that we disable
  82 # building all the projects that were previously enabled.
  83 set(LLVM_ENABLE_PROJECTS_USED OFF CACHE BOOL "")
  84 mark_as_advanced(LLVM_ENABLE_PROJECTS_USED)
  85
  86 if (LLVM_ENABLE_PROJECTS_USED OR NOT LLVM_ENABLE_PROJECTS STREQUAL "")
  87   set(LLVM_ENABLE_PROJECTS_USED ON CACHE BOOL "" FORCE)
  88   foreach(proj ${LLVM_ALL_PROJECTS} ${LLVM_EXTERNAL_PROJECTS})
  89     string(TOUPPER "${proj}" upper_proj)
  90     string(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
  91     if ("${proj}" IN_LIST LLVM_ENABLE_PROJECTS)
  92       message(STATUS "${proj} project is enabled")
  93       set(SHOULD_ENABLE_PROJECT TRUE)
  94       set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
  95       if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
  96         message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
  97       endif()
  98       if( LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR STREQUAL "" )
  99         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "" FORCE)
 100       else()
 101         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "")
 102       endif()
 103     elseif ("${proj}" IN_LIST LLVM_EXTERNAL_PROJECTS)
 104       message(STATUS "${proj} project is enabled")
 105       set(SHOULD_ENABLE_PROJECT TRUE)
 106     else()
 107       message(STATUS "${proj} project is disabled")
 108       set(SHOULD_ENABLE_PROJECT FALSE)
 109     endif()
 110     # Force `LLVM_TOOL_${upper_proj}_BUILD` variables to have values that
 111     # corresponds with `LLVM_ENABLE_PROJECTS`. This prevents the user setting
 112     # `LLVM_TOOL_${upper_proj}_BUILD` variables externally. At some point
 113     # we should deprecate allowing users to set these variables by turning them
 114     # into normal CMake variables rather than cache variables.
 115     set(LLVM_TOOL_${upper_proj}_BUILD
 116       ${SHOULD_ENABLE_PROJECT}
 117       CACHE
 118       BOOL "Whether to build ${upper_proj} as part of LLVM" FORCE
 119     )
 120   endforeach()
 121 endif()
 122 unset(SHOULD_ENABLE_PROJECT)
 123
 124 # Build llvm with ccache if the package is present
 125 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 126 if(LLVM_CCACHE_BUILD)
 127   find_program(CCACHE_PROGRAM ccache)
 128   if(CCACHE_PROGRAM)
 129       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 130       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 131       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 132           CACHE STRING "Parameters to pass through to ccache")
 133
 134       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 135       if (LLVM_CCACHE_MAXSIZE)
 136         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 137       endif()
 138       if (LLVM_CCACHE_DIR)
 139         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 140       endif()
 141       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 142   else()
 143     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 144   endif()
 145 endif()
 146
 147 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 148
 149 # Some features of the LLVM build may be disallowed when dependency debugging is
 150 # enabled. In particular you cannot use ccache because we want to force compile
 151 # operations to always happen.
 152 if(LLVM_DEPENDENCY_DEBUGGING)
 153   if(NOT CMAKE_HOST_APPLE)
 154     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 155   endif()
 156   if(LLVM_CCACHE_BUILD)
 157     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 158   endif()
 159 endif()
 160
 161 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 162 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 163 if(LLVM_ENABLE_GISEL_COV)
 164   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 165 endif()
 166
 167 # Add path for custom modules
 168 set(CMAKE_MODULE_PATH
 169   ${CMAKE_MODULE_PATH}
 170   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 171   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 172   )
 173
 174 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 175 # for use by clang_complete, YouCompleteMe, etc.
 176 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 177
 178 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 179   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 180
 181 option(LLVM_INSTALL_CCTOOLS_SYMLINKS
 182   "Install symlinks from the cctools tool names to the corresponding LLVM tools." OFF)
 183
 184 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 185
 186 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 187
 188 # Unfortunatly Clang is too eager to search directories for module maps, which can cause the
 189 # installed version of the maps to be found when building LLVM from source. Therefore we turn off
 190 # the installation by default. See llvm.org/PR31905.
 191 option(LLVM_INSTALL_MODULEMAPS "Install the modulemap files in the 'install' target." OFF)
 192
 193 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 194 if ( LLVM_USE_FOLDERS )
 195   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 196 endif()
 197
 198 include(VersionFromVCS)
 199
 200 option(LLVM_APPEND_VC_REV
 201   "Embed the version control system revision in LLVM" ON)
 202
 203 set(PACKAGE_NAME LLVM)
 204 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 205 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 206
 207 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 208   "Default URL where bug reports are to be submitted.")
 209
 210 # Configure CPack.
 211 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 212 set(CPACK_PACKAGE_VENDOR "LLVM")
 213 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 214 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 215 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 216 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 217 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 218 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 219 if(WIN32 AND NOT UNIX)
 220   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 221   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 222   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 223   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 224   set(CPACK_NSIS_MODIFY_PATH "ON")
 225   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 226   if( CMAKE_CL_64 )
 227     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 228   endif()
 229 endif()
 230 include(CPack)
 231
 232 # Sanity check our source directory to make sure that we are not trying to
 233 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 234 # sure that we don't have any stray generated files lying around in the tree
 235 # (which would end up getting picked up by header search, instead of the correct
 236 # versions).
 237 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 238   message(FATAL_ERROR "In-source builds are not allowed.
 239 Please create a directory and run cmake from there, passing the path
 240 to this source directory as the last argument.
 241 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 242 Please delete them.")
 243 endif()
 244
 245 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 246
 247 if (CMAKE_BUILD_TYPE AND
 248     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 249   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 250 endif()
 251
 252 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 253
 254 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 255 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 256
 257 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 258     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 259 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 260
 261 # They are used as destination of target generators.
 262 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 263 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 264 if(WIN32 OR CYGWIN)
 265   # DLL platform -- put DLLs into bin.
 266   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 267 else()
 268   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 269 endif()
 270
 271 # Each of them corresponds to llvm-config's.
 272 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 273 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 274 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 275 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 276 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 277
 278 # Note: LLVM_CMAKE_PATH does not include generated files
 279 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 280 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 281 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 282
 283 # List of all targets to be built by default:
 284 set(LLVM_ALL_TARGETS
 285   AArch64
 286   AMDGPU
 287   ARM
 288   BPF
 289   Hexagon
 290   Lanai
 291   Mips
 292   MSP430
 293   NVPTX
 294   PowerPC
 295   RISCV
 296   Sparc
 297   SystemZ
 298   WebAssembly
 299   X86
 300   XCore
 301   )
 302
 303 # List of targets with JIT support:
 304 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 305
 306 set(LLVM_TARGETS_TO_BUILD "all"
 307     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 308
 309 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 310   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 311
 312 option(BUILD_SHARED_LIBS
 313   "Build all libraries as shared libraries instead of static" OFF)
 314
 315 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 316 if(LLVM_ENABLE_BACKTRACES)
 317   set(ENABLE_BACKTRACES 1)
 318 endif()
 319
 320 option(LLVM_ENABLE_UNWIND_TABLES "Emit unwind tables for the libraries" ON)
 321
 322 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 323 if(LLVM_ENABLE_CRASH_OVERRIDES)
 324   set(ENABLE_CRASH_OVERRIDES 1)
 325 endif()
 326
 327 option(LLVM_ENABLE_CRASH_DUMPS "Turn on memory dumps on crashes. Currently only implemented on Windows." OFF)
 328
 329 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 330 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 331 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 332
 333 set(LLVM_TARGET_ARCH "host"
 334   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 335
 336 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 337
 338 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 339
 340 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 341
 342 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 343
 344 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 345
 346 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 347
 348 set(LLVM_Z3_INSTALL_DIR "" CACHE STRING "Install directory of the Z3 solver.")
 349
 350 find_package(Z3 4.7.1)
 351
 352 if (LLVM_Z3_INSTALL_DIR)
 353   if (NOT Z3_FOUND)
 354     message(FATAL_ERROR "Z3 >= 4.7.1 has not been found in LLVM_Z3_INSTALL_DIR: ${LLVM_Z3_INSTALL_DIR}.")
 355   endif()
 356 endif()
 357
 358 set(LLVM_ENABLE_Z3_SOLVER_DEFAULT "${Z3_FOUND}")
 359
 360 option(LLVM_ENABLE_Z3_SOLVER
 361   "Enable Support for the Z3 constraint solver in LLVM."
 362   ${LLVM_ENABLE_Z3_SOLVER_DEFAULT}
 363 )
 364
 365 if (LLVM_ENABLE_Z3_SOLVER)
 366   if (NOT Z3_FOUND)
 367     message(FATAL_ERROR "LLVM_ENABLE_Z3_SOLVER cannot be enabled when Z3 is not available.")
 368   endif()
 369
 370   set(LLVM_WITH_Z3 1)
 371 endif()
 372
 373 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 374   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 375 endif()
 376
 377 set(LLVM_TARGETS_TO_BUILD
 378    ${LLVM_TARGETS_TO_BUILD}
 379    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 380 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 381
 382 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 383 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 384 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 385 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 386   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 387   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 388 else()
 389   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 390   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 391 endif()
 392 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 393 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 394 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 395 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 396
 397 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 398
 399 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 400   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 401 else()
 402   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 403 endif()
 404
 405 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 406
 407 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 408   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 409
 410 option(LLVM_FORCE_USE_OLD_TOOLCHAIN
 411        "Set to ON to force using an old, unsupported host toolchain." OFF)
 412
 413 option(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN
 414        "Set to ON to only warn when using a toolchain which is about to be deprecated, instead of emitting an error." OFF)
 415
 416 option(LLVM_USE_INTEL_JITEVENTS
 417   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 418   OFF)
 419
 420 if( LLVM_USE_INTEL_JITEVENTS )
 421   # Verify we are on a supported platform
 422   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 423     message(FATAL_ERROR
 424       "Intel JIT API support is available on Linux and Windows only.")
 425   endif()
 426 endif( LLVM_USE_INTEL_JITEVENTS )
 427
 428 option(LLVM_USE_OPROFILE
 429   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 430
 431 option(LLVM_EXTERNALIZE_DEBUGINFO
 432   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 433
 434 set(LLVM_CODESIGNING_IDENTITY "" CACHE STRING
 435   "Sign executables and dylibs with the given identity or skip if empty (Darwin Only)")
 436
 437 # If enabled, verify we are on a platform that supports oprofile.
 438 if( LLVM_USE_OPROFILE )
 439   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 440     message(FATAL_ERROR "OProfile support is available on Linux only.")
 441   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 442 endif( LLVM_USE_OPROFILE )
 443
 444 option(LLVM_USE_PERF
 445   "Use perf JIT interface to inform perf about JIT code" OFF)
 446
 447 # If enabled, verify we are on a platform that supports perf.
 448 if( LLVM_USE_PERF )
 449   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 450     message(FATAL_ERROR "perf support is available on Linux only.")
 451   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 452 endif( LLVM_USE_PERF )
 453
 454 set(LLVM_USE_SANITIZER "" CACHE STRING
 455   "Define the sanitizer used to build binaries and tests.")
 456 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 457 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 458   "Path to fuzzing library for linking with fuzz targets")
 459
 460 option(LLVM_USE_SPLIT_DWARF
 461   "Use -gsplit-dwarf when compiling llvm." OFF)
 462
 463 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 464 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 465
 466 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 467   set(POLLY_IN_TREE TRUE)
 468 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 469   set(POLLY_IN_TREE TRUE)
 470 else()
 471   set(POLLY_IN_TREE FALSE)
 472 endif()
 473
 474 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 475   set(WITH_POLLY ON)
 476 else()
 477   set(WITH_POLLY OFF)
 478 endif()
 479
 480 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 481   set(LINK_POLLY_INTO_TOOLS ON)
 482 else()
 483   set(LINK_POLLY_INTO_TOOLS OFF)
 484 endif()
 485
 486 # Define an option controlling whether we should build for 32-bit on 64-bit
 487 # platforms, where supported.
 488 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 489   # TODO: support other platforms and toolchains.
 490   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 491 endif()
 492
 493 # Define the default arguments to use with 'lit', and an option for the user to
 494 # override.
 495 set(LIT_ARGS_DEFAULT "-sv")
 496 if (MSVC_IDE OR XCODE)
 497   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 498 endif()
 499 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 500
 501 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 502 if( WIN32 AND NOT CYGWIN )
 503   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 504 endif()
 505
 506 # Define options to control the inclusion and default build behavior for
 507 # components which may not strictly be necessary (tools, examples, and tests).
 508 #
 509 # This is primarily to support building smaller or faster project files.
 510 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 511 option(LLVM_BUILD_TOOLS
 512   "Build the LLVM tools. If OFF, just generate build targets." ON)
 513
 514 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 515 option(LLVM_BUILD_UTILS
 516   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 517
 518 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 519 option(LLVM_BUILD_RUNTIMES
 520   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 521
 522 option(LLVM_BUILD_RUNTIME
 523   "Build the LLVM runtime libraries." ON)
 524 option(LLVM_BUILD_EXAMPLES
 525   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 526 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 527
 528 option(LLVM_BUILD_TESTS
 529   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 530 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 531 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 532
 533 option(LLVM_BUILD_BENCHMARKS "Add LLVM benchmark targets to the list of default
 534 targets. If OFF, benchmarks still could be built using Benchmarks target." OFF)
 535 option(LLVM_INCLUDE_BENCHMARKS "Generate benchmark targets. If OFF, benchmarks can't be built." ON)
 536
 537 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 538 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 539 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 540 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 541 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 542 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 543
 544 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 545     CACHE STRING "Doxygen-generated HTML documentation install directory")
 546 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 547     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 548
 549 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 550   "Build compiler-rt as an external project." OFF)
 551
 552 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 553   "Show target and host info when tools are invoked with --version." ON)
 554
 555 # You can configure which libraries from LLVM you want to include in the
 556 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 557 # list of LLVM components. All component names handled by llvm-config are valid.
 558 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 559   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 560     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 561 endif()
 562 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 563 if(MSVC)
 564   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" ON)
 565 else()
 566   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
 567 endif()
 568 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 569 if(LLVM_LINK_LLVM_DYLIB OR (LLVM_BUILD_LLVM_C_DYLIB AND NOT MSVC))
 570   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 571 endif()
 572 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 573
 574 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 575 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 576   set(LLVM_USE_HOST_TOOLS ON)
 577 endif()
 578
 579 if (MSVC_IDE)
 580   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 581 endif()
 582
 583 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 584     LLVM_ENABLE_IR_PGO)
 585   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 586     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 587     # for spining disks. Anything higher may only help on slower mediums.
 588     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 589   endif()
 590   if(NOT LLVM_PROFILE_FILE_PATTERN)
 591     if(NOT LLVM_PROFILE_DATA_DIR)
 592       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 593     endif()
 594                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 595   endif()
 596   if(NOT LLVM_CSPROFILE_FILE_PATTERN)
 597     if(NOT LLVM_CSPROFILE_DATA_DIR)
 598       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/csprofiles" LLVM_CSPROFILE_DATA_DIR)
 599     endif()
 600     file(TO_NATIVE_PATH "${LLVM_CSPROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_CSPROFILE_FILE_PATTERN)
 601   endif()
 602 endif()
 603
 604 if (LLVM_BUILD_STATIC)
 605   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 606 endif()
 607
 608 # Use libtool instead of ar if you are both on an Apple host, and targeting Apple.
 609 if(CMAKE_HOST_APPLE AND APPLE)
 610   include(UseLibtool)
 611 endif()
 612
 613 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 614 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 615 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 616
 617 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR OFF CACHE BOOL
 618   "Enable per-target runtimes directory")
 619
 620 # All options referred to from HandleLLVMOptions have to be specified
 621 # BEFORE this include, otherwise options will not be correctly set on
 622 # first cmake run
 623 include(config-ix)
 624
 625 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 626   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 627 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 628
 629 # By default, we target the host, but this can be overridden at CMake
 630 # invocation time.
 631 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 632   "Default target for which LLVM will generate code." )
 633 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 634 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 635 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 636
 637 if(WIN32 OR CYGWIN)
 638   if(BUILD_SHARED_LIBS OR LLVM_BUILD_LLVM_DYLIB)
 639     set(LLVM_ENABLE_PLUGINS_default ON)
 640   else()
 641     set(LLVM_ENABLE_PLUGINS_default OFF)
 642   endif()
 643 else()
 644   set(LLVM_ENABLE_PLUGINS_default ${LLVM_ENABLE_PIC})
 645 endif()
 646 option(LLVM_ENABLE_PLUGINS "Enable plugin support" ${LLVM_ENABLE_PLUGINS_default})
 647
 648 include(HandleLLVMOptions)
 649
 650 include(FindPythonInterp)
 651 if( NOT PYTHONINTERP_FOUND )
 652   message(FATAL_ERROR
 653 "Unable to find Python interpreter, required for builds and testing.
 654
 655 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 656 endif()
 657
 658 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 659   message(FATAL_ERROR "Python 2.7 or newer is required")
 660 endif()
 661
 662 ######
 663 # LLVMBuild Integration
 664 #
 665 # We use llvm-build to generate all the data required by the CMake based
 666 # build system in one swoop:
 667 #
 668 #  - We generate a file (a CMake fragment) in the object root which contains
 669 #    all the definitions that are required by CMake.
 670 #
 671 #  - We generate the library table used by llvm-config.
 672 #
 673 #  - We generate the dependencies for the CMake fragment, so that we will
 674 #    automatically reconfigure ourselves.
 675
 676 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 677 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 678   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 679 set(LLVMBUILDCMAKEFRAG
 680   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 681
 682 # Create the list of optional components that are enabled
 683 if (LLVM_USE_INTEL_JITEVENTS)
 684   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 685 endif (LLVM_USE_INTEL_JITEVENTS)
 686 if (LLVM_USE_OPROFILE)
 687   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 688 endif (LLVM_USE_OPROFILE)
 689 if (LLVM_USE_PERF)
 690   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} PerfJITEvents)
 691 endif (LLVM_USE_PERF)
 692
 693 message(STATUS "Constructing LLVMBuild project information")
 694 execute_process(
 695   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 696             --native-target "${LLVM_NATIVE_ARCH}"
 697             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 698             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 699             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 700             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 701             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 702             ERROR_VARIABLE LLVMBUILDERRORS
 703             OUTPUT_STRIP_TRAILING_WHITESPACE
 704             ERROR_STRIP_TRAILING_WHITESPACE
 705   RESULT_VARIABLE LLVMBUILDRESULT)
 706
 707 # On Win32, CMake doesn't properly handle piping the default output/error
 708 # streams into the GUI console. So, we explicitly catch and report them.
 709 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 710   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 711 endif()
 712 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 713   message(FATAL_ERROR
 714     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 715 endif()
 716
 717 # Include the generated CMake fragment. This will define properties from the
 718 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 719 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 720 # files change.
 721 include(${LLVMBUILDCMAKEFRAG})
 722
 723 ######
 724
 725 # Configure all of the various header file fragments LLVM uses which depend on
 726 # configuration variables.
 727 set(LLVM_ENUM_TARGETS "")
 728 set(LLVM_ENUM_ASM_PRINTERS "")
 729 set(LLVM_ENUM_ASM_PARSERS "")
 730 set(LLVM_ENUM_DISASSEMBLERS "")
 731 foreach(t ${LLVM_TARGETS_TO_BUILD})
 732   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 733
 734   list(FIND LLVM_ALL_TARGETS ${t} idx)
 735   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 736   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 737   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 738   # this test just makes sure that any experimental targets were passed via
 739   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 740   if( idx LESS 0 AND idy LESS 0 )
 741     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 742       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 743   else()
 744     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 745   endif()
 746
 747   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 748   if( asmp_file )
 749     set(LLVM_ENUM_ASM_PRINTERS
 750       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 751   endif()
 752   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 753     set(LLVM_ENUM_ASM_PARSERS
 754       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 755   endif()
 756   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 757     set(LLVM_ENUM_DISASSEMBLERS
 758       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 759   endif()
 760 endforeach(t)
 761
 762 # Produce the target definition files, which provide a way for clients to easily
 763 # include various classes of targets.
 764 configure_file(
 765   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 766   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 767   )
 768 configure_file(
 769   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 770   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 771   )
 772 configure_file(
 773   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 774   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 775   )
 776 configure_file(
 777   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 778   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 779   )
 780
 781 # Configure the three LLVM configuration header files.
 782 configure_file(
 783   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 784   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 785 configure_file(
 786   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 787   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 788 configure_file(
 789   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 790   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 791
 792 # Add target for generating source rpm package.
 793 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 794     CACHE FILEPATH ".spec file to use for srpm generation")
 795 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 796 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 797
 798 get_source_info(${CMAKE_CURRENT_SOURCE_DIR} revision repository)
 799 string(LENGTH "${revision}" revision_length)
 800 if(revision MATCHES "^[0-9]+$" AND revision_length LESS 40)
 801   set(LLVM_RPM_SPEC_REVISION "r${revision}")
 802 else()
 803   set(LLVM_RPM_SPEC_REVISION "${revision}")
 804 endif()
 805
 806 configure_file(
 807   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 808   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 809
 810 add_custom_target(srpm
 811   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 812   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 813 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 814
 815
 816 # They are not referenced. See set_output_directory().
 817 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 818 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 819 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 820
 821 if(APPLE AND DARWIN_LTO_LIBRARY)
 822   set(CMAKE_EXE_LINKER_FLAGS
 823     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 824   set(CMAKE_SHARED_LINKER_FLAGS
 825     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 826   set(CMAKE_MODULE_LINKER_FLAGS
 827     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 828 endif()
 829
 830 # Build with _XOPEN_SOURCE on AIX, as stray macros in _ALL_SOURCE mode tend to
 831 # break things. In this case we need to enable the large-file API as well.
 832 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 833           add_definitions("-D_XOPEN_SOURCE=700")
 834           add_definitions("-D_LARGE_FILE_API")
 835 endif()
 836
 837 # Build with _FILE_OFFSET_BITS=64 on Solaris to match g++ >= 9.
 838 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 839           add_definitions("-D_FILE_OFFSET_BITS=64")
 840 endif()
 841
 842 # Work around a broken bfd ld behavior. When linking a binary with a
 843 # foo.so library, it will try to find any library that foo.so uses and
 844 # check its symbols. This is wasteful (the check was done when foo.so
 845 # was created) and can fail since it is not the dynamic linker and
 846 # doesn't know how to handle search paths correctly.
 847 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 848   set(CMAKE_EXE_LINKER_FLAGS
 849       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 850 endif()
 851
 852 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 853
 854 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 855
 856 # when crosscompiling import the executable targets from a file
 857 if(LLVM_USE_HOST_TOOLS)
 858   include(CrossCompile)
 859   llvm_create_cross_target(LLVM NATIVE "" Release)
 860 endif(LLVM_USE_HOST_TOOLS)
 861 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 862 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 863 # (this is a variable that CrossCompile sets on recursive invocations)
 864 endif()
 865
 866 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 867   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 868   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 869   include_directories(SYSTEM "/usr/local/include")
 870   link_directories("/usr/local/lib")
 871 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 872
 873 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 874    # special hack for Solaris to handle crazy system sys/regset.h
 875    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 876 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 877
 878 # Make sure we don't get -rdynamic in every binary. For those that need it,
 879 # use export_executable_symbols(target).
 880 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 881
 882 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 883   "Profiling data file to use when compiling in order to improve runtime performance.")
 884
 885 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 886   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 887     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 888   else()
 889     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 890   endif()
 891 endif()
 892
 893 include(AddLLVM)
 894 include(TableGen)
 895
 896 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 897   # People report that -O3 is unreliable on MinGW. The traditional
 898   # build also uses -O2 for that reason:
 899   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 900 endif()
 901
 902 # Put this before tblgen. Else we have a circular dependence.
 903 add_subdirectory(lib/Demangle)
 904 add_subdirectory(lib/Support)
 905 add_subdirectory(lib/TableGen)
 906
 907 add_subdirectory(utils/TableGen)
 908
 909 add_subdirectory(include/llvm)
 910
 911 add_subdirectory(lib)
 912
 913 if( LLVM_INCLUDE_UTILS )
 914   add_subdirectory(utils/FileCheck)
 915   add_subdirectory(utils/PerfectShuffle)
 916   add_subdirectory(utils/count)
 917   add_subdirectory(utils/not)
 918   add_subdirectory(utils/yaml-bench)
 919 else()
 920   if ( LLVM_INCLUDE_TESTS )
 921     message(FATAL_ERROR "Including tests when not building utils will not work.
 922     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLUDE_TESTS to Off.")
 923   endif()
 924 endif()
 925
 926 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 927 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 928   add_subdirectory(utils/LLVMVisualizers)
 929 endif()
 930
 931 foreach( binding ${LLVM_BINDINGS_LIST} )
 932   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 933     add_subdirectory(bindings/${binding})
 934   endif()
 935 endforeach()
 936
 937 add_subdirectory(projects)
 938
 939 if( LLVM_INCLUDE_TOOLS )
 940   add_subdirectory(tools)
 941 endif()
 942
 943 if( LLVM_INCLUDE_RUNTIMES )
 944   add_subdirectory(runtimes)
 945 endif()
 946
 947 if( LLVM_INCLUDE_EXAMPLES )
 948   add_subdirectory(examples)
 949 endif()
 950
 951 if( LLVM_INCLUDE_TESTS )
 952   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 953     include(LLVMExternalProjectUtils)
 954     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 955       USE_TOOLCHAIN
 956       EXCLUDE_FROM_ALL
 957       NO_INSTALL
 958       ALWAYS_CLEAN)
 959   endif()
 960   add_subdirectory(utils/lit)
 961   add_subdirectory(test)
 962   add_subdirectory(unittests)
 963   if( LLVM_INCLUDE_UTILS )
 964     add_subdirectory(utils/unittest)
 965   endif()
 966
 967   if (WIN32)
 968     # This utility is used to prevent crashing tests from calling Dr. Watson on
 969     # Windows.
 970     add_subdirectory(utils/KillTheDoctor)
 971   endif()
 972
 973   # Add a global check rule now that all subdirectories have been traversed
 974   # and we know the total set of lit testsuites.
 975   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 976   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 977   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 978   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 979   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 980                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 981   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 982                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 983   add_lit_target(check-all
 984     "Running all regression tests"
 985     ${LLVM_LIT_TESTSUITES}
 986     PARAMS ${LLVM_LIT_PARAMS}
 987     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 988     ARGS ${LLVM_LIT_EXTRA_ARGS}
 989     )
 990   if(TARGET check-runtimes)
 991     add_dependencies(check-all check-runtimes)
 992   endif()
 993   add_custom_target(test-depends
 994                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 995   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 996 endif()
 997
 998 if (LLVM_INCLUDE_DOCS)
 999   add_subdirectory(docs)
1000 endif()
1001
1002 add_subdirectory(cmake/modules)
1003
1004 # Do this last so that all lit targets have already been created.
1005 if (LLVM_INCLUDE_UTILS)
1006   add_subdirectory(utils/llvm-lit)
1007 endif()
1008
1009 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1010   install(DIRECTORY include/llvm include/llvm-c
1011     DESTINATION include
1012     COMPONENT llvm-headers
1013     FILES_MATCHING
1014     PATTERN "*.def"
1015     PATTERN "*.h"
1016     PATTERN "*.td"
1017     PATTERN "*.inc"
1018     PATTERN "LICENSE.TXT"
1019     PATTERN ".svn" EXCLUDE
1020     )
1021
1022   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
1023     DESTINATION include
1024     COMPONENT llvm-headers
1025     FILES_MATCHING
1026     PATTERN "*.def"
1027     PATTERN "*.h"
1028     PATTERN "*.gen"
1029     PATTERN "*.inc"
1030     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
1031     PATTERN "CMakeFiles" EXCLUDE
1032     PATTERN "config.h" EXCLUDE
1033     PATTERN ".svn" EXCLUDE
1034     )
1035
1036   if (LLVM_INSTALL_MODULEMAPS)
1037     install(DIRECTORY include/llvm include/llvm-c
1038             DESTINATION include
1039             COMPONENT llvm-headers
1040             FILES_MATCHING
1041             PATTERN "module.modulemap"
1042             )
1043     install(FILES include/llvm/module.install.modulemap
1044             DESTINATION include/llvm
1045             COMPONENT llvm-headers
1046             RENAME "module.extern.modulemap"
1047             )
1048   endif(LLVM_INSTALL_MODULEMAPS)
1049
1050   # Installing the headers needs to depend on generating any public
1051   # tablegen'd headers.
1052   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
1053   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
1054
1055   if (NOT LLVM_ENABLE_IDE)
1056     add_llvm_install_targets(install-llvm-headers
1057                              DEPENDS llvm-headers
1058                              COMPONENT llvm-headers)
1059   endif()
1060
1061   # Custom target to install all libraries.
1062   add_custom_target(llvm-libraries)
1063   set_target_properties(llvm-libraries PROPERTIES FOLDER "Misc")
1064
1065   if (NOT LLVM_ENABLE_IDE)
1066     add_llvm_install_targets(install-llvm-libraries
1067                              DEPENDS llvm-libraries
1068                              COMPONENT llvm-libraries)
1069   endif()
1070
1071   get_property(LLVM_LIBS GLOBAL PROPERTY LLVM_LIBS)
1072   if(LLVM_LIBS)
1073     list(REMOVE_DUPLICATES LLVM_LIBS)
1074     foreach(lib ${LLVM_LIBS})
1075       add_dependencies(llvm-libraries ${lib})
1076       if (NOT LLVM_ENABLE_IDE)
1077         add_dependencies(install-llvm-libraries install-${lib})
1078       endif()
1079     endforeach()
1080   endif()
1081 endif()
1082
1083 # This must be at the end of the LLVM root CMakeLists file because it must run
1084 # after all targets are created.
1085 include(LLVMDistributionSupport)
1086 llvm_distribution_add_targets()
1087
1088 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1089 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1090   include(InstallRequiredSystemLibraries)
1091 endif()
1092
1093 if (LLVM_INCLUDE_BENCHMARKS)
1094   # Override benchmark defaults so that when the library itself is updated these
1095   # modifications are not lost.
1096   set(BENCHMARK_ENABLE_TESTING OFF CACHE BOOL "Disable benchmark testing" FORCE)
1097   set(BENCHMARK_ENABLE_EXCEPTIONS OFF CACHE BOOL "Disable benchmark exceptions" FORCE)
1098   set(BENCHMARK_ENABLE_INSTALL OFF CACHE BOOL "Don't install benchmark" FORCE)
1099   set(BENCHMARK_DOWNLOAD_DEPENDENCIES OFF CACHE BOOL "Don't download dependencies" FORCE)
1100   set(BENCHMARK_ENABLE_GTEST_TESTS OFF CACHE BOOL "Disable Google Test in benchmark" FORCE)
1101   # Since LLVM requires C++11 it is safe to assume that std::regex is available.
1102   set(HAVE_STD_REGEX ON CACHE BOOL "OK" FORCE)
1103
1104   add_subdirectory(utils/benchmark)
1105   add_subdirectory(benchmarks)
1106 endif()