libgloss/rs6000/ads.ld

   1 OUTPUT_FORMAT("elf32-powerpc", "elf32-powerpc",
   2               "elf32-powerpc")
   3 OUTPUT_ARCH(powerpc)
   4 ENTRY(_start)
   5 /* Do we need any of these for elf?
   6    __DYNAMIC = 0;    */
   7
   8 PROVIDE (__stack = 0x2000000);
   9
  10 MEMORY
  11 {
  12   ram (rwx) : ORIGIN = 0x10000, LENGTH = 0x2000000
  13 }
  14
  15 SECTIONS
  16 {
  17   /* Read-only sections, merged into text segment: */
  18   . = 0x10000 + SIZEOF_HEADERS;
  19   .interp   : { *(.interp) }
  20   .hash           : { *(.hash)          }
  21   .dynsym         : { *(.dynsym)                }
  22   .dynstr         : { *(.dynstr)                }
  23   .rela.text     :
  24     { *(.rela.text) *(.rela.gnu.linkonce.t*) }
  25   .rela.data     :
  26     { *(.rela.data) *(.rela.gnu.linkonce.d*) }
  27   .rela.rodata   :
  28     { *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
  29   .rela.got       : { *(.rela.got)      }
  30   .rela.got1      : { *(.rela.got1)     }
  31   .rela.got2      : { *(.rela.got2)     }
  32   .rela.ctors     : { *(.rela.ctors)    }
  33   .rela.dtors     : { *(.rela.dtors)    }
  34   .rela.init      : { *(.rela.init)     }
  35   .rela.fini      : { *(.rela.fini)     }
  36   .rela.bss       : { *(.rela.bss)      }
  37   .rela.plt       : { *(.rela.plt)      }
  38   .rela.sdata     : { *(.rela.sdata2)   }
  39   .rela.sbss      : { *(.rela.sbss2)    }
  40   .rela.sdata2    : { *(.rela.sdata2)   }
  41   .rela.sbss2     : { *(.rela.sbss2)    }
  42   .plt   : { *(.plt) }
  43   .text      :
  44   {
  45     *(.text)
  46     /* .gnu.warning sections are handled specially by elf32.em.  */
  47     *(.gnu.warning)
  48     *(.gnu.linkonce.t*)
  49   } =0
  50   .init                 : { *(.init)                            } =0
  51   .fini                 : { *(.fini)                            } =0
  52   .rodata               : { *(.rodata) *(.gnu.linkonce.r*)      }
  53   .rodata1              : { *(.rodata1)                         }
  54   .gcc_except_table     : { *(.gcc_except_table)                }
  55   _etext = .;
  56   PROVIDE (etext = .);
  57   .sdata2   : { *(.sdata2) }
  58   .sbss2   : { *(.sbss2) }
  59   /* Adjust the address for the data segment.  We want to adjust up to
  60      the same address within the page on the next page up.  It would
  61      be more correct to do this:
  62        . = ALIGN(0x10000) + (ALIGN(8) & (0x10000 - 1));
  63      The current expression does not correctly handle the case of a
  64      text segment ending precisely at the end of a page; it causes the
  65      data segment to skip a page.  The above expression does not have
  66      this problem, but it will currently (2/95) cause BFD to allocate
  67      a single segment, combining both text and data, for this case.
  68      This will prevent the text segment from being shared among
  69      multiple executions of the program; I think that is more
  70      important than losing a page of the virtual address space (note
  71      that no actual memory is lost; the page which is skipped can not
  72      be referenced).  */
  73   . =  ALIGN(8) + 0x10000;
  74   .data    :
  75   {
  76     *(.data)
  77     *(.gnu.linkonce.d*)
  78     CONSTRUCTORS
  79   }
  80   .data1   : { *(.data1) }
  81   .got1           : { *(.got1) }
  82   .dynamic        : { *(.dynamic) }
  83   /* Put .ctors and .dtors next to the .got2 section, so that the pointers
  84      get relocated with -mrelocatable. Also put in the .fixup pointers.
  85      The current compiler no longer needs this, but keep it around for 2.7.2  */
  86                 PROVIDE (_GOT2_START_ = .);
  87   .got2           :  { *(.got2) }
  88                 PROVIDE (__CTOR_LIST__ = .);
  89   .ctors          : { *(.ctors) }
  90                 PROVIDE (__CTOR_END__ = .);
  91                 PROVIDE (__DTOR_LIST__ = .);
  92   .dtors          : { *(.dtors) }
  93                 PROVIDE (__DTOR_END__ = .);
  94                 PROVIDE (_FIXUP_START_ = .);
  95   .fixup          : { *(.fixup) }
  96                 PROVIDE (_FIXUP_END_ = .);
  97                 PROVIDE (_GOT2_END_ = .);
  98                 PROVIDE (_GOT_START_ = .);
  99   .got            : { *(.got) }
 100   .got.plt        : { *(.got.plt) }
 101                 PROVIDE (_GOT_END_ = .);
 102   /* We want the small data sections together, so single-instruction offsets
 103      can access them all, and initialized data all before uninitialized, so
 104      we can shorten the on-disk segment size.  */
 105   .sdata          : { *(.sdata) }
 106   _edata  =  .;
 107   PROVIDE (edata = .);
 108   .sbss      :
 109   {
 110     PROVIDE (__sbss_start = .);
 111     *(.sbss)
 112     *(.scommon)
 113     PROVIDE (__sbss_end = .);
 114   }
 115   .bss       :
 116   {
 117    PROVIDE (__bss_start = .);
 118    *(.dynbss)
 119    *(.bss)
 120    *(COMMON)
 121   }
 122   _end = . ;
 123   PROVIDE (end = .);
 124   /* These are needed for ELF backends which have not yet been
 125      converted to the new style linker.  */
 126   .stab 0 : { *(.stab) }
 127   .stabstr 0 : { *(.stabstr) }
 128   /* DWARF debug sections.
 129      Symbols in the DWARF debugging sections are relative to the beginning
 130      of the section so we begin them at 0.  */
 131   /* DWARF 1 */
 132   .debug          0 : { *(.debug) }
 133   .line           0 : { *(.line) }
 134   /* GNU DWARF 1 extensions */
 135   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 136   .debug_sfnames  0 : { *(.debug_sfnames) }
 137   /* DWARF 1.1 and DWARF 2 */
 138   .debug_aranges  0 : { *(.debug_aranges) }
 139   .debug_pubnames 0 : { *(.debug_pubnames) }
 140   /* DWARF 2 */
 141   .debug_info     0 : { *(.debug_info) }
 142   .debug_abbrev   0 : { *(.debug_abbrev) }
 143   .debug_line     0 : { *(.debug_line) }
 144   .debug_frame    0 : { *(.debug_frame) }
 145   .debug_str      0 : { *(.debug_str) }
 146   .debug_loc      0 : { *(.debug_loc) }
 147   .debug_macinfo  0 : { *(.debug_macinfo) }
 148   .debug_ranges   0 : { *(.debug_ranges) }
 149   /* SGI/MIPS DWARF 2 extensions */
 150   .debug_weaknames 0 : { *(.debug_weaknames) }
 151   .debug_funcnames 0 : { *(.debug_funcnames) }
 152   .debug_typenames 0 : { *(.debug_typenames) }
 153   .debug_varnames  0 : { *(.debug_varnames) }
 154   /* These must appear regardless of  .  */
 155 }