test/Other/cgscc-libcall-update.ll

   1 ; Make sure that the CGSCC pass manager can handle when instcombine simplifies
   2 ; one libcall into an unrelated libcall and update the call graph accordingly.
   3 ;
   4 ; Also check that it can handle inlining *removing* a libcall entirely.
   5 ;
   6 ; Finally, we include some recursive patterns and forced analysis invaliadtion
   7 ; that can trigger infinite CGSCC refinement if not handled correctly.
   8 ;
   9 ; RUN: opt -passes='cgscc(inline,function(instcombine,invalidate<all>))' -S < %s | FileCheck %s
  10
  11 define i8* @wibble(i8* %arg1, i8* %arg2) {
  12 ; CHECK-LABEL: define i8* @wibble(
  13 bb:
  14   %tmp = alloca [1024 x i8], align 16
  15   %tmp2 = getelementptr inbounds [1024 x i8], [1024 x i8]* %tmp, i64 0, i64 0
  16   call void @llvm.memcpy.p0i8.p0i8.i64(i8* %tmp2, i8* %arg1, i64 1024, i1 false)
  17 ; CHECK:         call void @llvm.memcpy
  18   %tmp3 = call i64 @llvm.objectsize.i64.p0i8(i8* %tmp2, i1 false, i1 true)
  19   %tmp4 = call i8* @__strncpy_chk(i8* %arg2, i8* %tmp2, i64 1023, i64 %tmp3)
  20 ; CHECK-NOT:     call
  21 ; CHECK:         call i8* @strncpy(i8* %arg2, i8* nonnull %tmp2, i64 1023)
  22 ; CHECK-NOT:     call
  23
  24   ret i8* %tmp4
  25 ; CHECK:         ret
  26 }
  27
  28 define i8* @strncpy(i8* %arg1, i8* %arg2, i64 %size) noinline {
  29 bb:
  30   %result = call i8* @my_special_strncpy(i8* %arg1, i8* %arg2, i64 %size)
  31   ret i8* %result
  32 }
  33
  34 declare i8* @my_special_strncpy(i8* %arg1, i8* %arg2, i64 %size)
  35
  36 declare i64 @llvm.objectsize.i64.p0i8(i8*, i1, i1)
  37
  38 declare i8* @__strncpy_chk(i8*, i8*, i64, i64)
  39
  40 declare void @llvm.memcpy.p0i8.p0i8.i64(i8* nocapture writeonly, i8* nocapture readonly, i64, i1)
  41
  42 ; Check that even when we completely remove a libcall we don't get the call
  43 ; graph wrong once we handle libcalls in the call graph specially to address
  44 ; the above case.
  45 define i32 @hoge(i32* %arg1) {
  46 ; CHECK-LABEL: define i32 @hoge(
  47 bb:
  48   %tmp41 = load i32*, i32** null
  49   %tmp6 = load i32, i32* %arg1
  50   %tmp7 = call i32 @ntohl(i32 %tmp6)
  51 ; CHECK-NOT: call i32 @ntohl
  52   ret i32 %tmp7
  53 ; CHECK: ret i32
  54 }
  55
  56 ; Even though this function is not used, it should be retained as it may be
  57 ; used when doing further libcall transformations.
  58 define internal i32 @ntohl(i32 %x) {
  59 ; CHECK-LABEL: define internal i32 @ntohl(
  60 entry:
  61   %and2 = lshr i32 %x, 8
  62   %shr = and i32 %and2, 65280
  63   ret i32 %shr
  64 }
  65
  66 define i64 @write(i32 %i, i8* %p, i64 %j) {
  67 entry:
  68   %val = call i64 @write_wrapper(i32 %i, i8* %p, i64 %j) noinline
  69   ret i64 %val
  70 }
  71
  72 define i64 @write_wrapper(i32 %i, i8* %p, i64 %j) {
  73 entry:
  74   %val = call i64 @write(i32 %i, i8* %p, i64 %j) noinline
  75   ret i64 %val
  76 }