libc/benchmarks/CMakeLists.txt

   1 find_package(Threads)
   2
   3 set(LLVM_LINK_COMPONENTS
   4   Support
   5   TargetParser
   6   )
   7
   8 #==============================================================================
   9 # Add Unit Testing Support
  10 #==============================================================================
  11
  12 function(add_libc_benchmark_unittest target_name)
  13   if(NOT LLVM_INCLUDE_TESTS)
  14     return()
  15   endif()
  16
  17   cmake_parse_arguments(
  18     "LIBC_BENCHMARKS_UNITTEST"
  19     "" # No optional arguments
  20     "SUITE" # Single value arguments
  21     "SRCS;DEPENDS" # Multi-value arguments
  22     ${ARGN}
  23   )
  24
  25   add_executable(${target_name}
  26     EXCLUDE_FROM_ALL
  27     ${LIBC_BENCHMARKS_UNITTEST_SRCS}
  28   )
  29   target_link_libraries(${target_name}
  30     PRIVATE
  31     llvm_gtest_main
  32     llvm_gtest
  33     ${LIBC_BENCHMARKS_UNITTEST_DEPENDS}
  34   )
  35   llvm_update_compile_flags(${target_name})
  36
  37   add_custom_command(
  38     TARGET ${target_name}
  39     POST_BUILD
  40     COMMAND $<TARGET_FILE:${target_name}>
  41   )
  42   add_dependencies(libc-benchmark-util-tests ${target_name})
  43 endfunction()
  44
  45 #==============================================================================
  46 # Build Google Benchmark for libc
  47 #==============================================================================
  48
  49 include(ExternalProject)
  50 ExternalProject_Add(google-benchmark-libc
  51         EXCLUDE_FROM_ALL ON
  52         PREFIX google-benchmark-libc
  53         SOURCE_DIR ${LLVM_THIRD_PARTY_DIR}/benchmark
  54         INSTALL_DIR ${CMAKE_CURRENT_BINARY_DIR}/google-benchmark-libc
  55         CMAKE_CACHE_ARGS
  56           -DBENCHMARK_ENABLE_EXCEPTIONS:BOOL=OFF
  57           -DBENCHMARK_ENABLE_LTO:BOOL=OFF
  58           -DBENCHMARK_ENABLE_TESTING:BOOL=OFF
  59           -DBENCHMARK_ENABLE_WERROR:BOOL=${LLVM_ENABLE_WERROR}
  60           -DBENCHMARK_FORCE_WERROR:BOOL=OFF
  61           -DBENCHMARK_USE_LIBCXX:BOOL=OFF
  62           -DCMAKE_BUILD_TYPE:STRING=RELEASE
  63           -DCMAKE_C_COMPILER:STRING=${CMAKE_C_COMPILER}
  64           -DCMAKE_CXX_COMPILER:STRING=${CMAKE_CXX_COMPILER}
  65           -DCMAKE_CXX_FLAGS:STRING=${BENCHMARK_LIBC_COMPILE_FLAGS}
  66           -DCMAKE_CXX_STANDARD:STRING=14
  67           -DCMAKE_INSTALL_PREFIX:PATH=<INSTALL_DIR>
  68         )
  69
  70 add_custom_target(libc-benchmark-util-tests)
  71
  72 # libc-benchmark
  73 add_library(libc-benchmark
  74     STATIC
  75     EXCLUDE_FROM_ALL
  76     LibcBenchmark.cpp
  77     LibcBenchmark.h
  78 )
  79
  80 target_link_libraries(libc-benchmark
  81     PUBLIC
  82     benchmark::benchmark
  83     LLVMSupport
  84     LLVMTargetParser
  85     Threads::Threads
  86 )
  87 add_dependencies(libc-benchmark google-benchmark-libc)
  88 llvm_update_compile_flags(libc-benchmark)
  89
  90 add_libc_benchmark_unittest(libc-benchmark-test
  91     SRCS LibcBenchmarkTest.cpp
  92     DEPENDS libc-benchmark
  93 )
  94
  95 # libc-memory-benchmark
  96 add_library(libc-memory-benchmark
  97     STATIC
  98     EXCLUDE_FROM_ALL
  99     LibcMemoryBenchmark.cpp
 100     LibcMemoryBenchmark.h
 101     LibcFunctionPrototypes.h
 102     MemorySizeDistributions.cpp
 103     MemorySizeDistributions.h
 104 )
 105 target_include_directories(libc-memory-benchmark
 106     PUBLIC
 107     ${CMAKE_CURRENT_SOURCE_DIR}
 108 )
 109 target_link_libraries(libc-memory-benchmark
 110     PUBLIC
 111     libc-benchmark
 112 )
 113 llvm_update_compile_flags(libc-memory-benchmark)
 114
 115 add_libc_benchmark_unittest(libc-memory-benchmark-test
 116     SRCS LibcMemoryBenchmarkTest.cpp
 117     DEPENDS libc-memory-benchmark
 118 )
 119
 120 # json
 121 add_library(json
 122     STATIC
 123     EXCLUDE_FROM_ALL
 124     JSON.cpp
 125     JSON.h
 126 )
 127 target_link_libraries(json PUBLIC libc-memory-benchmark)
 128 llvm_update_compile_flags(json)
 129
 130 add_libc_benchmark_unittest(json-test
 131     SRCS JSONTest.cpp
 132     DEPENDS json
 133 )
 134
 135 #==============================================================================
 136 # Benchmarking tool
 137 #==============================================================================
 138
 139 # Benchmark all implementations that can run on the target CPU.
 140 function(add_libc_multi_impl_benchmark name)
 141   get_property(fq_implementations GLOBAL PROPERTY ${name}_implementations)
 142   foreach(fq_config_name IN LISTS fq_implementations)
 143     get_target_property(required_cpu_features ${fq_config_name} REQUIRE_CPU_FEATURES)
 144     cpu_supports(can_run "${required_cpu_features}")
 145     if(can_run)
 146         set(benchmark_name ${fq_config_name}_benchmark)
 147         add_executable(${benchmark_name}
 148             EXCLUDE_FROM_ALL
 149             LibcMemoryBenchmarkMain.cpp
 150         )
 151         get_target_property(entrypoint_object_file ${fq_config_name} "OBJECT_FILE_RAW")
 152         target_link_libraries(${benchmark_name} PUBLIC json ${entrypoint_object_file})
 153         string(TOUPPER ${name} name_upper)
 154         target_compile_definitions(${benchmark_name} PRIVATE "-DLIBC_BENCHMARK_FUNCTION_${name_upper}=__llvm_libc::${name}" "-DLIBC_BENCHMARK_FUNCTION_NAME=\"${fq_config_name}\"")
 155         llvm_update_compile_flags(${benchmark_name})
 156     else()
 157       message(STATUS "Skipping benchmark for '${fq_config_name}' insufficient host cpu features '${required_cpu_features}'")
 158     endif()
 159   endforeach()
 160 endfunction()
 161
 162 add_libc_multi_impl_benchmark(bcmp)
 163 add_libc_multi_impl_benchmark(bzero)
 164 add_libc_multi_impl_benchmark(memcmp)
 165 add_libc_multi_impl_benchmark(memcpy)
 166 add_libc_multi_impl_benchmark(memmove)
 167 add_libc_multi_impl_benchmark(memset)
 168
 169 #==============================================================================
 170 # Google Benchmarking tool
 171 #==============================================================================
 172
 173 # This target uses the Google Benchmark facility to report throughput for llvm
 174 # libc memory functions compiled for the host machine. This is useful to
 175 # continuously monitor the performance of the memory functions.
 176 add_executable(libc.benchmarks.memory_functions.opt_host
 177   EXCLUDE_FROM_ALL
 178   LibcMemoryGoogleBenchmarkMain.cpp
 179   LibcDefaultImplementations.cpp
 180 )
 181 target_link_libraries(libc.benchmarks.memory_functions.opt_host
 182   PRIVATE
 183   libc-memory-benchmark
 184   libc.src.string.memcmp_opt_host
 185   libc.src.string.bcmp_opt_host
 186   libc.src.string.memcpy_opt_host
 187   libc.src.string.memset_opt_host
 188   libc.src.string.bzero_opt_host
 189   libc.src.string.memmove_opt_host
 190   benchmark_main
 191 )
 192 llvm_update_compile_flags(libc.benchmarks.memory_functions.opt_host)
 193
 194 add_subdirectory(automemcpy)