mlir/test/mlir-vulkan-runner/subf.mlir

   1 // RUN: mlir-vulkan-runner %s --shared-libs=%vulkan-runtime-wrappers,%mlir_runner_utils --entry-point-result=void | FileCheck %s
   2
   3 // CHECK-COUNT-32: [2.2, 2.2, 2.2, 2.2]
   4 module attributes {
   5   gpu.container_module,
   6   spirv.target_env = #spirv.target_env<
   7     #spirv.vce<v1.0, [Shader], [SPV_KHR_storage_buffer_storage_class]>,
   8     #spirv.resource_limits<>>
   9 } {
  10   gpu.module @kernels {
  11     gpu.func @kernel_sub(%arg0 : memref<8x4x4xf32>, %arg1 : memref<4x4xf32>, %arg2 : memref<8x4x4xf32>)
  12       kernel attributes { spirv.entry_point_abi = #spirv.entry_point_abi<workgroup_size = [1, 1, 1]>} {
  13       %x = gpu.block_id x
  14       %y = gpu.block_id y
  15       %z = gpu.block_id z
  16       %1 = memref.load %arg0[%x, %y, %z] : memref<8x4x4xf32>
  17       %2 = memref.load %arg1[%y, %z] : memref<4x4xf32>
  18       %3 = arith.subf %1, %2 : f32
  19       memref.store %3, %arg2[%x, %y, %z] : memref<8x4x4xf32>
  20       gpu.return
  21     }
  22   }
  23
  24   func.func @main() {
  25     %arg0 = memref.alloc() : memref<8x4x4xf32>
  26     %arg1 = memref.alloc() : memref<4x4xf32>
  27     %arg2 = memref.alloc() : memref<8x4x4xf32>
  28     %0 = arith.constant 0 : i32
  29     %1 = arith.constant 1 : i32
  30     %2 = arith.constant 2 : i32
  31     %value0 = arith.constant 0.0 : f32
  32     %value1 = arith.constant 3.3 : f32
  33     %value2 = arith.constant 1.1 : f32
  34     %arg3 = memref.cast %arg0 : memref<8x4x4xf32> to memref<?x?x?xf32>
  35     %arg4 = memref.cast %arg1 : memref<4x4xf32> to memref<?x?xf32>
  36     %arg5 = memref.cast %arg2 : memref<8x4x4xf32> to memref<?x?x?xf32>
  37     call @fillResource3DFloat(%arg3, %value1) : (memref<?x?x?xf32>, f32) -> ()
  38     call @fillResource2DFloat(%arg4, %value2) : (memref<?x?xf32>, f32) -> ()
  39     call @fillResource3DFloat(%arg5, %value0) : (memref<?x?x?xf32>, f32) -> ()
  40
  41     %cst1 = arith.constant 1 : index
  42     %cst4 = arith.constant 4 : index
  43     %cst8 = arith.constant 8 : index
  44     gpu.launch_func @kernels::@kernel_sub
  45         blocks in (%cst8, %cst4, %cst4) threads in (%cst1, %cst1, %cst1)
  46         args(%arg0 : memref<8x4x4xf32>, %arg1 : memref<4x4xf32>, %arg2 : memref<8x4x4xf32>)
  47     %arg6 = memref.cast %arg5 : memref<?x?x?xf32> to memref<*xf32>
  48     call @printMemrefF32(%arg6) : (memref<*xf32>) -> ()
  49     return
  50   }
  51   func.func private @fillResource2DFloat(%0 : memref<?x?xf32>, %1 : f32)
  52   func.func private @fillResource3DFloat(%0 : memref<?x?x?xf32>, %1 : f32)
  53   func.func private @printMemrefF32(%ptr : memref<*xf32>)
  54 }