llvm/test/Transforms/Coroutines/ex0.ll

   1 ; First example from Doc/Coroutines.rst (two block loop)
   2 ; RUN: opt < %s -aa-pipeline=basic-aa -passes='default<O2>' -preserve-alignment-assumptions-during-inlining=false -S | FileCheck %s
   3
   4 define ptr @f(i32 %n) presplitcoroutine {
   5 entry:
   6   %id = call token @llvm.coro.id(i32 0, ptr null, ptr null, ptr null)
   7   %size = call i32 @llvm.coro.size.i32()
   8   %alloc = call ptr @malloc(i32 %size)
   9   %hdl = call ptr @llvm.coro.begin(token %id, ptr %alloc)
  10   br label %loop
  11
  12 loop:
  13   %n.val = phi i32 [ %n, %entry ], [ %inc, %resume ]
  14   call void @print(i32 %n.val)
  15   %0 = call i8 @llvm.coro.suspend(token none, i1 false)
  16   switch i8 %0, label %suspend [i8 0, label %resume
  17                                 i8 1, label %cleanup]
  18 resume:
  19   %inc = add i32 %n.val, 1
  20   br label %loop
  21
  22 cleanup:
  23   %mem = call ptr @llvm.coro.free(token %id, ptr %hdl)
  24   call void @free(ptr %mem)
  25   br label %suspend
  26 suspend:
  27   call i1 @llvm.coro.end(ptr %hdl, i1 0, token none)
  28   ret ptr %hdl
  29 }
  30
  31 ; CHECK-LABEL: @main(
  32 define i32 @main() {
  33 entry:
  34   %hdl = call ptr @f(i32 4)
  35   call void @llvm.coro.resume(ptr %hdl)
  36   call void @llvm.coro.resume(ptr %hdl)
  37   call void @llvm.coro.destroy(ptr %hdl)
  38   ret i32 0
  39 ; CHECK: entry:
  40 ; CHECK:      call void @print(i32 4)
  41 ; CHECK:      call void @print(i32 5)
  42 ; CHECK:      call void @print(i32 6)
  43 ; CHECK:      ret i32 0
  44 }
  45
  46 declare token @llvm.coro.id(i32, ptr, ptr, ptr)
  47 declare ptr @llvm.coro.alloc(token)
  48 declare ptr @llvm.coro.free(token, ptr)
  49 declare i32 @llvm.coro.size.i32()
  50 declare i8  @llvm.coro.suspend(token, i1)
  51 declare void @llvm.coro.resume(ptr)
  52 declare void @llvm.coro.destroy(ptr)
  53
  54 declare ptr @llvm.coro.begin(token, ptr)
  55 declare i1 @llvm.coro.end(ptr, i1, token)
  56
  57 declare noalias ptr @malloc(i32)
  58 declare void @print(i32)
  59 declare void @free(ptr)