src/gnuplot_def.lisp

   1 ;; gnuplot_def.lisp: routines for Maxima's interface to gnuplot
   2 ;; Copyright (C) 2007-2021 J. Villate
   3 ;; Time-stamp: "2022-02-14 17:40:06 villate"
   4 ;;
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the GNU General Public License
   7 ;; as published by the Free Software Foundation; either version 2
   8 ;; of the License, or (at your option) any later version.
   9 ;;
  10 ;; This program is distributed in the hope that it will be useful,
  11 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;; GNU General Public License for more details.
  14 ;;
  15 ;; You should have received a copy of the GNU General Public License
  16 ;; along with this program; if not, write to the Free Software
  17 ;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
  18 ;; MA  02110-1301, USA
  19
  20 (in-package :maxima)
  21
  22 ;; Checks that color is a six-digit hexadecimal number with the prefix #,
  23 ;; or a symbol for one of the 12 pre-defined colors, in which case the
  24 ;; hexadecimal code for that color will be returned. Unknown colors are
  25 ;; converted into black.
  26 (defun rgb-color (color)
  27   (if (plotcolorp color)
  28       (case color
  29         ($red "#ff0000")
  30         ($green "#00ff00")
  31         ($blue "#0000ff")
  32         ($magenta "#ff00ff")
  33         ($cyan "#00ffff")
  34         ($yellow "#ffff00")
  35         ($orange "#ffa500")
  36         ($violet "#ee82ee")
  37         ($brown "#a52a2a")
  38         ($gray "#bebebe")
  39         ($black "#000000")
  40         ($white "#ffffff")
  41         (t color))
  42       "#000000"))
  43
  44 ;; Given a list of valid colors (see rgb-color function) and an object c
  45 ;; that can be a real number or a string, produces a gnuplot color
  46 ;; specification for c; when c is real, its nearest integer is assigned
  47 ;; to one of the numbers in the list, using modulo length of the list.
  48 (defun gnuplot-color (colors c)
  49   (unless (listp colors) (setq colors (list colors)))
  50   (when (realp c)
  51     (unless (integerp c) (setq c (round c)))
  52     (setq c (nth (mod (1- c) (length colors)) colors)))
  53   (format nil "rgb ~s" (rgb-color c)))
  54
  55 (defun gnuplot-pointtype (type)
  56   (case type
  57     ($bullet 7) ($circle 6) ($plus 1) ($times 2) ($asterisk 3) ($box 5)
  58     ($square 4) ($triangle 9) ($delta 8) ($wedge 11) ($nabla 10)
  59     ($diamond 13) ($lozenge 12) (t 7)))
  60
  61 (defun gnuplot-pointtypes (types n)
  62   (unless (integerp n) (setq n (round n)))
  63   (unless (listp types) (setq types (list types)))
  64   (gnuplot-pointtype (nth (mod (- n 1) (length types)) types)))
  65
  66 ;; style is a list starting with one of the symbols: points, lines,
  67 ;; linespoints or dots,
  68 ;; The meaning of the numbers that follow the symbol are:
  69 ;;
  70 ;;   lines, linewidth, color
  71 ;;   points, radius, color, pointtype
  72 ;;   linespoints, linewidth, radius, color, pointtype
  73 ;;   dots, color
  74 ;;
  75 ;; linewidth and radius are measured in the same units and can be
  76 ;; floating-point numbers.
  77 ;;
  78 ;; type must be an integer
  79 ;; color can be an integer, used as index to get one of the colors defined
  80 ;; by the color option, or a 6-digit hexadecimal number #rrggbb
  81
  82 (defun gnuplot-curve-style (style colors types i)
  83   (unless (listp style) (setq style (list style)))
  84   (unless (listp colors) (setq colors (list colors)))
  85   (with-output-to-string
  86     (st)
  87     (case (first style)
  88       ($dots
  89        (format st "with dots")
  90        (if (second style)
  91          (format st " lt ~d" (gnuplot-color colors (second style)))
  92          (format st " lt ~d" (gnuplot-color colors i))))
  93       ($impulses
  94        (format st "with impulses")
  95        (if (integerp (second style))
  96          (format st " lt ~d" (gnuplot-color colors (second style)))
  97          (format st " lt ~d" (gnuplot-color colors i))))
  98       ($lines
  99        (format st "with lines")
 100        (if (realp (second style))
 101          (format st " lw ~f" (second style)))
 102        (if (third style)
 103          (format st " lt ~d" (gnuplot-color colors (third style)))
 104          (format st " lt ~d" (gnuplot-color colors i))))
 105       ($points
 106        (format st "with points")
 107        (if (realp (second style))
 108          (format st " ps ~f" (/ (second style) 2))
 109          (format st " ps 1.5"))
 110        (if (third style)
 111          (format st " lt ~d" (gnuplot-color colors (third style)))
 112          (format st " lt ~d" (gnuplot-color colors i)))
 113        (if (integerp (fourth style))
 114          (format st " pt ~d" (gnuplot-pointtypes types (fourth style)))
 115          (format st " pt ~d" (gnuplot-pointtypes types i))))
 116       ($linespoints
 117        (format st "with linespoints")
 118        (if (realp (second style))
 119          (format st " lw ~f" (second style)))
 120        (if (realp (third style))
 121          (format st " ps ~f" (/ (third style) 2))
 122          (format st " ps 1.5"))
 123        (if (fourth style)
 124          (format st " lt ~d" (gnuplot-color colors (fourth style)))
 125          (format st " lt ~d" (gnuplot-color colors i)))
 126        (if (integerp (fifth style))
 127          (format st " pt ~d" (gnuplot-pointtypes types (fifth style)))
 128          (format st " pt ~d" (gnuplot-pointtypes types i))))
 129       (t (format st "with lines lt ~d" (gnuplot-color colors i))))))
 130
 131 (defun gnuplot-palette (palette)
 132 ;; palette should be a list starting with one of the symbols: hue,
 133 ;; saturation, value, gray or gradient.
 134 ;;
 135 ;; If the symbol is gray, it should be followed by two floating point
 136 ;; numbers that indicate the initial gray level and the interval of
 137 ;; gray values.
 138 ;;
 139 ;; If the symbol is one of hue, saturation or value, it must be followed
 140 ;; by three numbers that specify the hue, saturation and value for the
 141 ;; initial color, and a fourth number that gives the range of values for
 142 ;; the increment of hue, saturation or value.
 143 ;; The values for the initial hue, saturation, value and grayness should
 144 ;; be within 0 and 1, while the range can be higher or even negative.
 145 ;;
 146 ;; If the symbol is gradient, it must be followed by either a list of valid
 147 ;; colors or by a list of lists with two elements, a number and a valid color.
 148
 149   (unless (listp palette) (setq palette (list palette)))
 150   (let (hue sat val gray range fun)
 151     (case (first palette)
 152       ($gray
 153        (case (length (rest palette))
 154          (2 (setq gray (second palette)) (setq range (third palette)))
 155          (t (merror
 156              (intl:gettext
 157               "palette: gray must be followed by two numbers."))))
 158        (when (or (< gray 0) (> gray 1))
 159          (setq gray (- gray (floor gray)))))
 160       (($hue $saturation $value)
 161        (case (length (rest palette))
 162          (4 (setq hue (second palette))
 163             (setq sat (third palette))
 164             (setq val (fourth palette))
 165             (setq range (fifth palette)))
 166          (t (merror
 167              (intl:gettext
 168               "palette: ~M must be followed by four numbers.")
 169               (first palette))))
 170        (when (or (< hue 0) (> hue 1)) (setq hue (- hue (floor hue))))
 171        (when (or (< sat 0) (> sat 1)) (setq sat (- sat (floor sat))))
 172        (when (or (< val 0) (> val 1)) (setq val (- val (floor val))))))
 173     (with-output-to-string (st)
 174       (case (first palette)
 175         ($hue
 176          (if (or (< (+ hue range) 0) (> (+ hue range) 1))
 177              (setq fun (format nil "~,3f+~,3f*gray-floor(~,3f+~,3f*gray)"
 178                                hue range hue range))
 179              (setq fun (format nil "~,3f+~,3f*gray" hue range)))
 180          (format st "model HSV functions ~a, ~,3f, ~,3f" fun sat val))
 181         ($saturation
 182          (if (or (< (+ sat range) 0) (> (+ sat range) 1))
 183              (setq fun (format nil "~,3f+~,3f*gray-floor(~,3f+~,3f*gray)"
 184                                sat range sat range))
 185              (setq fun (format nil "~,3f+~,3f*gray" sat range)))
 186          (format st "model HSV functions ~,3f, ~a, ~,3f" hue fun val))
 187         ($value
 188          (if (or (< (+ val range) 0) (> (+ val range) 1))
 189              (setq fun (format nil "~,3f+~,3f*gray" val range))
 190              (setq fun (format nil "~,3f+~,3f*gray-floor(~,3f+~,3f*gray)"
 191                                val range val range)))
 192          (format st "model HSV functions ~,3f, ~,3f, ~a" hue sat fun))
 193         ($gray
 194          (if (or (< (+ gray range) 0) (> (+ gray range) 1))
 195              (setq fun (format nil "~,3f+~,3f*gray" gray range))
 196              (setq fun (format nil "~,3f+~,3f*gray-floor(~,3f+~,3f*gray)"
 197                                gray range gray range)))
 198          (format st "model RGB functions ~a, ~a, ~a" fun fun fun))
 199
 200         ($gradient
 201          (let* ((colors (rest palette)) (n (length colors)) (map nil))
 202            ;; map is constructed as (n1 c1 n2 c2 ... nj cj) where ni is a
 203            ;; decreasing sequence of numbers (n1=1, nj=0) and ci are colors
 204            (cond
 205              ;; Maxima list of numbers and colors (((mlist) ni ci) ...)
 206              ((listp (first colors))
 207               (setq colors (sort colors #'< :key #'cadr))
 208               (dotimes (i n)
 209                 (setq map (cons (rgb-color (third (nth i colors))) ;; color
 210                                 (cons
 211                                  (/ (- (second (nth i colors))   ;; ni minus
 212                                        (second (first colors)))  ;; smallest ni
 213                                     (- (second (nth (- n 1) colors));; biggest
 214                                        (second (first colors)))) ;; - smallest
 215                                  map)))))
 216              ;; list of only colors
 217              (t (dotimes (i n)
 218                   (setq map (cons (rgb-color (nth i colors))  ;; color i
 219                                   (cons (/ i (1- n)) map))))))    ;; number i
 220
 221            ;; prints map with the format:  nj, "cj", ...,n1, "c1"
 222            (setq fun (format nil "~{~f ~s~^, ~}" (reverse map)))
 223            ;; outputs the string: defined (nj, "cj", ...,n1, "c1")
 224            (format st "defined (~a)" fun)))
 225         (t
 226          (merror
 227           (intl:gettext
 228            "palette: wrong keyword ~M. Must be hue, saturation, value, gray or gradient.")
 229           (first palette)))))))
 230
 231 (defun gnuplot-plot3d-command (file palette gstyles colors gstrings titles n)
 232 (let (title (style "with pm3d"))
 233   (with-output-to-string (out)
 234     (format out "splot ")
 235   (do ((i 1 (+ i 1))) ((> i n) (format out "~%"))
 236     (unless palette
 237       (if gstyles
 238           (setq style (ensure-string (nth (mod i (length gstyles)) gstyles)))
 239           (setq style
 240                 (format nil "with lines lt ~a" (gnuplot-color colors i)))))
 241     (when (> i 1) (format out ", "))
 242     (if titles
 243         (setq title (nth (mod i (length titles)) titles))
 244         (setq title ""))
 245     (format out "~s title ~s ~a ~a" file title gstrings style)))))
 246
 247 (defun gnuplot-terminal-and-file (plot-options)
 248 (let (terminal-command out-file (preserve-file t))
 249   (cond
 250     ((getf plot-options :svg_file)
 251      (if (getf plot-options :gnuplot_svg_term_command)
 252          (setq terminal-command
 253                (getf plot-options :gnuplot_svg_term_command))
 254          (setq terminal-command "set term svg font \",14\""))
 255      (setq out-file (getf plot-options :svg_file)))
 256     ((getf plot-options :png_file)
 257      (if (getf plot-options :gnuplot_png_term_command)
 258          (setq terminal-command
 259                (getf plot-options :gnuplot_png_term_command))
 260          (setq terminal-command "set term pngcairo font \",12\""))
 261      (setq out-file (getf plot-options :png_file)))
 262     ((getf plot-options :pdf_file)
 263      (if (getf plot-options :gnuplot_pdf_term_command)
 264          (setq terminal-command
 265                (getf plot-options :gnuplot_pdf_term_command))
 266          (setq terminal-command "set term pdfcairo color solid lw 3 size 17.2 cm, 12.9 cm font \",18\""))
 267      (setq out-file (getf plot-options :pdf_file)))
 268     ((getf plot-options :ps_file)
 269      (if (getf plot-options :gnuplot_ps_term_command)
 270          (setq terminal-command
 271                (getf plot-options :gnuplot_ps_term_command))
 272          (setq terminal-command "set term postscript eps color solid lw 2 size 16.4 cm, 12.3 cm font \",24\""))
 273      (setq out-file (getf plot-options :ps_file)))
 274     ((eq (getf plot-options :gnuplot_term) '$ps)
 275      (if (getf plot-options :gnuplot_ps_term_command)
 276          (setq terminal-command
 277                (getf plot-options :gnuplot_ps_term_command))
 278          (setq terminal-command "set term postscript eps color solid lw 2 size 16.4 cm, 12.3 cm font \",24\""))
 279      (if (getf plot-options :gnuplot_out_file)
 280          (setq out-file (getf plot-options :gnuplot_out_file))
 281          (setq out-file "maxplot.ps")))
 282     ((eq (getf plot-options :gnuplot_term) '$dumb)
 283      (if (getf plot-options :gnuplot_dumb_term_command)
 284          (setq terminal-command
 285                (getf plot-options :gnuplot_ps_term_command))
 286          (setq terminal-command "set term dumb 79 22"))
 287      (if (getf plot-options :gnuplot_out_file)
 288          (setq out-file (getf plot-options :gnuplot_out_file))
 289          (setq out-file "maxplot.txt")))
 290     ((eq (getf plot-options :gnuplot_term) '$default)
 291      (if (getf plot-options :gnuplot_default_term_command)
 292          (setq terminal-command
 293                (getf plot-options :gnuplot_default_term_command))
 294          (setq terminal-command
 295                (format nil "set term GPVAL_TERM title ~s"
 296                        (getf plot-options :type)))))
 297     ((getf plot-options :gnuplot_term)
 298      (setq
 299       terminal-command
 300           (format nil "set term ~(~a~)"
 301            (ensure-string (getf plot-options :gnuplot_term))))
 302      (if (getf plot-options :gnuplot_out_file)
 303          (setq out-file (getf plot-options :gnuplot_out_file))
 304          (setq preserve-file nil
 305           out-file
 306           (format nil "maxplot.~(~a~)"
 307                   (get-gnuplot-term (getf plot-options :gnuplot_term)))))))
 308
 309   (unless (null out-file) (setq out-file (plot-file-path out-file preserve-file plot-options)))
 310   (list terminal-command out-file)))
 311
 312 (defmethod plot-preamble ((plot gnuplot-plot) plot-options)
 313   (let ((palette (getf plot-options :palette))
 314                       (meshcolor (if (member :mesh_lines_color plot-options)
 315                                      (getf plot-options :mesh_lines_color)
 316                                      '$black))
 317                       (gstrings (if (getf plot-options :gnuplot_strings)
 318                                     "" "noenhanced"))  terminal-file)
 319     (when (find 'mlist palette :key #'car) (setq palette (list palette)))
 320     ;; sets-up terminal command and output file name
 321     (setq terminal-file (gnuplot-terminal-and-file plot-options))
 322     (setf
 323      (slot-value plot 'data)
 324      (concatenate
 325       'string
 326       (slot-value plot 'data)
 327       (with-output-to-string (dest)
 328         ;; user's preamble
 329         (when (and (getf plot-options :gnuplot_preamble)
 330                    (> (length  (getf plot-options :gnuplot_preamble)) 0))
 331           (format dest "~a~%" (getf plot-options :gnuplot_preamble)))
 332         ;; Don't round numbers with absolute value less than 1e-8 to zero
 333         (format dest "set zero 0.0~%")
 334         ;; prints terminal and output commands
 335         (when (first terminal-file)
 336           (format dest "~a~%" (first terminal-file)))
 337         (when (second terminal-file)
 338           (format dest "set output ~s~%" (second terminal-file)))
 339         ;; options specific to plot3d
 340         (when (string= (getf plot-options :type) "plot3d")
 341           (format dest "set xyplane relative 0~%")
 342           (if palette
 343               (progn
 344                 (if meshcolor
 345                     (progn
 346                       (format dest "set style line 100 lt rgb ~s lw 1~%"
 347                               (rgb-color meshcolor))
 348                       (format dest "set pm3d hidden3d 100~%")
 349                       (unless (getf plot-options :gnuplot_4_0)
 350                         (format dest "set pm3d depthorder~%")))
 351                     (format dest "set pm3d~%"))
 352                 (format dest "unset hidden3d~%")
 353                 (format dest "set palette ~a~%"
 354                         (gnuplot-palette (rest (first palette)))))
 355               (format dest "set hidden3d~%"))
 356           (let ((elev (getf plot-options :elevation))
 357                 (azim (getf plot-options :azimuth)))
 358             (when (or elev azim)
 359               (if elev
 360                   (format dest "set view ~d" elev)
 361                   (format dest "set view "))
 362               (when azim (format dest ", ~d" azim))
 363               (format dest "~%"))))
 364         ;; color_bar can be used by plot3d or plot2d
 365         (unless (getf plot-options :color_bar)
 366           (format dest "unset colorbox~%"))
 367         ;; ----- BEGIN GNUPLOT 4.0 WORK-AROUND -----
 368         ;; When the expression plotted is constant, Gnuplot 4.0 fails
 369         ;; with a division by 0.  Explicitly assigning cbrange prevents
 370         ;; the error. Also set zrange to match cbrange.
 371         (when (floatp (getf plot-options :const_expr))
 372           (format
 373            dest "set cbrange [~a : ~a]~%"
 374            (1- (getf plot-options :const_expr))
 375            (1+ (getf plot-options :const_expr)))
 376           (format
 377            dest "set zrange [~a : ~a]~%"
 378            (1- (getf plot-options :const_expr))
 379            (1+ (getf plot-options :const_expr))))
 380         ;; -----  END GNUPLOT 4.0 WORK-AROUND  -----
 381         ;; logarithmic plots
 382         (when (getf plot-options :logx) (format dest "set log x~%"))
 383         (when (getf plot-options :logy) (format dest "set log y~%"))
 384         ;; axes labels and legend
 385         (when (getf plot-options :xlabel)
 386           (format dest
 387                   "set xlabel ~s ~a~%" (getf plot-options :xlabel) gstrings))
 388         (when (getf plot-options :ylabel)
 389           (format dest
 390                   "set ylabel ~s ~a~%" (getf plot-options :ylabel) gstrings))
 391         (when (getf plot-options :zlabel)
 392           (format dest
 393                   "set zlabel ~s ~a~%" (getf plot-options :zlabel) gstrings))
 394         (when (and (member :legend plot-options)
 395                    (null (getf plot-options :legend)))
 396           (format dest "unset key~%"))
 397         ;; plotting box
 398         (when (and (member :box plot-options) (not (getf plot-options :box)))
 399           (format dest "unset border~%")
 400           (if (and (getf plot-options :axes)
 401                    (string= (getf plot-options :type) "plot2d"))
 402               (format dest "set xtics axis~%set ytics axis~%set ztics axis~%")
 403               (format dest "unset xtics~%unset ytics~%unset ztics~%")))
 404         ;; 2d grid (specific to plot2d)
 405         (when (string= (getf plot-options :type) "plot2d")
 406           (format dest "set grid front~%")
 407           (if (getf plot-options :grid2d)
 408               (format dest "set grid~%")
 409               (format dest "unset grid~%"))
 410           ;; plot size and aspect ratio for plot2d
 411           (if (getf plot-options :same_xy)
 412               (format dest "set size ratio -1~%")
 413               (if (getf plot-options :yx_ratio)
 414                   (format dest "set size ratio ~f~%"
 415                           (getf plot-options :yx_ratio))
 416                   (if (not (getf plot-options :xy_scale))
 417                       ;; emit the default only if there is no xy_scale specified.
 418                       (format dest "set size ratio 0.75~%"))))
 419           (if (and (getf plot-options :xy_scale)
 420                    (listp (getf plot-options :xy_scale)))
 421               (format dest "set size ~{~f~^, ~}~%"
 422                       (getf plot-options :xy_scale))))
 423         ;; plot size and aspect ratio for plot3d
 424         (when (string= (getf plot-options :type) "plot3d")
 425           (when (getf plot-options :same_xy)
 426             (format dest "set view equal xy~%"))
 427           (when (getf plot-options :same_xyz)
 428             (format dest "set view equal xyz~%"))
 429           (when (getf plot-options :zmin)
 430             (format dest "set xyplane at ~f~%" (getf plot-options :zmin))))
 431         ;; axes tics
 432         (when (member :xtics plot-options)
 433           (let ((xtics (getf plot-options :xtics)))
 434             (if (consp xtics)
 435                 (format dest "set xtics ~{~f~^, ~}~%" xtics)
 436                 (if xtics
 437                     (format dest "set xtics ~f~%" xtics)
 438                     (format dest "unset xtics~%")))))
 439         (when (member :ytics plot-options)
 440           (let ((ytics (getf plot-options :ytics)))
 441             (if (consp ytics)
 442                 (format dest "set ytics ~{~f~^, ~}~%" ytics)
 443                 (if ytics
 444                     (format dest "set ytics ~f~%" ytics)
 445                     (format dest "unset ytics~%")))))
 446         (when (member :ztics plot-options)
 447           (let ((ztics (getf plot-options :ztics)))
 448             (if (consp ztics)
 449                 (format dest "set ztics ~{~f~^, ~}~%" ztics)
 450                 (if ztics
 451                     (format dest "set ztics ~f~%" ztics)
 452                     (format dest "unset ztics~%")))))
 453         (when (member :color_bar_tics plot-options)
 454           (let ((cbtics (getf plot-options :color_bar_tics)))
 455             (if (consp cbtics)
 456                 (format dest "set cbtics ~{~f~^, ~}~%" cbtics)
 457                 (if cbtics
 458                     (format dest "set cbtics ~f~%" cbtics)
 459                     (format dest "unset cbtics~%")))))
 460         ;; axes ranges and style
 461         (when (and (getf plot-options :x) (listp (getf plot-options :x)))
 462           (format dest "set xrange [~{~,,,,,,'eg~^ : ~}]~%" (getf plot-options :x)))
 463         (when (and (getf plot-options :y) (listp (getf plot-options :y)))
 464           (format dest "set yrange [~{~,,,,,,'eg~^ : ~}]~%" (getf plot-options :y)))
 465         (when (and (getf plot-options :z) (listp (getf plot-options :z)))
 466           (format dest "set zrange [~{~,,,,,,'eg~^ : ~}]~%" (getf plot-options :z)))
 467         (when (and (string= (getf plot-options :type) "plot2d")
 468                    (member :axes plot-options))
 469           (if (getf plot-options :axes)
 470               (case (getf plot-options :axes)
 471                 ($x (format dest "set xzeroaxis~%"))
 472                 ($y (format dest "set yzeroaxis~%"))
 473                 ($solid (format dest "set zeroaxis lt -1~%"))
 474                 (t (format dest "set zeroaxis~%")))))
 475         ;; title and labels
 476         (when (getf plot-options :title)
 477           (format dest "set title ~s ~a~%" (getf plot-options :title) gstrings))
 478         (when (getf plot-options :label)
 479           (dolist (label (getf plot-options :label))
 480             (when (and (listp label) (= (length label) 4))
 481               (format dest "set label ~s ~a at ~{~f~^, ~}~%"
 482                       (cadr label) gstrings (cddr label)))))
 483         ;; identifier for missing data
 484         (format dest "set datafile missing ~s~%" *missing-data-indicator*))))
 485     ;;returns a list with the name of the file created, or nil
 486     (if (null (second terminal-file))
 487         nil (list (second terminal-file)))))
 488
 489 (defmethod plot2d-command ((plot gnuplot-plot) fun options range)
 490   ;; Compute points to plot for each element of FUN.
 491   ;; If no plottable points are found, end with an error.
 492   (let (points-lists)
 493     (setq points-lists
 494           (mapcar #'(lambda (f) (cdr (draw2d f range options))) (cdr fun)))
 495     (when (= (count-if #'(lambda (x) x) points-lists) 0)
 496       (merror (intl:gettext "plot2d: nothing to plot.~%")))
 497     (setf
 498      (slot-value plot 'data)
 499      (concatenate
 500       'string
 501       (slot-value plot 'data)
 502       (with-output-to-string (st)
 503         (unless (or (getf options :logy)
 504                     (and (getf options :y) (listp (getf options :y))))
 505           (let (y ymin ymax)
 506             (dolist (points-list points-lists)
 507               (dotimes (i (/ (length points-list) 2))
 508                 (setq y (nth (1+ (* i 2)) points-list))
 509                 (when (numberp y)
 510                   (if (numberp ymin)
 511                       (if (numberp ymax)
 512                           (progn
 513                             (when (< y ymin) (setq ymin y))
 514                             (when (> y ymax) (setq ymax y)))
 515                           (if (< y ymin)
 516                               (setq ymax ymin ymin y)
 517                               (setq ymax y)))
 518                       (if (numberp ymax)
 519                           (if (> y ymax)
 520                               (setq ymin ymax ymax y)
 521                               (setq ymin y))
 522                           (setq ymin y))))))
 523             (when (and (numberp ymin) (numberp ymax) (< ymin ymax))
 524               (psetq ymin (- (* 1.05 ymin) (* 0.05 ymax))
 525                      ymax (- (* 1.05 ymax) (* 0.05 ymin)))
 526               (format st "set yrange [~,,,,,,'eg: ~,,,,,,'eg]~%" ymin ymax))))
 527         ;; user's commands; may overule any of the previous settings
 528         (when (and (getf options :gnuplot_postamble)
 529                    (> (length  (getf options :gnuplot_postamble)) 0))
 530           (format st "~a~%" (getf options :gnuplot_postamble)))
 531         ;; plot command
 532         (format st "plot")
 533         (when (getf options :x)
 534           (format st " [~{~,,,,,,'eg~^ : ~}]" (getf options :x)))
 535         (when (getf options :y)
 536           (unless (getf options :x)
 537             (format st " []"))
 538           (format st " [~{~,,,,,,'eg~^ : ~}]"  (getf options :y)))
 539         (let ((legend (getf options :legend))
 540               (colors (getf options :color))
 541               (types (getf options :point_type))
 542               (styles (getf options :style))
 543               (gstrings (if (getf options :gnuplot_strings) "" "noenhanced "))
 544               (i 0) style plot-name)
 545           (unless (listp legend) (setq legend (list legend)))
 546           (unless (listp colors) (setq colors (list colors)))
 547           (unless (listp styles) (setq styles (list styles)))
 548           (loop for v in (cdr fun) for points-list in points-lists do
 549                (when points-list
 550                  (when ($listp (car points-list))
 551                    (dolist (level (cdar points-list))
 552                      (if styles
 553                          (setq style (nth (mod i (length styles)) styles))
 554                          (setq style nil))
 555                      (when ($listp style) (setq style (cdr style)))
 556                      (incf i)
 557                      (setq plot-name (ensure-string level))
 558                      (when (> i 1) (format st ","))
 559                      (format st " '-'")
 560                      (format st " title ~s ~a" plot-name gstrings)
 561                      (format st (gnuplot-curve-style style colors types i)))
 562                    (return))
 563                  (if styles
 564                      (setq style (nth (mod i (length styles)) styles))
 565                      (setq style nil))
 566                  (when ($listp style) (setq style (cdr style)))
 567                  (incf i)
 568                  ;; label the expression according to the legend,
 569                  ;; unless it is "false" or there is only one expression
 570                  (if (member :legend options)
 571                      (setq plot-name
 572                            (if (first legend)
 573                                (ensure-string
 574                                 (nth (mod (- i 1) (length legend)) legend)) nil))
 575                      (if (= 2 (length fun))
 576                          (setq plot-name nil)
 577                          (progn
 578                            (setq
 579                             plot-name
 580                             (with-output-to-string (pn)
 581                               (cond ((atom v) (format pn "~a" ($sconcat v)))
 582                                     ((eq (second v) '$parametric)
 583                                      (format pn "~a, ~a"
 584                                              ($sconcat (third v))
 585                                              ($sconcat (fourth v))))
 586                                     ((eq (second v) '$discrete)
 587                                      (format pn "discrete~a" i))
 588                                     (t (format pn "~a" ($sconcat v))))))
 589                            (when (> (length plot-name) 50)
 590                              (setq plot-name (format nil "fun~a" i))))))
 591                  (when (> i 1) (format st ","))
 592                  (format st " '-'")
 593                  (if plot-name
 594                      (format st " title ~s ~a" plot-name gstrings)
 595                      (format st " notitle "))
 596                  (format st (gnuplot-curve-style style colors types i)))))
 597         ;; Parses points data
 598         (format st "~%")
 599         (let (in-discontinuity points)
 600           (loop for points-list in points-lists do
 601                (when points-list
 602                  ;; case "contour" with several plots in one list
 603                  (when ($listp (car points-list))
 604                    (dolist (level (cdr points-list))
 605                      (loop for (v w) on (cdr level) by #'cddr do
 606                           (cond ((eq v 'moveto)
 607                                  ;; A blank line means a discontinuity
 608                                  (if (null in-discontinuity)
 609                                      (progn
 610                                        (format st "~%")
 611                                        (setq in-discontinuity t))))
 612                                 (t
 613                                  (format st "~,,,,,,'eg ~,,,,,,'eg ~%" v w)
 614                                  (setq points t)
 615                                  (setq in-discontinuity nil))))
 616                      (if (and (null points)
 617                               (first (getf options :x))
 618                               (first (getf options :y)))
 619                          (format st "~,,,,,,'eg ~,,,,,,'eg ~%"
 620                                  (first (getf options :x))
 621                                  (first (getf options :y))))
 622                      (format st "e~%"))
 623                    (return))
 624                  ;; other cases with only one plot per list
 625                  (loop for (v w) on points-list by #'cddr do
 626                       (cond ((eq v 'moveto)
 627                              ;; A blank line means a discontinuity
 628                              (if (null in-discontinuity)
 629                                  (progn
 630                                    (format st "~%")
 631                                    (setq in-discontinuity t))))
 632                             (t
 633                              (format st "~,,,,,,'eg ~,,,,,,'eg ~%" v w)
 634                              (setq points t)
 635                              (setq in-discontinuity nil))))
 636                  (if (and (null points)
 637                           (first (getf options :x)) (first (getf options :y)))
 638                      (format st "~,,,,,,'eg ~,,,,,,'eg ~%"
 639                              (first (getf options :x))
 640                              (first (getf options :y)))))
 641                (when points-list (format st "e~%")))))))))
 642
 643 (defmethod plot3d-command ((plot gnuplot-plot) functions options titles)
 644   (let ((i 0) fun xrange yrange lvars trans (n (length functions))
 645     (gstrings (if (getf options :gnuplot_strings) "" "")))
 646     (setf
 647      (slot-value plot 'data)
 648      (concatenate
 649       'string
 650       (slot-value plot 'data)
 651       (with-output-to-string ($pstream)
 652         (format $pstream "~a"
 653                 (gnuplot-plot3d-command "-" (getf options :palette)
 654                                         (getf options :gnuplot_curve_styles)
 655                                         (getf options :color)
 656                                         gstrings titles n))
 657         ;; generate the mesh points for each surface in the functions stack
 658         (dolist (f functions)
 659           (setq i (+ 1 i))
 660           (setq fun (first f))
 661           (setq xrange (second f))
 662           (setq yrange (third f))
 663           (if ($listp fun)
 664               (progn
 665                 (setq trans
 666                       ($make_transform `((mlist) ,(second xrange)
 667                                          ,(second yrange) $z)
 668                                        (second fun) (third fun) (fourth fun)))
 669                 (setq fun '$zero_fun))
 670               (let*
 671                   ((x0 (third xrange))
 672                    (x1 (fourth xrange))
 673                    (y0 (third yrange))
 674                    (y1 (fourth yrange))
 675                    (xmid (+ x0 (/ (- x1 x0) 2)))
 676                    (ymid (+ y0 (/ (- y1 y0) 2))))
 677                 (setq lvars `((mlist) ,(second xrange) ,(second yrange)))
 678                 (setq fun (coerce-float-fun fun lvars "plot3d"))
 679                 ;; Evaluate FUN at the middle point of the range.
 680                 ;; Looking at a single point is somewhat unreliable.
 681                 ;; Call FUN with numerical arguments (symbolic arguments may
 682                 ;; fail due to trouble computing real/imaginary parts for
 683                 ;; complicated expressions, or it may be a numerical function)
 684                 (when (cdr ($listofvars (mfuncall fun xmid ymid)))
 685                   (mtell
 686                    (intl:gettext
 687                     "plot3d: expected <expr. of v1 and v2>, [v1,min,max], [v2,min,max]~%"))
 688                   (mtell
 689                    (intl:gettext
 690                     "plot3d: keep going and hope for the best.~%")))))
 691           (let* ((pl
 692                   (draw3d
 693                    fun (third xrange) (fourth xrange) (third yrange)
 694                    (fourth yrange) (first (getf options :grid))
 695                    (second (getf options :grid))))
 696                  (ar (polygon-pts pl)))
 697             (declare (type (cl:array t) ar))
 698             (when trans (mfuncall trans ar))
 699             (when (getf options :transform_xy)
 700               (mfuncall (getf options :transform_xy) ar))
 701             (output-points pl (first (getf options :grid)))
 702             (format $pstream "e~%"))))))))
 703
 704 (defmethod plot-shipout ((plot gnuplot-plot) options &optional output-file)
 705    (case (getf options :plot_format)
 706      ($gnuplot
 707       (let ((file (plot-set-gnuplot-script-file-name options)))
 708         (with-open-file (fl
 709                          #+sbcl (sb-ext:native-namestring file)
 710                          #-sbcl file
 711                          :direction :output :if-exists :supersede)
 712           (format fl "~a" (slot-value plot 'data))
 713           (format fl "pause mouse close~%"))
 714         (gnuplot-process options file output-file)
 715         (cons '(mlist) (cons file output-file))))
 716      ($gnuplot_pipes
 717       (check-gnuplot-process)
 718       ($gnuplot_reset)
 719       (send-gnuplot-command (slot-value plot 'data))
 720       (if output-file (cons '(mlist) output-file) nil))))