tests/git-wip.t

   1 #!/usr/bin/env perl
   2
   3 #=======================================================================
   4 # git-wip.t
   5 # File ID: 3e1ac1d2-14cc-11e5-810f-000df06acc56
   6 #
   7 # Test suite for git-wip(1).
   8 #
   9 # Character set: UTF-8
  10 # ©opyleft 2015– Øyvind A. Holm <sunny@sunbase.org>
  11 # License: GNU General Public License version 2 or later, see end of
  12 # file for legal stuff.
  13 #=======================================================================
  14
  15 use strict;
  16 use warnings;
  17
  18 BEGIN {
  19     use Test::More qw{no_plan};
  20     # use_ok() goes here
  21 }
  22
  23 use Getopt::Long;
  24
  25 local $| = 1;
  26
  27 our $CMDB = "git-wip";
  28 our $CMD = "../$CMDB";
  29
  30 our %Opt = (
  31
  32     'all' => 0,
  33     'git' => defined($ENV{'GITWIP_GIT'}) ? $ENV{'GITWIP_GIT'} : 'git',
  34     'help' => 0,
  35     'quiet' => 0,
  36     'todo' => 0,
  37     'verbose' => 0,
  38     'version' => 0,
  39
  40 );
  41
  42 our $progname = $0;
  43 $progname =~ s/^.*\/(.*?)$/$1/;
  44 our $VERSION = '0.0.0';
  45
  46 my %descriptions = ();
  47
  48 Getopt::Long::Configure('bundling');
  49 GetOptions(
  50
  51     'all|a' => \$Opt{'all'},
  52     'git|g=s' => \$Opt{'git'},
  53     'help|h' => \$Opt{'help'},
  54     'quiet|q+' => \$Opt{'quiet'},
  55     'todo|t' => \$Opt{'todo'},
  56     'verbose|v+' => \$Opt{'verbose'},
  57     'version' => \$Opt{'version'},
  58
  59 ) || die("$progname: Option error. Use -h for help.\n");
  60
  61 $Opt{'verbose'} -= $Opt{'quiet'};
  62 $Opt{'help'} && usage(0);
  63 if ($Opt{'version'}) {
  64     print_version();
  65     exit(0);
  66 }
  67
  68 exit(main());
  69
  70 sub main {
  71     # {{{
  72     my $Retval = 0;
  73
  74     diag(sprintf('========== Executing %s v%s ==========',
  75                  $progname, $VERSION));
  76
  77     if ($Opt{'todo'} && !$Opt{'all'}) {
  78         goto todo_section;
  79     }
  80
  81 =pod
  82
  83     testcmd("$CMD command", # {{{
  84         <<'END',
  85 [expected stdout]
  86 END
  87         '',
  88         0,
  89         'description',
  90     );
  91
  92     # }}}
  93
  94 =cut
  95
  96     diag('Testing -h (--help) option...');
  97     likecmd("$CMD -h", # {{{
  98         '/  Show this help/i',
  99         '/^$/',
 100         0,
 101         'Option -h prints help screen',
 102     );
 103
 104     # }}}
 105     diag('Testing -v (--verbose) option...');
 106     likecmd("$CMD -h -v", # {{{
 107         '/^\n\S+ \d+\.\d+\.\d+/s',
 108         '/^$/',
 109         0,
 110         'Option -v with -h returns version number and help screen',
 111     );
 112
 113     # }}}
 114     diag('Testing --version option...');
 115     likecmd("$CMD --version", # {{{
 116         '/^\S+ \d+\.\d+\.\d+/',
 117         '/^$/',
 118         0,
 119         'Option --version returns version number',
 120     );
 121
 122     # }}}
 123     # git(1) refuses to commit if user.email or user.name isn't defined,
 124     # so abort if that's how things are.
 125     like(`git config --get user.email`,
 126         qr/./,
 127         'user.email is defined in Git') ||
 128         BAIL_OUT('user.email is not defined in Git');
 129     like(`git config --get user.name`,
 130         qr/./,
 131         'user.name is defined in Git') ||
 132         BAIL_OUT('user.name is not defined in Git');
 133
 134     my $Tmptop = "tmp-git-wip-t-$$-" . substr(rand, 2, 8);
 135     diag("Creating tempdir...");
 136     ok(mkdir($Tmptop), "mkdir [Tmptop]") or
 137         die("$progname: $Tmptop: Cannot create directory: $!\n");
 138     ok(chdir($Tmptop), "chdir [Tmptop]") or
 139         die("$progname: $Tmptop: Cannot chdir: $!\n");
 140
 141     diag("Initialise repository...");
 142     ok(mkdir("repo"), "mkdir repo");
 143     ok(chdir("repo"), "chdir repo") || BAIL_OUT("Cannot chdir repo");
 144     likecmd("$Opt{'git'} init", # {{{
 145         '/.*/',
 146         '/.*/',
 147         0,
 148         'Initialise Git repository',
 149     );
 150
 151     # }}}
 152     likecmd("../../$CMD", # {{{
 153         '/^$/',
 154         '/fatal: ambiguous argument \'HEAD\': ' .
 155             'unknown revision or path not in the working tree\./s',
 156         1,
 157         'master doesn\'t exist yet',
 158     );
 159
 160     # }}}
 161     create_empty_commit("Init");
 162     testcmd("$Opt{'git'} branch", # {{{
 163         "* master\n",
 164         '',
 165         0,
 166         'master is created',
 167     );
 168
 169     # }}}
 170     commit_new_file("file1.txt");
 171     is(commit_log(''), <<END, "Commit log with file1.txt is ok"); # {{{
 172 04c774c04d6f3c4915c535077c24bc00dba82828 Add file1.txt
 173 4b825dc642cb6eb9a060e54bf8d69288fbee4904 Init
 174 END
 175
 176     # }}}
 177     diag("Test without arguments...");
 178     testcmd("../../$CMD", # {{{
 179         "",
 180         "Switched to branch 'wip'\n",
 181         0,
 182         "Command without arguments uses default 'wip' branch",
 183     );
 184
 185     # }}}
 186     testcmd("../../$CMD", # {{{
 187         "",
 188         "Switched to branch 'wip.wip'\n",
 189         0,
 190         "No args again, create wip.wip",
 191     );
 192
 193     # }}}
 194     diag("Test -D option...");
 195     likecmd("../../$CMD -D", # {{{
 196         '/^wip\\nAlready up[ \-]to[ \-]date.*Deleted branch wip\.wip.*$/s',
 197         '/^Switched to branch \'wip\'\\n$/',
 198         0,
 199         "Delete empty branch with -D",
 200     );
 201
 202     # }}}
 203     diag("Test -m option...");
 204     create_and_switch_to_subbranch('add-files', 'wip.add-files');
 205     is(commit_log(''), <<END, "Commit log is unchanged since file1.txt"); # {{{
 206 04c774c04d6f3c4915c535077c24bc00dba82828 Add file1.txt
 207 4b825dc642cb6eb9a060e54bf8d69288fbee4904 Init
 208 END
 209
 210     # }}}
 211     commit_new_file("file2.txt");
 212     commit_new_file("file3.txt");
 213     is(commit_log(''), <<END, "Commit log with file3.txt is ok"); # {{{
 214 5c0f1e77ac82fe0d382b312202a467446d5948f4 Add file3.txt
 215 9ddbad632f192f4edd053709b3aaedc95bd9ac0e Add file2.txt
 216 04c774c04d6f3c4915c535077c24bc00dba82828 Add file1.txt
 217 4b825dc642cb6eb9a060e54bf8d69288fbee4904 Init
 218 END
 219
 220     # }}}
 221     likecmd("../../$CMD -m", # {{{
 222         '/^wip\\nMerge made by .*'
 223         . ' create mode 100644 file2\.txt\\n'
 224         . ' create mode 100644 file3\.txt\\n'
 225         . 'Deleted branch wip\.add-files .*'
 226         . '/s',
 227         '/^Switched to branch \'wip\'\\n$/',
 228         0,
 229         "Merge wip.add-files to parent (wip)",
 230     );
 231
 232     # }}}
 233     is(commit_log(''), <<END, "Commit log after -m is ok"); # {{{
 234 5c0f1e77ac82fe0d382b312202a467446d5948f4 Merge branch 'wip.add-files' into wip
 235 5c0f1e77ac82fe0d382b312202a467446d5948f4 Add file3.txt
 236 9ddbad632f192f4edd053709b3aaedc95bd9ac0e Add file2.txt
 237 04c774c04d6f3c4915c535077c24bc00dba82828 Add file1.txt
 238 4b825dc642cb6eb9a060e54bf8d69288fbee4904 Init
 239 END
 240
 241     # }}}
 242     create_and_switch_to_subbranch('more-files', 'wip.more-files');
 243     commit_new_file("file4.txt");
 244     diag("Test -p option...");
 245     likecmd("../../$CMD -p", # {{{
 246         '/^wip\\n$/',
 247         '/^Switched to branch \'wip\'\\n$/',
 248         0,
 249         "-p option works",
 250     );
 251
 252     # }}}
 253     testcmd("$Opt{'git'} branch", # {{{
 254         <<END,
 255   master
 256 * wip
 257   wip.more-files
 258 END
 259         '',
 260         0,
 261         "Branches after -p looks fine",
 262     );
 263
 264     # }}}
 265     likecmd("echo y | ../../$CMD -p", # {{{
 266         '/^master$/',
 267         '/^git-wip: Type \'y\' \+ Enter to set active branch ' .
 268             'to \'master\' \(git checkout\)\.\.\.' .
 269             'Switched to branch \'master\'$/',
 270         0,
 271         'If -p option and no parent, checkout master',
 272     );
 273
 274     # }}}
 275     testcmd("$Opt{'git'} branch", # {{{
 276         <<END,
 277 * master
 278   wip
 279   wip.more-files
 280 END
 281         '',
 282         0,
 283         "Check current branch status after -p to master",
 284     );
 285
 286     # }}}
 287     likecmd("../../$CMD", # {{{
 288         '/^$/',
 289         '/^fatal: [Aa] branch named \'wip\' already exists\.?\n$/',
 290         1,
 291         "wip branch already exists",
 292     );
 293
 294     # }}}
 295     testcmd("$Opt{'git'} branch", # {{{
 296         <<END,
 297 * master
 298   wip
 299   wip.more-files
 300 END
 301         '',
 302         0,
 303         "We're still on master because \"wip\" already exists",
 304     );
 305
 306     # }}}
 307     likecmd("$Opt{'git'} checkout wip.more-files", # {{{
 308         '/^$/',
 309         '/^Switched to branch \'wip\.more-files\'\\n$/',
 310         0,
 311         "Go back to wip.more-files",
 312     );
 313
 314     # }}}
 315     commit_new_file("file5.txt");
 316     is(commit_log(''), <<END, "Commit log with file5.txt is ok"); # {{{
 317 375860ebe00ccc64321c2ade0c1525e7428458fa Add file5.txt
 318 6c4c1a3c2c479e74e02394040d6da63046c1458c Add file4.txt
 319 5c0f1e77ac82fe0d382b312202a467446d5948f4 Merge branch 'wip.add-files' into wip
 320 5c0f1e77ac82fe0d382b312202a467446d5948f4 Add file3.txt
 321 9ddbad632f192f4edd053709b3aaedc95bd9ac0e Add file2.txt
 322 04c774c04d6f3c4915c535077c24bc00dba82828 Add file1.txt
 323 4b825dc642cb6eb9a060e54bf8d69288fbee4904 Init
 324 END
 325
 326     # }}}
 327     diag("Testing -s option...");
 328     likecmd("../../$CMD -s", # {{{
 329         '/^wip\\nUpdating [0-9a-f]+\.\.[0-9a-f]+\\n' .
 330         'Fast(-| )forward\\n' .
 331         'Squash commit -- not updating HEAD\\n' .
 332         '.*' .
 333         ' create mode 100644 file4\.txt\\n' .
 334         ' create mode 100644 file5\.txt\\n' .
 335         '/s',
 336         '/^Switched to branch \'wip\'\\n$/',
 337         0,
 338         "Squash wip.more-files to parent with -s",
 339     );
 340
 341     # }}}
 342     is(commit_log(''), <<END, "Commit log after squash (-s) is ok"); # {{{
 343 5c0f1e77ac82fe0d382b312202a467446d5948f4 Merge branch 'wip.add-files' into wip
 344 5c0f1e77ac82fe0d382b312202a467446d5948f4 Add file3.txt
 345 9ddbad632f192f4edd053709b3aaedc95bd9ac0e Add file2.txt
 346 04c774c04d6f3c4915c535077c24bc00dba82828 Add file1.txt
 347 4b825dc642cb6eb9a060e54bf8d69288fbee4904 Init
 348 END
 349
 350     # }}}
 351     likecmd("$Opt{'git'} commit -m 'Squash wip.more-files into wip'", # {{{
 352         '/^\[wip [0-9a-f]+\] Squash wip\.more-files into wip\\n' .
 353         ' 2 files changed, 2 insertions\(\+\)(, 0 deletions\(-\))?\\n' .
 354         ' create mode 100644 file4\.txt\\n' .
 355         ' create mode 100644 file5\.txt\\n$' .
 356         '/s',
 357         '/^$/',
 358         0,
 359         "Commit squashed changes",
 360     );
 361
 362     # }}}
 363     is(commit_log(''), <<END, "Commit log after squash commit is ok"); # {{{
 364 375860ebe00ccc64321c2ade0c1525e7428458fa Squash wip.more-files into wip
 365 5c0f1e77ac82fe0d382b312202a467446d5948f4 Merge branch 'wip.add-files' into wip
 366 5c0f1e77ac82fe0d382b312202a467446d5948f4 Add file3.txt
 367 9ddbad632f192f4edd053709b3aaedc95bd9ac0e Add file2.txt
 368 04c774c04d6f3c4915c535077c24bc00dba82828 Add file1.txt
 369 4b825dc642cb6eb9a060e54bf8d69288fbee4904 Init
 370 END
 371
 372     # }}}
 373     likecmd("echo y | ../../$CMD -m", # {{{
 374         '/^master\\n'
 375         . 'Merge made by .*'
 376         . ' create mode 100644 file2\.txt\\n'
 377         . ' create mode 100644 file3\.txt\\n'
 378         . ' create mode 100644 file4\.txt\\n'
 379         . ' create mode 100644 file5\.txt\\n'
 380         . 'Deleted branch wip \(was [0-9a-f]+\)\.\\n$'
 381         . '/s',
 382         '/^git-wip: Type \'y\' \+ Enter to merge wip to master\.\.\.' .
 383             'Switched to branch \'master\'\\n$/',
 384         0,
 385         "Merge wip to master with -m",
 386     );
 387
 388     # }}}
 389     is(commit_log(''), <<END, "Commit log after -m"); # {{{
 390 375860ebe00ccc64321c2ade0c1525e7428458fa Merge branch 'wip'
 391 375860ebe00ccc64321c2ade0c1525e7428458fa Squash wip.more-files into wip
 392 5c0f1e77ac82fe0d382b312202a467446d5948f4 Merge branch 'wip.add-files' into wip
 393 5c0f1e77ac82fe0d382b312202a467446d5948f4 Add file3.txt
 394 9ddbad632f192f4edd053709b3aaedc95bd9ac0e Add file2.txt
 395 04c774c04d6f3c4915c535077c24bc00dba82828 Add file1.txt
 396 4b825dc642cb6eb9a060e54bf8d69288fbee4904 Init
 397 END
 398
 399     # }}}
 400     likecmd("echo y | ../../$CMD -m", # {{{
 401         '/^$/',
 402         '/^Is already on master, nowhere to merge branch\\n$/',
 403         1,
 404         "Option -m on master doesn't work",
 405     );
 406
 407     # }}}
 408     likecmd("echo y | ../../$CMD -s", # {{{
 409         '/^$/',
 410         '/^Is already on master, nowhere to squash branch\\n$/',
 411         1,
 412         "Neither does -s",
 413     );
 414
 415     # }}}
 416     diag("Test for unknown options...");
 417     likecmd("../../$CMD -W", # {{{
 418         '/^$/',
 419         '/^git-wip: -W: Unknown option\\n$/',
 420         1,
 421         "It doesn't recognise -W",
 422     );
 423
 424     # }}}
 425     likecmd("../../$CMD -e", # {{{
 426         '/^$/',
 427         '/^git-wip: -e: Unknown option\\n$/',
 428         1,
 429         "It doesn't recognise -e (used by echo)",
 430     );
 431
 432     # }}}
 433     diag("Cleaning up temp files...");
 434     ok(chdir(".."), "chdir .."); # From $Tmptop/repo/
 435     likecmd("rm -rf repo", # {{{
 436         '/^$/',
 437         '/^$/',
 438         0,
 439         'Delete repo/',
 440     );
 441
 442     # }}}
 443     ok(chdir(".."), "chdir .."); # From $Tmptop/
 444
 445     ok(-d $Tmptop, "[Tmptop] exists");
 446     ok(rmdir($Tmptop), "rmdir([Tmptop])");
 447     ok(!-e $Tmptop, "Tempdir is gone");
 448
 449     todo_section:
 450     ;
 451
 452     if ($Opt{'all'} || $Opt{'todo'}) {
 453         diag('Running TODO tests...'); # {{{
 454
 455         TODO: {
 456
 457             local $TODO = '';
 458             # Insert TODO tests here.
 459
 460         }
 461         # TODO tests }}}
 462     }
 463
 464     diag('Testing finished.');
 465     return $Retval;
 466     # }}}
 467 } # main()
 468
 469 sub create_and_switch_to_subbranch {
 470     # {{{
 471     my ($branch, $exp_branch) = @_;
 472     testcmd("../../$CMD $branch",
 473         "",
 474         "Switched to branch '$exp_branch'\n",
 475         0,
 476         "Create subbranch '$branch' and checkout '$exp_branch'",
 477     );
 478     return;
 479     # }}}
 480 } # create_and_switch_to_subbranch()
 481
 482 sub commit_log {
 483     # {{{
 484     my $ref = shift;
 485     my $retval = '';
 486     open(my $pipefp, "$Opt{'git'} log --format='%T %s' --topo-order $ref |") or
 487         return("'$Opt{'git'} log' pipe error: $!\n");
 488     while (<$pipefp>) {
 489         $retval .= $_;
 490     }
 491     close($pipefp);
 492     return($retval);
 493     # }}}
 494 } # commit_log()
 495
 496 sub commit_new_file {
 497     # {{{
 498     my $file = shift;
 499     ok(!-e $file, "$file doesn't exist");
 500     ok(open(my $outfp, ">$file"), "Create file '$file'");
 501     ok(print($outfp "This is $file\n"), "Add content to $file");
 502     ok(close($outfp), "Close $file");
 503     ok(-f $file, "$file exists and is a regular file");
 504     is(file_data($file), "This is $file\n", "Contents of $file is ok");
 505     testcmd("$Opt{'git'} add \"$file\"",
 506         '',
 507         '',
 508         0,
 509         "$Opt{'git'} add $file",
 510     );
 511     likecmd("$Opt{'git'} commit -m \"Add $file\"",
 512         "/.* Add $file.*/s",
 513         '/^$/',
 514         0,
 515         "$Opt{'git'} commit (add $file)",
 516     );
 517     # }}}
 518 } # commit_new_file()
 519
 520 sub create_empty_commit {
 521     # {{{
 522     my $msg = shift;
 523     likecmd("$Opt{'git'} commit --allow-empty -m \"$msg\"",
 524         '/.*/', '/.*/', 0, "Create empty commit");
 525     return;
 526     # }}}
 527 } # create_empty_commit()
 528
 529 sub testcmd {
 530     # {{{
 531     my ($Cmd, $Exp_stdout, $Exp_stderr, $Exp_retval, $Desc) = @_;
 532     defined($descriptions{$Desc}) &&
 533         BAIL_OUT("testcmd(): '$Desc' description is used twice");
 534     $descriptions{$Desc} = 1;
 535     my $stderr_cmd = '';
 536     my $cmd_outp_str = $Opt{'verbose'} >= 1 ? "\"$Cmd\" - " : '';
 537     my $Txt = join('', $cmd_outp_str, defined($Desc) ? $Desc : '');
 538     my $TMP_STDERR = "$CMDB-stderr.tmp";
 539     my $retval = 1;
 540
 541     if (defined($Exp_stderr)) {
 542         $stderr_cmd = " 2>$TMP_STDERR";
 543     }
 544     $retval &= is(`$Cmd$stderr_cmd`, $Exp_stdout, "$Txt (stdout)");
 545     my $ret_val = $?;
 546     if (defined($Exp_stderr)) {
 547         $retval &= is(file_data($TMP_STDERR), $Exp_stderr, "$Txt (stderr)");
 548         unlink($TMP_STDERR);
 549     } else {
 550         diag("Warning: stderr not defined for '$Txt'");
 551     }
 552     $retval &= is($ret_val >> 8, $Exp_retval, "$Txt (retval)");
 553
 554     return $retval;
 555     # }}}
 556 } # testcmd()
 557
 558 sub likecmd {
 559     # {{{
 560     my ($Cmd, $Exp_stdout, $Exp_stderr, $Exp_retval, $Desc) = @_;
 561     defined($descriptions{$Desc}) &&
 562         BAIL_OUT("likecmd(): '$Desc' description is used twice");
 563     $descriptions{$Desc} = 1;
 564     my $stderr_cmd = '';
 565     my $cmd_outp_str = $Opt{'verbose'} >= 1 ? "\"$Cmd\" - " : '';
 566     my $Txt = join('', $cmd_outp_str, defined($Desc) ? $Desc : '');
 567     my $TMP_STDERR = "$CMDB-stderr.tmp";
 568     my $retval = 1;
 569
 570     if (defined($Exp_stderr)) {
 571         $stderr_cmd = " 2>$TMP_STDERR";
 572     }
 573     $retval &= like(`$Cmd$stderr_cmd`, $Exp_stdout, "$Txt (stdout)");
 574     my $ret_val = $?;
 575     if (defined($Exp_stderr)) {
 576         $retval &= like(file_data($TMP_STDERR), $Exp_stderr, "$Txt (stderr)");
 577         unlink($TMP_STDERR);
 578     } else {
 579         diag("Warning: stderr not defined for '$Txt'");
 580     }
 581     $retval &= is($ret_val >> 8, $Exp_retval, "$Txt (retval)");
 582
 583     return $retval;
 584     # }}}
 585 } # likecmd()
 586
 587 sub file_data {
 588     # Return file content as a string {{{
 589     my $File = shift;
 590     my $Txt;
 591
 592     open(my $fp, '<', $File) or return undef;
 593     local $/ = undef;
 594     $Txt = <$fp>;
 595     close($fp);
 596     return $Txt;
 597     # }}}
 598 } # file_data()
 599
 600 sub print_version {
 601     # Print program version {{{
 602     print("$progname $VERSION\n");
 603     return;
 604     # }}}
 605 } # print_version()
 606
 607 sub usage {
 608     # Send the help message to stdout {{{
 609     my $Retval = shift;
 610
 611     if ($Opt{'verbose'}) {
 612         print("\n");
 613         print_version();
 614     }
 615     print(<<"END");
 616
 617 Usage: $progname [options]
 618
 619 Contains tests for the $CMDB(1) program.
 620
 621 Options:
 622
 623   -a, --all
 624     Run all tests, also TODOs.
 625   -g X, --git X
 626     Specify alternative git executable to use. Used to execute the tests
 627     with different git versions. This can also be set with the GITWIP_GIT
 628     environment variable.
 629   -h, --help
 630     Show this help.
 631   -q, --quiet
 632     Be more quiet. Can be repeated to increase silence.
 633   -t, --todo
 634     Run only the TODO tests.
 635   -v, --verbose
 636     Increase level of verbosity. Can be repeated.
 637   --version
 638     Print version information.
 639
 640 END
 641     exit($Retval);
 642     # }}}
 643 } # usage()
 644
 645 sub msg {
 646     # Print a status message to stderr based on verbosity level {{{
 647     my ($verbose_level, $Txt) = @_;
 648
 649     $verbose_level > $Opt{'verbose'} && return;
 650     print(STDERR "$progname: $Txt\n");
 651     return;
 652     # }}}
 653 } # msg()
 654
 655 __END__
 656
 657 # This program is free software; you can redistribute it and/or modify
 658 # it under the terms of the GNU General Public License as published by
 659 # the Free Software Foundation; either version 2 of the License, or (at
 660 # your option) any later version.
 661 #
 662 # This program is distributed in the hope that it will be useful, but
 663 # WITHOUT ANY WARRANTY; without even the implied warranty of
 664 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
 665 # See the GNU General Public License for more details.
 666 #
 667 # You should have received a copy of the GNU General Public License
 668 # along with this program.
 669 # If not, see L<http://www.gnu.org/licenses/>.
 670
 671 # vim: set fenc=UTF-8 ft=perl fdm=marker ts=4 sw=4 sts=4 et fo+=w :