test/Analysis/BasicAA/featuretest.ll

   1 ; This testcase tests for various features the basicaa test should be able to
   2 ; determine, as noted in the comments.
   3
   4 ; RUN: opt < %s -basicaa -gvn -instcombine -dce -S | not grep REMOVE
   5
   6 @Global = external global { i32 }
   7
   8 ; Array test:  Test that operations on one local array do not invalidate
   9 ; operations on another array.  Important for scientific codes.
  10 ;
  11 define i32 @different_array_test(i64 %A, i64 %B) {
  12         %Array1 = alloca i32, i32 100
  13         %Array2 = alloca i32, i32 200
  14
  15         %pointer = getelementptr i32* %Array1, i64 %A
  16         %val = load i32* %pointer
  17
  18         %pointer2 = getelementptr i32* %Array2, i64 %B
  19         store i32 7, i32* %pointer2
  20
  21         %REMOVE = load i32* %pointer ; redundant with above load
  22         %retval = sub i32 %REMOVE, %val
  23         ret i32 %retval
  24 }
  25
  26 ; Constant index test: Constant indexes into the same array should not
  27 ; interfere with each other.  Again, important for scientific codes.
  28 ;
  29 define i32 @constant_array_index_test() {
  30         %Array = alloca i32, i32 100
  31         %P1 = getelementptr i32* %Array, i64 7
  32         %P2 = getelementptr i32* %Array, i64 6
  33
  34         %A = load i32* %P1
  35         store i32 1, i32* %P2   ; Should not invalidate load
  36         %BREMOVE = load i32* %P1
  37         %Val = sub i32 %A, %BREMOVE
  38         ret i32 %Val
  39 }
  40
  41 ; Test that if two pointers are spaced out by a constant getelementptr, that
  42 ; they cannot alias.
  43 define i32 @gep_distance_test(i32* %A) {
  44         %REMOVEu = load i32* %A
  45         %B = getelementptr i32* %A, i64 2  ; Cannot alias A
  46         store i32 7, i32* %B
  47         %REMOVEv = load i32* %A
  48         %r = sub i32 %REMOVEu, %REMOVEv
  49         ret i32 %r
  50 }
  51
  52 ; Test that if two pointers are spaced out by a constant offset, that they
  53 ; cannot alias, even if there is a variable offset between them...
  54 define i32 @gep_distance_test2({i32,i32}* %A, i64 %distance) {
  55         %A1 = getelementptr {i32,i32}* %A, i64 0, i32 0
  56         %REMOVEu = load i32* %A1
  57         %B = getelementptr {i32,i32}* %A, i64 %distance, i32 1
  58         store i32 7, i32* %B    ; B cannot alias A, it's at least 4 bytes away
  59         %REMOVEv = load i32* %A1
  60         %r = sub i32 %REMOVEu, %REMOVEv
  61         ret i32 %r
  62 }
  63
  64 ; Test that we can do funny pointer things and that distance calc will still
  65 ; work.
  66 define i32 @gep_distance_test3(i32 * %A) {
  67         %X = load i32* %A
  68         %B = bitcast i32* %A to i8*
  69         %C = getelementptr i8* %B, i64 4
  70         %Y = load i8* %C
  71         ret i32 8
  72 }
  73
  74 ; Test that we can disambiguate globals reached through constantexpr geps
  75 define i32 @constexpr_test() {
  76    %X = alloca i32
  77    %Y = load i32* %X
  78    store i32 5, i32* getelementptr ({ i32 }* @Global, i64 0, i32 0)
  79    %REMOVE = load i32* %X
  80    %retval = sub i32 %Y, %REMOVE
  81    ret i32 %retval
  82 }