flang/test/Fir/global-initialization.fir

   1 // RUN: fir-opt --fir-to-llvm-ir %s | FileCheck %s
   2 // RUN: tco --fir-to-llvm-ir %s | FileCheck %s
   3
   4 fir.global internal @_QEmask : !fir.array<32xi32> {
   5   %c0_i32 = arith.constant 1 : i32
   6   %0 = fir.undefined !fir.array<32xi32>
   7   %2 = fir.insert_on_range %0, %c0_i32 from (0) to (31) : (!fir.array<32xi32>, i32) -> !fir.array<32xi32>
   8   fir.has_value %2 : !fir.array<32xi32>
   9 }
  10
  11 // CHECK: llvm.mlir.global internal @_QEmask() {addr_space = 0 : i32} : !llvm.array<32 x i32> {
  12 // CHECK:   [[VAL0:%.*]] = llvm.mlir.constant(1 : i32) : i32
  13 // CHECK:   [[VAL1:%.*]] = llvm.mlir.undef : !llvm.array<32 x i32>
  14 // CHECK:   [[VAL2:%.*]] = llvm.mlir.constant(dense<1> : vector<32xi32>) : !llvm.array<32 x i32>
  15 // CHECK:   llvm.return [[VAL2]] : !llvm.array<32 x i32>
  16 // CHECK: }
  17
  18 fir.global internal @_QEmultiarray : !fir.array<32x32xi32> {
  19   %c0_i32 = arith.constant 1 : i32
  20   %0 = fir.undefined !fir.array<32x32xi32>
  21   %2 = fir.insert_on_range %0, %c0_i32 from (0,0) to (31,31) : (!fir.array<32x32xi32>, i32) -> !fir.array<32x32xi32>
  22   fir.has_value %2 : !fir.array<32x32xi32>
  23 }
  24
  25 // CHECK: llvm.mlir.global internal @_QEmultiarray() {addr_space = 0 : i32} : !llvm.array<32 x array<32 x i32>> {
  26 // CHECK:   [[VAL0:%.*]] = llvm.mlir.constant(1 : i32) : i32
  27 // CHECK:   [[VAL1:%.*]] = llvm.mlir.undef : !llvm.array<32 x array<32 x i32>>
  28 // CHECK:   [[VAL2:%.*]] = llvm.mlir.constant(dense<1> : vector<32x32xi32>) : !llvm.array<32 x array<32 x i32>>
  29 // CHECK:   llvm.return [[VAL2]] : !llvm.array<32 x array<32 x i32>>
  30 // CHECK: }
  31
  32 fir.global internal @_QEmasklogical : !fir.array<32768x!fir.logical<4>> {
  33   %true = arith.constant true
  34   %0 = fir.undefined !fir.array<32768x!fir.logical<4>>
  35   %1 = fir.convert %true : (i1) -> !fir.logical<4>
  36   %2 = fir.insert_on_range %0, %1 from (0) to (32767) : (!fir.array<32768x!fir.logical<4>>, !fir.logical<4>) -> !fir.array<32768x!fir.logical<4>>
  37   fir.has_value %2 : !fir.array<32768x!fir.logical<4>>
  38 }
  39
  40 // CHECK: llvm.mlir.global internal @_QEmasklogical() {addr_space = 0 : i32} : !llvm.array<32768 x i32> {
  41 // CHECK:   [[VAL0:%.*]] = llvm.mlir.constant(true) : i1
  42 // CHECK:   [[VAL1:%.*]] = llvm.mlir.undef : !llvm.array<32768 x i32>
  43 // CHECK:   [[VAL2:%.*]] = llvm.zext [[VAL0]] : i1 to i32
  44 // CHECK:   [[VAL3:%.*]] = llvm.mlir.constant(dense<true> : vector<32768xi1>) : !llvm.array<32768 x i32>
  45 // CHECK:   llvm.return [[VAL3]] : !llvm.array<32768 x i32>
  46 // CHECK: }
  47
  48 fir.global internal @_QElookforme : !fir.type<_QTt{i:!fir.array<500xi32>,j:!fir.array<500xi32>}> {
  49   %c2_i32 = arith.constant 2 : i32
  50   %c52_i32 = arith.constant 52 : i32
  51   %0 = fir.undefined !fir.type<_QTt{i:!fir.array<500xi32>,j:!fir.array<500xi32>}>
  52   %1 = fir.undefined !fir.array<500xi32>
  53   %2 = fir.insert_on_range %1, %c2_i32 from (0) to (499) : (!fir.array<500xi32>, i32) -> !fir.array<500xi32>
  54   %3 = fir.insert_value %0, %2, ["i", !fir.type<_QTt{i:!fir.array<500xi32>,j:!fir.array<500xi32>}>] :(!fir.type<_QTt{i:!fir.array<500xi32>,j:!fir.array<500xi32>}>, !fir.array<500xi32>) -> !fir.type<_QTt{i:!fir.array<500xi32>,j:!fir.array<500xi32>}>
  55   %4 = fir.insert_on_range %1, %c52_i32 from (0) to (499) : (!fir.array<500xi32>, i32) -> !fir.array<500xi32>
  56   %5 = fir.insert_value %3, %4, ["j", !fir.type<_QTt{i:!fir.array<500xi32>,j:!fir.array<500xi32>}>] : (!fir.type<_QTt{i:!fir.array<500xi32>,j:!fir.array<500xi32>}>, !fir.array<500xi32>) -> !fir.type<_QTt{i:!fir.array<500xi32>,j:!fir.array<500xi32>}>
  57   fir.has_value %5 : !fir.type<_QTt{i:!fir.array<500xi32>,j:!fir.array<500xi32>}>
  58 }
  59
  60 // CHECK: llvm.mlir.global internal @_QElookforme() {addr_space = 0 : i32} : !llvm.struct<"_QTt", (array<500 x i32>, array<500 x i32>)> {
  61 // CHECK:   [[CST0:%.*]] = llvm.mlir.constant(2 : i32) : i32
  62 // CHECK:   [[CST1:%.*]] = llvm.mlir.constant(52 : i32) : i32
  63 // CHECK:   [[STRUCT:%.*]] = llvm.mlir.undef : !llvm.struct<"_QTt", (array<500 x i32>, array<500 x i32>)>
  64 // CHECK:   [[ARR1:%.*]] = llvm.mlir.undef : !llvm.array<500 x i32>
  65 // CHECK:   [[DENSE1:%.*]] = llvm.mlir.constant(dense<2> : vector<500xi32>) : !llvm.array<500 x i32>
  66 // CHECK:   [[STRUCT1:%.*]] = llvm.insertvalue [[DENSE1]], [[STRUCT]][0] : !llvm.struct<"_QTt", (array<500 x i32>, array<500 x i32>)>
  67 // CHECK:   [[DENSE2:%.*]] = llvm.mlir.constant(dense<52> : vector<500xi32>) : !llvm.array<500 x i32>
  68 // CHECK:   [[STRUCT2:%.*]] = llvm.insertvalue [[DENSE2]], [[STRUCT1]][1] : !llvm.struct<"_QTt", (array<500 x i32>, array<500 x i32>)>
  69 // CHECK:   llvm.return [[STRUCT2]] : !llvm.struct<"_QTt", (array<500 x i32>, array<500 x i32>)>
  70 // CHECK: }