cmake/Options.cmake

   1 include(GNUInstallDirs)
   2
   3 # Set the options for the directories (personal, shared, global).
   4 #
   5 # set_directory_options()
   6 #
   7 function(set_directory_options)
   8     if(APPLE)
   9         set(DEFAULT_PERSONAL_DIR "Documents/OpenTTD")
  10         set(DEFAULT_SHARED_DIR "/Library/Application Support/OpenTTD")
  11         set(DEFAULT_GLOBAL_DIR "(not set)")
  12     elseif(WIN32)
  13         set(DEFAULT_PERSONAL_DIR "OpenTTD")
  14         set(DEFAULT_SHARED_DIR "(not set)")
  15         set(DEFAULT_GLOBAL_DIR "(not set)")
  16     elseif(UNIX)
  17         set(DEFAULT_PERSONAL_DIR ".${BINARY_NAME}")
  18         set(DEFAULT_SHARED_DIR "(not set)")
  19         set(DEFAULT_GLOBAL_DIR "${CMAKE_INSTALL_FULL_DATADIR}/${BINARY_NAME}")
  20     else()
  21         message(FATAL_ERROR "Unknown OS found; please consider creating a Pull Request to add support for this OS.")
  22     endif()
  23
  24     if(NOT PERSONAL_DIR)
  25         set(PERSONAL_DIR "${DEFAULT_PERSONAL_DIR}" CACHE STRING "Personal directory")
  26         message(STATUS "Detecting Personal Data directory - ${PERSONAL_DIR}")
  27     endif()
  28
  29     if(NOT SHARED_DIR)
  30         set(SHARED_DIR "${DEFAULT_SHARED_DIR}" CACHE STRING "Shared directory")
  31         message(STATUS "Detecting Shared Data directory - ${SHARED_DIR}")
  32     endif()
  33
  34     if(NOT GLOBAL_DIR)
  35         set(GLOBAL_DIR "${DEFAULT_GLOBAL_DIR}" CACHE STRING "Global directory")
  36         message(STATUS "Detecting Global Data directory - ${GLOBAL_DIR}")
  37     endif()
  38
  39     set(HOST_BINARY_DIR "" CACHE PATH "Full path to native cmake build directory")
  40 endfunction()
  41
  42 # Set some generic options that influence what is being build.
  43 #
  44 # set_options()
  45 #
  46 function(set_options)
  47     option(OPTION_PACKAGE_DEPENDENCIES "Copy dependencies into lib/ for easy packaging (Linux only)" OFF)
  48
  49     if(UNIX AND NOT APPLE AND NOT OPTION_PACKAGE_DEPENDENCIES)
  50         set(DEFAULT_OPTION_INSTALL_FHS ON)
  51     else()
  52         set(DEFAULT_OPTION_INSTALL_FHS OFF)
  53     endif()
  54
  55     option(OPTION_FORCE_COLORED_OUTPUT "Always produce ANSI-colored output (GNU/Clang only)." OFF)
  56
  57     option(OPTION_DEDICATED "Build dedicated server only (no GUI)" OFF)
  58     option(OPTION_INSTALL_FHS "Install with Filesystem Hierarchy Standard folders" ${DEFAULT_OPTION_INSTALL_FHS})
  59     option(OPTION_USE_ASSERTS "Use assertions; leave enabled for nightlies, betas, and RCs" ON)
  60     option(OPTION_USE_NSIS "Use NSIS to create windows installer; enable only for stable releases" OFF)
  61     option(OPTION_TOOLS_ONLY "Build only tools target" OFF)
  62     option(OPTION_DOCS_ONLY "Build only docs target" OFF)
  63     option(OPTION_ALLOW_INVALID_SIGNATURE "Allow loading of content with invalid signatures" OFF)
  64
  65     if (OPTION_DOCS_ONLY)
  66         set(OPTION_TOOLS_ONLY ON PARENT_SCOPE)
  67     endif()
  68
  69     option(OPTION_SURVEY_KEY "Survey-key to use for the opt-in survey (empty if you have none)" "")
  70 endfunction()
  71
  72 # Show the values of the generic options.
  73 #
  74 # show_options()
  75 #
  76 function(show_options)
  77     message(STATUS "Option Package Dependencies - ${OPTION_PACKAGE_DEPENDENCIES}")
  78     message(STATUS "Option Dedicated - ${OPTION_DEDICATED}")
  79     message(STATUS "Option Install FHS - ${OPTION_INSTALL_FHS}")
  80     message(STATUS "Option Use assert - ${OPTION_USE_ASSERTS}")
  81     message(STATUS "Option Use NSIS - ${OPTION_USE_NSIS}")
  82
  83     if(OPTION_SURVEY_KEY)
  84         message(STATUS "Option Survey Key - USED")
  85     else()
  86         message(STATUS "Option Survey Key - NOT USED")
  87     endif()
  88
  89     if(OPTION_ALLOW_INVALID_SIGNATURE)
  90         message(STATUS "Option Allow Invalid Signature - USED")
  91         message(WARNING "Ignoring invalid signatures is a security risk! Use with care!")
  92     endif()
  93 endfunction()
  94
  95 # Add the definitions for the options that are selected.
  96 #
  97 # add_definitions_based_on_options()
  98 #
  99 function(add_definitions_based_on_options)
 100     if(OPTION_DEDICATED)
 101         add_definitions(-DDEDICATED)
 102     endif()
 103
 104     if(OPTION_USE_ASSERTS)
 105         add_definitions(-DWITH_ASSERT)
 106     else()
 107         add_definitions(-DNDEBUG)
 108     endif()
 109
 110     if(OPTION_SURVEY_KEY)
 111         add_definitions(-DSURVEY_KEY="${OPTION_SURVEY_KEY}")
 112     endif()
 113
 114     if(OPTION_ALLOW_INVALID_SIGNATURE)
 115         add_definitions(-DALLOW_INVALID_SIGNATURE)
 116     endif()
 117 endfunction()