llvm/test/Transforms/Coroutines/ex4.ll

   1 ; Fourth example from Doc/Coroutines.rst (coroutine promise)
   2 ; RUN: opt < %s -passes='default<O2>' -enable-coroutines -S | FileCheck %s
   3
   4 define i8* @f(i32 %n) {
   5 entry:
   6   %promise = alloca i32
   7   %pv = bitcast i32* %promise to i8*
   8   %id = call token @llvm.coro.id(i32 0, i8* %pv, i8* null, i8* null)
   9   %need.dyn.alloc = call i1 @llvm.coro.alloc(token %id)
  10   br i1 %need.dyn.alloc, label %dyn.alloc, label %coro.begin
  11 dyn.alloc:
  12   %size = call i32 @llvm.coro.size.i32()
  13   %alloc = call i8* @malloc(i32 %size)
  14   br label %coro.begin
  15 coro.begin:
  16   %phi = phi i8* [ null, %entry ], [ %alloc, %dyn.alloc ]
  17   %hdl = call noalias i8* @llvm.coro.begin(token %id, i8* %phi)
  18   br label %loop
  19 loop:
  20   %n.val = phi i32 [ %n, %coro.begin ], [ %inc, %loop ]
  21   %inc = add nsw i32 %n.val, 1
  22   store i32 %n.val, i32* %promise
  23   %0 = call i8 @llvm.coro.suspend(token none, i1 false)
  24   switch i8 %0, label %suspend [i8 0, label %loop
  25                                 i8 1, label %cleanup]
  26 cleanup:
  27   %mem = call i8* @llvm.coro.free(token %id, i8* %hdl)
  28   call void @free(i8* %mem)
  29   br label %suspend
  30 suspend:
  31   call i1 @llvm.coro.end(i8* %hdl, i1 false)
  32   ret i8* %hdl
  33 }
  34
  35 ; CHECK-LABEL: @main
  36 define i32 @main() {
  37 entry:
  38   %hdl = call i8* @f(i32 4)
  39   %promise.addr.raw = call i8* @llvm.coro.promise(i8* %hdl, i32 4, i1 false)
  40   %promise.addr = bitcast i8* %promise.addr.raw to i32*
  41   %val0 = load i32, i32* %promise.addr
  42   call void @print(i32 %val0)
  43   call void @llvm.coro.resume(i8* %hdl)
  44   %val1 = load i32, i32* %promise.addr
  45   call void @print(i32 %val1)
  46   call void @llvm.coro.resume(i8* %hdl)
  47   %val2 = load i32, i32* %promise.addr
  48   call void @print(i32 %val2)
  49   call void @llvm.coro.destroy(i8* %hdl)
  50   ret i32 0
  51 ; CHECK:      call void @print(i32 4)
  52 ; CHECK-NEXT: call void @print(i32 5)
  53 ; CHECK-NEXT: call void @print(i32 6)
  54 ; CHECK:      ret i32 0
  55 }
  56
  57 declare i8* @llvm.coro.promise(i8*, i32, i1)
  58 declare i8* @malloc(i32)
  59 declare void @free(i8*)
  60 declare void @print(i32)
  61
  62 declare token @llvm.coro.id(i32, i8*, i8*, i8*)
  63 declare i1 @llvm.coro.alloc(token)
  64 declare i32 @llvm.coro.size.i32()
  65 declare i8* @llvm.coro.begin(token, i8*)
  66 declare i8 @llvm.coro.suspend(token, i1)
  67 declare i8* @llvm.coro.free(token, i8*)
  68 declare i1 @llvm.coro.end(i8*, i1)
  69
  70 declare void @llvm.coro.resume(i8*)
  71 declare void @llvm.coro.destroy(i8*)