net/meson.build

   1 system_ss.add(files(
   2   'announce.c',
   3   'checksum.c',
   4   'dump.c',
   5   'eth.c',
   6   'filter-buffer.c',
   7   'filter-mirror.c',
   8   'filter.c',
   9   'hub.c',
  10   'net-hmp-cmds.c',
  11   'net.c',
  12   'queue.c',
  13   'socket.c',
  14   'stream.c',
  15   'dgram.c',
  16   'util.c',
  17 ))
  18
  19 if get_option('replication').allowed() or \
  20     get_option('colo_proxy').allowed()
  21   system_ss.add(files('colo-compare.c'))
  22   system_ss.add(files('colo.c'))
  23 else
  24   system_ss.add(files('colo-stubs.c'))
  25 endif
  26
  27 if get_option('colo_proxy').allowed()
  28   system_ss.add(files('filter-rewriter.c'))
  29 endif
  30
  31 system_ss.add(when: 'CONFIG_TCG', if_true: files('filter-replay.c'))
  32
  33 if have_l2tpv3
  34   system_ss.add(files('l2tpv3.c'))
  35 endif
  36 system_ss.add(when: slirp, if_true: files('slirp.c'))
  37 system_ss.add(when: vde, if_true: files('vde.c'))
  38 if have_netmap
  39   system_ss.add(files('netmap.c'))
  40 endif
  41
  42 system_ss.add(when: libxdp, if_true: files('af-xdp.c'))
  43
  44 if have_vhost_net_user
  45   system_ss.add(when: 'CONFIG_VIRTIO_NET', if_true: files('vhost-user.c'), if_false: files('vhost-user-stub.c'))
  46 endif
  47
  48 if host_os == 'windows'
  49   system_ss.add(files('tap-win32.c'))
  50 elif host_os == 'linux'
  51   system_ss.add(files('tap.c', 'tap-linux.c'))
  52 elif host_os in bsd_oses
  53   system_ss.add(files('tap.c', 'tap-bsd.c'))
  54 elif host_os == 'sunos'
  55   system_ss.add(files('tap.c', 'tap-solaris.c'))
  56 else
  57   system_ss.add(files('tap.c', 'tap-stub.c'))
  58 endif
  59 if have_vhost_net_vdpa
  60   system_ss.add(when: 'CONFIG_VIRTIO_NET', if_true: files('vhost-vdpa.c'), if_false: files('vhost-vdpa-stub.c'))
  61 endif
  62
  63 vmnet_files = files(
  64   'vmnet-common.m',
  65   'vmnet-bridged.m',
  66   'vmnet-host.c',
  67   'vmnet-shared.c'
  68 )
  69 system_ss.add(when: vmnet, if_true: vmnet_files)
  70 subdir('can')