llvm/cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckLibraryExists)
   8 include(CheckSymbolExists)
   9 include(CheckCXXSymbolExists)
  10 include(CheckFunctionExists)
  11 include(CheckStructHasMember)
  12 include(CheckCCompilerFlag)
  13 include(CMakePushCheckState)
  14
  15 include(CheckCompilerVersion)
  16 include(CheckProblematicConfigurations)
  17 include(HandleLLVMStdlib)
  18
  19 if( UNIX AND NOT (APPLE OR BEOS OR HAIKU) )
  20   # Used by check_symbol_exists:
  21   list(APPEND CMAKE_REQUIRED_LIBRARIES "m")
  22 endif()
  23 # x86_64 FreeBSD 9.2 requires libcxxrt to be specified explicitly.
  24 if( CMAKE_SYSTEM MATCHES "FreeBSD-9.2-RELEASE" AND
  25     CMAKE_SIZEOF_VOID_P EQUAL 8 )
  26   list(APPEND CMAKE_REQUIRED_LIBRARIES "cxxrt")
  27 endif()
  28
  29 # Do checks with _XOPEN_SOURCE and large-file API on AIX, because we will build
  30 # with those too.
  31 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
  32           list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_XOPEN_SOURCE=700")
  33           list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_LARGE_FILE_API")
  34 endif()
  35
  36 # Do checks with _FILE_OFFSET_BITS=64 on Solaris, because we will build
  37 # with those too.
  38 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  39           list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_FILE_OFFSET_BITS=64")
  40 endif()
  41
  42 # include checks
  43 check_include_file(dlfcn.h HAVE_DLFCN_H)
  44 check_include_file(errno.h HAVE_ERRNO_H)
  45 check_include_file(fcntl.h HAVE_FCNTL_H)
  46 check_include_file(link.h HAVE_LINK_H)
  47 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  48 if( NOT PURE_WINDOWS )
  49   check_include_file(pthread.h HAVE_PTHREAD_H)
  50 endif()
  51 check_include_file(signal.h HAVE_SIGNAL_H)
  52 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  53 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  54 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  55 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  56 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  57 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  58 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  59 check_include_file(sysexits.h HAVE_SYSEXITS_H)
  60 check_include_file(termios.h HAVE_TERMIOS_H)
  61 check_include_file(unistd.h HAVE_UNISTD_H)
  62 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  63 check_include_file(fenv.h HAVE_FENV_H)
  64 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  65 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  66
  67 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  68 check_include_file(CrashReporterClient.h HAVE_CRASHREPORTERCLIENT_H)
  69 if(APPLE)
  70   include(CheckCSourceCompiles)
  71   CHECK_C_SOURCE_COMPILES("
  72      static const char *__crashreporter_info__ = 0;
  73      asm(\".desc ___crashreporter_info__, 0x10\");
  74      int main() { return 0; }"
  75     HAVE_CRASHREPORTER_INFO)
  76 endif()
  77
  78 if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
  79   check_include_file(linux/magic.h HAVE_LINUX_MAGIC_H)
  80   if(NOT HAVE_LINUX_MAGIC_H)
  81     # older kernels use split files
  82     check_include_file(linux/nfs_fs.h HAVE_LINUX_NFS_FS_H)
  83     check_include_file(linux/smb.h HAVE_LINUX_SMB_H)
  84   endif()
  85 endif()
  86
  87 # library checks
  88 if( NOT PURE_WINDOWS )
  89   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  90   if (HAVE_LIBPTHREAD)
  91     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  92     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  93   else()
  94     # this could be Android
  95     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  96     if (PTHREAD_IN_LIBC)
  97       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  98       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  99     endif()
 100   endif()
 101   check_library_exists(dl dlopen "" HAVE_LIBDL)
 102   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 103 endif()
 104
 105 # Check for libpfm.
 106 include(FindLibpfm)
 107
 108 if(HAVE_LIBPTHREAD)
 109   # We want to find pthreads library and at the moment we do want to
 110   # have it reported as '-l<lib>' instead of '-pthread'.
 111   # TODO: switch to -pthread once the rest of the build system can deal with it.
 112   set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
 113   set(THREADS_HAVE_PTHREAD_ARG Off)
 114   find_package(Threads REQUIRED)
 115   set(LLVM_PTHREAD_LIB ${CMAKE_THREAD_LIBS_INIT})
 116 endif()
 117
 118 if(LLVM_ENABLE_ZLIB)
 119   if(LLVM_ENABLE_ZLIB STREQUAL FORCE_ON)
 120     find_package(ZLIB REQUIRED)
 121   elseif(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 122     find_package(ZLIB)
 123   endif()
 124   if(ZLIB_FOUND)
 125     # Check if zlib we found is usable; for example, we may have found a 32-bit
 126     # library on a 64-bit system which would result in a link-time failure.
 127     cmake_push_check_state()
 128     list(APPEND CMAKE_REQUIRED_INCLUDES ${ZLIB_INCLUDE_DIRS})
 129     list(APPEND CMAKE_REQUIRED_LIBRARIES ${ZLIB_LIBRARY})
 130     check_symbol_exists(compress2 zlib.h HAVE_ZLIB)
 131     cmake_pop_check_state()
 132     if(LLVM_ENABLE_ZLIB STREQUAL FORCE_ON AND NOT HAVE_ZLIB)
 133       message(FATAL_ERROR "Failed to configure zlib")
 134     endif()
 135   endif()
 136   set(LLVM_ENABLE_ZLIB "${HAVE_ZLIB}")
 137 else()
 138   set(LLVM_ENABLE_ZLIB 0)
 139 endif()
 140
 141 set(zstd_FOUND 0)
 142 if(LLVM_ENABLE_ZSTD)
 143   if(LLVM_ENABLE_ZSTD STREQUAL FORCE_ON)
 144     find_package(zstd REQUIRED)
 145     if(NOT zstd_FOUND)
 146       message(FATAL_ERROR "Failed to configure zstd, but LLVM_ENABLE_ZSTD is FORCE_ON")
 147     endif()
 148   elseif(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 149     find_package(zstd QUIET)
 150   endif()
 151 endif()
 152 set(LLVM_ENABLE_ZSTD ${zstd_FOUND})
 153
 154 if(LLVM_ENABLE_LIBXML2)
 155   if(LLVM_ENABLE_LIBXML2 STREQUAL FORCE_ON)
 156     find_package(LibXml2 REQUIRED)
 157   elseif(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 158     find_package(LibXml2)
 159   endif()
 160   if(LibXml2_FOUND)
 161     # Check if libxml2 we found is usable; for example, we may have found a 32-bit
 162     # library on a 64-bit system which would result in a link-time failure.
 163     cmake_push_check_state()
 164     list(APPEND CMAKE_REQUIRED_INCLUDES ${LIBXML2_INCLUDE_DIRS})
 165     list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBXML2_LIBRARIES})
 166     list(APPEND CMAKE_REQUIRED_DEFINITIONS ${LIBXML2_DEFINITIONS})
 167     check_symbol_exists(xmlReadMemory libxml/xmlreader.h HAVE_LIBXML2)
 168     cmake_pop_check_state()
 169     if(LLVM_ENABLE_LIBXML2 STREQUAL FORCE_ON AND NOT HAVE_LIBXML2)
 170       message(FATAL_ERROR "Failed to configure libxml2")
 171     endif()
 172   endif()
 173   set(LLVM_ENABLE_LIBXML2 "${HAVE_LIBXML2}")
 174 endif()
 175
 176 if(LLVM_ENABLE_CURL)
 177   if(LLVM_ENABLE_CURL STREQUAL FORCE_ON)
 178     find_package(CURL REQUIRED)
 179   else()
 180     find_package(CURL)
 181   endif()
 182   if(CURL_FOUND)
 183     # Check if curl we found is usable; for example, we may have found a 32-bit
 184     # library on a 64-bit system which would result in a link-time failure.
 185     cmake_push_check_state()
 186     list(APPEND CMAKE_REQUIRED_LIBRARIES CURL::libcurl)
 187     check_symbol_exists(curl_easy_init curl/curl.h HAVE_CURL)
 188     cmake_pop_check_state()
 189     if(LLVM_ENABLE_CURL STREQUAL FORCE_ON AND NOT HAVE_CURL)
 190       message(FATAL_ERROR "Failed to configure curl")
 191     endif()
 192   endif()
 193   set(LLVM_ENABLE_CURL "${HAVE_CURL}")
 194 endif()
 195
 196 if(LLVM_ENABLE_HTTPLIB)
 197   if(LLVM_ENABLE_HTTPLIB STREQUAL FORCE_ON)
 198     find_package(httplib REQUIRED)
 199   else()
 200     find_package(httplib)
 201   endif()
 202   if(HTTPLIB_FOUND)
 203     # Check if the "httplib" we found is usable; for example there may be another
 204     # library with the same name.
 205     cmake_push_check_state()
 206     list(APPEND CMAKE_REQUIRED_LIBRARIES ${HTTPLIB_LIBRARY})
 207     check_cxx_symbol_exists(CPPHTTPLIB_HTTPLIB_H ${HTTPLIB_HEADER_PATH} HAVE_HTTPLIB)
 208     cmake_pop_check_state()
 209     if(LLVM_ENABLE_HTTPLIB STREQUAL FORCE_ON AND NOT HAVE_HTTPLIB)
 210       message(FATAL_ERROR "Failed to configure cpp-httplib")
 211     endif()
 212   endif()
 213   set(LLVM_ENABLE_HTTPLIB "${HAVE_HTTPLIB}")
 214 endif()
 215
 216 # Don't look for these libraries if we're using MSan, since uninstrumented third
 217 # party code may call MSan interceptors like strlen, leading to false positives.
 218 if(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 219   # Don't look for these libraries on Windows.
 220   if (NOT PURE_WINDOWS)
 221     # Skip libedit if using ASan as it contains memory leaks.
 222     if (LLVM_ENABLE_LIBEDIT AND NOT LLVM_USE_SANITIZER MATCHES ".*Address.*")
 223       find_package(LibEdit)
 224       set(HAVE_LIBEDIT ${LibEdit_FOUND})
 225     else()
 226       set(HAVE_LIBEDIT 0)
 227     endif()
 228     if(LLVM_ENABLE_TERMINFO)
 229       if(LLVM_ENABLE_TERMINFO STREQUAL FORCE_ON)
 230         find_package(Terminfo REQUIRED)
 231       else()
 232         find_package(Terminfo)
 233       endif()
 234       set(LLVM_ENABLE_TERMINFO "${Terminfo_FOUND}")
 235     endif()
 236   else()
 237     set(LLVM_ENABLE_TERMINFO 0)
 238   endif()
 239 else()
 240   set(LLVM_ENABLE_TERMINFO 0)
 241 endif()
 242
 243 check_library_exists(xar xar_open "" LLVM_HAVE_LIBXAR)
 244 if(LLVM_HAVE_LIBXAR)
 245   message(STATUS "The xar file format has been deprecated: LLVM_HAVE_LIBXAR might be removed in the future.")
 246   # The xar file format has been deprecated since macOS 12.0.
 247   if (CMAKE_OSX_DEPLOYMENT_TARGET VERSION_GREATER_EQUAL 12)
 248     set(LLVM_HAVE_LIBXAR 0)
 249   else()
 250     set(XAR_LIB xar)
 251   endif()
 252 endif()
 253
 254 # function checks
 255 check_symbol_exists(arc4random "stdlib.h" HAVE_DECL_ARC4RANDOM)
 256 find_package(Backtrace)
 257 set(HAVE_BACKTRACE ${Backtrace_FOUND})
 258 set(BACKTRACE_HEADER ${Backtrace_HEADER})
 259
 260 # Prevent check_symbol_exists from using API that is not supported for a given
 261 # deployment target.
 262 check_c_compiler_flag("-Werror=unguarded-availability-new" "C_SUPPORTS_WERROR_UNGUARDED_AVAILABILITY_NEW")
 263 if(C_SUPPORTS_WERROR_UNGUARDED_AVAILABILITY_NEW)
 264   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror=unguarded-availability-new")
 265 endif()
 266
 267 # Determine whether we can register EH tables.
 268 check_symbol_exists(__register_frame "${CMAKE_CURRENT_LIST_DIR}/unwind.h" HAVE_REGISTER_FRAME)
 269 check_symbol_exists(__deregister_frame "${CMAKE_CURRENT_LIST_DIR}/unwind.h" HAVE_DEREGISTER_FRAME)
 270 check_symbol_exists(__unw_add_dynamic_fde "${CMAKE_CURRENT_LIST_DIR}/unwind.h" HAVE_UNW_ADD_DYNAMIC_FDE)
 271
 272 check_symbol_exists(_Unwind_Backtrace "unwind.h" HAVE__UNWIND_BACKTRACE)
 273 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 274 check_symbol_exists(sysconf unistd.h HAVE_SYSCONF)
 275 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 276 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 277 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 278 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 279 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 280 # AddressSanitizer conflicts with lib/Support/Unix/Signals.inc
 281 # Avoid sigaltstack on Apple platforms, where backtrace() cannot handle it
 282 # (rdar://7089625) and _Unwind_Backtrace is unusable because it cannot unwind
 283 # past the signal handler after an assertion failure (rdar://29866587).
 284 if( HAVE_SIGNAL_H AND NOT LLVM_USE_SANITIZER MATCHES ".*Address.*" AND NOT APPLE )
 285   check_symbol_exists(sigaltstack signal.h HAVE_SIGALTSTACK)
 286 endif()
 287 set(CMAKE_REQUIRED_DEFINITIONS "-D_LARGEFILE64_SOURCE")
 288 check_symbol_exists(lseek64 "sys/types.h;unistd.h" HAVE_LSEEK64)
 289 set(CMAKE_REQUIRED_DEFINITIONS "")
 290 check_symbol_exists(mallctl malloc_np.h HAVE_MALLCTL)
 291 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 292 check_symbol_exists(mallinfo2 malloc.h HAVE_MALLINFO2)
 293 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 294                     HAVE_MALLOC_ZONE_STATISTICS)
 295 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 296 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 297 check_symbol_exists(pread unistd.h HAVE_PREAD)
 298 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 299 check_symbol_exists(strerror string.h HAVE_STRERROR)
 300 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 301 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 302 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 303 if( PURE_WINDOWS )
 304   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 305
 306   check_function_exists(_alloca HAVE__ALLOCA)
 307   check_function_exists(__alloca HAVE___ALLOCA)
 308   check_function_exists(__chkstk HAVE___CHKSTK)
 309   check_function_exists(__chkstk_ms HAVE___CHKSTK_MS)
 310   check_function_exists(___chkstk HAVE____CHKSTK)
 311   check_function_exists(___chkstk_ms HAVE____CHKSTK_MS)
 312
 313   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 314   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 315   check_function_exists(__divdi3 HAVE___DIVDI3)
 316   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 317   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 318   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 319   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 320   check_function_exists(__moddi3 HAVE___MODDI3)
 321   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 322   check_function_exists(__umoddi3 HAVE___UMODDI3)
 323
 324   check_function_exists(__main HAVE___MAIN)
 325   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 326 endif()
 327 if( HAVE_DLFCN_H )
 328   if( HAVE_LIBDL )
 329     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 330   endif()
 331   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 332   check_symbol_exists(dladdr dlfcn.h HAVE_DLADDR)
 333   if( HAVE_LIBDL )
 334     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 335   endif()
 336 endif()
 337
 338 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec
 339     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIMESPEC_TV_NSEC)
 340 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 341 # The st_mtim.tv_nsec member of a `stat` structure is not reliable on some AIX
 342 # environments.
 343   set(HAVE_STRUCT_STAT_ST_MTIM_TV_NSEC 0)
 344 else()
 345   CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec
 346       "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIM_TV_NSEC)
 347 endif()
 348
 349 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 350 if( LLVM_USING_GLIBC )
 351   add_definitions( -D_GNU_SOURCE )
 352   list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_GNU_SOURCE")
 353 endif()
 354 # This check requires _GNU_SOURCE
 355 if (NOT PURE_WINDOWS)
 356   if (LLVM_PTHREAD_LIB)
 357     list(APPEND CMAKE_REQUIRED_LIBRARIES ${LLVM_PTHREAD_LIB})
 358   endif()
 359   check_symbol_exists(pthread_getname_np pthread.h HAVE_PTHREAD_GETNAME_NP)
 360   check_symbol_exists(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 361   if (LLVM_PTHREAD_LIB)
 362     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${LLVM_PTHREAD_LIB})
 363   endif()
 364 endif()
 365
 366 # available programs checks
 367 function(llvm_find_program name)
 368   string(TOUPPER ${name} NAME)
 369   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 370
 371   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 372   mark_as_advanced(LLVM_PATH_${NAME})
 373   if(LLVM_PATH_${NAME})
 374     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 375     mark_as_advanced(HAVE_${NAME})
 376   else(LLVM_PATH_${NAME})
 377     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 378   endif(LLVM_PATH_${NAME})
 379 endfunction()
 380
 381 if (LLVM_ENABLE_DOXYGEN)
 382   llvm_find_program(dot)
 383 endif ()
 384
 385 if(LLVM_ENABLE_FFI)
 386   set(FFI_REQUIRE_INCLUDE On)
 387   if(LLVM_ENABLE_FFI STREQUAL FORCE_ON)
 388     find_package(FFI REQUIRED)
 389   else()
 390     find_package(FFI)
 391   endif()
 392   set(LLVM_ENABLE_FFI "${FFI_FOUND}")
 393 else()
 394   unset(HAVE_FFI_FFI_H CACHE)
 395   unset(HAVE_FFI_H CACHE)
 396   unset(HAVE_FFI_CALL CACHE)
 397 endif()
 398
 399 check_symbol_exists(proc_pid_rusage "libproc.h" HAVE_PROC_PID_RUSAGE)
 400
 401 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 402 include(CheckAtomic)
 403
 404 if( LLVM_ENABLE_PIC )
 405   set(ENABLE_PIC 1)
 406 else()
 407   set(ENABLE_PIC 0)
 408   check_cxx_compiler_flag("-fno-pie" SUPPORTS_NO_PIE_FLAG)
 409   if(SUPPORTS_NO_PIE_FLAG)
 410     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fno-pie")
 411   endif()
 412 endif()
 413
 414 check_cxx_compiler_flag("-Wvariadic-macros" SUPPORTS_VARIADIC_MACROS_FLAG)
 415 check_cxx_compiler_flag("-Wgnu-zero-variadic-macro-arguments"
 416                         SUPPORTS_GNU_ZERO_VARIADIC_MACRO_ARGUMENTS_FLAG)
 417
 418 set(USE_NO_MAYBE_UNINITIALIZED 0)
 419 set(USE_NO_UNINITIALIZED 0)
 420
 421 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 422 # false positives.
 423 if (CMAKE_COMPILER_IS_GNUCXX)
 424   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 425   if (HAS_MAYBE_UNINITIALIZED)
 426     set(USE_NO_MAYBE_UNINITIALIZED 1)
 427   else()
 428     # Only recent versions of gcc make the distinction between -Wuninitialized
 429     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 430     # turn off all uninitialized use warnings.
 431     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 432     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 433   endif()
 434 endif()
 435
 436 # By default, we target the host, but this can be overridden at CMake
 437 # invocation time.
 438 include(GetHostTriple)
 439 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 440
 441 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 442     "Host on which LLVM binaries will run")
 443
 444 # Determine the native architecture.
 445 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 446 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 447   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 448 endif ()
 449
 450 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 451   set(LLVM_NATIVE_ARCH X86)
 452 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 453   set(LLVM_NATIVE_ARCH X86)
 454 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 455   set(LLVM_NATIVE_ARCH X86)
 456 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 457   set(LLVM_NATIVE_ARCH X86)
 458 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 459   set(LLVM_NATIVE_ARCH Sparc)
 460 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 461   set(LLVM_NATIVE_ARCH PowerPC)
 462 elseif (LLVM_NATIVE_ARCH MATCHES "ppc64le")
 463   set(LLVM_NATIVE_ARCH PowerPC)
 464 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 465   set(LLVM_NATIVE_ARCH AArch64)
 466 elseif (LLVM_NATIVE_ARCH MATCHES "arm64")
 467   set(LLVM_NATIVE_ARCH AArch64)
 468 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 469   set(LLVM_NATIVE_ARCH ARM)
 470 elseif (LLVM_NATIVE_ARCH MATCHES "avr")
 471   set(LLVM_NATIVE_ARCH AVR)
 472 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 473   set(LLVM_NATIVE_ARCH Mips)
 474 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 475   set(LLVM_NATIVE_ARCH XCore)
 476 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 477   set(LLVM_NATIVE_ARCH MSP430)
 478 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 479   set(LLVM_NATIVE_ARCH Hexagon)
 480 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 481   set(LLVM_NATIVE_ARCH SystemZ)
 482 elseif (LLVM_NATIVE_ARCH MATCHES "wasm32")
 483   set(LLVM_NATIVE_ARCH WebAssembly)
 484 elseif (LLVM_NATIVE_ARCH MATCHES "wasm64")
 485   set(LLVM_NATIVE_ARCH WebAssembly)
 486 elseif (LLVM_NATIVE_ARCH MATCHES "riscv32")
 487   set(LLVM_NATIVE_ARCH RISCV)
 488 elseif (LLVM_NATIVE_ARCH MATCHES "riscv64")
 489   set(LLVM_NATIVE_ARCH RISCV)
 490 elseif (LLVM_NATIVE_ARCH STREQUAL "m68k")
 491   set(LLVM_NATIVE_ARCH M68k)
 492 elseif (LLVM_NATIVE_ARCH MATCHES "loongarch")
 493   set(LLVM_NATIVE_ARCH LoongArch)
 494 else ()
 495   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 496 endif ()
 497
 498 # If build targets includes "host" or "Native", then replace with native architecture.
 499 foreach (NATIVE_KEYWORD host Native)
 500   list(FIND LLVM_TARGETS_TO_BUILD ${NATIVE_KEYWORD} idx)
 501   if( NOT idx LESS 0 )
 502     list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 503     list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 504     list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 505   endif()
 506 endforeach()
 507
 508 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 509 if (NATIVE_ARCH_IDX EQUAL -1)
 510   message(STATUS
 511     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 512 else ()
 513   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 514   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 515   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 516   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 517   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 518
 519   # We don't have an ASM parser for all architectures yet.
 520   if (EXISTS ${PROJECT_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 521     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 522   endif ()
 523
 524   # We don't have an disassembler for all architectures yet.
 525   if (EXISTS ${PROJECT_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 526     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 527   endif ()
 528 endif ()
 529
 530 if( MSVC )
 531   set(SHLIBEXT ".lib")
 532   set(stricmp "_stricmp")
 533   set(strdup "_strdup")
 534
 535   # Allow setting clang-cl's /winsysroot flag.
 536   set(LLVM_WINSYSROOT "" CACHE STRING
 537     "If set, argument to clang-cl's /winsysroot")
 538
 539   if (LLVM_WINSYSROOT)
 540     set(MSVC_DIA_SDK_DIR "${LLVM_WINSYSROOT}/DIA SDK" CACHE PATH
 541         "Path to the DIA SDK")
 542   else()
 543     set(MSVC_DIA_SDK_DIR "$ENV{VSINSTALLDIR}DIA SDK" CACHE PATH
 544         "Path to the DIA SDK")
 545   endif()
 546
 547   # See if the DIA SDK is available and usable.
 548   # Due to a bug in MSVC 2013's installation software, it is possible
 549   # for MSVC 2013 to write the DIA SDK into the Visual Studio 2012
 550   # install directory.  If this happens, the installation is corrupt
 551   # and there's nothing we can do.  It happens with enough frequency
 552   # though that we should handle it.  We do so by simply checking that
 553   # the DIA SDK folder exists.  Should this happen you will need to
 554   # uninstall VS 2012 and then re-install VS 2013.
 555   if (IS_DIRECTORY "${MSVC_DIA_SDK_DIR}")
 556     set(HAVE_DIA_SDK 1)
 557   else()
 558     set(HAVE_DIA_SDK 0)
 559   endif()
 560
 561   option(LLVM_ENABLE_DIA_SDK "Use MSVC DIA SDK for debugging if available."
 562                              ${HAVE_DIA_SDK})
 563
 564   if(LLVM_ENABLE_DIA_SDK AND NOT HAVE_DIA_SDK)
 565     message(FATAL_ERROR "DIA SDK not found. If you have both VS 2012 and 2013 installed, you may need to uninstall the former and re-install the latter afterwards.")
 566   endif()
 567 else()
 568   set(LLVM_ENABLE_DIA_SDK 0)
 569 endif( MSVC )
 570
 571 if( LLVM_ENABLE_THREADS )
 572   # Check if threading primitives aren't supported on this platform
 573   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 574     set(LLVM_ENABLE_THREADS 0)
 575   endif()
 576 endif()
 577
 578 if( LLVM_ENABLE_THREADS )
 579   message(STATUS "Threads enabled.")
 580 else( LLVM_ENABLE_THREADS )
 581   message(STATUS "Threads disabled.")
 582 endif()
 583
 584 if (LLVM_ENABLE_DOXYGEN)
 585   message(STATUS "Doxygen enabled.")
 586   find_package(Doxygen REQUIRED)
 587
 588   if (DOXYGEN_FOUND)
 589     # If we find doxygen and we want to enable doxygen by default create a
 590     # global aggregate doxygen target for generating llvm and any/all
 591     # subprojects doxygen documentation.
 592     if (LLVM_BUILD_DOCS)
 593       add_custom_target(doxygen ALL)
 594     endif()
 595
 596     option(LLVM_DOXYGEN_EXTERNAL_SEARCH "Enable doxygen external search." OFF)
 597     if (LLVM_DOXYGEN_EXTERNAL_SEARCH)
 598       set(LLVM_DOXYGEN_SEARCHENGINE_URL "" CACHE STRING "URL to use for external search.")
 599       set(LLVM_DOXYGEN_SEARCH_MAPPINGS "" CACHE STRING "Doxygen Search Mappings")
 600     endif()
 601   endif()
 602 else()
 603   message(STATUS "Doxygen disabled.")
 604 endif()
 605
 606 set(LLVM_BINDINGS "")
 607 find_program(GO_EXECUTABLE NAMES go DOC "go executable")
 608 if(WIN32 OR NOT LLVM_ENABLE_BINDINGS)
 609   message(STATUS "Go bindings disabled.")
 610 else()
 611   if(GO_EXECUTABLE STREQUAL "GO_EXECUTABLE-NOTFOUND")
 612     message(STATUS "Go bindings disabled.")
 613   else()
 614     execute_process(COMMAND ${GO_EXECUTABLE} run ${PROJECT_SOURCE_DIR}/bindings/go/conftest.go
 615                     RESULT_VARIABLE GO_CONFTEST)
 616     if(GO_CONFTEST STREQUAL "0")
 617       set(LLVM_BINDINGS "${LLVM_BINDINGS} go")
 618       message(STATUS "Go bindings enabled.")
 619     else()
 620       message(STATUS "Go bindings disabled, need at least Go 1.2.")
 621     endif()
 622   endif()
 623 endif()
 624
 625 find_program(GOLD_EXECUTABLE NAMES ${LLVM_DEFAULT_TARGET_TRIPLE}-ld.gold ld.gold ${LLVM_DEFAULT_TARGET_TRIPLE}-ld ld DOC "The gold linker")
 626 set(LLVM_BINUTILS_INCDIR "" CACHE PATH
 627     "PATH to binutils/include containing plugin-api.h for gold plugin.")
 628
 629 if(CMAKE_GENERATOR MATCHES "Ninja")
 630   execute_process(COMMAND ${CMAKE_MAKE_PROGRAM} --version
 631     OUTPUT_VARIABLE NINJA_VERSION
 632     OUTPUT_STRIP_TRAILING_WHITESPACE)
 633   set(NINJA_VERSION ${NINJA_VERSION} CACHE STRING "Ninja version number" FORCE)
 634   message(STATUS "Ninja version: ${NINJA_VERSION}")
 635 endif()
 636
 637 if(CMAKE_GENERATOR MATCHES "Ninja" AND
 638     NOT "${NINJA_VERSION}" VERSION_LESS "1.9.0" AND
 639     CMAKE_HOST_APPLE AND CMAKE_HOST_SYSTEM_VERSION VERSION_GREATER "15.6.0")
 640   set(LLVM_TOUCH_STATIC_LIBRARIES ON)
 641 endif()
 642
 643 if(CMAKE_HOST_APPLE AND APPLE)
 644   if(NOT CMAKE_XCRUN)
 645     find_program(CMAKE_XCRUN NAMES xcrun)
 646   endif()
 647   if(CMAKE_XCRUN)
 648     execute_process(COMMAND ${CMAKE_XCRUN} -find ld
 649       OUTPUT_VARIABLE LD64_EXECUTABLE
 650       OUTPUT_STRIP_TRAILING_WHITESPACE)
 651   else()
 652     find_program(LD64_EXECUTABLE NAMES ld DOC "The ld64 linker")
 653   endif()
 654
 655   if(LD64_EXECUTABLE)
 656     set(LD64_EXECUTABLE ${LD64_EXECUTABLE} CACHE PATH "ld64 executable")
 657     message(STATUS "Found ld64 - ${LD64_EXECUTABLE}")
 658   endif()
 659 endif()
 660
 661 # Keep the version requirements in sync with bindings/ocaml/README.txt.
 662 include(FindOCaml)
 663 include(AddOCaml)
 664 if(WIN32 OR NOT LLVM_ENABLE_BINDINGS)
 665   message(STATUS "OCaml bindings disabled.")
 666 else()
 667   find_package(OCaml)
 668   if( NOT OCAML_FOUND )
 669     message(STATUS "OCaml bindings disabled.")
 670   else()
 671     if( OCAML_VERSION VERSION_LESS "4.00.0" )
 672       message(STATUS "OCaml bindings disabled, need OCaml >=4.00.0.")
 673     else()
 674       find_ocamlfind_package(ctypes VERSION 0.4 OPTIONAL)
 675       if( HAVE_OCAML_CTYPES )
 676         message(STATUS "OCaml bindings enabled.")
 677         set(LLVM_BINDINGS "${LLVM_BINDINGS} ocaml")
 678
 679         set(LLVM_OCAML_INSTALL_PATH "${OCAML_STDLIB_PATH}" CACHE STRING
 680             "Install directory for LLVM OCaml packages")
 681       else()
 682         message(STATUS "OCaml bindings disabled, need ctypes >=0.4.")
 683       endif()
 684     endif()
 685   endif()
 686 endif()
 687
 688 string(REPLACE " " ";" LLVM_BINDINGS_LIST "${LLVM_BINDINGS}")
 689
 690 function(find_python_module module)
 691   string(REPLACE "." "_" module_name ${module})
 692   string(TOUPPER ${module_name} module_upper)
 693   set(FOUND_VAR PY_${module_upper}_FOUND)
 694   if (DEFINED ${FOUND_VAR})
 695     return()
 696   endif()
 697
 698   execute_process(COMMAND "${Python3_EXECUTABLE}" "-c" "import ${module}"
 699     RESULT_VARIABLE status
 700     ERROR_QUIET)
 701
 702   if(status)
 703     set(${FOUND_VAR} OFF CACHE BOOL "Failed to find python module '${module}'")
 704     message(STATUS "Could NOT find Python module ${module}")
 705   else()
 706   set(${FOUND_VAR} ON CACHE BOOL "Found python module '${module}'")
 707     message(STATUS "Found Python module ${module}")
 708   endif()
 709 endfunction()
 710
 711 set (PYTHON_MODULES
 712   pygments
 713   # Some systems still don't have pygments.lexers.c_cpp which was introduced in
 714   # version 2.0 in 2014...
 715   pygments.lexers.c_cpp
 716   yaml
 717   )
 718 foreach(module ${PYTHON_MODULES})
 719   find_python_module(${module})
 720 endforeach()
 721
 722 if(PY_PYGMENTS_FOUND AND PY_PYGMENTS_LEXERS_C_CPP_FOUND AND PY_YAML_FOUND)
 723   set (LLVM_HAVE_OPT_VIEWER_MODULES 1)
 724 else()
 725   set (LLVM_HAVE_OPT_VIEWER_MODULES 0)
 726 endif()
 727
 728 function(llvm_get_host_prefixes_and_suffixes)
 729   # Not all platform files will set these variables (relying on them being
 730   # implicitly empty if they're unset), so unset the variables before including
 731   # the platform file, to prevent any values from the target system leaking.
 732   unset(CMAKE_STATIC_LIBRARY_PREFIX)
 733   unset(CMAKE_STATIC_LIBRARY_SUFFIX)
 734   unset(CMAKE_SHARED_LIBRARY_PREFIX)
 735   unset(CMAKE_SHARED_LIBRARY_SUFFIX)
 736   unset(CMAKE_IMPORT_LIBRARY_PREFIX)
 737   unset(CMAKE_IMPORT_LIBRARY_SUFFIX)
 738   unset(CMAKE_EXECUTABLE_SUFFIX)
 739   unset(CMAKE_LINK_LIBRARY_SUFFIX)
 740   include(Platform/${CMAKE_HOST_SYSTEM_NAME} OPTIONAL RESULT_VARIABLE _includedFile)
 741   if (_includedFile)
 742     set(LLVM_HOST_STATIC_LIBRARY_PREFIX ${CMAKE_STATIC_LIBRARY_PREFIX} PARENT_SCOPE)
 743     set(LLVM_HOST_STATIC_LIBRARY_SUFFIX ${CMAKE_STATIC_LIBRARY_SUFFIX} PARENT_SCOPE)
 744     set(LLVM_HOST_SHARED_LIBRARY_PREFIX ${CMAKE_SHARED_LIBRARY_PREFIX} PARENT_SCOPE)
 745     set(LLVM_HOST_SHARED_LIBRARY_SUFFIX ${CMAKE_SHARED_LIBRARY_SUFFIX} PARENT_SCOPE)
 746     set(LLVM_HOST_IMPORT_LIBRARY_PREFIX ${CMAKE_IMPORT_LIBRARY_PREFIX} PARENT_SCOPE)
 747     set(LLVM_HOST_IMPORT_LIBRARY_SUFFIX ${CMAKE_IMPORT_LIBRARY_SUFFIX} PARENT_SCOPE)
 748     set(LLVM_HOST_EXECUTABLE_SUFFIX ${CMAKE_EXECUTABLE_SUFFIX} PARENT_SCOPE)
 749     set(LLVM_HOST_LINK_LIBRARY_SUFFIX ${CMAKE_LINK_LIBRARY_SUFFIX} PARENT_SCOPE)
 750   endif()
 751 endfunction()
 752
 753 llvm_get_host_prefixes_and_suffixes()