llvm/test/Transforms/LoopDistribute/crash-in-memcheck-generation.ll

   1 ; RUN: opt -passes=loop-distribute,loop-vectorize -enable-loop-distribute -force-vector-width=4 \
   2 ; RUN:   -verify-loop-info -verify-dom-info -S < %s | FileCheck %s
   3
   4 ; If only A and B can alias here, we don't need memchecks to distribute since
   5 ; A and B are in the same partition.  This used to cause a crash in the
   6 ; memcheck generation.
   7 ;
   8 ;   for (i = 0; i < n; i++) {
   9 ;     A[i + 1] = A[i] * B[i];
  10 ; ------------------------------
  11 ;     C[i] = D[i] * E[i];
  12 ;   }
  13
  14 target datalayout = "e-m:o-i64:64-f80:128-n8:16:32:64-S128"
  15 target triple = "x86_64-apple-macosx10.10.0"
  16
  17 define void @f(ptr  %a,
  18                ptr  %b,
  19                ptr noalias %c,
  20                ptr noalias %d,
  21                ptr noalias %e) {
  22 entry:
  23   br label %for.body
  24
  25 ; CHECK-NOT: memcheck:
  26 ; CHECK: mul <4 x i32>
  27
  28 for.body:                                         ; preds = %for.body, %entry
  29   %ind = phi i64 [ 0, %entry ], [ %add, %for.body ]
  30
  31   %arrayidxA = getelementptr inbounds i32, ptr %a, i64 %ind
  32   %loadA = load i32, ptr %arrayidxA, align 4
  33
  34   %arrayidxB = getelementptr inbounds i32, ptr %b, i64 %ind
  35   %loadB = load i32, ptr %arrayidxB, align 4
  36
  37   %mulA = mul i32 %loadB, %loadA
  38
  39   %add = add nuw nsw i64 %ind, 1
  40   %arrayidxA_plus_4 = getelementptr inbounds i32, ptr %a, i64 %add
  41   store i32 %mulA, ptr %arrayidxA_plus_4, align 4
  42
  43   %arrayidxD = getelementptr inbounds i32, ptr %d, i64 %ind
  44   %loadD = load i32, ptr %arrayidxD, align 4
  45
  46   %arrayidxE = getelementptr inbounds i32, ptr %e, i64 %ind
  47   %loadE = load i32, ptr %arrayidxE, align 4
  48
  49   %mulC = mul i32 %loadD, %loadE
  50
  51   %arrayidxC = getelementptr inbounds i32, ptr %c, i64 %ind
  52   store i32 %mulC, ptr %arrayidxC, align 4
  53
  54   %exitcond = icmp eq i64 %add, 20
  55   br i1 %exitcond, label %for.end, label %for.body
  56
  57 for.end:                                          ; preds = %for.body
  58   ret void
  59 }