configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use `VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9           m4_substr(SIPE_VERSION_DATA,
  10                     [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/tracker/?atid=949931&group_id=194563], [],
  18         SIPE_HOMEPAGE)
  19
  20 dnl setup automake and require recent enough version
  21 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-define tar-ustar])
  22
  23 AC_CANONICAL_HOST
  24
  25 dnl set PACKAGE_URL for autoconf < 2.64
  26 AS_IF([test "x${PACKAGE_URL}" = x],
  27         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  28          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  29 ])
  30
  31 dnl set programming language
  32 AC_LANG(C)
  33 AM_PROG_CC_C_O
  34 AC_HEADER_STDC
  35
  36 dnl setup shared library generation
  37 LT_INIT([disable-static])
  38
  39 dnl checks for tools
  40 IT_PROG_INTLTOOL([0.35.0])
  41 AC_PROG_INSTALL
  42 AC_PROG_RANLIB
  43
  44 dnl ******************************
  45 dnl Win32
  46 dnl ******************************
  47 AC_MSG_CHECKING([for Win32])
  48 AS_CASE(["$host"],
  49                 [*-mingw*], [os_win32=yes],
  50                 [os_win32=no])
  51 AC_MSG_RESULT([$os_win32])
  52 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  53
  54 dnl checks for header files
  55 AC_CHECK_HEADERS([sys/sockio.h])
  56
  57 dnl checks for library functions
  58 AC_CHECK_FUNCS([])
  59
  60 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  61 dnl as that is likely where libpurple will be found if it is not in the default
  62 dnl pkgconfig path
  63 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  64 export PKG_CONFIG_PATH
  65
  66 dnl debug mode
  67 AC_ARG_ENABLE(debug,
  68         [AS_HELP_STRING([--enable-debug],
  69                         [compile with debugging support [default=no]])],
  70         [],
  71         [enable_debug=no])
  72
  73 AS_IF([test "x$enable_debug" = xyes],
  74         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  75 AC_SUBST(DEBUG_CFLAGS)
  76
  77 dnl quality check mode
  78 dnl For people who are interested in finding bugs and not hiding them
  79 AC_ARG_ENABLE(quality-check,
  80         [AS_HELP_STRING([--enable-quality-check],
  81                         [compile with compiler checks enabled [default=yes]])],
  82         [],
  83         [enable_quality_check=yes])
  84
  85 AS_IF([test "x$enable_quality_check" = xyes],
  86         [dnl default quality configuration
  87          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  88
  89          dnl enable warnings supported by the GCC on the build system
  90          for newflag in \
  91                         "-Wextra" \
  92                         "-Waggregate-return" \
  93                         "-Wcast-align" \
  94                         "-Wdeclaration-after-statement" \
  95                         "-Winit-self" \
  96                         "-Wmissing-declarations" \
  97                         "-Wmissing-prototypes" \
  98                         "-Wnested-externs" \
  99                         "-Wpointer-arith" \
 100                         "-Wundef" \
 101          ; do
 102                  ac_save_CFLAGS=$CFLAGS
 103                  AC_MSG_CHECKING([if $CC supports $newflag])
 104                  CFLAGS="$QUALITY_CFLAGS $newflag"
 105                  AC_COMPILE_IFELSE(
 106                         AC_LANG_PROGRAM(),
 107                         [AC_MSG_RESULT(yes)
 108                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 109                         [AC_MSG_RESULT(no)]
 110                  )
 111                  CFLAGS=$ac_save_CFLAGS
 112          done
 113         ])
 114 AC_SUBST(QUALITY_CFLAGS)
 115
 116 dnl Check for pkg-config before using it
 117 PKG_PROG_PKG_CONFIG
 118
 119 dnl build option: with voice & video support (for all backends)
 120 AC_ARG_WITH(vv,
 121         [AC_HELP_STRING([--with-vv],
 122                 [compile with voice and video support @<:@default=check@:>@])],
 123         [AS_IF([test "x$withval" = xyes], [with_vv=check])],
 124         [with_vv=check])
 125
 126 dnl check for Kerberos 5 support
 127 AC_ARG_WITH([krb5],
 128         [AC_HELP_STRING([--with-krb5],
 129                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 130         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 131         [with_krb5=check])
 132
 133 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 134       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 135         [AC_MSG_CHECKING(if Kerberos 5 is available)
 136          AS_IF([AC_RUN_LOG([krb5-config --version])],
 137                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 138                  KRB5_LDFLAGS=""
 139
 140                  dnl same as AC_CHECK_LIB()
 141                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"
 142                  AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5)])],
 143                 [AC_MSG_RESULT(no)
 144                  with_krb5=no])],
 145       [                               dnl path specified by user
 146         KRB5_CFLAGS="-I${with_krb5}/include"
 147         KRB5_LDFLAGS="-L${with_krb5}/lib"
 148         ac_save_LDFLAGS="$LDLAGS"
 149         LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 150         AC_CHECK_LIB(krb5, krb5_rd_req,          [],
 151                 [AC_CHECK_LIB(krb5, krb5_rd_req, [],
 152                         [AC_ERROR(Kerberos 5 libraries not found)])])
 153         AC_CHECK_LIB(gssapi_krb5, gss_krb5_export_lucid_sec_context, [],
 154                         [AC_ERROR(GSSAPI Kerberos 5 libraries not found)])
 155         LDFLAGS="$ac_save_LDFLAGS"])
 156 AM_CONDITIONAL(SIP_SEC_KRB5, [test "x$with_krb5" != xno])
 157 AC_SUBST(KRB5_CFLAGS)
 158 AC_SUBST(KRB5_LDFLAGS)
 159
 160 dnl check for glib
 161 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 162 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 163
 164 dnl check for gmime
 165 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 166 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 167         [ac_have_gmime=yes],
 168         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 169                 [ac_have_gmime=yes],
 170                 [ac_have_gmime=no])
 171 ])
 172 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 173 AS_IF([test "x$ac_have_gmime" = xyes],
 174         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 175
 176 dnl check for NSS
 177 PKG_CHECK_MODULES(NSS, [nss],
 178         [ac_have_nss=yes],
 179         [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 180                 [ac_have_nss=yes],
 181                 [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 182                         [ac_have_nss=yes],
 183                         [ac_have_nss=no])
 184         ])
 185 ])
 186 AM_CONDITIONAL(SIPE_CRYPTO_NSS, [test "x$ac_have_nss" = xyes])
 187 AS_IF([test "x$ac_have_nss" = xyes],
 188         [AC_DEFINE(HAVE_NSS, 1, [Define if nss should be used in sipe.])])
 189
 190 dnl check for libxml2
 191 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 192
 193 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 194 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 195 ac_save_CFLAGS=$CFLAGS
 196 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 197 dnl note the [[[ quoting: our code contains []!
 198 AC_RUN_IFELSE(
 199         AC_LANG_PROGRAM(
 200                 [[[
 201 #include <glib.h>
 202 #include <stdio.h>
 203
 204 /* Copied from uuid.c */
 205 typedef struct {
 206    guint32 time_low;
 207    guint16 time_mid;
 208    guint16 time_hi_and_version;
 209    guint8  clock_seq_hi_and_reserved;
 210    guint8  clock_seq_low;
 211    guint8  node[6];
 212 } uuid_t;
 213                 ]]],
 214                 [if (sizeof(uuid_t) == 16) {
 215                         return(0);
 216                  } else {
 217                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 218                         return(1);
 219                  }]),
 220         [AC_MSG_RESULT(yes)],
 221         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 222
 223 Please notify the SIPE developers.
 224
 225 Copy & paste all lines starting with the line
 226
 227   checking that sizeof(uuid_t) is 16...
 228
 229 to the report and attach the file "config.log".
 230
 231 Compiler information:
 232
 233  host:     $host
 234  build:    $build
 235  compiler: $CC
 236 ])],
 237         [AC_MSG_WARN([cross compiling: not checking])])
 238 CFLAGS=$ac_save_CFLAGS
 239
 240 dnl build option: purple backend
 241 AC_ARG_ENABLE([purple],
 242         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 243         [],
 244         [enable_purple=yes])
 245 with_purple_vv=no
 246 AS_IF([test "x$enable_purple" != xno],
 247         [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 248                 [dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 249                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion purple | cut -d. -f 1`
 250                  AC_SUBST(PURPLE_MAJOR_VERSION)
 251
 252                  dnl let user now if he has a 32- and 64-bit header conflict...
 253                  AC_MSG_CHECKING([for 32- and 64-bit header conflicts])
 254                  ac_save_CFLAGS=$CFLAGS
 255                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 256                  AC_COMPILE_IFELSE(
 257                         AC_LANG_PROGRAM([
 258 #include <glib.h>
 259 #include <cipher.h>
 260
 261 /* Compile some code that has caused trouble in the past */
 262 static void testfunc(unsigned long len)
 263 {
 264   PurpleCipherContext *rc4 = NULL;
 265   guchar *plaintext = NULL;
 266   gsize plaintext_length = 0;
 267   guchar *encrypted_text = NULL;
 268   gsize dummy;
 269   purple_cipher_context_set_option(rc4, "key_len", GUINT_TO_POINTER(len));
 270   purple_cipher_context_encrypt(rc4, plaintext, plaintext_length,
 271                                 encrypted_text, &dummy);
 272 }
 273                                         ],
 274                                         [testfunc(16);]),
 275                         [AC_MSG_RESULT(none)],
 276                         [AC_MSG_FAILURE([conflicts found.
 277
 278 Check that you have the correct glib/libpurple headers installed for
 279 your architecture or set GLIB_CFLAGS/PURPLE_CFLAGS to override the
 280 system defaults.
 281 ])
 282                         ])
 283
 284                  dnl on windows
 285                  dnl test program needs to be in the same location as libpurple
 286                  dnl installation for latter to load ssl plugin referenced by
 287                  dnl RELATIVE path.
 288                  AS_IF([test "x${os_win32}" != xyes],
 289                         [dnl purple SSL support is mandatory
 290                          AC_MSG_CHECKING([for purple SSL support])
 291                          ac_save_LIBS=$LIBS
 292                          LIBS="$PURPLE_LIBS"
 293                          AC_RUN_IFELSE(
 294                                 AC_LANG_PROGRAM([
 295 #include <glib.h>
 296 #include <plugin.h>
 297 #include <sslconn.h>
 298 ],
 299                                                 [
 300         purple_plugins_init();
 301         purple_plugins_probe(G_MODULE_SUFFIX);
 302         purple_ssl_init();
 303         return(purple_ssl_is_supported()?0:1);
 304                                                 ]),
 305                                 [AC_MSG_RESULT(ok)],
 306                                 [AC_MSG_FAILURE([your purple hasn't been compiled with SSL support.
 307 ])
 308                                 ],
 309                                 [AC_MSG_WARN([cross compiling: not checking])])
 310                  ])
 311
 312                  dnl check whether enable voice and video support
 313                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 314                        [test "x$with_vv" = xcheck],  dnl autodetect
 315                          [AC_MSG_CHECKING(for purple voice and video support)
 316                           AC_RUN_IFELSE(
 317                                 AC_LANG_PROGRAM(
 318                                         [[[
 319 #include <libpurple/media.h>
 320                                         ]]],
 321                                         [return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);
 322                                          purple_media_get_active_local_candidates(NULL, NULL, NULL);
 323                                          purple_media_get_active_remote_candidates(NULL, NULL, NULL);]
 324                                 ),
 325                                 [AC_MSG_RESULT(ok)
 326                                  PKG_CHECK_MODULES(NICE, [nice >= 0.0.14],
 327                                         [PKG_CHECK_MODULES(PURPLE_MEDIA, [purple >= 2.7.0],
 328                                                 [PKG_CHECK_MODULES(GSTREAMER, [gstreamer-0.10],
 329                                                         [with_purple_vv=yes],
 330                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 331                                                 [AC_MSG_NOTICE(libpurple >= 2.7.0 required: disabling purple voice and video support)])],
 332                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])],
 333                                 [AC_MSG_RESULT(no - your purple hasn't been compiled with voice and video support.)],
 334                                 [AC_MSG_WARN([cross compiling: not checking])])
 335                          ])
 336                  CFLAGS=$ac_save_CFLAGS
 337                  LIBS=$ac_save_LIBS],
 338                 [enable_purple=no])])
 339 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 340
 341 dnl build option: telepathy backend
 342 AC_ARG_ENABLE([telepathy],
 343         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 344         [],
 345         [enable_telepathy=yes])
 346 AS_IF([test "x$enable_telepathy" != xno],
 347         [PKG_CHECK_MODULES(TELEPATHY, [telepathy-glib],
 348                 [dnl GMIME is a build requirement
 349                  AS_IF([test "x$ac_have_gmime" = xyes],
 350                         [],
 351                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 352
 353                  dnl NSS is a build requirement
 354                  AS_IF([test "x$ac_have_nss" = xyes],
 355                         [],
 356                         [AC_ERROR(NSS package is required for telepathy plugin)])
 357
 358                  dnl NOTHING IMPLEMENTED YET!!!
 359                 ],
 360                 [enable_telepathy=no])])
 361 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 362
 363 dnl build option: kopete backend
 364 AC_ARG_ENABLE([kopete],
 365         [AC_HELP_STRING([--enable-kopete], [build kopete plugin @<:@default=no@:>@])],
 366         [],
 367         [enable_kopete=no])
 368 AS_IF([test "x$enable_kopete" != xno],
 369         [dnl GMIME is a build requirement
 370          AS_IF([test "x$ac_have_gmime" = xyes],
 371                 [],
 372                 [AC_ERROR(GMIME package is required for kopete plugin)])
 373
 374          dnl NSS is a build requirement
 375          AS_IF([test "x$ac_have_nss" = xyes],
 376                 [],
 377                 [AC_ERROR(NSS package is required for kopete plugin)])
 378
 379          dnl NOTHING IMPLEMENTED YET!!!
 380         ],
 381         [enable_kopete=no])
 382 AM_CONDITIONAL(SIPE_INCLUDE_KOPETE, [test "x$enable_kopete" != xno])
 383
 384 dnl sanity check
 385 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno -a "x$enable_kopete" = xno],
 386         [AC_ERROR(at least one plugin must be selected
 387
 388 If you didn't use a --enable option then please check that you have
 389 the headers for the packages "purple" or "telepathy-glib" installed.
 390 )],
 391         [])
 392
 393 dnl enable voice & video support if any backend supports it
 394 AS_IF([test "x$with_purple_vv" != xno],
 395         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 396 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 397
 398 dnl i18n
 399 AC_MSG_CHECKING([locale_CPPFLAGS])
 400 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 401 AC_SUBST([LOCALE_CPPFLAGS])
 402 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 403 AM_GLIB_GNU_GETTEXT
 404 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 405
 406 dnl codeset
 407 AM_LANGINFO_CODESET
 408
 409 dnl substitutions and generated files
 410 AC_CONFIG_HEADERS([config.h])
 411 AC_CONFIG_FILES([
 412         Makefile
 413         pixmaps/Makefile
 414         m4macros/Makefile
 415         po/Makefile.in
 416         pixmaps/16/Makefile
 417         pixmaps/22/Makefile
 418         pixmaps/48/Makefile
 419         pixmaps/scalable/Makefile
 420         src/Makefile
 421         src/core/Makefile
 422         src/api/Makefile
 423         src/purple/Makefile
 424         src/telepathy/Makefile
 425         src/kopete/Makefile
 426         ])
 427
 428 dnl generate files
 429 AC_OUTPUT()
 430
 431 dnl additional info for the user
 432 AS_ECHO()
 433 AS_IF([test "x$enable_purple" = xno],
 434         [AS_ECHO("Not building purple plugin")],
 435         [AS_ECHO("Build purple plugin")
 436          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 437          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 438          AS_IF([test "x$with_purple_vv" = xno],
 439           [AS_ECHO("Voice and video: disabled")],
 440           [AS_ECHO("Voice and video: enabled")])
 441         ])
 442 AS_ECHO()
 443 AS_IF([test "x$enable_telepathy" = xno],
 444         [AS_ECHO("Not building telepathy plugin")],
 445         [AS_ECHO("Build telepathy plugin")
 446          AS_ECHO()
 447          AS_ECHO("NOTHING IMPLEMENTED YET!!!")
 448          AS_ECHO()
 449          AS_ECHO("TELEPATHY_CFLAGS: $TELEPATHY_CFLAGS")
 450          AS_ECHO("TELEPATHY_LIBS  : $TELEPATHY_LIBS")])
 451 AS_ECHO()
 452 AS_IF([test "x$enable_kopete" = xno],
 453         [AS_ECHO("Not building kopete plugin")],
 454         [AS_ECHO("Build kopete plugin")
 455          AS_ECHO()
 456          AS_ECHO("NOTHING IMPLEMENTED YET!!!")
 457          AS_ECHO()])
 458 AS_ECHO()
 459 AS_IF([test "x$with_krb5" = xno],
 460         [AS_ECHO("Not building with Kerberos 5 support")],
 461         [AS_ECHO("Build with Kerberos 5 support")
 462          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 463          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 464 AS_ECHO()
 465 AS_IF([test "x$enable_debug" = xno],
 466         [AS_ECHO("Debugging not enabled")],
 467         [AS_ECHO("Build with debugging enabled")
 468          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 469 AS_ECHO()
 470 AS_IF([test "x$QUALITY_CFLAGS" = x],
 471         [AS_ECHO("Compiler checks disabled")],
 472         [AS_ECHO("Build with compiler checks enabled")
 473          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 474 AS_ECHO()
 475 AS_ECHO("configure complete. Now run 'make'")
 476 AS_ECHO()
 477
 478 dnl The End.