llvm/test/Transforms/Coroutines/coro-alloca-01.ll

   1 ; Tests that CoroSplit can succesfully determine allocas should live on the frame
   2 ; if their aliases are used across suspension points through PHINode.
   3 ; RUN: opt < %s -passes='cgscc(coro-split),simplifycfg,early-cse' -S | FileCheck %s
   4
   5 define i8* @f(i1 %n) "coroutine.presplit"="1" {
   6 entry:
   7   %x = alloca i64
   8   %y = alloca i64
   9   %id = call token @llvm.coro.id(i32 0, i8* null, i8* null, i8* null)
  10   %size = call i32 @llvm.coro.size.i32()
  11   %alloc = call i8* @malloc(i32 %size)
  12   %hdl = call i8* @llvm.coro.begin(token %id, i8* %alloc)
  13   br i1 %n, label %flag_true, label %flag_false
  14
  15 flag_true:
  16   %x.alias = bitcast i64* %x to i32*
  17   br label %merge
  18
  19 flag_false:
  20   %y.alias = bitcast i64* %y to i32*
  21   br label %merge
  22
  23 merge:
  24   %alias_phi = phi i32* [ %x.alias, %flag_true ], [ %y.alias, %flag_false ]
  25   %sp1 = call i8 @llvm.coro.suspend(token none, i1 false)
  26   switch i8 %sp1, label %suspend [i8 0, label %resume
  27                                   i8 1, label %cleanup]
  28 resume:
  29   call void @print(i32* %alias_phi)
  30   br label %cleanup
  31
  32 cleanup:
  33   %mem = call i8* @llvm.coro.free(token %id, i8* %hdl)
  34   call void @free(i8* %mem)
  35   br label %suspend
  36
  37 suspend:
  38   call i1 @llvm.coro.end(i8* %hdl, i1 0)
  39   ret i8* %hdl
  40 }
  41
  42 ; both %x and %y, as well as %alias_phi would all go to the frame.
  43 ; CHECK:       %f.Frame = type { void (%f.Frame*)*, void (%f.Frame*)*, i64, i64, i32*, i1 }
  44 ; CHECK-LABEL: @f(
  45 ; CHECK:         %x.reload.addr = getelementptr inbounds %f.Frame, %f.Frame* %FramePtr, i32 0, i32 2
  46 ; CHECK:         %y.reload.addr = getelementptr inbounds %f.Frame, %f.Frame* %FramePtr, i32 0, i32 3
  47 ; CHECK:         %x.alias = bitcast i64* %x.reload.addr to i32*
  48 ; CHECK:         %y.alias = bitcast i64* %y.reload.addr to i32*
  49 ; CHECK:         %alias_phi = select i1 %n, i32* %x.alias, i32* %y.alias
  50 ; CHECK:         %alias_phi.spill.addr = getelementptr inbounds %f.Frame, %f.Frame* %FramePtr, i32 0, i32 4
  51 ; CHECK:         store i32* %alias_phi, i32** %alias_phi.spill.addr, align 8
  52
  53 declare i8* @llvm.coro.free(token, i8*)
  54 declare i32 @llvm.coro.size.i32()
  55 declare i8  @llvm.coro.suspend(token, i1)
  56 declare void @llvm.coro.resume(i8*)
  57 declare void @llvm.coro.destroy(i8*)
  58
  59 declare token @llvm.coro.id(i32, i8*, i8*, i8*)
  60 declare i1 @llvm.coro.alloc(token)
  61 declare i8* @llvm.coro.begin(token, i8*)
  62 declare i1 @llvm.coro.end(i8*, i1)
  63
  64 declare void @print(i32*)
  65 declare noalias i8* @malloc(i32)
  66 declare void @free(i8*)