llvm/test/Analysis/Delinearization/multidim_ivs_and_parameteric_offsets_3d.ll

   1 ; RUN: opt < %s -passes='print<delinearization>' -disable-output 2>&1 | FileCheck %s
   2
   3 ; void foo(long n, long m, long o, double A[n][m][o], long p, long q, long r) {
   4 ;
   5 ;   for (long i = 0; i < n; i++)
   6 ;     for (long j = 0; j < m; j++)
   7 ;       for (long k = 0; k < o; k++)
   8 ;         A[i+p][j+q][k+r] = 1.0;
   9 ; }
  10
  11 ; AddRec: {{{((8 * ((((%m * %p) + %q) * %o) + %r)) + %A),+,(8 * %m * %o)}<%for.i>,+,(8 * %o)}<%for.j>,+,8}<%for.k>
  12 ; CHECK: Base offset: %A
  13 ; CHECK: ArrayDecl[UnknownSize][%m][%o] with elements of 8 bytes.
  14 ; CHECK: ArrayRef[{%p,+,1}<nw><%for.i>][{%q,+,1}<nsw><%for.j>][{%r,+,1}<nsw><%for.k>]
  15
  16 define void @foo(i64 %n, i64 %m, i64 %o, ptr %A, i64 %p, i64 %q, i64 %r) {
  17 entry:
  18   br label %for.i
  19
  20 for.i:
  21   %i = phi i64 [ 0, %entry ], [ %i.inc, %for.i.inc ]
  22   br label %for.j
  23
  24 for.j:
  25   %j = phi i64 [ 0, %for.i ], [ %j.inc, %for.j.inc ]
  26   br label %for.k
  27
  28 for.k:
  29   %k = phi i64 [ 0, %for.j ], [ %k.inc, %for.k.inc ]
  30   %offset0 = add nsw i64 %i, %p
  31   %subscript0 = mul i64 %offset0, %m
  32   %offset1 = add nsw i64 %j, %q
  33   %subscript1 = add i64 %offset1, %subscript0
  34   %subscript2 = mul i64 %subscript1, %o
  35   %offset2 = add nsw i64 %k, %r
  36   %subscript = add i64 %subscript2, %offset2
  37   %idx = getelementptr inbounds double, ptr %A, i64 %subscript
  38   store double 1.0, ptr %idx
  39   br label %for.k.inc
  40
  41 for.k.inc:
  42   %k.inc = add nsw i64 %k, 1
  43   %k.exitcond = icmp eq i64 %k.inc, %o
  44   br i1 %k.exitcond, label %for.j.inc, label %for.k
  45
  46 for.j.inc:
  47   %j.inc = add nsw i64 %j, 1
  48   %j.exitcond = icmp eq i64 %j.inc, %m
  49   br i1 %j.exitcond, label %for.i.inc, label %for.j
  50
  51 for.i.inc:
  52   %i.inc = add nsw i64 %i, 1
  53   %i.exitcond = icmp eq i64 %i.inc, %n
  54   br i1 %i.exitcond, label %end, label %for.i
  55
  56 end:
  57   ret void
  58 }