lib/libc/arch/mips/string/bcmp.S

   1 /*      $NetBSD: bcmp.S,v 1.9 2009/12/14 01:07:42 matt Exp $    */
   2
   3 /*-
   4  * Copyright (c) 1991, 1993
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * Ralph Campbell.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <mips/asm.h>
  36 #define _LOCORE         /* XXX not really, just assembly-code source */
  37 #include <machine/endian.h>     /* LWLO/LWHI, SWLO/SWHI */
  38
  39 #if defined(LIBC_SCCS) && !defined(lint)
  40 #if 0
  41         RCSID("from: @(#)bcmp.s 8.1 (Berkeley) 6/4/93")
  42 #else
  43         RCSID("$NetBSD: bcmp.S,v 1.9 2009/12/14 01:07:42 matt Exp $")
  44 #endif
  45 #endif /* LIBC_SCCS and not lint */
  46
  47 /* bcmp(s1, s2, n) */
  48
  49
  50 LEAF(bcmp)
  51         .set    noreorder
  52         blt             a2, 16, small   # is it worth any trouble?
  53         xor             v0, a0, a1      # compare low two bits of addresses
  54         and             v0, v0, 3
  55         PTR_SUBU        a3, zero, a1    # compute # bytes to word align address
  56         bne             v0, zero, unaligned # not possible to align addresses
  57         and             a3, a3, 3
  58
  59         beq             a3, zero, 1f
  60         PTR_SUBU        a2, a2, a3      # subtract from remaining count
  61         move            v0, v1          # init v0,v1 so unmodified bytes match
  62         LWHI            v0, 0(a0)       # read 1, 2, or 3 bytes
  63         LWHI            v1, 0(a1)
  64         PTR_ADDU        a1, a1, a3
  65         bne             v0, v1, nomatch
  66         PTR_ADDU        a0, a0, a3
  67 1:
  68         and             a3, a2, ~3      # compute number of whole words left
  69         PTR_SUBU        a2, a2, a3      #   which has to be >= (16-3) & ~3
  70         PTR_ADDU        a3, a3, a0      # compute ending address
  71 2:
  72         lw              v0, 0(a0)       # compare words
  73         lw              v1, 0(a1)
  74         PTR_ADDU        a0, a0, 4
  75         bne             v0, v1, nomatch
  76         PTR_ADDU        a1, a1, 4
  77         bne             a0, a3, 2b
  78         nop
  79         b               small           # finish remainder
  80         nop
  81 unaligned:
  82         beq             a3, zero, 2f
  83         PTR_SUBU        a2, a2, a3      # subtract from remaining count
  84         PTR_ADDU        a3, a3, a0      # compute ending address
  85 1:
  86         lbu             v0, 0(a0)       # compare bytes until a1 word aligned
  87         lbu             v1, 0(a1)
  88         PTR_ADDU        a0, a0, 1
  89         bne             v0, v1, nomatch
  90         PTR_ADDU        a1, a1, 1
  91         bne             a0, a3, 1b
  92         nop
  93 2:
  94         and             a3, a2, ~3      # compute number of whole words left
  95         PTR_SUBU        a2, a2, a3      #   which has to be >= (16-3) & ~3
  96         PTR_ADDU        a3, a3, a0      # compute ending address
  97 3:
  98         LWHI            v0, 0(a0)       # compare words a0 unaligned, a1 aligned
  99         LWLO            v0, 3(a0)
 100         lw              v1, 0(a1)
 101         PTR_ADDU        a0, a0, 4
 102         bne             v0, v1, nomatch
 103         PTR_ADDU        a1, a1, 4
 104         bne             a0, a3, 3b
 105         nop
 106 small:
 107         ble             a2, zero, match
 108         PTR_ADDU        a3, a2, a0              # compute ending address
 109 1:
 110         lbu             v0, 0(a0)
 111         lbu             v1, 0(a1)
 112         PTR_ADDU        a0, a0, 1
 113         bne             v0, v1, nomatch
 114         PTR_ADDU        a1, a1, 1
 115         bne             a0, a3, 1b
 116         nop
 117 match:
 118         j               ra
 119         move            v0, zero
 120 nomatch:
 121         j               ra
 122         li              v0, 1
 123         .set    reorder
 124 END(bcmp)