contrib/pgcrypto/meson.build

   1 # Copyright (c) 2022-2024, PostgreSQL Global Development Group
   2
   3 if not ssl.found()
   4   subdir_done()
   5 endif
   6
   7 pgcrypto_sources = files(
   8   'crypt-blowfish.c',
   9   'crypt-des.c',
  10   'crypt-gensalt.c',
  11   'crypt-md5.c',
  12   'mbuf.c',
  13   'pgcrypto.c',
  14   'pgp-armor.c',
  15   'pgp-cfb.c',
  16   'pgp-compress.c',
  17   'pgp-decrypt.c',
  18   'pgp-encrypt.c',
  19   'pgp-info.c',
  20   'pgp-mpi.c',
  21   'pgp-pgsql.c',
  22   'pgp-pubdec.c',
  23   'pgp-pubenc.c',
  24   'pgp-pubkey.c',
  25   'pgp-s2k.c',
  26   'pgp.c',
  27   'px-crypt.c',
  28   'px-hmac.c',
  29   'px.c',
  30 )
  31
  32 pgcrypto_regress = [
  33   'init',
  34   'md5',
  35   'sha1',
  36   'hmac-md5',
  37   'hmac-sha1',
  38   'blowfish',
  39   'rijndael',
  40   'sha2',
  41   'des',
  42   '3des',
  43   'cast5',
  44   'crypt-des',
  45   'crypt-md5',
  46   'crypt-blowfish',
  47   'crypt-xdes',
  48   'pgp-armor',
  49   'pgp-decrypt',
  50   'pgp-encrypt',
  51   'pgp-encrypt-md5',
  52   'pgp-pubkey-decrypt',
  53   'pgp-pubkey-encrypt',
  54   'pgp-info',
  55 ]
  56
  57 pgcrypto_openssl_sources = files(
  58   'openssl.c',
  59   'pgp-mpi-openssl.c',
  60 )
  61
  62 pgcrypto_deps = []
  63 pgcrypto_link_with = []
  64
  65 pgcrypto_deps += ssl
  66 pgcrypto_sources += pgcrypto_openssl_sources
  67
  68 if zlib.found()
  69   pgcrypto_deps += zlib
  70   pgcrypto_regress += 'pgp-compression'
  71 else
  72   pgcrypto_regress += 'pgp-zlib-DISABLED'
  73 endif
  74
  75 if host_system == 'windows'
  76   pgcrypto_sources += rc_lib_gen.process(win32ver_rc, extra_args: [
  77     '--NAME', 'pgcrypto',
  78     '--FILEDESC', 'pgcrypto - cryptographic functions',])
  79 endif
  80
  81 pgcrypto = shared_module('pgcrypto',
  82   pgcrypto_sources,
  83   link_with: pgcrypto_link_with,
  84   c_pch: pch_postgres_h,
  85   kwargs: contrib_mod_args + {
  86     'dependencies': [pgcrypto_deps, contrib_mod_args['dependencies']]
  87   },
  88 )
  89 contrib_targets += pgcrypto
  90
  91 install_data(
  92   'pgcrypto--1.0--1.1.sql',
  93   'pgcrypto--1.1--1.2.sql',
  94   'pgcrypto--1.2--1.3.sql',
  95   'pgcrypto--1.3.sql',
  96   'pgcrypto.control',
  97   kwargs: contrib_data_args,
  98 )
  99
 100
 101 tests += {
 102   'name': 'pgcrypto',
 103   'sd': meson.current_source_dir(),
 104   'bd': meson.current_build_dir(),
 105   'regress': {
 106     'sql': [
 107       pgcrypto_regress,
 108     ],
 109   },
 110 }