mlir/test/mlir-vulkan-runner/addi8.mlir

   1 // RUN: mlir-vulkan-runner %s --shared-libs=%vulkan_wrapper_library_dir/libvulkan-runtime-wrappers%shlibext,%linalg_test_lib_dir/libmlir_runner_utils%shlibext --entry-point-result=void | FileCheck %s
   2
   3 // CHECK-COUNT-64: [3, 3, 3, 3, 3, 3, 3, 3]
   4 module attributes {
   5   gpu.container_module,
   6   spv.target_env = #spv.target_env<
   7     #spv.vce<v1.0, [Shader], [SPV_KHR_storage_buffer_storage_class, SPV_KHR_8bit_storage]>, {}>
   8 } {
   9   gpu.module @kernels {
  10     gpu.func @kernel_addi(%arg0 : memref<8xi8>, %arg1 : memref<8x8xi8>, %arg2 : memref<8x8x8xi32>)
  11       kernel attributes { spv.entry_point_abi = {local_size = dense<[1, 1, 1]>: vector<3xi32>}} {
  12       %x = "gpu.block_id"() {dimension = "x"} : () -> index
  13       %y = "gpu.block_id"() {dimension = "y"} : () -> index
  14       %z = "gpu.block_id"() {dimension = "z"} : () -> index
  15       %0 = memref.load %arg0[%x] : memref<8xi8>
  16       %1 = memref.load %arg1[%y, %x] : memref<8x8xi8>
  17       %2 = arith.addi %0, %1 : i8
  18       %3 = arith.extui %2 : i8 to i32
  19       memref.store %3, %arg2[%z, %y, %x] : memref<8x8x8xi32>
  20       gpu.return
  21     }
  22   }
  23
  24   func @main() {
  25     %arg0 = memref.alloc() : memref<8xi8>
  26     %arg1 = memref.alloc() : memref<8x8xi8>
  27     %arg2 = memref.alloc() : memref<8x8x8xi32>
  28     %value0 = arith.constant 0 : i32
  29     %value1 = arith.constant 1 : i8
  30     %value2 = arith.constant 2 : i8
  31     %arg3 = memref.cast %arg0 : memref<8xi8> to memref<?xi8>
  32     %arg4 = memref.cast %arg1 : memref<8x8xi8> to memref<?x?xi8>
  33     %arg5 = memref.cast %arg2 : memref<8x8x8xi32> to memref<?x?x?xi32>
  34     call @fillResource1DInt8(%arg3, %value1) : (memref<?xi8>, i8) -> ()
  35     call @fillResource2DInt8(%arg4, %value2) : (memref<?x?xi8>, i8) -> ()
  36     call @fillResource3DInt(%arg5, %value0) : (memref<?x?x?xi32>, i32) -> ()
  37
  38     %cst1 = arith.constant 1 : index
  39     %cst8 = arith.constant 8 : index
  40     gpu.launch_func @kernels::@kernel_addi
  41         blocks in (%cst8, %cst8, %cst8) threads in (%cst1, %cst1, %cst1)
  42         args(%arg0 : memref<8xi8>, %arg1 : memref<8x8xi8>, %arg2 : memref<8x8x8xi32>)
  43     %arg6 = memref.cast %arg5 : memref<?x?x?xi32> to memref<*xi32>
  44     call @print_memref_i32(%arg6) : (memref<*xi32>) -> ()
  45     return
  46   }
  47   func private @fillResource1DInt8(%0 : memref<?xi8>, %1 : i8)
  48   func private @fillResource2DInt8(%0 : memref<?x?xi8>, %1 : i8)
  49   func private @fillResource3DInt(%0 : memref<?x?x?xi32>, %1 : i32)
  50   func private @print_memref_i32(%ptr : memref<*xi32>)
  51 }