server/scsynth/CMakeLists.txt

   1 find_package(Sndfile)
   2 if (WIN32)
   3         find_package(Portaudio)
   4 endif()
   5
   6 # here we choose who provides us with the FFT lib
   7 if (FFT_GREEN)
   8         add_definitions("-DSC_FFT_GREEN")
   9 elseif (APPLE)
  10         add_definitions("-DSC_FFT_VDSP")
  11 else()
  12         find_package(FFTW3f)
  13
  14         if (FFTW3F_FOUND)
  15                 add_definitions("-DSC_FFT_FFTW")
  16         else()
  17                 message(SEND_ERROR "Cannot find libfftw3f")
  18         endif()
  19 endif()
  20
  21
  22 if (NO_AVAHI)
  23
  24 elseif (APPLE)
  25         add_definitions(-DUSE_RENDEZVOUS=1)
  26 else()
  27         find_package(Avahi)
  28         if (AVAHI_FOUND)
  29                 add_definitions(-DUSE_RENDEZVOUS=1)
  30         endif()
  31 endif()
  32
  33 # Here we work out which audio API to use, from system type and/or user option.
  34 string(TOLOWER "$ENV{AUDIOAPI}" AUDIOAPI)
  35 if(AUDIOAPI STREQUAL "")
  36         if(APPLE)
  37                 set(AUDIOAPI coreaudio)
  38         elseif(WIN32)
  39                 set(AUDIOAPI portaudio)
  40         else()
  41                 set(AUDIOAPI jack)
  42         endif(APPLE)
  43 endif()
  44
  45 if(NOT AUDIOAPI MATCHES "^(jack|coreaudio|portaudio)$")
  46         message(WARNING "Unrecognised audio API: ${AUDIOAPI}")
  47 endif()
  48
  49 if(AUDIOAPI STREQUAL jack)
  50         find_package(Jack)
  51         if(NOT JACK_FOUND)
  52                 message(FATAL_ERROR "Jack selected as audio API, but development files not found")
  53         endif()
  54 elseif(AUDIOAPI STREQUAL portaudio)
  55         find_package(Portaudio)
  56         if(NOT PORTAUDIO_FOUND)
  57                 message(FATAL_ERROR "Portaudio selected as audio API, but development files not found")
  58         endif()
  59 endif()
  60 message(STATUS "Audio API: ${AUDIOAPI}")
  61
  62 set(scsynth_sources
  63         Samp.cpp
  64         SC_BufGen.cpp
  65         SC_Carbon.cpp
  66
  67         SC_ComPort.cpp
  68         SC_CoreAudio.cpp
  69         SC_Errors.cpp
  70         SC_Graph.cpp
  71         SC_GraphDef.cpp
  72         SC_Group.cpp
  73         SC_Lib_Cintf.cpp
  74         SC_Lib.cpp
  75         SC_MiscCmds.cpp
  76         SC_Node.cpp
  77         SC_Rate.cpp
  78         SC_SequencedCommand.cpp
  79         SC_Str4.cpp
  80         SC_Unit.cpp
  81         SC_UnitDef.cpp
  82         SC_World.cpp
  83         Rendezvous.cpp
  84
  85         ${CMAKE_SOURCE_DIR}/common/SC_fftlib.cpp
  86         ${CMAKE_SOURCE_DIR}/common/SC_AllocPool.cpp
  87         ${CMAKE_SOURCE_DIR}/common/SC_DirUtils.cpp
  88         ${CMAKE_SOURCE_DIR}/common/SC_Sem.cpp
  89         ${CMAKE_SOURCE_DIR}/common/SC_StandAloneInfo_Darwin.cpp
  90         ${CMAKE_SOURCE_DIR}/common/SC_StringBuffer.cpp
  91         ${CMAKE_SOURCE_DIR}/common/SC_StringParser.cpp
  92         ${CMAKE_SOURCE_DIR}/common/scsynthsend.cpp
  93         ${CMAKE_SOURCE_DIR}/common/sc_popen.cpp
  94
  95         ${CMAKE_SOURCE_DIR}/external_libraries/TLSF-2.4.6/src/tlsf.c
  96 )
  97
  98 if(WIN32)
  99     list(APPEND scsynth_sources ${CMAKE_SOURCE_DIR}/common/SC_Win32Utils.cpp)
 100 endif()
 101
 102 if (FFT_GREEN)
 103         list(APPEND scsynth_sources ../../common/fftlib.c)
 104 endif()
 105
 106 if (FFTW3F_FOUND)
 107         include_directories (${FFTW3F_INCLUDE_DIR})
 108 endif()
 109
 110
 111 include_directories(${CMAKE_SOURCE_DIR}/include/common
 112                     ${CMAKE_SOURCE_DIR}/common
 113                     ${CMAKE_SOURCE_DIR}/include/server
 114                     ${CMAKE_SOURCE_DIR}/include/plugin_interface)
 115
 116 include_directories (${CMAKE_SOURCE_DIR}/external_libraries/TLSF-2.4.6/src)
 117
 118 set_property(DIRECTORY
 119              APPEND
 120              PROPERTY COMPILE_DEFINITIONS SC_MEMORY_ALIGNMENT=32)
 121
 122 if (AUDIOAPI STREQUAL jack)
 123         list(APPEND scsynth_sources SC_Jack.cpp)
 124         add_definitions("-DSC_AUDIO_API=SC_AUDIO_API_JACK" ${JACK_DEFINITIONS})
 125         include_directories(${JACK_INCLUDE_DIRS})
 126 elseif (AUDIOAPI STREQUAL portaudio)
 127         add_definitions("-DSC_AUDIO_API=SC_AUDIO_API_PORTAUDIO" ${PORTAUDIO_DEFINITIONS})
 128         include_directories(${PORTAUDIO_INCLUDE_DIRS})
 129 endif()
 130
 131 set (FINAL_BUILD 0) # disable final build for scsynth
 132
 133 if (FINAL_BUILD)
 134         CREATE_FINAL_FILE(libscsynth_final.cpp ${scsynth_sources})
 135         add_library(libscsynth SHARED libscsynth_final.cpp)
 136 else()
 137         add_library(libscsynth SHARED ${scsynth_sources})
 138 endif()
 139
 140 set_property(TARGET libscsynth
 141         APPEND
 142         PROPERTY COMPILE_DEFINITIONS BUILDING_SUPERCOLLIDER)
 143
 144 find_library(DL NAMES dl)
 145 if (DL)
 146     target_link_libraries(libscsynth ${DL})
 147 endif()
 148
 149 if(AVAHI_FOUND)
 150         add_definitions("-DHAVE_AVAHI=1")
 151         include_directories(${AVAHI_INCLUDE_DIRS})
 152         target_link_libraries(libscsynth ${AVAHI_LIBRARIES})
 153 endif()
 154
 155 if(SNDFILE_FOUND)
 156         include_directories(${SNDFILE_INCLUDE_DIR})
 157         target_link_libraries(libscsynth ${SNDFILE_LIBRARIES})
 158 elseif(NOT NO_LIBSNDFILE)
 159         message(SEND_ERROR "Cannot find libsndfile")
 160 endif(SNDFILE_FOUND)
 161
 162 if(CMAKE_SYSTEM_NAME MATCHES "Linux")
 163         add_definitions(-DSC_PLUGIN_DIR="${CMAKE_INSTALL_PREFIX}/lib/SuperCollider/plugins")
 164 endif()
 165
 166 if (AUDIOAPI STREQUAL jack)
 167         target_link_libraries(libscsynth ${JACK_LIBRARIES})
 168 elseif(AUDIOAPI STREQUAL portaudio)
 169         target_link_libraries(libscsynth ${PORTAUDIO_LIBRARIES})
 170 elseif(AUDIOAPI STREQUAL coreaudio)
 171         target_link_libraries(libscsynth "-framework CoreAudio")
 172 endif()
 173
 174 if(PTHREADS_FOUND)
 175         target_link_libraries(libscsynth ${PTHREADS_LIBRARIES})
 176 endif()
 177
 178
 179 if (WIN32)
 180         target_link_libraries(libscsynth wsock32 ws2_32)
 181 endif()
 182
 183
 184 set_property(TARGET libscsynth PROPERTY OUTPUT_NAME scsynth)
 185 # These two properties are ABI version info, not sc version:
 186 set_property(TARGET libscsynth PROPERTY VERSION     1.0.0)
 187 set_property(TARGET libscsynth PROPERTY SOVERSION   1)
 188
 189
 190 if (FFTW3F_FOUND)
 191         target_link_libraries(libscsynth ${FFTW3F_LIBRARY})
 192 endif()
 193
 194 if (APPLE)
 195         target_link_libraries(libscsynth "-framework vecLib -framework CoreServices")
 196 endif()
 197
 198 add_executable(scsynth scsynth_main.cpp)
 199 target_link_libraries(scsynth libscsynth ${PTHREADS_LIBRARY})
 200
 201 if(LTO)
 202     set_property(TARGET scsynth libscsynth
 203                  APPEND PROPERTY COMPILE_FLAGS "-flto -flto-report")
 204
 205     set_property(TARGET scsynth libscsynth
 206                  APPEND PROPERTY LINK_FLAGS "-flto -flto-report -fwhole-program")
 207 endif()
 208
 209 #TODO allow apple users to install to fhs-ish path if INSTALL_FHS option is enabled
 210
 211 if(APPLE)
 212         # determines the app name and app install location (scappbundlename, scappdir):
 213         include (${CMAKE_SOURCE_DIR}/cmake_modules/MacAppFolder.cmake)
 214
 215         install(TARGETS libscsynth scsynth
 216                         DESTINATION ${scappauxresourcesdir}
 217                         RUNTIME DESTINATION ${scappauxresourcesdir}
 218                         PERMISSIONS OWNER_READ OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE OWNER_WRITE
 219                         COMPONENT app)
 220 elseif(WIN32)
 221         install(TARGETS libscsynth scsynth
 222                         DESTINATION "SuperCollider"
 223                         PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 224 else()
 225         install(TARGETS libscsynth scsynth
 226                         LIBRARY DESTINATION "lib"
 227                         RUNTIME DESTINATION "bin"
 228                         PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 229 endif()