utils/llvm.grm

   1 (*
   2
   3 polygen grammar for LLVM assembly language.
   4
   5 This file defines an LLVM assembly language grammar for polygen,
   6 which is a tool for generating random text based on a grammar.
   7 It is strictly syntax-based, and makes no attempt to generate
   8 IR that is semantically valid. Most of the IR produced doesn't
   9 pass the Verifier.
  10
  11 *)
  12
  13 I ::=   "title:    LLVM assembly language\n"
  14       ^ "status:   experimental\n"
  15       ^ "audience: LLVM developers\n"
  16 ;
  17
  18 S ::= Module ;
  19
  20 (*
  21 Define rules for non-keyword tokens. This is currently just a bunch
  22 of hacks. They don't cover many valid forms of tokens, and they also
  23 generate some invalid forms of tokens. The LLVM parser has custom
  24 C++ code to lex these; custom C++ code for emitting them would be
  25 convenient, but polygen doesn't support that.
  26 *)
  27 NonZeroDecimalDigit ::=     1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 ;
  28 DecimalDigit        ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 ;
  29 DecimalDigitSeq     ::= DecimalDigit [^ DecimalDigitSeq ];
  30 HexDigit            ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9
  31                       | a | b | c | d | e | f ;
  32 HexDigitSeq         ::= HexDigit [^ HexDigitSeq ];
  33 StringChar          ::= a | b | c | d | e | f | g | h | i | j | k | l | m
  34                       | n | o | p | q | r | s | t | u | v | w | x | y | z ;
  35 StringConstantSeq   ::= StringChar [^ StringConstantSeq ];
  36 StringConstant      ::= StringChar [^ StringConstantSeq ];
  37 EUINT64VAL          ::= NonZeroDecimalDigit [^ DecimalDigitSeq ];
  38 ESINT64VAL          ::= [ "-" ] ^ EUINT64VAL ;
  39 EUAPINTVAL          ::= EUINT64VAL ;
  40 ESAPINTVAL          ::= ESINT64VAL ;
  41 LOCALVALID          ::= "%" ^ DecimalDigitSeq ;
  42 GLOBALVALID         ::= "@" ^ DecimalDigitSeq ;
  43 INTTYPE             ::= "i" ^ EUINT64VAL ;
  44 GLOBALVAR           ::= "@" ^ StringConstant ;
  45 LOCALVAR            ::= "%" ^ StringConstant ;
  46 STRINGCONSTANT      ::= "\"" ^ StringConstant ^ "\"" ;
  47 ATSTRINGCONSTANT    ::= "@" ^ STRINGCONSTANT ;
  48 PCTSTRINGCONSTANT   ::= "%" ^ STRINGCONSTANT ;
  49 LABELSTR            ::= StringConstant ;
  50 FPVAL               ::= ESAPINTVAL ^ "." ^ EUAPINTVAL | "0x" ^ HexDigitSeq ;
  51
  52 (*
  53 The rest of this file is derived directly from llvmAsmParser.y.
  54 *)
  55
  56 ArithmeticOps ::= add | sub | mul | udiv | sdiv | fdiv | urem | srem | frem ;
  57 LogicalOps    ::= shl | lshr | ashr | and | or | xor;
  58 CastOps       ::= trunc | zext | sext | fptrunc | fpext | bitcast |
  59                   uitofp | sitofp | fptoui | fptosi | inttoptr | ptrtoint ;
  60
  61 IPredicates ::= eq | ne | slt | sgt | sle | sge | ult | ugt | ule | uge ;
  62
  63 FPredicates ::= oeq | one | olt | ogt | ole | oge | ord | uno | ueq | une
  64               | ult | ugt | ule | uge | true | false ;
  65
  66 IntType ::= INTTYPE;
  67 FPType  ::= float | double | "ppc_fp128" | fp128 | "x86_fp80";
  68
  69 LocalName ::= LOCALVAR | STRINGCONSTANT | PCTSTRINGCONSTANT ;
  70 OptLocalName ::= LocalName | _ ;
  71
  72 OptAddrSpace ::= - addrspace ^ "(" ^ EUINT64VAL ^ ")" | _ ;
  73
  74 OptLocalAssign ::= LocalName "=" | _ ;
  75
  76 GlobalName ::= GLOBALVAR | ATSTRINGCONSTANT ;
  77
  78 OptGlobalAssign ::= GlobalAssign | _ ;
  79
  80 GlobalAssign ::= GlobalName "=" ;
  81
  82 GVInternalLinkage
  83   ::= + internal
  84  | weak
  85  | "weak_odr"
  86  | linkonce
  87  | "linkonce_odr"
  88  | appending
  89  | dllexport
  90  | common
  91  ;
  92
  93 GVExternalLinkage
  94   ::= dllimport
  95  | "extern_weak"
  96  | + external
  97  ;
  98
  99 GVVisibilityStyle
 100   ::= + _
 101  | default
 102  | hidden
 103  | protected
 104  ;
 105
 106 FunctionDeclareLinkage
 107   ::= + _
 108  | dllimport
 109  | "extern_weak"
 110  ;
 111
 112 FunctionDefineLinkage
 113   ::= + _
 114  | internal
 115  | linkonce
 116  | "linkonce_odr"
 117  | weak
 118  | "weak_odr"
 119  | dllexport
 120  ;
 121
 122 AliasLinkage ::= + _ | weak | "weak_odr" | internal ;
 123
 124 OptCallingConv ::= + _ |
 125                  ccc |
 126                  fastcc |
 127                  coldcc |
 128                  "x86_stdcallcc" |
 129                  "x86_fastcallcc" |
 130                  cc EUINT64VAL ;
 131
 132 ParamAttr ::= zeroext
 133  | signext
 134  | inreg
 135  | sret
 136  | noalias
 137  | nocapture
 138  | byval
 139  | nest
 140  | align EUINT64VAL
 141  ;
 142
 143 OptParamAttrs ::= + _ | OptParamAttrs ParamAttr ;
 144
 145 RetAttr       ::= inreg
 146               | zeroext
 147               | signext
 148               | noalias
 149               ;
 150
 151 OptRetAttrs  ::= _
 152              | OptRetAttrs RetAttr
 153              ;
 154
 155 FuncAttr      ::= noreturn
 156  | nounwind
 157  | inreg
 158  | zeroext
 159  | signext
 160  | readnone
 161  | readonly
 162  | noinline
 163  | alwaysinline
 164  | optsize
 165  | ssp
 166  | sspreq
 167  ;
 168
 169 OptFuncAttrs  ::= + _ | OptFuncAttrs FuncAttr ;
 170
 171 OptGC         ::= + _ | gc STRINGCONSTANT ;
 172
 173 OptAlign      ::= + _ | align EUINT64VAL ;
 174 OptCAlign     ::= + _ | ^ "," align EUINT64VAL ;
 175
 176 SectionString ::= section STRINGCONSTANT ;
 177
 178 OptSection    ::= + _ | SectionString ;
 179
 180 GlobalVarAttributes ::= + _ | ^ "," GlobalVarAttribute GlobalVarAttributes ;
 181 GlobalVarAttribute  ::= SectionString | align EUINT64VAL ;
 182
 183 PrimType ::= INTTYPE | float | double | "ppc_fp128" | fp128 | "x86_fp80"
 184           | - label ;
 185
 186 Types
 187   ::= opaque
 188  | PrimType
 189  | Types OptAddrSpace ^ "*"
 190  | SymbolicValueRef
 191  | "\\" ^ EUINT64VAL
 192  | Types "(" ^ ArgTypeListI ^ ")" OptFuncAttrs
 193  | void "(" ^ ArgTypeListI ^ ")" OptFuncAttrs
 194  | "[" ^ EUINT64VAL "x" Types ^ "]"
 195  | "<" ^ EUINT64VAL "x" Types ^ ">"
 196  | "{" TypeListI "}"
 197  | "{" ^ "}"
 198  | "<" ^ "{" TypeListI "}" ^ ">"
 199  | "<" ^ "{" ^ "}" ^ ">"
 200  ;
 201
 202 ArgType ::= Types OptParamAttrs ;
 203
 204 ResultTypes ::= Types | void ;
 205
 206 ArgTypeList ::= ArgType | ArgTypeList ^ "," ArgType ;
 207
 208 ArgTypeListI ::= ArgTypeList | ArgTypeList ^ "," "..." | "..." | _ ;
 209
 210 TypeListI ::= Types | TypeListI ^ "," Types ;
 211
 212 ConstVal::= Types "[" ^ ConstVector ^ "]"
 213  | Types "[" ^ "]"
 214  | Types "c" ^ STRINGCONSTANT
 215  | Types "<" ^ ConstVector ^ ">"
 216  | Types "{" ConstVector "}"
 217  | Types "{" ^ "}"
 218  | Types "<" ^ "{" ConstVector "}" ^ ">"
 219  | Types "<" ^ "{" ^ "}" ^ ">"
 220  | Types null
 221  | Types undef
 222  | Types SymbolicValueRef
 223  | Types ConstExpr
 224  | Types zeroinitializer
 225  | Types ESINT64VAL
 226  | Types ESAPINTVAL
 227  | Types EUINT64VAL
 228  | Types EUAPINTVAL
 229  | Types true
 230  | Types false
 231  | Types FPVAL ;
 232
 233 ConstExpr::= CastOps "(" ^ ConstVal to Types ^ ")"
 234  | getelementptr "(" ^ ConstVal IndexList ^ ")"
 235  | select "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 236  | ArithmeticOps "(" ^ ConstVal ^ "," ConstVal ^ ")"
 237  | LogicalOps "(" ^ ConstVal ^ "," ConstVal ^ ")"
 238  | icmp IPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 239  | fcmp FPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 240  | vicmp IPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 241  | vfcmp FPredicates "(" ^ ConstVal ^ "," ConstVal ^ ")"
 242  | extractelement "(" ^ ConstVal ^ "," ConstVal ^ ")"
 243  | insertelement "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 244  | shufflevector "(" ^ ConstVal ^ "," ConstVal ^ "," ConstVal ^ ")"
 245  | extractvalue "(" ^ ConstVal ^ ConstantIndexList ^ ")"
 246  | insertvalue "(" ^ ConstVal ^ "," ConstVal ^ ConstantIndexList ^ ")" ;
 247
 248 ConstVector ::= ConstVector ^ "," ConstVal | ConstVal ;
 249
 250 GlobalType ::= global | constant ;
 251
 252 ThreadLocal ::= - "thread_local" | _ ;
 253
 254 AliaseeRef ::= ResultTypes SymbolicValueRef
 255  | bitcast "(" ^ AliaseeRef to Types ^ ")" ;
 256
 257 Module ::= +++ DefinitionList | --- _ ;
 258
 259 DefinitionList ::= - Definition | + DefinitionList Definition ;
 260
 261 Definition
 262   ::= ^ ( +++++ define Function
 263  | declare FunctionProto
 264  | - module asm AsmBlock
 265  | OptLocalAssign type Types
 266  | OptGlobalAssign GVVisibilityStyle ThreadLocal OptAddrSpace GlobalType
 267    ConstVal GlobalVarAttributes
 268  | OptGlobalAssign GVInternalLinkage GVVisibilityStyle ThreadLocal OptAddrSpace
 269    GlobalType ConstVal GlobalVarAttributes
 270  | OptGlobalAssign GVExternalLinkage GVVisibilityStyle ThreadLocal OptAddrSpace
 271    GlobalType Types GlobalVarAttributes
 272  | OptGlobalAssign GVVisibilityStyle alias AliasLinkage AliaseeRef
 273  | target TargetDefinition
 274  | deplibs "=" LibrariesDefinition
 275  ) ^ "\n";
 276
 277 AsmBlock ::= STRINGCONSTANT ;
 278
 279 TargetDefinition ::= triple "=" STRINGCONSTANT
 280  | datalayout "=" STRINGCONSTANT ;
 281
 282 LibrariesDefinition ::= "[" ( LibList | _ ) "]";
 283
 284 LibList ::= LibList ^ "," STRINGCONSTANT | STRINGCONSTANT ;
 285
 286 ArgListH ::= ArgListH ^ "," Types OptParamAttrs OptLocalName
 287  | Types OptParamAttrs OptLocalName ;
 288
 289 ArgList ::= ArgListH | ArgListH ^ "," "..." | "..." | _ ;
 290
 291 FunctionHeaderH ::= OptCallingConv OptRetAttrs ResultTypes
 292                   GlobalName ^ "(" ^ ArgList ^ ")"
 293                   OptFuncAttrs OptSection OptAlign OptGC ;
 294
 295 BEGIN ::= ( begin | "{" ) ^ "\n";
 296
 297 FunctionHeader ::=
 298   FunctionDefineLinkage GVVisibilityStyle FunctionHeaderH BEGIN ;
 299
 300 END ::= ^ ( end | "}" ) ^ "\n";
 301
 302 Function ::= BasicBlockList END ;
 303
 304 FunctionProto ::= FunctionDeclareLinkage GVVisibilityStyle FunctionHeaderH ;
 305
 306 OptSideEffect ::= _ | sideeffect ;
 307
 308 ConstValueRef ::= ESINT64VAL
 309  | EUINT64VAL
 310  | FPVAL
 311  | true
 312  | false
 313  | null
 314  | undef
 315  | zeroinitializer
 316  | "<" ConstVector ">"
 317  | "[" ConstVector "]"
 318  | "[" ^ "]"
 319  | "c" ^ STRINGCONSTANT
 320  | "{" ConstVector "}"
 321  | "{" ^ "}"
 322  | "<" ^ "{" ConstVector "}" ^ ">"
 323  | "<" ^ "{" ^ "}" ^ ">"
 324  | ConstExpr
 325  | asm OptSideEffect STRINGCONSTANT ^ "," STRINGCONSTANT ;
 326
 327 SymbolicValueRef ::= LOCALVALID
 328  | GLOBALVALID
 329  | LocalName
 330  | GlobalName ;
 331
 332 ValueRef ::= SymbolicValueRef | ConstValueRef;
 333
 334 ResolvedVal ::= Types ValueRef ;
 335
 336 ReturnedVal ::= ResolvedVal | ReturnedVal ^ "," ResolvedVal ;
 337
 338 BasicBlockList ::= BasicBlockList BasicBlock | FunctionHeader BasicBlock ;
 339
 340 BasicBlock ::= InstructionList OptLocalAssign BBTerminatorInst ;
 341
 342 InstructionList ::= +++ InstructionList Inst
 343  | - _
 344  | ^ LABELSTR ^ ":\n" ;
 345
 346 BBTerminatorInst ::= ^ "  " ^
 347  ( ret ReturnedVal
 348  | ret void
 349  | br label ValueRef
 350  | br INTTYPE ValueRef ^ "," label ValueRef ^ "," label ValueRef
 351  | switch IntType ValueRef ^ "," label ValueRef "[" JumpTable "]"
 352  | switch IntType ValueRef ^ "," label ValueRef "[" ^ "]"
 353  | invoke OptCallingConv ResultTypes ValueRef ^ "(" ^ ParamList ^ ")"
 354    OptFuncAttrs
 355    to label ValueRef unwind label ValueRef
 356  | unwind
 357  | unreachable ) ^ "\n";
 358
 359 JumpTable ::= JumpTable IntType ConstValueRef ^ "," label ValueRef
 360  | IntType ConstValueRef ^ "," label ValueRef ;
 361
 362 Inst ::= ^ "  " ^ OptLocalAssign InstVal ^ "\n";
 363
 364 PHIList ::= Types "[" ValueRef ^ "," ValueRef "]"
 365  | PHIList ^ "," "[" ValueRef ^ "," ValueRef "]" ;
 366
 367 ParamList ::= Types OptParamAttrs ValueRef OptParamAttrs
 368  | label OptParamAttrs ValueRef OptParamAttrs
 369  | ParamList ^ "," Types OptParamAttrs ValueRef OptParamAttrs
 370  | ParamList ^ "," label OptParamAttrs ValueRef OptParamAttrs
 371  | - _ ;
 372
 373 IndexList ::= _ | IndexList ^ "," ResolvedVal ;
 374
 375 ConstantIndexList ::= "," EUINT64VAL | ConstantIndexList ^ "," EUINT64VAL ;
 376
 377 OptTailCall ::= tail call | call ;
 378
 379 InstVal ::=
 380    ArithmeticOps Types ValueRef ^ "," ValueRef
 381  | LogicalOps Types ValueRef ^ "," ValueRef
 382  | icmp IPredicates Types ValueRef ^ "," ValueRef
 383  | fcmp FPredicates Types ValueRef ^ "," ValueRef
 384  | vicmp IPredicates Types ValueRef ^ "," ValueRef
 385  | vfcmp FPredicates Types ValueRef ^ "," ValueRef
 386  | CastOps ResolvedVal to Types
 387  | select ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 388  | "va_arg" ResolvedVal ^ "," Types
 389  | extractelement ResolvedVal ^ "," ResolvedVal
 390  | insertelement ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 391  | shufflevector ResolvedVal ^ "," ResolvedVal ^ "," ResolvedVal
 392  | phi PHIList
 393  | OptTailCall OptCallingConv ResultTypes ValueRef ^ "(" ^ ParamList ^ ")"
 394    OptFuncAttrs
 395  | MemoryInst ;
 396
 397 OptVolatile ::= - volatile | _ ;
 398
 399 MemoryInst ::= malloc Types OptCAlign
 400  | malloc Types ^ "," INTTYPE ValueRef OptCAlign
 401  | alloca Types OptCAlign
 402  | alloca Types ^ "," INTTYPE ValueRef OptCAlign
 403  | free ResolvedVal
 404  | OptVolatile load Types ValueRef OptCAlign
 405  | OptVolatile store ResolvedVal ^ "," Types ValueRef OptCAlign
 406  | getresult Types ValueRef ^ "," EUINT64VAL
 407  | getelementptr Types ValueRef IndexList
 408  | extractvalue Types ValueRef ^ ConstantIndexList
 409  | insertvalue Types ValueRef ^ "," Types ValueRef ^ ConstantIndexList ;