llvm/test/Transforms/Coroutines/ex1.ll

   1 ; First example from Doc/Coroutines.rst (one block loop)
   2 ; RUN: opt < %s -aa-pipeline=basic-aa -passes='default<O2>' -enable-coroutines -preserve-alignment-assumptions-during-inlining=false -S | FileCheck %s
   3
   4 define i8* @f(i32 %n) {
   5 entry:
   6   %id = call token @llvm.coro.id(i32 0, i8* null, i8* null, i8* null)
   7   %size = call i32 @llvm.coro.size.i32()
   8   %alloc = call i8* @malloc(i32 %size)
   9   %hdl = call noalias i8* @llvm.coro.begin(token %id, i8* %alloc)
  10   br label %loop
  11 loop:
  12   %n.val = phi i32 [ %n, %entry ], [ %inc, %loop ]
  13   %inc = add nsw i32 %n.val, 1
  14   call void @print(i32 %n.val)
  15   %0 = call i8 @llvm.coro.suspend(token none, i1 false)
  16   switch i8 %0, label %suspend [i8 0, label %loop
  17                                 i8 1, label %cleanup]
  18 cleanup:
  19   %mem = call i8* @llvm.coro.free(token %id, i8* %hdl)
  20   call void @free(i8* %mem)
  21   br label %suspend
  22 suspend:
  23   call i1 @llvm.coro.end(i8* %hdl, i1 false)
  24   ret i8* %hdl
  25 }
  26
  27 ; CHECK-LABEL: @main(
  28 define i32 @main() {
  29 entry:
  30   %hdl = call i8* @f(i32 4)
  31   call void @llvm.coro.resume(i8* %hdl)
  32   call void @llvm.coro.resume(i8* %hdl)
  33   call void @llvm.coro.destroy(i8* %hdl)
  34   ret i32 0
  35 ; CHECK-NEXT: entry:
  36 ; CHECK:      call void @print(i32 4)
  37 ; CHECK:      call void @print(i32 5)
  38 ; CHECK:      call void @print(i32 6)
  39 ; CHECK:      ret i32 0
  40 }
  41
  42 declare i8* @malloc(i32)
  43 declare void @free(i8*)
  44 declare void @print(i32)
  45
  46 declare token @llvm.coro.id(i32, i8*, i8*, i8*)
  47 declare i32 @llvm.coro.size.i32()
  48 declare i8* @llvm.coro.begin(token, i8*)
  49 declare i8 @llvm.coro.suspend(token, i1)
  50 declare i8* @llvm.coro.free(token, i8*)
  51 declare i1 @llvm.coro.end(i8*, i1)
  52
  53 declare void @llvm.coro.resume(i8*)
  54 declare void @llvm.coro.destroy(i8*)