configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.59)
   7
   8 RSYNC_VERSION=2.6.7pre2
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_TARGET([])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_EGREP
  22 AC_PROG_INSTALL
  23 AC_PROG_CC_STDC
  24 AC_SUBST(SHELL)
  25
  26 AC_DEFINE([_GNU_SOURCE], 1,
  27           [Define _GNU_SOURCE so that we get all necessary prototypes])
  28
  29 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  30         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  31 fi
  32
  33 # We must decide this before testing the compiler.
  34
  35 # Please allow this to default to yes, so that your users have more
  36 # chance of getting a useful stack trace if problems occur.
  37
  38 AC_MSG_CHECKING([whether to include debugging symbols])
  39 AC_ARG_ENABLE(debug,
  40         AC_HELP_STRING([--disable-debug],
  41                 [turn off debugging symbols and features]))
  42
  43 if test x"$enable_debug" = x"no"; then
  44     AC_MSG_RESULT(no)
  45     CFLAGS=${CFLAGS-"-O"}
  46 else
  47     AC_MSG_RESULT([yes])
  48     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  49     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  50     dnl CFLAGS=${CFLAGS-"-g"}
  51 fi
  52
  53
  54 AC_ARG_ENABLE(profile,
  55         AC_HELP_STRING([--enable-profile],
  56                 [turn on CPU profiling]))
  57 if test x"$enable_profile" = x"yes"; then
  58         CFLAGS="$CFLAGS -pg"
  59 fi
  60
  61
  62 # Specifically, this turns on panic_action handling.
  63 AC_ARG_ENABLE(maintainer-mode,
  64         AC_HELP_STRING([--enable-maintainer-mode],
  65                 [turn on extra debug features]))
  66 if test x"$enable_maintainer_mode" = x"yes"; then
  67         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  68 fi
  69
  70
  71 # This is needed for our included version of popt.  Kind of silly, but
  72 # I don't want our version too far out of sync.
  73 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  74
  75 # If GCC, turn on warnings.
  76 if test x"$GCC" = x"yes"; then
  77         CFLAGS="$CFLAGS -Wall -W"
  78 fi
  79
  80 AC_ARG_WITH(included-popt,
  81         AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
  82
  83 AC_ARG_WITH(rsync-path,
  84         AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
  85         [ RSYNC_PATH="$with_rsync_path" ],
  86         [ RSYNC_PATH="rsync" ])
  87
  88 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  89
  90 AC_ARG_WITH(rsyncd-conf,
  91         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
  92         [ if test ! -z "$with_rsyncd_conf" ; then
  93                 case $with_rsyncd_conf in
  94                         yes|no)
  95                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
  96                                 ;;
  97                         /*)
  98                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
  99                                 ;;
 100                         *)
 101                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 102                                 ;;
 103                 esac
 104         else
 105                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 106         fi ],
 107         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 108
 109 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 110
 111 AC_ARG_WITH(rsh,
 112         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 113
 114 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 115 if test x$HAVE_REMSH = x1; then
 116         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 117 fi
 118
 119 if test x"$with_rsh" != x; then
 120         RSYNC_RSH="$with_rsh"
 121 else
 122         RSYNC_RSH="ssh"
 123 fi
 124 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 125
 126 AC_MSG_CHECKING([the group for user "nobody"])
 127 if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 128     NOBODY_GROUP=nobody
 129 elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 130     NOBODY_GROUP=nogroup
 131 else
 132     NOBODY_GROUP=nobody # test for others?
 133 fi
 134 AC_MSG_RESULT($NOBODY_GROUP)
 135 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 136 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 137
 138 # arrgh. libc in some old debian version screwed up the largefile
 139 # stuff, getting byte range locking wrong
 140 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 141 AC_TRY_RUN([
 142 #define _FILE_OFFSET_BITS 64
 143 #include <stdio.h>
 144 #include <fcntl.h>
 145 #include <sys/types.h>
 146 #include <sys/wait.h>
 147
 148 int main(void)
 149 {
 150         struct flock lock;
 151         int status;
 152         char tpl[32] = "/tmp/locktest.XXXXXX";
 153         int fd = mkstemp(tpl);
 154         if (fd < 0) {
 155                 strcpy(tpl, "conftest.dat");
 156                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 157         }
 158
 159         lock.l_type = F_WRLCK;
 160         lock.l_whence = SEEK_SET;
 161         lock.l_start = 0;
 162         lock.l_len = 1;
 163         lock.l_pid = 0;
 164         fcntl(fd,F_SETLK,&lock);
 165         if (fork() == 0) {
 166                 lock.l_start = 1;
 167                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 168         }
 169         wait(&status);
 170         unlink(tpl);
 171         exit(WEXITSTATUS(status));
 172 }
 173 ],
 174 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 175 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 176    AC_SYS_LARGEFILE
 177 fi
 178
 179 ipv6type=unknown
 180 ipv6lib=none
 181 ipv6trylibc=yes
 182
 183 AC_ARG_ENABLE(ipv6,
 184         AC_HELP_STRING([--disable-ipv6],
 185                 [don't even try to use IPv6]))
 186 if test x"$enable_ipv6" != x"no"; then
 187         AC_MSG_CHECKING([ipv6 stack type])
 188         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 189                 case $i in
 190                 inria)
 191                         # http://www.kame.net/
 192                         AC_EGREP_CPP(yes, [
 193 #include <netinet/in.h>
 194 #ifdef IPV6_INRIA_VERSION
 195 yes
 196 #endif],
 197                                 [ipv6type=$i;
 198                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 199                                 ])
 200                         ;;
 201                 kame)
 202                         # http://www.kame.net/
 203                         AC_EGREP_CPP(yes, [
 204 #include <netinet/in.h>
 205 #ifdef __KAME__
 206 yes
 207 #endif],
 208                                 [ipv6type=$i;
 209                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 210                         ;;
 211                 linux-glibc)
 212                         # http://www.v6.linux.or.jp/
 213                         AC_EGREP_CPP(yes, [
 214 #include <features.h>
 215 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 216 yes
 217 #endif],
 218                                 [ipv6type=$i;
 219 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 220                         ;;
 221                 linux-inet6)
 222                         # http://www.v6.linux.or.jp/
 223                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 224                                 ipv6type=$i
 225                                 ipv6lib=inet6
 226                                 ipv6libdir=/usr/inet6/lib
 227                                 ipv6trylibc=yes;
 228                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 229                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 230                         fi
 231                         ;;
 232                 toshiba)
 233                         AC_EGREP_CPP(yes, [
 234 #include <sys/param.h>
 235 #ifdef _TOSHIBA_INET6
 236 yes
 237 #endif],
 238                                 [ipv6type=$i;
 239                                 ipv6lib=inet6;
 240                                 ipv6libdir=/usr/local/v6/lib;
 241                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 242                         ;;
 243                 v6d)
 244                         AC_EGREP_CPP(yes, [
 245 #include </usr/local/v6/include/sys/v6config.h>
 246 #ifdef __V6D__
 247 yes
 248 #endif],
 249                                 [ipv6type=$i;
 250                                 ipv6lib=v6;
 251                                 ipv6libdir=/usr/local/v6/lib;
 252                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 253                         ;;
 254                 zeta)
 255                         AC_EGREP_CPP(yes, [
 256 #include <sys/param.h>
 257 #ifdef _ZETA_MINAMI_INET6
 258 yes
 259 #endif],
 260                                 [ipv6type=$i;
 261                                 ipv6lib=inet6;
 262                                 ipv6libdir=/usr/local/v6/lib;
 263                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 264                         ;;
 265                 esac
 266                 if test "$ipv6type" != "unknown"; then
 267                         break
 268                 fi
 269         done
 270         AC_MSG_RESULT($ipv6type)
 271
 272         AC_SEARCH_LIBS(getaddrinfo, inet6)
 273 fi
 274
 275 dnl Do you want to disable use of locale functions
 276 AC_ARG_ENABLE([locale],
 277         AC_HELP_STRING([--disable-locale],
 278                 [turn off locale features]))
 279 AH_TEMPLATE([CONFIG_LOCALE],
 280 [Undefine if you don't want locale features.  By default this is defined.])
 281 if test x"$enable_locale" != x"no"; then
 282         AC_DEFINE(CONFIG_LOCALE)
 283 fi
 284
 285 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 286 case $host_os in
 287         *cygwin* ) AC_MSG_RESULT(yes)
 288                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 289                             [Define to 1 if sockets need to be shutdown])
 290                    ;;
 291                * ) AC_MSG_RESULT(no);;
 292 esac
 293
 294 AC_C_BIGENDIAN
 295 AC_HEADER_DIRENT
 296 AC_HEADER_TIME
 297 AC_HEADER_SYS_WAIT
 298 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 299     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 300     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 301     sys/un.h glob.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 302     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h)
 303 AC_HEADER_MAJOR
 304
 305 AC_CHECK_SIZEOF(int)
 306 AC_CHECK_SIZEOF(long)
 307 AC_CHECK_SIZEOF(long long)
 308 AC_CHECK_SIZEOF(short)
 309 AC_CHECK_SIZEOF(off_t)
 310 AC_CHECK_SIZEOF(off64_t)
 311
 312 AC_C_INLINE
 313 AC_C_LONG_DOUBLE
 314
 315 AC_TYPE_SIGNAL
 316 AC_TYPE_UID_T
 317 AC_TYPE_MODE_T
 318 AC_TYPE_OFF_T
 319 AC_TYPE_SIZE_T
 320 AC_TYPE_PID_T
 321 AC_TYPE_GETGROUPS
 322 AC_CHECK_MEMBERS([struct stat.st_rdev])
 323
 324 TYPE_SOCKLEN_T
 325
 326 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 327     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 328         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 329 if test x"$rsync_cv_errno" = x"yes"; then
 330    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 331 fi
 332
 333 # The following test taken from the cvs sources
 334 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 335 # These need checks to be before checks for any other functions that
 336 #    might be in the same libraries.
 337 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 338 # libsocket.so which has a bad implementation of gethostbyname (it
 339 # only looks in /etc/hosts), so we only look for -lsocket if we need
 340 # it.
 341 AC_CHECK_FUNCS(connect)
 342 if test x"$ac_cv_func_connect" = x"no"; then
 343     case "$LIBS" in
 344     *-lnsl*) ;;
 345     *) AC_CHECK_LIB(nsl_s, printf) ;;
 346     esac
 347     case "$LIBS" in
 348     *-lnsl*) ;;
 349     *) AC_CHECK_LIB(nsl, printf) ;;
 350     esac
 351     case "$LIBS" in
 352     *-lsocket*) ;;
 353     *) AC_CHECK_LIB(socket, connect) ;;
 354     esac
 355     case "$LIBS" in
 356     *-linet*) ;;
 357     *) AC_CHECK_LIB(inet, connect) ;;
 358     esac
 359     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 360     dnl has been cached.
 361     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 362        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 363         # ac_cv_func_connect=yes
 364         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 365         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 366     fi
 367 fi
 368
 369 AC_SEARCH_LIBS(inet_ntop, resolv)
 370
 371 # Solaris and HP-UX weirdness:
 372 # Search for libiconv_open (not iconv_open) to discover if -liconv is needed!
 373 AC_SEARCH_LIBS(libiconv_open, iconv)
 374
 375 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 376
 377 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
 378 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
 379
 380 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 381 #   builtin getaddrinfo if one of the defines don't exist
 382 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 383                rsync_cv_HAVE_GETADDR_DEFINES,[
 384                         AC_EGREP_CPP(yes, [
 385                         #include <sys/types.h>
 386                         #include <sys/socket.h>
 387                         #include <netdb.h>
 388                         #ifdef AI_PASSIVE
 389                         yes
 390                         #endif],
 391                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 392                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 393 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes"; then
 394         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 395         # something else so we must include <netdb.h> to get the
 396         # redefinition.
 397         AC_CHECK_FUNCS(getaddrinfo, ,
 398                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 399                 AC_TRY_LINK([#include <sys/types.h>
 400                 #include <sys/socket.h>
 401                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 402                         [AC_MSG_RESULT([yes])
 403                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 404                                 [Define to 1 if you have the "getaddrinfo" function.])],
 405                         [AC_MSG_RESULT([no])
 406                         AC_LIBOBJ(lib/getaddrinfo)])])
 407         AC_CHECK_FUNCS(getnameinfo, , [AC_LIBOBJ(lib/getnameinfo)])
 408 else
 409         AC_LIBOBJ(lib/getaddrinfo)
 410         AC_LIBOBJ(lib/getnameinfo)
 411 fi
 412
 413 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 414                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 415                 [],
 416                 [
 417 #include <sys/types.h>
 418 #include <sys/socket.h>
 419 ])
 420
 421 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 422                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 423                 [],
 424                 [
 425 #include <sys/types.h>
 426 #include <sys/socket.h>
 427 #include <netinet/in.h>
 428 ])
 429
 430 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 431                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 432                 [],
 433                 [
 434 #include <sys/types.h>
 435 #include <sys/socket.h>
 436 #include <netinet/in.h>
 437 ])
 438
 439 AC_MSG_CHECKING(struct sockaddr_storage)
 440 AC_TRY_COMPILE([#include <sys/types.h>
 441 #include <sys/socket.h>],
 442 [struct sockaddr_storage x;],
 443         AC_MSG_RESULT(yes)
 444         AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1,
 445                 [Define to 1 if you have struct sockaddr_storage.] ),
 446         AC_MSG_RESULT(no))
 447
 448 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 449                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 450                 [],
 451                 [
 452 #include <sys/types.h>
 453 #include <sys/socket.h>
 454 #include <netinet/in.h>
 455 ])
 456
 457 AC_MSG_CHECKING(struct stat64)
 458 AC_TRY_COMPILE([#include <stdio.h>
 459 #if HAVE_SYS_TYPES_H
 460 # include <sys/types.h>
 461 #endif
 462 #if HAVE_SYS_STAT_H
 463 # include <sys/stat.h>
 464 #endif
 465 #if STDC_HEADERS
 466 # include <stdlib.h>
 467 # include <stddef.h>
 468 #else
 469 # if HAVE_STDLIB_H
 470 #  include <stdlib.h>
 471 # endif
 472 #endif
 473 ],[struct stat64 st;],
 474     AC_MSG_RESULT(yes)
 475         AC_DEFINE(HAVE_STRUCT_STAT64,1,[Define to 1 if you have struct stat64.]),
 476     AC_MSG_RESULT(no))
 477
 478 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 479 #
 480 AC_CHECK_FUNCS(strcasecmp)
 481 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 482     AC_CHECK_LIB(resolv, strcasecmp)
 483 fi
 484
 485 dnl At the moment we don't test for a broken memcmp(), because all we
 486 dnl need to do is test for equality, not comparison, and it seems that
 487 dnl every platform has a memcmp that can do at least that.
 488 dnl AC_FUNC_MEMCMP
 489
 490 AC_FUNC_UTIME_NULL
 491 AC_FUNC_ALLOCA
 492 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 493     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 494     memmove lchown vsnprintf snprintf vasprintf asprintf setsid glob strpbrk \
 495     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 496     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 497     strerror putenv iconv_open locale_charset nl_langinfo \
 498     sigaction sigprocmask)
 499
 500 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 501 if test $ac_cv_func_getpgrp = yes; then
 502     AC_FUNC_GETPGRP
 503 fi
 504
 505 # Determine whether chown follows symlinks (it should).
 506 AC_CACHE_CHECK([whether chown() dereferences symlinks],rsync_cv_chown_follows_symlink,[
 507   AC_TRY_RUN([
 508 #if HAVE_UNISTD_H
 509 # include <unistd.h>
 510 #endif
 511 #include <stdlib.h>
 512 #include <errno.h>
 513     main() {
 514         char const *dangling_symlink = "conftest.dangle";
 515         unlink(dangling_symlink);
 516         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 517         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(0);
 518         exit(1);
 519     }],
 520   rsync_cv_chown_follows_symlink=yes,rsync_cv_chown_follows_symlink=no,rsync_cv_chown_follows_symlink=yes)])
 521 if test $rsync_cv_chown_follows_symlink = no; then
 522   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 523 fi
 524
 525 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 526 AC_TRY_RUN([
 527 #include <sys/types.h>
 528 #include <sys/socket.h>
 529
 530 main() {
 531        int fd[2];
 532        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 533 }],
 534 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 535 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 536     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 537 fi
 538
 539 if test x"$with_included_popt" != x"yes"; then
 540     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 541 fi
 542
 543 AC_MSG_CHECKING([whether to use included libpopt])
 544 if test x"$with_included_popt" = x"yes"; then
 545     AC_MSG_RESULT($srcdir/popt)
 546     BUILD_POPT='$(popt_OBJS)'
 547     CFLAGS="$CFLAGS -I$srcdir/popt"
 548     if test x"$ALLOCA" != x
 549     then
 550         # this can be removed when/if we add an included alloca.c;
 551         #  see autoconf documentation on AC_FUNC_ALLOCA
 552         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 553     fi
 554 else
 555     AC_MSG_RESULT(no)
 556 fi
 557
 558 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 559 AC_TRY_COMPILE([],[signed char *s = ""],
 560 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
 561 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 562     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 563 fi
 564
 565 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 566 AC_TRY_RUN([#include <sys/types.h>
 567 #include <dirent.h>
 568 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 569 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 570 di->d_name[0] == 0) exit(0); exit(1);} ],
 571 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 572 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 573     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 574 fi
 575
 576 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 577 AC_TRY_COMPILE([#include <sys/types.h>
 578 #include <utime.h>],
 579 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 580 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no)])
 581 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 582     AC_DEFINE(HAVE_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 583 fi
 584
 585 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 586 AC_TRY_COMPILE([#include <sys/time.h>
 587 #include <unistd.h>],
 588 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
 589 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
 590 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 591     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 592 fi
 593
 594 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 595 AC_TRY_RUN([
 596 #include <sys/types.h>
 597 #include <stdarg.h>
 598 void foo(const char *format, ...) {
 599        va_list ap;
 600        int len;
 601        char buf[5];
 602
 603        va_start(ap, format);
 604        len = vsnprintf(0, 0, format, ap);
 605        va_end(ap);
 606        if (len != 5) exit(1);
 607
 608        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 609
 610        exit(0);
 611 }
 612 main() { foo("hello"); }
 613 ],
 614 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 615 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 616     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 617 fi
 618
 619
 620 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 621 AC_TRY_RUN([#include <stdlib.h>
 622 #include <sys/types.h>
 623 #include <sys/stat.h>
 624 #include <unistd.h>
 625 main() {
 626   struct stat st;
 627   char tpl[20]="/tmp/test.XXXXXX";
 628   int fd = mkstemp(tpl);
 629   if (fd == -1) exit(1);
 630   unlink(tpl);
 631   if (fstat(fd, &st) != 0) exit(1);
 632   if ((st.st_mode & 0777) != 0600) exit(1);
 633   exit(0);
 634 }],
 635 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 636 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 637 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 638 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 639     case $target_os in
 640     hpux*)
 641         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 642         dnl so we noisily skip using it.  See HP change request JAGaf34426
 643         dnl for details. (sbonds)
 644         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 645         ;;
 646     *)
 647         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 648         ;;
 649     esac
 650 fi
 651
 652
 653 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 654 AC_TRY_RUN([
 655 #include <stdio.h>
 656 #include <sys/types.h>
 657 #include <netinet/in.h>
 658 #include <arpa/inet.h>
 659 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 660 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 661     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); }
 662 exit(0);}],
 663            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
 664 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 665     AC_DEFINE(REPLACE_INET_NTOA, 1, [Define to 1 if inet_ntoa() needs to be replaced])
 666 fi
 667
 668
 669 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
 670 AC_TRY_RUN([
 671 #include <stdio.h>
 672 #include <sys/types.h>
 673 #include <netinet/in.h>
 674 #include <arpa/inet.h>
 675 main() { struct in_addr ip;
 676 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
 677            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
 678 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
 679     AC_DEFINE(REPLACE_INET_ATON, 1, [Define to 1 if inet_aton() needs to be replaced])
 680 fi
 681
 682 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 683 AC_TRY_RUN([
 684 #include <stdio.h>
 685 #include <sys/stat.h>
 686 #include <errno.h>
 687 main() { int rc, ec; char *fn = "fifo-test";
 688 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 689 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 690 return 0;}],
 691            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
 692 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 693     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 694 fi
 695
 696 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 697 AC_TRY_RUN([
 698 #include <stdio.h>
 699 #include <sys/stat.h>
 700 #include <errno.h>
 701 main() { int rc, ec; char *fn = "sock-test";
 702 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 703 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 704 return 0;}],
 705            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
 706 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 707     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 708 fi
 709
 710 #
 711 # The following test was mostly taken from the tcl/tk plus patches
 712 #
 713 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 714 rm -rf conftest*
 715 cat > conftest.$ac_ext <<EOF
 716 int main() { return 0; }
 717 EOF
 718 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 719 if test -f conftest..o; then
 720     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 721 else
 722     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 723 fi
 724 rm -rf conftest*
 725 ])
 726 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 727     OBJ_SAVE="#"
 728     OBJ_RESTORE="#"
 729     CC_SHOBJ_FLAG='-o $@'
 730 else
 731     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 732     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 733     CC_SHOBJ_FLAG=""
 734 fi
 735
 736 AC_SUBST(OBJ_SAVE)
 737 AC_SUBST(OBJ_RESTORE)
 738 AC_SUBST(CC_SHOBJ_FLAG)
 739 AC_SUBST(BUILD_POPT)
 740
 741 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 742 AC_OUTPUT
 743
 744 AC_MSG_RESULT()
 745 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
 746 AC_MSG_RESULT()