check-strings.pl

   1 #!/usr/bin/perl -w
   2 # -*- Mode: perl; indent-tabs-mode: nil -*-
   3
   4 #
   5 #  Nautilus
   6 #
   7 #  Copyright (C) 2000, 2001 Eazel, Inc.
   8 #
   9 #  This library is free software; you can redistribute it and/or
  10 #  modify it under the terms of the GNU General Public License as
  11 #  published by the Free Software Foundation; either version 2 of the
  12 #  License, or (at your option) any later version.
  13 #
  14 #  This library is distributed in the hope that it will be useful,
  15 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 #  General Public License for more details.
  18 #
  19 #  You should have received a copy of the GNU General Public License
  20 #  along with this library; if not, write to the Free Software
  21 #  Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  22 #
  23 #  Author: Darin Adler <darin@bentspoon.com>,
  24 #
  25
  26 # check-strings.pl: Search for .c and .h files where someone forgot
  27 # to put _() around a string.
  28
  29 # Throughout this file you will find extra \ before quote symbols
  30 # that perl does not require. These are to appease emacs perl mode.
  31
  32 use diagnostics;
  33 use strict;
  34
  35 # default to all the files starting from the current directory
  36 if (!@ARGV)
  37   {
  38     @ARGV = `find . \\( -name '*.c' -o -name '*.h' \\) -print`;
  39   }
  40
  41 sub found_string;
  42
  43 # read in file with functions for which no translation is needed
  44 my @no_translation_needed_functions;
  45 open FUNCTIONS, "check-strings-functions" or die "can't open functions file";
  46 while (<FUNCTIONS>)
  47   {
  48     chomp;
  49     s/(([^\\]|\\.)*)\#.*/$1/;
  50     s/\s*$//;
  51     next if /^$/;
  52     push @no_translation_needed_functions, $_;
  53   }
  54 close FUNCTIONS;
  55 my $no_translation_needed_function_pattern = "^(" . (join "|", @no_translation_needed_functions) . ")\$";
  56
  57 # read in file with patterns for which no translation is needed
  58 my @no_translation_needed_patterns;
  59 open STRINGS, "check-strings-patterns" or die "can't open patterns file";
  60 while (<STRINGS>)
  61   {
  62     chomp;
  63     s/(([^\\]|\\.)*)\#.*/$1/;
  64     s/\s*$//;
  65     next if /^$/;
  66     my ($string_pattern, $file_name_pattern) = /(.+?)\s*\|\|\|\s*(.+)/;
  67     $string_pattern ||= $_;
  68     $file_name_pattern ||= ".";
  69     push @no_translation_needed_patterns, [$string_pattern, $file_name_pattern];
  70   }
  71 close STRINGS;
  72
  73 FILE: foreach my $file (@ARGV)
  74   {
  75     chomp $file;
  76     open FILE, $file or die "can't open $file";
  77
  78     my $in_comment = 0;
  79
  80     my $string = "";
  81
  82     my $last_word;
  83     my @stack = ();
  84     my $paren_level = 0;
  85     my $in_exception_function = 0;
  86
  87     LINE: while (<FILE>)
  88       {
  89         if ($in_comment)
  90           {
  91             s/.*?\*\/// or next LINE;
  92             $in_comment = 0;
  93           }
  94
  95         # general approach is to just remove things we aren't interested in
  96
  97         next LINE if /^\s*#\s*(\d|include)/;
  98
  99         while (s/(((.*?)(\/\*|[\'\"\(\)]|\w+))|.+)//)
 100           {
 101             my $skipped = $3;
 102             $skipped = $1 unless defined $skipped;
 103             my $found = $4;
 104             $found = "" unless defined $found;
 105
 106             my $function_name = $last_word || "";
 107
 108             if ($skipped =~ /\S/ or $found =~ /^[\(\)\w]/)
 109               {
 110                 if ($string ne "")
 111                   {
 112                     found_string ($string, $file, $.) unless $in_exception_function;
 113                     $string = "";
 114                   }
 115                 undef $last_word;
 116               }
 117
 118             last unless $found ne "";
 119
 120             if ($found eq '"')
 121               {
 122                 s/^(([^\\\"]|\\.)*)\"// or (print "$file:$.:unclosed quote\n"), next FILE;
 123                 $string .= $1;
 124               }
 125             elsif ($found eq "'")
 126               {
 127                 s/^([^\\\']|\\.)*\'// or (print "$file:$.:unclosed single quote\n"), next FILE;
 128               }
 129             elsif ($found eq "/*")
 130               {
 131                 s/^.*?\*\/// or $in_comment = 1, next LINE;
 132               }
 133             elsif ($found eq "(")
 134               {
 135                 if ($function_name or $paren_level == 0)
 136                   {
 137                     push @stack, [$paren_level, $in_exception_function];
 138                     $paren_level = 0;
 139                     $in_exception_function = 1 if $function_name =~ /$no_translation_needed_function_pattern/o;
 140                   }
 141                 $paren_level++;
 142               }
 143             elsif ($found eq ")")
 144               {
 145                 (print "$file:$.:mismatched paren (type 1)\n"), next FILE if $paren_level == 0;
 146                 $paren_level--;
 147                 if ($paren_level == 0)
 148                   {
 149                     (print "$file:$.:mismatched paren (type 2)\n"), next FILE if @stack == 0;
 150                     ($paren_level, $in_exception_function) = @{pop @stack};
 151                   }
 152               }
 153             else
 154               {
 155                 $last_word = $found;
 156               }
 157           }
 158       }
 159     close FILE;
 160   }
 161
 162 sub found_string
 163   {
 164     my ($string, $file, $line) = @_;
 165
 166     for my $exception (@no_translation_needed_patterns)
 167       {
 168         return if $string =~ /$exception->[0]/ and $file =~ /$exception->[1]/;
 169       }
 170
 171     print "$file:$line:\"$string\" is not marked for translation\n";
 172   }