winconf.pri

   1 # After 1.55 some Windows users reported regular UI freezes.
   2 # This makes ASIO use the pre-1.56 way of doing things. See issue #2003
   3 DEFINES += BOOST_ASIO_DISABLE_CONNECTEX
   4 DEFINES += BOOST_EXCEPTION_DISABLE
   5
   6 DEFINES += TORRENT_USE_LIBCRYPTO
   7 # TODO: remove the following define as it is not used since OpenSSL >= 1.1
   8 DEFINES += TORRENT_USE_OPENSSL
   9 # TODO: remove the following define as it is not used since libtorrent >= 1.2
  10 DEFINES += TORRENT_DISABLE_RESOLVE_COUNTRIES
  11
  12 DEFINES += NTDDI_VERSION=0x06010000
  13 DEFINES += _WIN32_WINNT=0x0601
  14 DEFINES += _WIN32_IE=0x0601
  15 DEFINES += UNICODE
  16 DEFINES += _UNICODE
  17 DEFINES += WIN32
  18 DEFINES += _WIN32
  19 DEFINES += WIN32_LEAN_AND_MEAN
  20 DEFINES += NOMINMAX
  21
  22 CONFIG(debug, debug|release) {
  23     DEFINES += TORRENT_DEBUG
  24 }
  25 else {
  26     DEFINES += NDEBUG
  27 }
  28
  29 win32-g++* {
  30     CONFIG(debug, debug|release) {
  31         # Make sure binary is not relocatable, otherwise debugging will fail
  32         QMAKE_LFLAGS -= -Wl,--dynamicbase
  33     }
  34
  35     DEFINES += _FILE_OFFSET_BITS=64
  36     DEFINES += __USE_W32_SOCKETS
  37
  38     RC_FILE = qbittorrent_mingw.rc
  39
  40     LIBS += libadvapi32 libiphlpapi libole32 libpowrprof libshell32 libuser32 libwsock32 libws2_32
  41 }
  42 else:win32-msvc* {
  43     CONFIG -= embed_manifest_exe
  44     QMAKE_LFLAGS += "/MANIFEST:EMBED /MANIFESTINPUT:$$quote($${PWD}/src/qbittorrent.exe.manifest) /STACK:0x800000"
  45
  46     RC_FILE = qbittorrent.rc
  47
  48     LIBS += advapi32.lib crypt32.lib Iphlpapi.lib ole32.lib PowrProf.lib shell32.lib User32.lib
  49 }
  50
  51 # See an example build configuration in "conf.pri.windows"
  52 exists(conf.pri) {
  53     include(conf.pri)
  54 }
  55 else {
  56     error("'conf.pri' does not exist. See an example configuration in 'conf.pri.windows'.")
  57 }
  58
  59 # Stack trace support can be enabled in 'conf.pri'
  60 stacktrace {
  61     win32-g++* {
  62         contains(QMAKE_HOST.arch, x86) {
  63             # i686 arch requires frame pointer preservation
  64             QMAKE_CXXFLAGS += -fno-omit-frame-pointer
  65         }
  66
  67         QMAKE_LFLAGS += -Wl,--export-all-symbols
  68
  69         LIBS += libdbghelp
  70     }
  71     else:win32-msvc* {
  72         contains(QMAKE_HOST.arch, x86) {
  73             # i686 arch requires frame pointer preservation
  74             QMAKE_CXXFLAGS += -Oy-
  75         }
  76
  77         QMAKE_CXXFLAGS *= -Zi
  78         QMAKE_LFLAGS *= "/DEBUG"
  79
  80         LIBS += dbghelp.lib
  81     }
  82 }