llvm/test/CodeGen/X86/shrink-wrap-chkstk.ll

   1 ; RUN: llc < %s -enable-shrink-wrap=true | FileCheck %s
   2
   3 ; TODO: add preallocated versions of tests
   4 ; we don't yet support conditionally called preallocated calls after the setup
   5
   6 ; chkstk cannot come before the usual prologue, since it adjusts ESP.
   7 ; If chkstk is used in the prologue, we also have to be careful about preserving
   8 ; EAX if it is used.
   9
  10 target datalayout = "e-m:x-p:32:32-i64:64-f80:32-n8:16:32-a:0:32-S32"
  11 target triple = "i686-pc-windows-msvc18.0.0"
  12
  13 %struct.S = type { [8192 x i8] }
  14
  15 define x86_thiscallcc void @call_inalloca(i1 %x) {
  16 entry:
  17   %argmem = alloca inalloca <{ %struct.S }>, align 4
  18   %argidx2 = getelementptr inbounds <{ %struct.S }>, ptr %argmem, i32 0, i32 0, i32 0, i32 1
  19   store i8 42, ptr %argidx2, align 4
  20   br i1 %x, label %bb1, label %bb2
  21
  22 bb1:
  23   store i8 42, ptr %argmem, align 4
  24   br label %bb2
  25
  26 bb2:
  27   call void @inalloca_params(ptr inalloca(<{ %struct.S }>) nonnull %argmem)
  28   ret void
  29 }
  30
  31 ; CHECK-LABEL: _call_inalloca: # @call_inalloca
  32 ; CHECK: pushl %ebp
  33 ; CHECK: movl %esp, %ebp
  34 ; CHECK: movl $8192, %eax
  35 ; CHECK: calll __chkstk
  36 ; CHECK: calll _inalloca_params
  37 ; CHECK: movl %ebp, %esp
  38 ; CHECK: popl %ebp
  39 ; CHECK: retl
  40
  41 declare void @inalloca_params(ptr inalloca(<{ %struct.S }>))
  42
  43 declare i32 @doSomething(i32, ptr)
  44
  45 ; In this test case, we force usage of EAX before the prologue, and have to
  46 ; compensate before calling __chkstk. It would also be valid for us to avoid
  47 ; shrink wrapping in this case.
  48
  49 define x86_fastcallcc i32 @use_eax_before_prologue(i32 inreg %a, i32 inreg %b) {
  50   %tmp = alloca i32, i32 1024, align 4
  51   %tmp2 = icmp slt i32 %a, %b
  52   br i1 %tmp2, label %true, label %false
  53
  54 true:
  55   store i32 %a, ptr %tmp, align 4
  56   %tmp4 = call i32 @doSomething(i32 0, ptr %tmp)
  57   br label %false
  58
  59 false:
  60   %tmp.0 = phi i32 [ %tmp4, %true ], [ %a, %0 ]
  61   ret i32 %tmp.0
  62 }
  63
  64 ; CHECK-LABEL: @use_eax_before_prologue@8: # @use_eax_before_prologue
  65 ; CHECK: movl %ecx, %eax
  66 ; CHECK: cmpl %edx, %ecx
  67 ; CHECK: jge LBB1_2
  68 ; CHECK: pushl %eax
  69 ; CHECK: movl $4092, %eax
  70 ; CHECK: calll __chkstk
  71 ; CHECK: movl 4092(%esp), %eax
  72 ; CHECK: calll _doSomething
  73 ; CHECK: LBB1_2:
  74 ; CHECK: retl