| blob | 271140b38b6f9d5867c66b23bf6b6e4d6642314a |
1 /*
2 * PowerPC version
3 * Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
4 *
5 * Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
6 * Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
7 * Adapted for Power Macintosh by Paul Mackerras.
8 * Low-level exception handlers and MMU support
9 * rewritten by Paul Mackerras.
10 * Copyright (C) 1996 Paul Mackerras.
11 *
12 * Adapted for 64bit PowerPC by Dave Engebretsen, Peter Bergner, and
13 * Mike Corrigan {engebret|bergner|mikejc}@us.ibm.com
14 *
15 * This file contains the entry point for the 64-bit kernel along
16 * with some early initialization code common to all 64-bit powerpc
17 * variants.
18 *
19 * This program is free software; you can redistribute it and/or
20 * modify it under the terms of the GNU General Public License
21 * as published by the Free Software Foundation; either version
22 * 2 of the License, or (at your option) any later version.
23 */
25 #include <linux/threads.h>
26 #include <asm/reg.h>
27 #include <asm/page.h>
28 #include <asm/mmu.h>
29 #include <asm/ppc_asm.h>
30 #include <asm/asm-offsets.h>
31 #include <asm/bug.h>
32 #include <asm/cputable.h>
33 #include <asm/setup.h>
34 #include <asm/hvcall.h>
35 #include <asm/iseries/lpar_map.h>
36 #include <asm/thread_info.h>
37 #include <asm/firmware.h>
38 #include <asm/page_64.h>
39 #include <asm/irqflags.h>
40 #include <asm/kvm_book3s_asm.h>
41 #include <asm/ptrace.h>
43 /* The physical memory is layed out such that the secondary processor
44 * spin code sits at 0x0000...0x00ff. On server, the vectors follow
45 * using the layout described in exceptions-64s.S
46 */
48 /*
49 * Entering into this code we make the following assumptions:
50 *
51 * For pSeries or server processors:
52 * 1. The MMU is off & open firmware is running in real mode.
53 * 2. The kernel is entered at __start
54 *
55 * For iSeries:
56 * 1. The MMU is on (as it always is for iSeries)
57 * 2. The kernel is entered at system_reset_iSeries
58 *
59 * For Book3E processors:
60 * 1. The MMU is on running in AS0 in a state defined in ePAPR
61 * 2. The kernel is entered at __start
62 */
64 .text
65 .globl _stext
66 _stext:
67 _GLOBAL(__start)
68 /* NOP this out unconditionally */
69 BEGIN_FTR_SECTION
70 b .__start_initialization_multiplatform
71 END_FTR_SECTION(0, 1)
73 /* Catch branch to 0 in real mode */
74 trap
76 /* Secondary processors spin on this value until it becomes nonzero.
77 * When it does it contains the real address of the descriptor
78 * of the function that the cpu should jump to to continue
79 * initialization.
80 */
81 .globl __secondary_hold_spinloop
82 __secondary_hold_spinloop:
83 .llong 0x0
85 /* Secondary processors write this value with their cpu # */
86 /* after they enter the spin loop immediately below. */
87 .globl __secondary_hold_acknowledge
88 __secondary_hold_acknowledge:
89 .llong 0x0
91 #ifdef CONFIG_PPC_ISERIES
92 /*
93 * At offset 0x20, there is a pointer to iSeries LPAR data.
94 * This is required by the hypervisor
95 */
96 . = 0x20
97 .llong hvReleaseData-KERNELBASE
98 #endif /* CONFIG_PPC_ISERIES */
100 #ifdef CONFIG_RELOCATABLE
101 /* This flag is set to 1 by a loader if the kernel should run
102 * at the loaded address instead of the linked address. This
103 * is used by kexec-tools to keep the the kdump kernel in the
104 * crash_kernel region. The loader is responsible for
105 * observing the alignment requirement.
106 */
107 /* Do not move this variable as kexec-tools knows about it. */
108 . = 0x5c
109 .globl __run_at_load
110 __run_at_load:
111 .long 0x72756e30 /* "run0" -- relocate to 0 by default */
112 #endif
114 . = 0x60
115 /*
116 * The following code is used to hold secondary processors
117 * in a spin loop after they have entered the kernel, but
118 * before the bulk of the kernel has been relocated. This code
119 * is relocated to physical address 0x60 before prom_init is run.
120 * All of it must fit below the first exception vector at 0x100.
121 * Use .globl here not _GLOBAL because we want __secondary_hold
122 * to be the actual text address, not a descriptor.
123 */
124 .globl __secondary_hold
125 __secondary_hold:
126 #ifndef CONFIG_PPC_BOOK3E
127 mfmsr r24
128 ori r24,r24,MSR_RI
129 mtmsrd r24 /* RI on */
130 #endif
131 /* Grab our physical cpu number */
132 mr r24,r3
134 /* Tell the master cpu we're here */
135 /* Relocation is off & we are located at an address less */
136 /* than 0x100, so only need to grab low order offset. */
137 std r24,__secondary_hold_acknowledge-_stext(0)
138 sync
140 /* All secondary cpus wait here until told to start. */
141 100: ld r4,__secondary_hold_spinloop-_stext(0)
142 cmpdi 0,r4,0
143 beq 100b
145 #if defined(CONFIG_SMP) || defined(CONFIG_KEXEC)
146 ld r4,0(r4) /* deref function descriptor */
147 mtctr r4
148 mr r3,r24
149 li r4,0
150 bctr
151 #else
152 BUG_OPCODE
153 #endif
155 /* This value is used to mark exception frames on the stack. */
156 .section ".toc","aw"
157 exception_marker:
158 .tc ID_72656773_68657265[TC],0x7265677368657265
159 .text
161 /*
162 * On server, we include the exception vectors code here as it
163 * relies on absolute addressing which is only possible within
164 * this compilation unit
165 */
166 #ifdef CONFIG_PPC_BOOK3S
167 #include "exceptions-64s.S"
168 #endif
170 _GLOBAL(generic_secondary_thread_init)
171 mr r24,r3
173 /* turn on 64-bit mode */
174 bl .enable_64b_mode
176 /* get a valid TOC pointer, wherever we're mapped at */
177 bl .relative_toc
179 #ifdef CONFIG_PPC_BOOK3E
180 /* Book3E initialization */
181 mr r3,r24
182 bl .book3e_secondary_thread_init
183 #endif
184 b generic_secondary_common_init
186 /*
187 * On pSeries and most other platforms, secondary processors spin
188 * in the following code.
189 * At entry, r3 = this processor's number (physical cpu id)
190 *
191 * On Book3E, r4 = 1 to indicate that the initial TLB entry for
192 * this core already exists (setup via some other mechanism such
193 * as SCOM before entry).
194 */
195 _GLOBAL(generic_secondary_smp_init)
196 mr r24,r3
197 mr r25,r4
199 /* turn on 64-bit mode */
200 bl .enable_64b_mode
202 /* get a valid TOC pointer, wherever we're mapped at */
203 bl .relative_toc
205 #ifdef CONFIG_PPC_BOOK3E
206 /* Book3E initialization */
207 mr r3,r24
208 mr r4,r25
209 bl .book3e_secondary_core_init
210 #endif
212 generic_secondary_common_init:
213 /* Set up a paca value for this processor. Since we have the
214 * physical cpu id in r24, we need to search the pacas to find
215 * which logical id maps to our physical one.
216 */
217 LOAD_REG_ADDR(r13, paca) /* Load paca pointer */
218 ld r13,0(r13) /* Get base vaddr of paca array */
219 li r5,0 /* logical cpu id */
220 1: lhz r6,PACAHWCPUID(r13) /* Load HW procid from paca */
221 cmpw r6,r24 /* Compare to our id */
222 beq 2f
223 addi r13,r13,PACA_SIZE /* Loop to next PACA on miss */
224 addi r5,r5,1
225 cmpwi r5,NR_CPUS
226 blt 1b
228 mr r3,r24 /* not found, copy phys to r3 */
229 b .kexec_wait /* next kernel might do better */
231 2: mtspr SPRN_SPRG_PACA,r13 /* Save vaddr of paca in an SPRG */
232 #ifdef CONFIG_PPC_BOOK3E
233 addi r12,r13,PACA_EXTLB /* and TLB exc frame in another */
234 mtspr SPRN_SPRG_TLB_EXFRAME,r12
235 #endif
237 /* From now on, r24 is expected to be logical cpuid */
238 mr r24,r5
239 3: HMT_LOW
240 lbz r23,PACAPROCSTART(r13) /* Test if this processor should */
241 /* start. */
243 #ifndef CONFIG_SMP
244 b 3b /* Never go on non-SMP */
245 #else
246 cmpwi 0,r23,0
247 beq 3b /* Loop until told to go */
249 sync /* order paca.run and cur_cpu_spec */
251 /* See if we need to call a cpu state restore handler */
252 LOAD_REG_ADDR(r23, cur_cpu_spec)
253 ld r23,0(r23)
254 ld r23,CPU_SPEC_RESTORE(r23)
255 cmpdi 0,r23,0
256 beq 4f
257 ld r23,0(r23)
258 mtctr r23
259 bctrl
261 4: /* Create a temp kernel stack for use before relocation is on. */
262 ld r1,PACAEMERGSP(r13)
263 subi r1,r1,STACK_FRAME_OVERHEAD
265 b __secondary_start
266 #endif
268 /*
269 * Turn the MMU off.
270 * Assumes we're mapped EA == RA if the MMU is on.
271 */
272 #ifdef CONFIG_PPC_BOOK3S
273 _STATIC(__mmu_off)
274 mfmsr r3
275 andi. r0,r3,MSR_IR|MSR_DR
276 beqlr
277 mflr r4
278 andc r3,r3,r0
279 mtspr SPRN_SRR0,r4
280 mtspr SPRN_SRR1,r3
281 sync
282 rfid
283 b . /* prevent speculative execution */
284 #endif
287 /*
288 * Here is our main kernel entry point. We support currently 2 kind of entries
289 * depending on the value of r5.
290 *
291 * r5 != NULL -> OF entry, we go to prom_init, "legacy" parameter content
292 * in r3...r7
293 *
294 * r5 == NULL -> kexec style entry. r3 is a physical pointer to the
295 * DT block, r4 is a physical pointer to the kernel itself
296 *
297 */
298 _GLOBAL(__start_initialization_multiplatform)
299 /* Make sure we are running in 64 bits mode */
300 bl .enable_64b_mode
302 /* Get TOC pointer (current runtime address) */
303 bl .relative_toc
305 /* find out where we are now */
306 bcl 20,31,$+4
307 0: mflr r26 /* r26 = runtime addr here */
308 addis r26,r26,(_stext - 0b)@ha
309 addi r26,r26,(_stext - 0b)@l /* current runtime base addr */
311 /*
312 * Are we booted from a PROM Of-type client-interface ?
313 */
314 cmpldi cr0,r5,0
315 beq 1f
316 b .__boot_from_prom /* yes -> prom */
317 1:
318 /* Save parameters */
319 mr r31,r3
320 mr r30,r4
322 #ifdef CONFIG_PPC_BOOK3E
323 bl .start_initialization_book3e
324 b .__after_prom_start
325 #else
326 /* Setup some critical 970 SPRs before switching MMU off */
327 mfspr r0,SPRN_PVR
328 srwi r0,r0,16
329 cmpwi r0,0x39 /* 970 */
330 beq 1f
331 cmpwi r0,0x3c /* 970FX */
332 beq 1f
333 cmpwi r0,0x44 /* 970MP */
334 beq 1f
335 cmpwi r0,0x45 /* 970GX */
336 bne 2f
337 1: bl .__cpu_preinit_ppc970
338 2:
340 /* Switch off MMU if not already off */
341 bl .__mmu_off
342 b .__after_prom_start
343 #endif /* CONFIG_PPC_BOOK3E */
345 _INIT_STATIC(__boot_from_prom)
346 #ifdef CONFIG_PPC_OF_BOOT_TRAMPOLINE
347 /* Save parameters */
348 mr r31,r3
349 mr r30,r4
350 mr r29,r5
351 mr r28,r6
352 mr r27,r7
354 /*
355 * Align the stack to 16-byte boundary
356 * Depending on the size and layout of the ELF sections in the initial
357 * boot binary, the stack pointer may be unaligned on PowerMac
358 */
359 rldicr r1,r1,0,59
361 #ifdef CONFIG_RELOCATABLE
362 /* Relocate code for where we are now */
363 mr r3,r26
364 bl .relocate
365 #endif
367 /* Restore parameters */
368 mr r3,r31
369 mr r4,r30
370 mr r5,r29
371 mr r6,r28
372 mr r7,r27
374 /* Do all of the interaction with OF client interface */
375 mr r8,r26
376 bl .prom_init
377 #endif /* #CONFIG_PPC_OF_BOOT_TRAMPOLINE */
379 /* We never return. We also hit that trap if trying to boot
380 * from OF while CONFIG_PPC_OF_BOOT_TRAMPOLINE isn't selected */
381 trap
383 _STATIC(__after_prom_start)
384 #ifdef CONFIG_RELOCATABLE
385 /* process relocations for the final address of the kernel */
386 lis r25,PAGE_OFFSET@highest /* compute virtual base of kernel */
387 sldi r25,r25,32
388 lwz r7,__run_at_load-_stext(r26)
389 cmplwi cr0,r7,1 /* flagged to stay where we are ? */
390 bne 1f
391 add r25,r25,r26
392 1: mr r3,r25
393 bl .relocate
394 #endif
396 /*
397 * We need to run with _stext at physical address PHYSICAL_START.
398 * This will leave some code in the first 256B of
399 * real memory, which are reserved for software use.
400 *
401 * Note: This process overwrites the OF exception vectors.
402 */
403 li r3,0 /* target addr */
404 #ifdef CONFIG_PPC_BOOK3E
405 tovirt(r3,r3) /* on booke, we already run at PAGE_OFFSET */
406 #endif
407 mr. r4,r26 /* In some cases the loader may */
408 beq 9f /* have already put us at zero */
409 li r6,0x100 /* Start offset, the first 0x100 */
410 /* bytes were copied earlier. */
411 #ifdef CONFIG_PPC_BOOK3E
412 tovirt(r6,r6) /* on booke, we already run at PAGE_OFFSET */
413 #endif
415 #ifdef CONFIG_CRASH_DUMP
416 /*
417 * Check if the kernel has to be running as relocatable kernel based on the
418 * variable __run_at_load, if it is set the kernel is treated as relocatable
419 * kernel, otherwise it will be moved to PHYSICAL_START
420 */
421 lwz r7,__run_at_load-_stext(r26)
422 cmplwi cr0,r7,1
423 bne 3f
425 li r5,__end_interrupts - _stext /* just copy interrupts */
426 b 5f
427 3:
428 #endif
429 lis r5,(copy_to_here - _stext)@ha
430 addi r5,r5,(copy_to_here - _stext)@l /* # bytes of memory to copy */
432 bl .copy_and_flush /* copy the first n bytes */
433 /* this includes the code being */
434 /* executed here. */
435 addis r8,r3,(4f - _stext)@ha /* Jump to the copy of this code */
436 addi r8,r8,(4f - _stext)@l /* that we just made */
437 mtctr r8
438 bctr
440 p_end: .llong _end - _stext
442 4: /* Now copy the rest of the kernel up to _end */
443 addis r5,r26,(p_end - _stext)@ha
444 ld r5,(p_end - _stext)@l(r5) /* get _end */
445 5: bl .copy_and_flush /* copy the rest */
447 9: b .start_here_multiplatform
449 /*
450 * Copy routine used to copy the kernel to start at physical address 0
451 * and flush and invalidate the caches as needed.
452 * r3 = dest addr, r4 = source addr, r5 = copy limit, r6 = start offset
453 * on exit, r3, r4, r5 are unchanged, r6 is updated to be >= r5.
454 *
455 * Note: this routine *only* clobbers r0, r6 and lr
456 */
457 _GLOBAL(copy_and_flush)
458 addi r5,r5,-8
459 addi r6,r6,-8
460 4: li r0,8 /* Use the smallest common */
461 /* denominator cache line */
462 /* size. This results in */
463 /* extra cache line flushes */
464 /* but operation is correct. */
465 /* Can't get cache line size */
466 /* from NACA as it is being */
467 /* moved too. */
469 mtctr r0 /* put # words/line in ctr */
470 3: addi r6,r6,8 /* copy a cache line */
471 ldx r0,r6,r4
472 stdx r0,r6,r3
473 bdnz 3b
474 dcbst r6,r3 /* write it to memory */
475 sync
476 icbi r6,r3 /* flush the icache line */
477 cmpld 0,r6,r5
478 blt 4b
479 sync
480 addi r5,r5,8
481 addi r6,r6,8
482 blr
484 .align 8
485 copy_to_here:
487 #ifdef CONFIG_SMP
488 #ifdef CONFIG_PPC_PMAC
489 /*
490 * On PowerMac, secondary processors starts from the reset vector, which
491 * is temporarily turned into a call to one of the functions below.
492 */
493 .section ".text";
494 .align 2 ;
496 .globl __secondary_start_pmac_0
497 __secondary_start_pmac_0:
498 /* NB the entries for cpus 0, 1, 2 must each occupy 8 bytes. */
499 li r24,0
500 b 1f
501 li r24,1
502 b 1f
503 li r24,2
504 b 1f
505 li r24,3
506 1:
508 _GLOBAL(pmac_secondary_start)
509 /* turn on 64-bit mode */
510 bl .enable_64b_mode
512 li r0,0
513 mfspr r3,SPRN_HID4
514 rldimi r3,r0,40,23 /* clear bit 23 (rm_ci) */
515 sync
516 mtspr SPRN_HID4,r3
517 isync
518 sync
519 slbia
521 /* get TOC pointer (real address) */
522 bl .relative_toc
524 /* Copy some CPU settings from CPU 0 */
525 bl .__restore_cpu_ppc970
527 /* pSeries do that early though I don't think we really need it */
528 mfmsr r3
529 ori r3,r3,MSR_RI
530 mtmsrd r3 /* RI on */
532 /* Set up a paca value for this processor. */
533 LOAD_REG_ADDR(r4,paca) /* Load paca pointer */
534 ld r4,0(r4) /* Get base vaddr of paca array */
535 mulli r13,r24,PACA_SIZE /* Calculate vaddr of right paca */
536 add r13,r13,r4 /* for this processor. */
537 mtspr SPRN_SPRG_PACA,r13 /* Save vaddr of paca in an SPRG*/
539 /* Mark interrupts soft and hard disabled (they might be enabled
540 * in the PACA when doing hotplug)
541 */
542 li r0,0
543 stb r0,PACASOFTIRQEN(r13)
544 stb r0,PACAHARDIRQEN(r13)
546 /* Create a temp kernel stack for use before relocation is on. */
547 ld r1,PACAEMERGSP(r13)
548 subi r1,r1,STACK_FRAME_OVERHEAD
550 b __secondary_start
552 #endif /* CONFIG_PPC_PMAC */
554 /*
555 * This function is called after the master CPU has released the
556 * secondary processors. The execution environment is relocation off.
557 * The paca for this processor has the following fields initialized at
558 * this point:
559 * 1. Processor number
560 * 2. Segment table pointer (virtual address)
561 * On entry the following are set:
562 * r1 = stack pointer. vaddr for iSeries, raddr (temp stack) for pSeries
563 * r24 = cpu# (in Linux terms)
564 * r13 = paca virtual address
565 * SPRG_PACA = paca virtual address
566 */
567 .section ".text";
568 .align 2 ;
570 .globl __secondary_start
571 __secondary_start:
572 /* Set thread priority to MEDIUM */
573 HMT_MEDIUM
575 /* Initialize the kernel stack. Just a repeat for iSeries. */
576 LOAD_REG_ADDR(r3, current_set)
577 sldi r28,r24,3 /* get current_set[cpu#] */
578 ldx r14,r3,r28
579 addi r14,r14,THREAD_SIZE-STACK_FRAME_OVERHEAD
580 std r14,PACAKSAVE(r13)
582 /* Do early setup for that CPU (stab, slb, hash table pointer) */
583 bl .early_setup_secondary
585 /*
586 * setup the new stack pointer, but *don't* use this until
587 * translation is on.
588 */
589 mr r1, r14
591 /* Clear backchain so we get nice backtraces */
592 li r7,0
593 mtlr r7
595 /* enable MMU and jump to start_secondary */
596 LOAD_REG_ADDR(r3, .start_secondary_prolog)
597 LOAD_REG_IMMEDIATE(r4, MSR_KERNEL)
598 #ifdef CONFIG_PPC_ISERIES
599 BEGIN_FW_FTR_SECTION
600 ori r4,r4,MSR_EE
601 li r8,1
602 stb r8,PACAHARDIRQEN(r13)
603 END_FW_FTR_SECTION_IFSET(FW_FEATURE_ISERIES)
604 #endif
605 BEGIN_FW_FTR_SECTION
606 stb r7,PACAHARDIRQEN(r13)
607 END_FW_FTR_SECTION_IFCLR(FW_FEATURE_ISERIES)
608 stb r7,PACASOFTIRQEN(r13)
610 mtspr SPRN_SRR0,r3
611 mtspr SPRN_SRR1,r4
612 RFI
613 b . /* prevent speculative execution */
615 /*
616 * Running with relocation on at this point. All we want to do is
617 * zero the stack back-chain pointer and get the TOC virtual address
618 * before going into C code.
619 */
620 _GLOBAL(start_secondary_prolog)
621 ld r2,PACATOC(r13)
622 li r3,0
623 std r3,0(r1) /* Zero the stack frame pointer */
624 bl .start_secondary
625 b .
626 /*
627 * Reset stack pointer and call start_secondary
628 * to continue with online operation when woken up
629 * from cede in cpu offline.
630 */
631 _GLOBAL(start_secondary_resume)
632 ld r1,PACAKSAVE(r13) /* Reload kernel stack pointer */
633 li r3,0
634 std r3,0(r1) /* Zero the stack frame pointer */
635 bl .start_secondary
636 b .
637 #endif
639 /*
640 * This subroutine clobbers r11 and r12
641 */
642 _GLOBAL(enable_64b_mode)
643 mfmsr r11 /* grab the current MSR */
644 #ifdef CONFIG_PPC_BOOK3E
645 oris r11,r11,0x8000 /* CM bit set, we'll set ICM later */
646 mtmsr r11
647 #else /* CONFIG_PPC_BOOK3E */
648 li r12,(MSR_SF | MSR_ISF)@highest
649 sldi r12,r12,48
650 or r11,r11,r12
651 mtmsrd r11
652 isync
653 #endif
654 blr
656 /*
657 * This puts the TOC pointer into r2, offset by 0x8000 (as expected
658 * by the toolchain). It computes the correct value for wherever we
659 * are running at the moment, using position-independent code.
660 */
661 _GLOBAL(relative_toc)
662 mflr r0
663 bcl 20,31,$+4
664 0: mflr r9
665 ld r2,(p_toc - 0b)(r9)
666 add r2,r2,r9
667 mtlr r0
668 blr
670 p_toc: .llong __toc_start + 0x8000 - 0b
672 /*
673 * This is where the main kernel code starts.
674 */
675 _INIT_STATIC(start_here_multiplatform)
676 /* set up the TOC (real address) */
677 bl .relative_toc
679 /* Clear out the BSS. It may have been done in prom_init,
680 * already but that's irrelevant since prom_init will soon
681 * be detached from the kernel completely. Besides, we need
682 * to clear it now for kexec-style entry.
683 */
684 LOAD_REG_ADDR(r11,__bss_stop)
685 LOAD_REG_ADDR(r8,__bss_start)
686 sub r11,r11,r8 /* bss size */
687 addi r11,r11,7 /* round up to an even double word */
688 srdi. r11,r11,3 /* shift right by 3 */
689 beq 4f
690 addi r8,r8,-8
691 li r0,0
692 mtctr r11 /* zero this many doublewords */
693 3: stdu r0,8(r8)
694 bdnz 3b
695 4:
697 #ifndef CONFIG_PPC_BOOK3E
698 mfmsr r6
699 ori r6,r6,MSR_RI
700 mtmsrd r6 /* RI on */
701 #endif
703 #ifdef CONFIG_RELOCATABLE
704 /* Save the physical address we're running at in kernstart_addr */
705 LOAD_REG_ADDR(r4, kernstart_addr)
706 clrldi r0,r25,2
707 std r0,0(r4)
708 #endif
710 /* The following gets the stack set up with the regs */
711 /* pointing to the real addr of the kernel stack. This is */
712 /* all done to support the C function call below which sets */
713 /* up the htab. This is done because we have relocated the */
714 /* kernel but are still running in real mode. */
716 LOAD_REG_ADDR(r3,init_thread_union)
718 /* set up a stack pointer */
719 addi r1,r3,THREAD_SIZE
720 li r0,0
721 stdu r0,-STACK_FRAME_OVERHEAD(r1)
723 /* Do very early kernel initializations, including initial hash table,
724 * stab and slb setup before we turn on relocation. */
726 /* Restore parameters passed from prom_init/kexec */
727 mr r3,r31
728 bl .early_setup /* also sets r13 and SPRG_PACA */
730 LOAD_REG_ADDR(r3, .start_here_common)
731 ld r4,PACAKMSR(r13)
732 mtspr SPRN_SRR0,r3
733 mtspr SPRN_SRR1,r4
734 RFI
735 b . /* prevent speculative execution */
737 /* This is where all platforms converge execution */
738 _INIT_GLOBAL(start_here_common)
739 /* relocation is on at this point */
740 std r1,PACAKSAVE(r13)
742 /* Load the TOC (virtual address) */
743 ld r2,PACATOC(r13)
745 bl .setup_system
747 /* Load up the kernel context */
748 5:
749 li r5,0
750 stb r5,PACASOFTIRQEN(r13) /* Soft Disabled */
751 #ifdef CONFIG_PPC_ISERIES
752 BEGIN_FW_FTR_SECTION
753 mfmsr r5
754 ori r5,r5,MSR_EE /* Hard Enabled on iSeries*/
755 mtmsrd r5
756 li r5,1
757 END_FW_FTR_SECTION_IFSET(FW_FEATURE_ISERIES)
758 #endif
759 stb r5,PACAHARDIRQEN(r13) /* Hard Disabled on others */
761 bl .start_kernel
763 /* Not reached */
764 BUG_OPCODE
766 /*
767 * We put a few things here that have to be page-aligned.
768 * This stuff goes at the beginning of the bss, which is page-aligned.
769 */
770 .section ".bss"
772 .align PAGE_SHIFT
774 .globl empty_zero_page
775 empty_zero_page:
776 .space PAGE_SIZE
778 .globl swapper_pg_dir
779 swapper_pg_dir:
780 .space PGD_TABLE_SIZE