mlir/CMakeLists.txt

   1 # MLIR project.
   2 cmake_minimum_required(VERSION 3.20.0)
   3
   4 if(NOT DEFINED LLVM_COMMON_CMAKE_UTILS)
   5   set(LLVM_COMMON_CMAKE_UTILS ${CMAKE_CURRENT_SOURCE_DIR}/../cmake)
   6 endif()
   7 include(${LLVM_COMMON_CMAKE_UTILS}/Modules/CMakePolicy.cmake
   8   NO_POLICY_SCOPE)
   9
  10 # Check if MLIR is built as a standalone project.
  11 if(CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
  12   project(mlir)
  13   set(MLIR_STANDALONE_BUILD TRUE)
  14 endif()
  15
  16 # Must go below project(..)
  17 include(GNUInstallDirs)
  18 set(CMAKE_CXX_STANDARD 17)
  19
  20 if(MLIR_STANDALONE_BUILD)
  21   find_package(LLVM CONFIG REQUIRED)
  22   set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${LLVM_CMAKE_DIR})
  23   include(HandleLLVMOptions)
  24   include(AddLLVM)
  25   include(TableGen)
  26
  27   include_directories(${LLVM_INCLUDE_DIRS})
  28
  29   set(UNITTEST_DIR ${LLVM_THIRD_PARTY_DIR}/unittest)
  30   if(EXISTS ${UNITTEST_DIR}/googletest/include/gtest/gtest.h)
  31     add_subdirectory(${UNITTEST_DIR} third-party/unittest)
  32   endif()
  33
  34   set(CMAKE_LIBRARY_OUTPUT_DIRECTORY
  35     "${CMAKE_CURRENT_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX}")
  36   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/bin")
  37
  38   set(LLVM_LIT_ARGS "-sv" CACHE STRING "Default options for lit")
  39 endif()
  40
  41 set(MLIR_TOOLS_INSTALL_DIR "${CMAKE_INSTALL_BINDIR}" CACHE PATH
  42     "Path for binary subdirectory (defaults to '${CMAKE_INSTALL_BINDIR}')")
  43 mark_as_advanced(MLIR_TOOLS_INSTALL_DIR)
  44
  45 set(MLIR_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  )
  46 set(MLIR_MAIN_INCLUDE_DIR ${MLIR_MAIN_SRC_DIR}/include )
  47
  48 set(MLIR_SOURCE_DIR  ${CMAKE_CURRENT_SOURCE_DIR})
  49 set(MLIR_BINARY_DIR  ${CMAKE_CURRENT_BINARY_DIR})
  50 set(MLIR_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
  51 set(MLIR_TOOLS_DIR   ${CMAKE_RUNTIME_OUTPUT_DIRECTORY})
  52
  53 # Make sure that our source directory is on the current cmake module path so
  54 # that we can include cmake files from this directory.
  55 list(INSERT CMAKE_MODULE_PATH 0
  56   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  57   "${LLVM_COMMON_CMAKE_UTILS}/Modules"
  58   )
  59
  60 include(AddMLIR)
  61
  62 # -BSymbolic is incompatible with TypeID
  63 if("${CMAKE_SHARED_LINKER_FLAGS}" MATCHES "-Bsymbolic[^-]")
  64   message(FATAL_ERROR " MLIR does not support `-Bsymbolic` (see http://llvm.org/pr51420 ),"
  65           " try `-Bsymbolic-functions` instead.")
  66 endif()
  67
  68 # Forbid implicit function declaration: this may lead to subtle bugs and we
  69 # don't have a reason to support this.
  70 check_c_compiler_flag("-Werror=implicit-function-declaration" C_SUPPORTS_WERROR_IMPLICIT_FUNCTION_DECLARATION)
  71 append_if(C_SUPPORTS_WERROR_IMPLICIT_FUNCTION_DECLARATION "-Werror=implicit-function-declaration" CMAKE_C_FLAGS)
  72
  73 # Forbid mismatch between declaration and definition for class vs struct. This is
  74 # harmless on Unix systems, but it'll be a ticking bomb for MSVC/Windows systems
  75 # where it creeps into the ABI.
  76 check_c_compiler_flag("-Werror=mismatched-tags" C_SUPPORTS_WERROR_MISMATCHED_TAGS)
  77 append_if(C_SUPPORTS_WERROR_MISMATCHED_TAGS "-Werror=mismatched-tags" CMAKE_C_FLAGS)
  78 append_if(C_SUPPORTS_WERROR_MISMATCHED_TAGS "-Werror=mismatched-tags" CMAKE_CXX_FLAGS)
  79
  80 # Installing the headers and docs needs to depend on generating any public
  81 # tablegen'd targets.
  82 # mlir-generic-headers are dialect-independent.
  83 add_custom_target(mlir-generic-headers)
  84 set_target_properties(mlir-generic-headers PROPERTIES FOLDER "Misc")
  85 # mlir-headers may be dialect-dependent.
  86 add_custom_target(mlir-headers)
  87 set_target_properties(mlir-headers PROPERTIES FOLDER "Misc")
  88 add_dependencies(mlir-headers mlir-generic-headers)
  89 add_custom_target(mlir-doc)
  90
  91 # Only enable execution engine if the native target is available.
  92 if(${LLVM_NATIVE_ARCH} IN_LIST LLVM_TARGETS_TO_BUILD)
  93   set(MLIR_ENABLE_EXECUTION_ENGINE 1)
  94 else()
  95   set(MLIR_ENABLE_EXECUTION_ENGINE 0)
  96 endif()
  97
  98 # Build the CUDA conversions and run according tests if the NVPTX backend
  99 # is available
 100 if ("NVPTX" IN_LIST LLVM_TARGETS_TO_BUILD AND MLIR_ENABLE_EXECUTION_ENGINE)
 101   set(MLIR_ENABLE_CUDA_CONVERSIONS 1)
 102 else()
 103   set(MLIR_ENABLE_CUDA_CONVERSIONS 0)
 104 endif()
 105 # TODO: we should use a config.h file like LLVM does
 106 add_definitions(-DMLIR_CUDA_CONVERSIONS_ENABLED=${MLIR_ENABLE_CUDA_CONVERSIONS})
 107
 108 # Build the ROCm conversions and run according tests if the AMDGPU backend
 109 # is available.
 110 if ("AMDGPU" IN_LIST LLVM_TARGETS_TO_BUILD AND MLIR_ENABLE_EXECUTION_ENGINE)
 111   set(MLIR_ENABLE_ROCM_CONVERSIONS 1)
 112 else()
 113   set(MLIR_ENABLE_ROCM_CONVERSIONS 0)
 114 endif()
 115 add_definitions(-DMLIR_ROCM_CONVERSIONS_ENABLED=${MLIR_ENABLE_ROCM_CONVERSIONS})
 116
 117 set(MLIR_ENABLE_CUDA_RUNNER 0 CACHE BOOL "Enable building the mlir CUDA runner")
 118 set(MLIR_ENABLE_ROCM_RUNNER 0 CACHE BOOL "Enable building the mlir ROCm runner")
 119 set(MLIR_ENABLE_SPIRV_CPU_RUNNER 0 CACHE BOOL "Enable building the mlir SPIR-V cpu runner")
 120 set(MLIR_ENABLE_VULKAN_RUNNER 0 CACHE BOOL "Enable building the mlir Vulkan runner")
 121
 122 option(MLIR_INCLUDE_TESTS
 123        "Generate build targets for the MLIR unit tests."
 124        ${LLVM_INCLUDE_TESTS})
 125
 126 option(MLIR_INCLUDE_INTEGRATION_TESTS
 127        "Generate build targets for the MLIR integration tests.")
 128
 129 set(MLIR_INSTALL_AGGREGATE_OBJECTS 1 CACHE BOOL
 130     "Installs object files needed for add_mlir_aggregate to work out of \
 131     tree. Package maintainers can disable this to exclude these assets if \
 132     not desired. Enabling this will result in object files being written \
 133     under lib/objects-{CMAKE_BUILD_TYPE}.")
 134
 135 set(MLIR_BUILD_MLIR_C_DYLIB 0 CACHE BOOL "Builds libMLIR-C shared library.")
 136
 137 configure_file(
 138   ${MLIR_MAIN_INCLUDE_DIR}/mlir/Config/mlir-config.h.cmake
 139   ${MLIR_INCLUDE_DIR}/mlir/Config/mlir-config.h)
 140
 141 #-------------------------------------------------------------------------------
 142 # Python Bindings Configuration
 143 # Requires:
 144 #   The pybind11 library can be found (set with -DPYBIND_DIR=...)
 145 #   The python executable is correct (set with -DPython3_EXECUTABLE=...)
 146 #-------------------------------------------------------------------------------
 147
 148 set(MLIR_ENABLE_BINDINGS_PYTHON 0 CACHE BOOL
 149        "Enables building of Python bindings.")
 150 set(MLIR_DETECT_PYTHON_ENV_PRIME_SEARCH 1 CACHE BOOL
 151        "Prime the python detection by searching for a full 'Development' \
 152        component first (temporary while diagnosing environment specific Python \
 153        detection issues)")
 154 if(MLIR_ENABLE_BINDINGS_PYTHON)
 155   include(MLIRDetectPythonEnv)
 156   mlir_configure_python_dev_packages()
 157 endif()
 158
 159 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 160
 161 include_directories( "include")
 162 include_directories( ${MLIR_INCLUDE_DIR})
 163
 164 # Adding tools/mlir-tblgen here as calling add_tablegen sets some variables like
 165 # MLIR_TABLEGEN_EXE in PARENT_SCOPE which gets lost if that folder is included
 166 # from another directory like tools
 167 add_subdirectory(tools/mlir-tblgen)
 168 add_subdirectory(tools/mlir-linalg-ods-gen)
 169 add_subdirectory(tools/mlir-pdll)
 170
 171 set(MLIR_TABLEGEN_EXE "${MLIR_TABLEGEN_EXE}" CACHE INTERNAL "")
 172 set(MLIR_TABLEGEN_TARGET "${MLIR_TABLEGEN_TARGET}" CACHE INTERNAL "")
 173 set(MLIR_PDLL_TABLEGEN_EXE "${MLIR_PDLL_TABLEGEN_EXE}" CACHE INTERNAL "")
 174 set(MLIR_PDLL_TABLEGEN_TARGET "${MLIR_PDLL_TABLEGEN_TARGET}" CACHE INTERNAL "")
 175
 176 add_subdirectory(include/mlir)
 177 add_subdirectory(lib)
 178 # C API needs all dialects for registration, but should be built before tests.
 179 add_subdirectory(lib/CAPI)
 180
 181 if (MLIR_INCLUDE_TESTS)
 182   add_definitions(-DMLIR_INCLUDE_TESTS)
 183   add_custom_target(MLIRUnitTests)
 184   if (EXISTS ${LLVM_THIRD_PARTY_DIR}/unittest/googletest/include/gtest/gtest.h)
 185     add_subdirectory(unittests)
 186   else()
 187     message(WARNING "gtest not found, unittests will not be available")
 188   endif()
 189   add_subdirectory(test)
 190 endif()
 191 # Tools needs to come late to ensure that MLIR_ALL_LIBS is populated.
 192 # Generally things after this point may depend on MLIR_ALL_LIBS or libMLIR.so.
 193 add_subdirectory(tools)
 194
 195 if(MLIR_ENABLE_BINDINGS_PYTHON)
 196   # Python sources: built extensions come in via lib/Bindings/Python
 197   add_subdirectory(python)
 198 endif()
 199
 200 if( LLVM_INCLUDE_EXAMPLES )
 201   add_subdirectory(examples)
 202 endif()
 203
 204 option(MLIR_INCLUDE_DOCS "Generate build targets for the MLIR docs."
 205   ${LLVM_INCLUDE_DOCS})
 206 if (MLIR_INCLUDE_DOCS)
 207   add_subdirectory(docs)
 208 endif()
 209
 210 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 211   install(DIRECTORY include/mlir include/mlir-c
 212     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
 213     COMPONENT mlir-headers
 214     FILES_MATCHING
 215     PATTERN "*.def"
 216     PATTERN "*.h"
 217     PATTERN "*.inc"
 218     PATTERN "*.td"
 219     PATTERN "LICENSE.TXT"
 220     )
 221
 222   install(DIRECTORY ${MLIR_INCLUDE_DIR}/mlir ${MLIR_INCLUDE_DIR}/mlir-c
 223     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
 224     COMPONENT mlir-headers
 225     FILES_MATCHING
 226     PATTERN "*.def"
 227     PATTERN "*.h"
 228     PATTERN "*.gen"
 229     PATTERN "*.inc"
 230     PATTERN "*.td"
 231     PATTERN "CMakeFiles" EXCLUDE
 232     PATTERN "config.h" EXCLUDE
 233     )
 234
 235   if (NOT LLVM_ENABLE_IDE)
 236     add_llvm_install_targets(install-mlir-headers
 237                              DEPENDS mlir-headers
 238                              COMPONENT mlir-headers)
 239   endif()
 240 endif()
 241
 242 # Custom target to install all mlir libraries
 243 add_custom_target(mlir-libraries)
 244 set_target_properties(mlir-libraries PROPERTIES FOLDER "Misc")
 245
 246 if (NOT LLVM_ENABLE_IDE)
 247   add_llvm_install_targets(install-mlir-libraries
 248                            DEPENDS mlir-libraries
 249                            COMPONENT mlir-libraries)
 250 endif()
 251
 252 get_property(MLIR_LIBS GLOBAL PROPERTY MLIR_ALL_LIBS)
 253 if(MLIR_LIBS)
 254   list(REMOVE_DUPLICATES MLIR_LIBS)
 255   foreach(lib ${MLIR_LIBS})
 256     add_dependencies(mlir-libraries ${lib})
 257     if(NOT LLVM_ENABLE_IDE)
 258       add_dependencies(install-mlir-libraries install-${lib})
 259       add_dependencies(install-mlir-libraries-stripped install-${lib}-stripped)
 260     endif()
 261   endforeach()
 262 endif()
 263
 264 add_subdirectory(cmake/modules)
 265
 266 if (MLIR_ENABLE_PYTHON_BENCHMARKS)
 267   add_subdirectory(utils/mbr)
 268 endif()
 269
 270 if(MLIR_STANDALONE_BUILD)
 271   llvm_distribution_add_targets()
 272 endif()