llvm/test/ThinLTO/X86/devirt_external_comdat_same_guid.ll

   1 ; REQUIRES: x86-registered-target
   2
   3 ; Test that index-based devirtualization in the presence of external
   4 ; vtables with the same name (with comdat) succeeds.
   5
   6 ; Generate unsplit module with summary for ThinLTO index-based WPD.
   7 ; RUN: opt -thinlto-bc -o %t3.o %s
   8 ; RUN: opt -thinlto-bc -o %t4.o %p/Inputs/devirt_external_comdat_same_guid.ll
   9
  10 ; RUN: llvm-lto2 run %t3.o %t4.o -save-temps -pass-remarks=. \
  11 ; RUN:   -whole-program-visibility \
  12 ; RUN:   -wholeprogramdevirt-print-index-based \
  13 ; RUN:   -o %t5 \
  14 ; RUN:   -r=%t3.o,use_B,px \
  15 ; RUN:   -r=%t3.o,test,px \
  16 ; RUN:   -r=%t3.o,_ZTV1B,px \
  17 ; RUN:   -r=%t3.o,_ZN1B1fEi,px \
  18 ; RUN:   -r=%t3.o,_ZN1B1nEi,px \
  19 ; RUN:   -r=%t4.o,_ZTV1B,x \
  20 ; RUN:   -r=%t4.o,_ZN1B1fEi,x \
  21 ; RUN:   -r=%t4.o,_ZN1A1nEi,x \
  22 ; RUN:   -r=%t4.o,test2,px \
  23 ; RUN:   2>&1 | FileCheck %s --check-prefix=REMARK --check-prefix=PRINT
  24 ; RUN: llvm-dis %t5.1.4.opt.bc -o - | FileCheck %s --check-prefix=CHECK-IR1
  25 ; RUN: llvm-dis %t5.2.4.opt.bc -o - | FileCheck %s --check-prefix=CHECK-IR2
  26
  27 ; PRINT-DAG: Devirtualized call to {{.*}} (_ZN1A1nEi)
  28
  29 ; REMARK-DAG: single-impl: devirtualized a call to _ZN1A1nEi
  30
  31 target datalayout = "e-m:e-p270:32:32-p271:32:32-p272:64:64-i64:64-f80:128-n8:16:32:64-S128"
  32 target triple = "x86_64-grtev4-linux-gnu"
  33
  34 source_filename = "-"
  35
  36 %struct.A = type { ptr }
  37 %struct.B = type { %struct.A }
  38
  39 $_ZTV1B = comdat any
  40
  41 @_ZTV1B = constant { [4 x ptr] } { [4 x ptr] [ptr null, ptr undef, ptr @_ZN1B1fEi, ptr @_ZN1B1nEi] }, comdat, !type !0, !type !1
  42
  43 define i32 @_ZN1B1fEi(ptr %this, i32 %a) #0 comdat($_ZTV1B) {
  44    ret i32 0;
  45 }
  46
  47 define i32 @_ZN1B1nEi(ptr %this, i32 %a) #0 comdat($_ZTV1B) {
  48    ret i32 0;
  49 }
  50
  51 ; Ensures that vtable of B is live so that we will attempt devirt.
  52 define dso_local i32 @use_B(ptr %a) {
  53 entry:
  54   store ptr getelementptr inbounds ({ [4 x ptr] }, ptr @_ZTV1B, i64 0, i32 0, i64 2), ptr %a, align 8
  55   ret i32 0
  56 }
  57
  58 ; CHECK-IR1: define i32 @test(
  59 define i32 @test(ptr %obj, i32 %a) {
  60 entry:
  61   %vtable = load ptr, ptr %obj
  62   %p = call i1 @llvm.type.test(ptr %vtable, metadata !"_ZTS1A")
  63   call void @llvm.assume(i1 %p)
  64   %fptrptr = getelementptr ptr, ptr %vtable, i32 1
  65   %fptr1 = load ptr, ptr %fptrptr, align 8
  66
  67   ; Check that the call was devirtualized.
  68   ; CHECK-IR1: tail call i32 {{.*}}@_ZN1A1nEi
  69   %call = tail call i32 %fptr1(ptr nonnull %obj, i32 %a)
  70
  71   ret i32 %call
  72 }
  73
  74 ; CHECK-IR2: define i32 @test2
  75 ; Check that the call was devirtualized.
  76 ; CHECK-IR2:   tail call i32 @_ZN1A1nEi
  77
  78 declare i1 @llvm.type.test(ptr, metadata)
  79 declare void @llvm.assume(i1)
  80
  81 attributes #0 = { noinline optnone }
  82
  83 !0 = !{i64 16, !"_ZTS1A"}
  84 !1 = !{i64 16, !"_ZTS1B"}