changelog.xsl

   1 <?xml version="1.0" encoding="ISO-8859-1"?>
   2 <xsl:stylesheet
   3     xmlns:xsl='http://www.w3.org/1999/XSL/Transform'
   4     version='1.0'>
   5
   6 <!--
   7 /* ====================================================================
   8    Licensed to the Apache Software Foundation (ASF) under one or more
   9    contributor license agreements.  See the NOTICE file distributed with
  10    this work for additional information regarding copyright ownership.
  11    The ASF licenses this file to You under the Apache License, Version 2.0
  12    (the "License"); you may not use this file except in compliance with
  13    the License.  You may obtain a copy of the License at
  14
  15        http://www.apache.org/licenses/LICENSE-2.0
  16
  17    Unless required by applicable law or agreed to in writing, software
  18    distributed under the License is distributed on an "AS IS" BASIS,
  19    WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  20    See the License for the specific language governing permissions and
  21    limitations under the License.
  22 ==================================================================== */
  23  -->
  24   <xsl:param name="title"/>
  25   <xsl:param name="module"/>
  26   <xsl:param name="cvsweb"/>
  27
  28   <xsl:output method="html" indent="yes"  encoding="US-ASCII"/>
  29
  30   <!-- Copy standard document elements.  Elements that
  31        should be ignored must be filtered by apply-templates
  32        tags. -->
  33   <xsl:template match="*">
  34     <xsl:copy>
  35       <xsl:copy-of select="attribute::*[. != '']"/>
  36       <xsl:apply-templates/>
  37     </xsl:copy>
  38   </xsl:template>
  39
  40   <xsl:template match="changelog">
  41     <HTML>
  42       <HEAD>
  43         <TITLE><xsl:value-of select="$title"/></TITLE>
  44       </HEAD>
  45       <BODY link="#000000" alink="#000000" vlink="#000000" text="#000000">
  46         <style type="text/css">
  47           body, p {
  48           font-family: verdana,arial,helvetica;
  49           font-size: 100%;
  50           color:#000000;
  51           }
  52           .dateAndAuthor {
  53           font-family: verdana,arial,helvetica;
  54           font-size: 100%;
  55           font-weight: bold;
  56           text-align:left;
  57           background:#a6caf0;
  58           }
  59           tr, td{
  60           font-family: verdana,arial,helvetica;
  61           font-size: 120%;
  62           background:#eeeee0;
  63           }
  64           </style>
  65           <h1>
  66             <a name="top"><xsl:value-of select="$title"/></a>
  67           </h1>
  68
  69           <hr size="2"/>
  70         <TABLE BORDER="0" WIDTH="100%" CELLPADDING="3" CELLSPACING="1">
  71
  72           <xsl:apply-templates select=".//entry">
  73             <xsl:sort select="date" data-type="text" order="descending"/>
  74             <xsl:sort select="time" data-type="text" order="descending"/>
  75           </xsl:apply-templates>
  76
  77         </TABLE>
  78
  79       </BODY>
  80     </HTML>
  81   </xsl:template>
  82
  83   <xsl:template match="entry">
  84     <TR>
  85       <TD colspan="2" class="dateAndAuthor">
  86         <xsl:value-of select="date"/><xsl:text> </xsl:text><xsl:value-of select="time"/><xsl:text> </xsl:text><xsl:value-of select="author"/>
  87       </TD>
  88     </TR>
  89     <TR>
  90       <TD width="20">
  91         <xsl:text>    </xsl:text>
  92       </TD>
  93       <TD>
  94         <pre>
  95 <xsl:apply-templates select="msg"/></pre>
  96         <ul>
  97           <xsl:apply-templates select="file"/>
  98         </ul>
  99       </TD>
 100     </TR>
 101   </xsl:template>
 102
 103   <xsl:template match="date">
 104     <i><xsl:value-of select="."/></i>
 105   </xsl:template>
 106
 107   <xsl:template match="time">
 108     <i><xsl:value-of select="."/></i>
 109   </xsl:template>
 110
 111   <xsl:template match="author">
 112     <i>
 113       <a>
 114         <xsl:attribute name="href">mailto:<xsl:value-of select="."/></xsl:attribute>
 115         <xsl:value-of select="."/>
 116       </a>
 117     </i>
 118   </xsl:template>
 119
 120   <xsl:template match="file">
 121     <li>
 122       <a>
 123         <xsl:choose>
 124           <xsl:when test="string-length(prevrevision) = 0 ">
 125             <xsl:attribute name="href"><xsl:value-of select="$cvsweb"/><xsl:value-of select="$module" />/<xsl:value-of select="name" />?rev=<xsl:value-of select="revision" />&amp;content-type=text/x-cvsweb-markup</xsl:attribute>
 126           </xsl:when>
 127           <xsl:otherwise>
 128             <xsl:attribute name="href"><xsl:value-of select="$cvsweb"/><xsl:value-of select="$module" />/<xsl:value-of select="name" />?r1=<xsl:value-of select="revision" />&amp;r2=<xsl:value-of select="prevrevision"/></xsl:attribute>
 129           </xsl:otherwise>
 130         </xsl:choose>
 131         <xsl:value-of select="name" /> (<xsl:value-of select="revision"/>)
 132       </a>
 133     </li>
 134   </xsl:template>
 135
 136   <!-- Any elements within a msg are processed,
 137        so that we can preserve HTML tags. -->
 138   <xsl:template match="msg">
 139     <b><xsl:apply-templates/></b>
 140   </xsl:template>
 141
 142 </xsl:stylesheet>
 143