configure.ac

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 dnl 2.64 is required at least for m4_esyscmd_s()
   6 AC_PREREQ([2.64])
   7
   8 AC_INIT([GNU Midnight Commander], m4_esyscmd_s([./version.sh .]),
   9         [https://www.midnight-commander.org/wiki/NewTicket], [mc],
  10         [https://www.midnight-commander.org/])
  11
  12 m4_pattern_forbid(MC_)
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CONFIG_AUX_DIR(config)
  15 AC_CONFIG_SRCDIR(src/main.c)
  16 AC_CONFIG_HEADERS(config.h)
  17
  18 dnl Apply "no-define" to avoid defining the VERSION macro in config.h
  19 AM_INIT_AUTOMAKE([no-define])
  20 dnl PACKAGE macro isn't defined if "no-define" is applied
  21 AC_DEFINE([PACKAGE], ["mc"], [Name of package])
  22
  23 dnl Enable silent rules by default (if yes)
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  25
  26 mc_VERSION
  27
  28 AM_MAINTAINER_MODE
  29
  30 AC_CANONICAL_HOST
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34
  35 dnl ############################################################################
  36 dnl Check for compiler
  37 dnl ############################################################################
  38
  39 dnl This should be checked before toolchain macros, otherwise they will remember
  40 dnl that ar cannot be found and linking via libtool will fail at a later stage
  41 AC_CHECK_TOOLS([AR], [ar gar])
  42
  43 AC_PROG_CC
  44
  45 # AC_PROG_CC doesn't try enabling C99 in autoconf 2.69 and below, but
  46 # AC_PROG_CC_C99 is deprecated in newer ones. In autoconf 2.70+ both
  47 # will try enabling features up to C11.
  48 m4_version_prereq([2.70], [AC_PROG_CC], [AC_PROG_CC_C99])
  49
  50 mc_CHECK_CFLAGS
  51
  52 CFLAGS_OPTS=""
  53 if test "x$CFLAGS" = "x"; then
  54     CFLAGS_OPTS=" -O2 "
  55 fi
  56 if test x$USE_MAINTAINER_MODE = xyes; then
  57     CFLAGS_OPTS="-g3 -Og -ggdb"
  58     AC_DEFINE(USE_MAINTAINER_MODE, 1, [Use maintainer mode])
  59 fi
  60
  61 AC_ARG_ENABLE([werror],
  62     AS_HELP_STRING([--enable-werror], [Handle all compiler warnings as errors]))
  63 if test "x$enable_werror" = xyes; then
  64     AX_APPEND_COMPILE_FLAGS([-Werror], [mc_configured_cflags])
  65 fi
  66
  67 dnl Compiler can generate warnings for unrecognized flags added to CFLAGS
  68 dnl which causes attribute checks to fail
  69 ax_gcc_func_attribute_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
  70 _AC_LANG_PREFIX[]FLAGS=
  71 AX_GCC_FUNC_ATTRIBUTE([fallthrough])
  72 AX_GCC_FUNC_ATTRIBUTE([weak])
  73 AX_GCC_FUNC_ATTRIBUTE([unused])
  74 _AC_LANG_PREFIX[]FLAGS=$ax_gcc_func_attribute_save_flags
  75 unset ax_gcc_func_attribute_save_flags
  76
  77 LT_INIT
  78
  79
  80 dnl ############################################################################
  81 dnl Check for programs
  82 dnl ############################################################################
  83
  84 AC_PROG_SED
  85 PKG_PROG_PKG_CONFIG
  86 AC_PROG_INSTALL
  87 AC_PROG_LN_S
  88 dnl See also the "OS specific stuff" section below.
  89
  90 dnl Check nroff and the options it supports
  91 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
  92 dnl Default values
  93 MANDOC=-man
  94 MAN_FLAGS=
  95 if $HAVE_nroff; then
  96     AC_MSG_CHECKING([for manual formatting macros])
  97     AC_CACHE_VAL(mc_cv_mandoc, [
  98     nroff -mandoc < /dev/null > /dev/null 2>&1
  99     if test $? = 0; then
 100         mc_cv_mandoc=-mandoc
 101     else
 102         mc_cv_mandoc=-man
 103     fi
 104     ])
 105     MANDOC=$mc_cv_mandoc
 106     AC_MSG_RESULT([$MANDOC])
 107
 108     AC_MSG_CHECKING([for option to disable ANSI color in manuals])
 109     AC_CACHE_VAL(mc_cv_man_nocolor, [
 110     nroff -c < /dev/null > /dev/null 2>&1
 111     if test $? = 0; then
 112         mc_cv_man_nocolor=-c
 113     else
 114         mc_cv_man_nocolor=
 115     fi
 116     ])
 117     MAN_FLAGS=$mc_cv_man_nocolor
 118     AC_MSG_RESULT([${MAN_NOCOLOR-none}])
 119
 120     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 121     AC_CACHE_VAL(mc_cv_nroff_tascii, [
 122     mc_cv_nroff_tascii=
 123     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 124     if test $? = 0; then
 125         mc_cv_nroff_tascii=-Tlatin1
 126     else
 127         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 128         if test $? = 0; then
 129             mc_cv_nroff_tascii=-Tascii
 130         fi
 131     fi
 132     ])
 133     AC_MSG_RESULT([${mc_cv_nroff_tascii-no}])
 134     MAN_FLAGS="$MAN_FLAGS $mc_cv_nroff_tascii"
 135 fi
 136
 137 AC_SUBST(MANDOC)
 138 AC_SUBST(MAN_FLAGS)
 139
 140 dnl Check for -z, -b, -L, and -S options to file
 141 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 142 if $HAVE_FILECMD; then
 143     dnl Don't use the file command if it doesn't accept the -z option
 144     AC_MSG_CHECKING([for -z option to file command])
 145     AC_CACHE_VAL(mc_cv_file_z, [
 146         file -z . > /dev/null 2>&1
 147         if test $? = 0; then
 148             mc_cv_file_z=yes
 149         else
 150             mc_cv_file_z=no
 151         fi
 152     ])
 153     AC_MSG_RESULT([$mc_cv_file_z])
 154
 155     if test x$mc_cv_file_z = xyes; then
 156         AC_DEFINE(USE_FILE_CMD, 1, [Define if the file command accepts the -z option])
 157     else
 158         AC_MSG_WARN([The file command doesn't accept the -z option and will not be used])
 159     fi
 160
 161     if test x$mc_cv_file_z = xyes; then
 162         dnl file is used; check -b, -L and -S options
 163
 164         AC_MSG_CHECKING([for -b option to file command])
 165         AC_CACHE_VAL(mc_cv_file_b, [
 166             file -b . > /dev/null 2>&1
 167             if test $? = 0; then
 168                 mc_cv_file_b=yes
 169             else
 170                 mc_cv_file_b=no
 171             fi
 172         ])
 173         AC_MSG_RESULT([$mc_cv_file_b])
 174
 175         if test x$mc_cv_file_b = xyes; then
 176             AC_DEFINE(FILE_B, "-b ", [Define if the file command accepts the -b option])
 177         fi
 178
 179         AC_MSG_CHECKING([for -L option to file command])
 180         AC_CACHE_VAL(mc_cv_file_L, [
 181             file -L . > /dev/null 2>&1
 182             if test $? = 0; then
 183                 mc_cv_file_L=yes
 184             else
 185                 mc_cv_file_L=no
 186             fi
 187         ])
 188         AC_MSG_RESULT([$mc_cv_file_L])
 189
 190         if test x$mc_cv_file_L = xyes; then
 191             AC_DEFINE(FILE_L, "-L ", [Define if the file command accepts the -L option])
 192         else
 193             AC_DEFINE(FILE_L, "", [Define if the file command accepts the -L option])
 194         fi
 195
 196         dnl The file command accepts the -S option since 5.33
 197         AC_MSG_CHECKING([for -S option to file command])
 198         AC_CACHE_VAL(mc_cv_file_S, [
 199             file -S . > /dev/null 2>&1
 200             if test $? = 0; then
 201                 mc_cv_file_S=yes
 202             else
 203                 mc_cv_file_S=no
 204             fi
 205         ])
 206         AC_MSG_RESULT([$mc_cv_file_S])
 207
 208         if test x$mc_cv_file_S = xyes; then
 209             AC_DEFINE(FILE_S, "-S ", [Define if file command accepts the -S option])
 210         else
 211             AC_DEFINE(FILE_S, "", [Define if file command accepts the -S option])
 212         fi
 213     fi
 214 fi
 215
 216 dnl Only list browsers here that can be run in background (i.e. with `&')
 217 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla firefox konqueror opera])
 218
 219
 220 dnl ############################################################################
 221 dnl Check for other tools
 222 dnl ############################################################################
 223
 224 AC_CHECK_TOOLS([INDENT], [gindent indent])
 225 mc_UNIT_TESTS
 226
 227
 228 dnl ############################################################################
 229 dnl Check for main libraries
 230 dnl ############################################################################
 231
 232 mc_CHECK_GLIB
 233 mc_G_MODULE_SUPPORTED
 234 mc_WITH_SCREEN
 235 mc_CHECK_SEARCH_TYPE
 236 dnl X11 support. Used to read keyboard modifiers when running under X11.
 237 mc_WITH_X
 238
 239
 240 dnl ############################################################################
 241 dnl Check for header files
 242 dnl ############################################################################
 243
 244 AC_CHECK_HEADERS([string.h memory.h limits.h malloc.h \
 245         utime.h sys/statfs.h sys/vfs.h \
 246         sys/select.h sys/ioctl.h stropts.h arpa/inet.h \
 247         sys/socket.h])
 248 dnl This macro is redefined in m4.include/gnulib/sys_types_h.m4
 249 dnl   to work around a buggy version in autoconf <= 2.69.
 250 AC_HEADER_MAJOR
 251
 252 mc_CHECK_HEADER_STDCKDINT
 253
 254
 255 dnl ############################################################################
 256 dnl Check for types
 257 dnl ############################################################################
 258
 259 dnl Check largefile before type sizeof checks
 260 AC_SYS_LARGEFILE
 261
 262 AC_CHECK_SIZEOF(long)
 263 AC_TYPE_UINTMAX_T
 264 AC_CHECK_SIZEOF(uintmax_t)
 265 AC_TYPE_OFF_T
 266 AC_CHECK_SIZEOF(off_t)
 267 AC_TYPE_MODE_T
 268 gl_PROMOTED_TYPE_MODE_T
 269 AC_TYPE_PID_T
 270 AC_TYPE_UID_T
 271
 272 dnl Taken from GNU/Linux, and should be good enough on platforms lacking these types.
 273 AC_CHECK_TYPE([dev_t], [unsigned long long int])
 274 AC_CHECK_TYPE([ino_t], [unsigned long long int])
 275
 276 dnl Taken from GNU/Linux, and should be good enough on platforms lacking these types.
 277 AC_CHECK_TYPE([major_t], [unsigned int])
 278 AC_CHECK_TYPE([minor_t], [unsigned int])
 279
 280 AC_STRUCT_ST_BLOCKS
 281 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_rdev, struct stat.st_mtim, struct stat.st_mtimespec, struct stat.st_mtimensec])
 282 gl_STAT_SIZE
 283
 284 AH_TEMPLATE([sig_atomic_t],
 285             [/* Define to `int' if <signal.h> doesn't define.])
 286 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
 287             [Some systems declare sig_atomic_t as volatile, some others -- no.
 288              This define will have value `sig_atomic_t' or
 289              `volatile sig_atomic_t' accordingly.])
 290
 291 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 292 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 293   [
 294     ac_cv_type_sig_atomic_t=yes;
 295     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 296                     signal.h,
 297                     [
 298                         is_sig_atomic_t_volatile=yes;
 299                         AC_MSG_RESULT([yes, volatile])
 300                     ],
 301                     [
 302                         is_sig_atomic_t_volatile=no;
 303                         AC_MSG_RESULT([yes, non volatile])
 304                     ])
 305   ],
 306   [
 307     AC_MSG_RESULT(no)
 308     AC_CHECK_TYPE(sig_atomic_t, int)
 309     is_sig_atomic_t_volatile=no
 310   ])
 311 if test $is_sig_atomic_t_volatile = 'yes'
 312 then
 313     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 314 else
 315     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 316 fi
 317
 318
 319 dnl ############################################################################
 320 dnl Check for functions
 321 dnl ############################################################################
 322
 323 AC_CHECK_FUNCS([\
 324         strverscmp \
 325         strncasecmp \
 326         realpath
 327 ])
 328
 329 dnl getpt is a GNU Extension (glibc 2.1.x)
 330 AC_CHECK_FUNCS(posix_openpt, , [AC_CHECK_FUNCS(getpt)])
 331 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 332
 333 dnl replacing lstat with statlstat on sco makes it more portable between
 334 dnl sco clones
 335 AC_CHECK_FUNCS(statlstat)
 336
 337 mc_GET_FS_INFO
 338
 339
 340 dnl ############################################################################
 341 dnl Internationalization
 342 dnl ############################################################################
 343
 344 AC_CHECK_FUNCS([setlocale])
 345
 346 AM_GNU_GETTEXT([external], [need-ngettext])
 347 AM_GNU_GETTEXT_VERSION([0.18.2])
 348
 349 mc_I18N
 350
 351 dnl ############################################################################
 352 dnl OS specific stuff
 353 dnl ############################################################################
 354
 355 AC_CHECK_DECLS([environ], , ,
 356   [ #include <unistd.h>
 357     #include <stdlib.h> ])
 358
 359 case $host_os in
 360 *os400)
 361     AC_PATH_PROG([PERL], [perl], [/QOpenSys/pkgs/bin/perl])
 362     AC_PATH_PROG([PERL_FOR_BUILD], [perl], [/QOpenSys/pkgs/bin/perl])
 363     AC_PATH_PROG([PYTHON], [python], [/QOpenSys/pkgs/bin/python2])
 364     AC_PATH_PROG([RUBY], [ruby], [/QOpenSys/pkgs/bin/ruby])
 365     ;;
 366 *)
 367     AC_PATH_PROG([PERL], [perl], [/usr/bin/perl])
 368     AC_PATH_PROG([PERL_FOR_BUILD], [perl], [/usr/bin/perl])
 369     AC_PATH_PROG([PYTHON], [python], [/usr/bin/python])
 370     AC_PATH_PROG([RUBY], [ruby], [/usr/bin/ruby])
 371 esac
 372
 373 case $host_os in
 374 aux*)
 375     # A/UX
 376     LIBS="$LIBS -lposix"
 377     AC_DEFINE(_POSIX_SOURCE)
 378     ;;
 379 esac
 380
 381 dnl If running under AIX, AC_USE_SYSTEM_EXTENSIONS does not tell us that
 382 AC_MSG_CHECKING([for AIX defines])
 383 AC_EGREP_CPP([yes],
 384     [
 385         #if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 386         yes
 387         #endif
 388     ],
 389     [
 390         AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 391         AC_MSG_RESULT(yes)
 392     ],
 393     [
 394         AC_MSG_RESULT(no)
 395     ])
 396
 397 dnl utimensat is supported since glibc 2.6 and specified in POSIX.1-2008
 398 AC_CHECK_FUNCS([utimensat])
 399
 400 case $host_os in
 401 *os400)
 402     AC_DEFINE([PTY_ZEROREAD], [1], [read(1) can return 0 for a non-closed fd])
 403 esac
 404
 405 dnl Check linux/fs.h for FICLONE to support BTRFS's file clone operation
 406 case $host_os in
 407 linux*)
 408     AC_CHECK_HEADERS([linux/fs.h])
 409 esac
 410
 411 dnl Check if the OS is supported by the console saver.
 412 cons_saver=""
 413 case $host_os in
 414 linux*)
 415     cons_saver=yes
 416 esac
 417
 418 dnl Check for gpm mouse support (Linux only)
 419 mouse_lib="xterm only"
 420 AC_ARG_WITH([gpm-mouse],
 421     AS_HELP_STRING([--with-gpm-mouse], [Compile with gpm mouse support (Linux only) @<:@yes if found@:>@]))
 422
 423 case $host_os in
 424 linux*)
 425     if test x$with_gpm_mouse != xno; then
 426         AC_CHECK_LIB(gpm, Gpm_Repeat,
 427             [AC_DEFINE(HAVE_LIBGPM, 1,
 428                        [Define to enable gpm mouse support on Linux])
 429             mouse_lib="gpm and xterm"
 430             MCLIBS="$MCLIBS -lgpm"],
 431             if test "x$with_gpm_mouse" = "xyes"; then
 432                 [AC_MSG_ERROR([libgpm is missing or older than 0.18])]
 433             else
 434                 [AC_MSG_WARN([libgpm is missing or older than 0.18])]
 435             fi
 436         )
 437     fi
 438     ;;
 439 esac
 440
 441
 442 dnl ############################################################################
 443 dnl libmc
 444 dnl ############################################################################
 445
 446 LIBMC_VERSION="0.0.1"
 447 LIBMC_RELEASE="1"
 448 AC_SUBST(LIBMC_VERSION)
 449 AC_SUBST(LIBMC_RELEASE)
 450
 451 AC_ARG_ENABLE([mclib],
 452         [AS_HELP_STRING([--enable-mclib], [Compile shared library libmc.so @<:@no@:>@])],
 453         [
 454             if test "x$enableval" = "xno" ; then
 455                 enable_mclib=no
 456             else
 457                 if test "x$enable_shared" = "xno" ; then
 458                     AC_MSG_WARN([Build of shared library is disabled. Specify --enable-shared first])
 459                     enable_mclib=no
 460                 else
 461                     enable_mclib=yes
 462                 fi
 463             fi
 464         ],
 465         [enable_mclib=no])
 466
 467 AM_CONDITIONAL([ENABLE_MCLIB], [test x$enable_mclib = xyes])
 468
 469
 470 dnl ############################################################################
 471 dnl MC options
 472 dnl ############################################################################
 473
 474 mc_ASSERT
 475
 476 mc_WITH_INTERNAL_EDIT
 477
 478 dnl Diff viewer support.
 479 AC_ARG_WITH([diff_viewer],
 480     AS_HELP_STRING([--with-diff-viewer], [Compile with diff viewer @<:@yes@:>@]))
 481
 482 if test x$with_diff_viewer != xno; then
 483         AC_DEFINE(USE_DIFF_VIEW, 1, [Define to enable diff viewer])
 484         use_diff=yes
 485         diff_msg="yes"
 486         AC_MSG_NOTICE([using diff viewer])
 487 else
 488         diff_msg="no"
 489 fi
 490
 491 mc_SUBSHELL
 492 mc_BACKGROUND
 493 mc_EXT2FS_ATTR
 494 mc_VFS_CHECKS
 495
 496 dnl ############################################################################
 497 dnl Directories
 498 dnl ############################################################################
 499
 500 dnl ${prefix} and ${exec_prefix} are undefined here if --prefix is not used in command line
 501 dnl Let define ${prefix} and ${exec_prefix}
 502 test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"
 503 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
 504
 505 if test x${libexecdir} = x'${exec_prefix}/libexec'; then
 506     EXTHELPERSDIR=${prefix}/libexec/${PACKAGE}/ext.d
 507 elif test x${libexecdir} = x'${exec_prefix}/lib'; then
 508     EXTHELPERSDIR=${prefix}/lib/${PACKAGE}/ext.d
 509 else
 510     EXTHELPERSDIR=${libexecdir}/${PACKAGE}/ext.d
 511 fi
 512 AC_SUBST(EXTHELPERSDIR)
 513
 514
 515 dnl ############################################################################
 516 dnl Documentation
 517 dnl ############################################################################
 518
 519 MAN_DATE="$(LC_ALL=C date "+%B %Y")"
 520 AC_SUBST(MAN_DATE)
 521
 522 dnl Determine which help translations we want to install.
 523 ALL_DOC_LINGUAS="es hu it pl ru sr"
 524
 525 DOC_LINGUAS=
 526 if test "x$USE_NLS" = xyes; then
 527     if test -z "$LINGUAS"; then
 528         langs="`grep -v '^#' $srcdir/po/LINGUAS`"
 529     else
 530         langs="$LINGUAS"
 531     fi
 532 else
 533     langs=
 534 fi
 535
 536 for h_lang in $ALL_DOC_LINGUAS; do
 537     for lang in $langs; do
 538         if test "$lang" = "$h_lang"; then
 539             DOC_LINGUAS="$DOC_LINGUAS $lang"
 540             break
 541         fi
 542     done
 543 done
 544 AC_SUBST(DOC_LINGUAS)
 545
 546 DX_HTML_FEATURE(ON)
 547 DX_CHM_FEATURE(OFF)
 548 DX_CHI_FEATURE(OFF)
 549 DX_MAN_FEATURE(OFF)
 550 DX_RTF_FEATURE(OFF)
 551 DX_XML_FEATURE(OFF)
 552 DX_PDF_FEATURE(OFF)
 553 DX_PS_FEATURE(OFF)
 554 DX_INIT_DOXYGEN(mc,doxygen.cfg,devel)
 555
 556
 557 dnl ############################################################################
 558 dnl Configure results
 559 dnl ############################################################################
 560
 561 CFLAGS="$mc_configured_cflags $CFLAGS_OPTS $CFLAGS"
 562
 563 AC_SUBST(MCLIBS)
 564 AC_SUBST(CFLAGS)
 565 AC_SUBST(CPPFLAGS)
 566 AC_SUBST(LDFLAGS)
 567 AC_SUBST(LIBS)
 568
 569 AM_CONDITIONAL(USE_NLS, [test x"$USE_NLS" = xyes])
 570 AM_CONDITIONAL(USE_MAINTAINER_MODE, [test x"$USE_MAINTAINER_MODE" = xyes])
 571 AM_CONDITIONAL(USE_SCREEN_SLANG, [test x"$with_screen" = xslang])
 572 AM_CONDITIONAL(USE_INTERNAL_EDIT, [test x"$use_internal_edit" = xyes ])
 573 AM_CONDITIONAL(USE_ASPELL, [test x"$enable_aspell" = xyes ])
 574 AM_CONDITIONAL(USE_DIFF, [test -n "$use_diff"])
 575 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 576 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 577 dnl Clarify do we really need GModule
 578 AM_CONDITIONAL([HAVE_GMODULE], [test -n "$g_module_supported" && \
 579                                 test x"$textmode_x11_support" = x"yes" -o x"$enable_aspell" = x"yes"])
 580
 581 AC_ARG_ENABLE([configure-args],
 582     AS_HELP_STRING([--enable-configure-args], [Embed ./configure arguments into binaries]))
 583 if test "x$enable_configure_args" != xno; then
 584     AC_DEFINE([ENABLE_CONFIGURE_ARGS], 1, [Define to enable showing configure arguments in help])
 585     AC_DEFINE_UNQUOTED([MC_CONFIGURE_ARGS], ["$ac_configure_args"], [MC configure arguments])
 586 fi
 587
 588
 589 AC_CONFIG_FILES(
 590 [
 591 src/man2hlp/man2hlp
 592 ],
 593 [
 594 chmod +x src/man2hlp/man2hlp
 595 ])
 596
 597 AC_CONFIG_FILES([
 598 Makefile
 599
 600 contrib/Makefile
 601
 602 misc/Makefile
 603 misc/mc.charsets
 604 misc/mc.menu
 605 misc/mcedit.menu
 606 misc/skins/Makefile
 607 misc/ext.d/Makefile
 608 misc/ext.d/doc.sh
 609 misc/ext.d/misc.sh
 610 misc/ext.d/text.sh
 611 misc/ext.d/web.sh
 612 misc/macros.d/Makefile
 613 misc/mc.ext.ini
 614
 615 src/Makefile
 616 src/consaver/Makefile
 617 src/editor/Makefile
 618 src/man2hlp/Makefile
 619 src/subshell/Makefile
 620 src/viewer/Makefile
 621 src/diffviewer/Makefile
 622 src/filemanager/Makefile
 623
 624 src/vfs/Makefile
 625
 626 src/vfs/cpio/Makefile
 627
 628 src/vfs/extfs/Makefile
 629 src/vfs/extfs/helpers/Makefile
 630 src/vfs/extfs/helpers/a+
 631 src/vfs/extfs/helpers/apt+
 632 src/vfs/extfs/helpers/audio
 633 src/vfs/extfs/helpers/deb
 634 src/vfs/extfs/helpers/deba
 635 src/vfs/extfs/helpers/debd
 636 src/vfs/extfs/helpers/dpkg+
 637 src/vfs/extfs/helpers/iso9660
 638 src/vfs/extfs/helpers/hp48+
 639 src/vfs/extfs/helpers/lslR
 640 src/vfs/extfs/helpers/mailfs
 641 src/vfs/extfs/helpers/patchfs
 642 src/vfs/extfs/helpers/rpms+
 643 src/vfs/extfs/helpers/s3+
 644 src/vfs/extfs/helpers/uace
 645 src/vfs/extfs/helpers/ualz
 646 src/vfs/extfs/helpers/uar
 647 src/vfs/extfs/helpers/uarc
 648 src/vfs/extfs/helpers/uarj
 649 src/vfs/extfs/helpers/ucab
 650 src/vfs/extfs/helpers/uha
 651 src/vfs/extfs/helpers/ulha
 652 src/vfs/extfs/helpers/ulib
 653 src/vfs/extfs/helpers/unar
 654 src/vfs/extfs/helpers/urar
 655 src/vfs/extfs/helpers/uwim
 656 src/vfs/extfs/helpers/uzip
 657 src/vfs/extfs/helpers/uzoo
 658
 659 src/vfs/shell/Makefile
 660 src/vfs/shell/helpers/Makefile
 661
 662 src/vfs/ftpfs/Makefile
 663
 664 src/vfs/sftpfs/Makefile
 665
 666 src/vfs/local/Makefile
 667
 668 src/vfs/sfs/Makefile
 669
 670 src/vfs/tar/Makefile
 671
 672 src/vfs/undelfs/Makefile
 673
 674 lib/Makefile
 675 lib/event/Makefile
 676 lib/filehighlight/Makefile
 677 lib/mcconfig/Makefile
 678 lib/search/Makefile
 679 lib/skin/Makefile
 680 lib/strutil/Makefile
 681 lib/tty/Makefile
 682
 683 lib/vfs/Makefile
 684
 685 lib/widget/Makefile
 686
 687 misc/syntax/Makefile
 688
 689 doc/Makefile
 690
 691 doc/hints/Makefile
 692 doc/hints/l10n/Makefile
 693
 694 doc/man/Makefile
 695 doc/man/es/Makefile
 696 doc/man/hu/Makefile
 697 doc/man/it/Makefile
 698 doc/man/pl/Makefile
 699 doc/man/ru/Makefile
 700 doc/man/sr/Makefile
 701
 702 doc/hlp/Makefile
 703 doc/hlp/es/Makefile
 704 doc/hlp/hu/Makefile
 705 doc/hlp/it/Makefile
 706 doc/hlp/pl/Makefile
 707 doc/hlp/ru/Makefile
 708 doc/hlp/sr/Makefile
 709
 710 po/Makefile.in
 711 ])
 712
 713 dnl https://stackoverflow.com/questions/30897170/ac-subst-does-not-expand-variable/30932102#30932102
 714 AC_CONFIG_FILES(
 715 [misc/syntax/Syntax], [${SED-sed} -e "s%\${prefix}%$PREFIX%" misc/syntax/Syntax > misc/syntax/Syntax.tmp && \
 716   mv -f misc/syntax/Syntax.tmp misc/syntax/Syntax], [export PREFIX=$prefix]
 717 )
 718
 719 AC_CONFIG_FILES([
 720 tests/Makefile
 721 tests/lib/Makefile
 722 tests/lib/mcconfig/Makefile
 723 tests/lib/search/Makefile
 724 tests/lib/strutil/Makefile
 725 tests/lib/vfs/Makefile
 726 tests/lib/vfs/mc.charsets
 727 tests/lib/widget/Makefile
 728 tests/src/Makefile
 729 tests/src/filemanager/Makefile
 730 tests/src/editor/Makefile
 731 tests/src/editor/test-data.txt
 732 tests/src/vfs/Makefile
 733 tests/src/vfs/extfs/Makefile
 734 tests/src/vfs/extfs/helpers-list/Makefile
 735 tests/src/vfs/extfs/helpers-list/data/config.sh
 736 tests/src/vfs/extfs/helpers-list/misc/Makefile
 737 tests/src/vfs/ftpfs/Makefile
 738 ])
 739
 740 AC_OUTPUT
 741
 742 AC_MSG_NOTICE([
 743
 744 Configuration:
 745
 746   Source code location:           ${srcdir}
 747   Compiler:                       ${CC}
 748   Compiler flags:                 ${CFLAGS}
 749   Assertions:                     ${enable_assert}
 750   Unit tests:                     ${tests_msg}
 751   File system:                    ${vfs_type}
 752                                   ${vfs_flags}
 753   Screen library:                 ${screen_msg}
 754   Mouse support:                  ${mouse_lib}
 755   X11 events support:             ${textmode_x11_support}
 756   With subshell support:          ${subshell}
 757   With background operations:     ${enable_background}
 758   With ext2fs attributes support: ${ext2fs_attr_msg}
 759   Internal editor:                ${edit_msg}
 760   Diff viewer:                    ${diff_msg}
 761   Support for charset:            ${charset_msg}
 762   Search type:                    ${SEARCH_TYPE}
 763 ])
 764
 765 dnl option checking is disable by default due to AC_CONFIG_SUBDIRS
 766 dnl we enable it back for top-level ./configure
 767 if test -n "$ac_unrecognized_opts"; then
 768   case $enable_option_checking in
 769     fatal) AC_MSG_ERROR([unrecognized options: $ac_unrecognized_opts]) ;;
 770     *)     AC_MSG_WARN( [unrecognized options: $ac_unrecognized_opts]) ;;
 771   esac
 772 fi