mlir/CMakeLists.txt

   1 # MLIR project.
   2 cmake_minimum_required(VERSION 3.20.0)
   3
   4 if(NOT DEFINED LLVM_COMMON_CMAKE_UTILS)
   5   set(LLVM_COMMON_CMAKE_UTILS ${CMAKE_CURRENT_SOURCE_DIR}/../cmake)
   6 endif()
   7 include(${LLVM_COMMON_CMAKE_UTILS}/Modules/CMakePolicy.cmake
   8   NO_POLICY_SCOPE)
   9
  10 # Check if MLIR is built as a standalone project.
  11 if(CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
  12   project(mlir)
  13   set(MLIR_STANDALONE_BUILD TRUE)
  14 endif()
  15
  16 # Must go below project(..)
  17 include(GNUInstallDirs)
  18 set(CMAKE_CXX_STANDARD 17)
  19
  20 if(MLIR_STANDALONE_BUILD)
  21   find_package(LLVM CONFIG REQUIRED)
  22   set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${LLVM_CMAKE_DIR})
  23   include(HandleLLVMOptions)
  24   include(AddLLVM)
  25   include(TableGen)
  26
  27   include_directories(${LLVM_INCLUDE_DIRS})
  28
  29   set(UNITTEST_DIR ${LLVM_THIRD_PARTY_DIR}/unittest)
  30   if(EXISTS ${UNITTEST_DIR}/googletest/include/gtest/gtest.h)
  31     add_subdirectory(${UNITTEST_DIR} third-party/unittest)
  32   endif()
  33
  34   set(CMAKE_LIBRARY_OUTPUT_DIRECTORY
  35     "${CMAKE_CURRENT_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX}")
  36   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/bin")
  37
  38   set(LLVM_LIT_ARGS "-sv" CACHE STRING "Default options for lit")
  39 endif()
  40
  41 set(MLIR_TOOLS_INSTALL_DIR "${CMAKE_INSTALL_BINDIR}" CACHE PATH
  42     "Path for binary subdirectory (defaults to '${CMAKE_INSTALL_BINDIR}')")
  43 mark_as_advanced(MLIR_TOOLS_INSTALL_DIR)
  44
  45 set(MLIR_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  )
  46 set(MLIR_MAIN_INCLUDE_DIR ${MLIR_MAIN_SRC_DIR}/include )
  47
  48 set(MLIR_SOURCE_DIR  ${CMAKE_CURRENT_SOURCE_DIR})
  49 set(MLIR_BINARY_DIR  ${CMAKE_CURRENT_BINARY_DIR})
  50 set(MLIR_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
  51 set(MLIR_TOOLS_DIR   ${CMAKE_RUNTIME_OUTPUT_DIRECTORY})
  52
  53 # Make sure that our source directory is on the current cmake module path so
  54 # that we can include cmake files from this directory.
  55 list(INSERT CMAKE_MODULE_PATH 0
  56   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  57   "${LLVM_COMMON_CMAKE_UTILS}/Modules"
  58   )
  59
  60 include(AddMLIR)
  61
  62 # -BSymbolic is incompatible with TypeID
  63 if("${CMAKE_SHARED_LINKER_FLAGS}" MATCHES "-Bsymbolic[^-]")
  64   message(FATAL_ERROR " MLIR does not support `-Bsymbolic` (see http://llvm.org/pr51420 ),"
  65           " try `-Bsymbolic-functions` instead.")
  66 endif()
  67
  68 # Forbid implicit function declaration: this may lead to subtle bugs and we
  69 # don't have a reason to support this.
  70 check_c_compiler_flag("-Werror=implicit-function-declaration" C_SUPPORTS_WERROR_IMPLICIT_FUNCTION_DECLARATION)
  71 append_if(C_SUPPORTS_WERROR_IMPLICIT_FUNCTION_DECLARATION "-Werror=implicit-function-declaration" CMAKE_C_FLAGS)
  72
  73 # Forbid mismatch between declaration and definition for class vs struct. This is
  74 # harmless on Unix systems, but it'll be a ticking bomb for MSVC/Windows systems
  75 # where it creeps into the ABI.
  76 check_c_compiler_flag("-Werror=mismatched-tags" C_SUPPORTS_WERROR_MISMATCHED_TAGS)
  77 append_if(C_SUPPORTS_WERROR_MISMATCHED_TAGS "-Werror=mismatched-tags" CMAKE_C_FLAGS)
  78 append_if(C_SUPPORTS_WERROR_MISMATCHED_TAGS "-Werror=mismatched-tags" CMAKE_CXX_FLAGS)
  79
  80 # Silence a false positive GCC -Wunused-but-set-parameter warning in constexpr
  81 # cases, by marking SelectedCase as used. See
  82 # https://gcc.gnu.org/bugzilla/show_bug.cgi?id=85827 for details. The issue is
  83 # fixed in GCC 10.
  84 if(CMAKE_CXX_COMPILER_ID MATCHES "GNU" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "10.0")
  85   check_cxx_compiler_flag("-Wno-unused-but-set-parameter" CXX_SUPPORTS_WNO_UNUSED_BUT_SET_PARAMETER)
  86   append_if(CXX_SUPPORTS_WNO_UNUSED_BUT_SET_PARAMETER "-Wno-unused-but-set-parameter" CMAKE_CXX_FLAGS)
  87 endif()
  88
  89 # Installing the headers and docs needs to depend on generating any public
  90 # tablegen'd targets.
  91 # mlir-generic-headers are dialect-independent.
  92 add_custom_target(mlir-generic-headers)
  93 set_target_properties(mlir-generic-headers PROPERTIES FOLDER "Misc")
  94 # mlir-headers may be dialect-dependent.
  95 add_custom_target(mlir-headers)
  96 set_target_properties(mlir-headers PROPERTIES FOLDER "Misc")
  97 add_dependencies(mlir-headers mlir-generic-headers)
  98 add_custom_target(mlir-doc)
  99
 100 # Only enable execution engine if the native target is available.
 101 if(${LLVM_NATIVE_ARCH} IN_LIST LLVM_TARGETS_TO_BUILD)
 102   set(MLIR_ENABLE_EXECUTION_ENGINE 1)
 103 else()
 104   set(MLIR_ENABLE_EXECUTION_ENGINE 0)
 105 endif()
 106
 107 # Build the CUDA conversions and run according tests if the NVPTX backend
 108 # is available
 109 if ("NVPTX" IN_LIST LLVM_TARGETS_TO_BUILD)
 110   set(MLIR_ENABLE_CUDA_CONVERSIONS 1)
 111 else()
 112   set(MLIR_ENABLE_CUDA_CONVERSIONS 0)
 113 endif()
 114 # TODO: we should use a config.h file like LLVM does
 115 add_definitions(-DMLIR_CUDA_CONVERSIONS_ENABLED=${MLIR_ENABLE_CUDA_CONVERSIONS})
 116
 117 # Build the ROCm conversions and run according tests if the AMDGPU backend
 118 # is available.
 119 if ("AMDGPU" IN_LIST LLVM_TARGETS_TO_BUILD)
 120   set(MLIR_ENABLE_ROCM_CONVERSIONS 1)
 121 else()
 122   set(MLIR_ENABLE_ROCM_CONVERSIONS 0)
 123 endif()
 124 add_definitions(-DMLIR_ROCM_CONVERSIONS_ENABLED=${MLIR_ENABLE_ROCM_CONVERSIONS})
 125
 126 set(MLIR_ENABLE_DEPRECATED_GPU_SERIALIZATION 0 CACHE BOOL "Enable deprecated GPU serialization passes")
 127 set(MLIR_ENABLE_CUDA_RUNNER 0 CACHE BOOL "Enable building the mlir CUDA runner")
 128 set(MLIR_ENABLE_ROCM_RUNNER 0 CACHE BOOL "Enable building the mlir ROCm runner")
 129 set(MLIR_ENABLE_SPIRV_CPU_RUNNER 0 CACHE BOOL "Enable building the mlir SPIR-V cpu runner")
 130 set(MLIR_ENABLE_VULKAN_RUNNER 0 CACHE BOOL "Enable building the mlir Vulkan runner")
 131 set(MLIR_ENABLE_NVPTXCOMPILER 0 CACHE BOOL
 132     "Statically link the nvptxlibrary instead of calling ptxas as a subprocess \
 133     for compiling PTX to cubin")
 134
 135 option(MLIR_INCLUDE_TESTS
 136        "Generate build targets for the MLIR unit tests."
 137        ${LLVM_INCLUDE_TESTS})
 138
 139 option(MLIR_INCLUDE_INTEGRATION_TESTS
 140        "Generate build targets for the MLIR integration tests.")
 141
 142 set(MLIR_INSTALL_AGGREGATE_OBJECTS 1 CACHE BOOL
 143     "Installs object files needed for add_mlir_aggregate to work out of \
 144     tree. Package maintainers can disable this to exclude these assets if \
 145     not desired. Enabling this will result in object files being written \
 146     under lib/objects-{CMAKE_BUILD_TYPE}.")
 147
 148 set(MLIR_BUILD_MLIR_C_DYLIB 0 CACHE BOOL "Builds libMLIR-C shared library.")
 149
 150 configure_file(
 151   ${MLIR_MAIN_INCLUDE_DIR}/mlir/Config/mlir-config.h.cmake
 152   ${MLIR_INCLUDE_DIR}/mlir/Config/mlir-config.h)
 153
 154 #-------------------------------------------------------------------------------
 155 # Python Bindings Configuration
 156 # Requires:
 157 #   The pybind11 library can be found (set with -DPYBIND_DIR=...)
 158 #   The python executable is correct (set with -DPython3_EXECUTABLE=...)
 159 #-------------------------------------------------------------------------------
 160
 161 set(MLIR_ENABLE_BINDINGS_PYTHON 0 CACHE BOOL
 162        "Enables building of Python bindings.")
 163 set(MLIR_DETECT_PYTHON_ENV_PRIME_SEARCH 1 CACHE BOOL
 164        "Prime the python detection by searching for a full 'Development' \
 165        component first (temporary while diagnosing environment specific Python \
 166        detection issues)")
 167 if(MLIR_ENABLE_BINDINGS_PYTHON)
 168   include(MLIRDetectPythonEnv)
 169   mlir_configure_python_dev_packages()
 170 endif()
 171
 172 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 173
 174 include_directories( "include")
 175 include_directories( ${MLIR_INCLUDE_DIR})
 176
 177 # Adding tools/mlir-tblgen here as calling add_tablegen sets some variables like
 178 # MLIR_TABLEGEN_EXE in PARENT_SCOPE which gets lost if that folder is included
 179 # from another directory like tools
 180 add_subdirectory(tools/mlir-tblgen)
 181 add_subdirectory(tools/mlir-linalg-ods-gen)
 182 add_subdirectory(tools/mlir-pdll)
 183
 184 set(MLIR_TABLEGEN_EXE "${MLIR_TABLEGEN_EXE}" CACHE INTERNAL "")
 185 set(MLIR_TABLEGEN_TARGET "${MLIR_TABLEGEN_TARGET}" CACHE INTERNAL "")
 186 set(MLIR_PDLL_TABLEGEN_EXE "${MLIR_PDLL_TABLEGEN_EXE}" CACHE INTERNAL "")
 187 set(MLIR_PDLL_TABLEGEN_TARGET "${MLIR_PDLL_TABLEGEN_TARGET}" CACHE INTERNAL "")
 188
 189 add_subdirectory(include/mlir)
 190 add_subdirectory(lib)
 191 # C API needs all dialects for registration, but should be built before tests.
 192 add_subdirectory(lib/CAPI)
 193
 194 if (MLIR_INCLUDE_TESTS)
 195   add_definitions(-DMLIR_INCLUDE_TESTS)
 196   add_custom_target(MLIRUnitTests)
 197   if (EXISTS ${LLVM_THIRD_PARTY_DIR}/unittest/googletest/include/gtest/gtest.h)
 198     add_subdirectory(unittests)
 199   else()
 200     message(WARNING "gtest not found, unittests will not be available")
 201   endif()
 202   add_subdirectory(test)
 203 endif()
 204 # Tools needs to come late to ensure that MLIR_ALL_LIBS is populated.
 205 # Generally things after this point may depend on MLIR_ALL_LIBS or libMLIR.so.
 206 add_subdirectory(tools)
 207
 208 if(MLIR_ENABLE_BINDINGS_PYTHON)
 209   # Python sources: built extensions come in via lib/Bindings/Python
 210   add_subdirectory(python)
 211 endif()
 212
 213 if( LLVM_INCLUDE_EXAMPLES )
 214   add_subdirectory(examples)
 215 endif()
 216
 217 option(MLIR_INCLUDE_DOCS "Generate build targets for the MLIR docs."
 218   ${LLVM_INCLUDE_DOCS})
 219 if (MLIR_INCLUDE_DOCS)
 220   add_subdirectory(docs)
 221 endif()
 222
 223 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 224   install(DIRECTORY include/mlir include/mlir-c
 225     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
 226     COMPONENT mlir-headers
 227     FILES_MATCHING
 228     PATTERN "*.def"
 229     PATTERN "*.h"
 230     PATTERN "*.inc"
 231     PATTERN "*.td"
 232     PATTERN "LICENSE.TXT"
 233     )
 234
 235   install(DIRECTORY ${MLIR_INCLUDE_DIR}/mlir ${MLIR_INCLUDE_DIR}/mlir-c
 236     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
 237     COMPONENT mlir-headers
 238     FILES_MATCHING
 239     PATTERN "*.def"
 240     PATTERN "*.h"
 241     PATTERN "*.gen"
 242     PATTERN "*.inc"
 243     PATTERN "*.td"
 244     PATTERN "CMakeFiles" EXCLUDE
 245     PATTERN "config.h" EXCLUDE
 246     )
 247
 248   if (NOT LLVM_ENABLE_IDE)
 249     add_llvm_install_targets(install-mlir-headers
 250                              DEPENDS mlir-headers
 251                              COMPONENT mlir-headers)
 252   endif()
 253 endif()
 254
 255 # Custom target to install all mlir libraries
 256 add_custom_target(mlir-libraries)
 257 set_target_properties(mlir-libraries PROPERTIES FOLDER "Misc")
 258
 259 if (NOT LLVM_ENABLE_IDE)
 260   add_llvm_install_targets(install-mlir-libraries
 261                            DEPENDS mlir-libraries
 262                            COMPONENT mlir-libraries)
 263 endif()
 264
 265 get_property(MLIR_LIBS GLOBAL PROPERTY MLIR_ALL_LIBS)
 266 if(MLIR_LIBS)
 267   list(REMOVE_DUPLICATES MLIR_LIBS)
 268   foreach(lib ${MLIR_LIBS})
 269     add_dependencies(mlir-libraries ${lib})
 270     if(NOT LLVM_ENABLE_IDE)
 271       add_dependencies(install-mlir-libraries install-${lib})
 272       add_dependencies(install-mlir-libraries-stripped install-${lib}-stripped)
 273     endif()
 274   endforeach()
 275 endif()
 276
 277 add_subdirectory(cmake/modules)
 278
 279 if (MLIR_ENABLE_PYTHON_BENCHMARKS)
 280   add_subdirectory(utils/mbr)
 281 endif()
 282
 283 if(MLIR_STANDALONE_BUILD)
 284   llvm_distribution_add_targets()
 285 endif()